AutoIt Français

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#include <GDIPlus.au3>
Opt("GUIOnEventMode", 1)

$autoitlogo = @tempdir & "\autoit_logo.png"
InetGet("http://affz.free.fr/autoit/autoit_logo.png", $autoitlogo)

Global Const $AC_SRC_ALPHA  = 1
Global $aSP, $gui[2][2]
_GDIPlus_Startup()

For $i = 0 to 1
$gui[$i][0] = _CreateGui($i, $autoitlogo)
Next

While 1
 Sleep(10)
Wend

;==========================================
Func _CreateGui($n, $img)
Local $hImage = _GDIPlus_ImageLoadFromFile($img)
Local $gui0 =GuiCreate("", 257, 92, @desktopwidth/4+267*$n, 110, $WS_POPUP, $WS_EX_LAYERED)
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, "_GereMoiCeTruc")
GUISetOnEvent($GUI_EVENT_SECONDARYUP, "_Exit")
SetBitMap($gui0, $hImage, 255)
GuiSetState()
_GDIPlus_ImageDispose($hImage)
Return $gui0
EndFunc


Func _Events()
Switch @GUI_WinHandle
        Case $gui[0][0]
            Msgbox(0,"", "cliqué 1")
        Case $gui[1][0]
            Msgbox(0,"", "cliqué 2")
EndSwitch
EndFunc

Func _GereMoiCeTruc()
If _IsPressed("01") Then
    $aSP = MouseGetPos()
    For $i = 0 to 1
    $posall = WinGetPos($gui[$i][0])
    $gui[$i][1] = $posall[0]
    Next
    Do
        $aMP = MouseGetPos()
        $dif = $aMP[0] - $aSP[0]
    For $i = 0 to 1
        WinMove($gui[$i][0], "", $gui[$i][1]+$dif, 110)
    Next
    Until Not _IsPressed("01")
    $aNP = MouseGetPos()
    If $aNP[0] = $aSP[0] Then _Events()
EndIf
EndFunc

Func _Exit()
_GDIPlus_Shutdown()
  Exit
EndFunc


Func SetBitmap($hGUI, $hImage, $iOpacity)
  Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend
  $hScrDC  = _WinAPI_GetDC(0)
  $hMemDC  = _WinAPI_CreateCompatibleDC($hScrDC)
  $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
  $hOld    = _WinAPI_SelectObject($hMemDC, $hBitmap)
  $tSize   = DllStructCreate($tagSIZE)
  $pSize   = DllStructGetPtr($tSize  )
  DllStructSetData($tSize, "X", _GDIPlus_ImageGetWidth ($hImage))
  DllStructSetData($tSize, "Y", _GDIPlus_ImageGetHeight($hImage))
  $tSource = DllStructCreate($tagPOINT)
  $pSource = DllStructGetPtr($tSource)
  $tBlend  = DllStructCreate($tagBLENDFUNCTION)
  $pBlend  = DllStructGetPtr($tBlend)
  DllStructSetData($tBlend, "Alpha" , $iOpacity    )
  DllStructSetData($tBlend, "Format", $AC_SRC_ALPHA)
  _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
  _WinAPI_ReleaseDC   (0, $hScrDC)
  _WinAPI_SelectObject($hMemDC, $hOld)
  _WinAPI_DeleteObject($hBitmap)
  _WinAPI_DeleteDC    ($hMemDC)
EndFunc
 

Code : Tout sélectionner

#Include <GUIConstantsEx.au3>
#Include <Icons.au3>
Opt("GUIOnEventMode", 1)

$autoitlogo = @tempdir & "\autoit_logo.png"
InetGet("http://affz.free.fr/autoit/autoit_logo.png", $autoitlogo)

$img = "c:\Program Files\AutoIt3\Examples\GUI\Torus.png"
$fond = "c:\Program Files\AutoIt3\Examples\GUI\msoobe.jpg"

$gui = GUICreate("test", 700, 400, 300, 100, $WS_POPUP, $WS_EX_LAYERED)
GUISetOnEvent($GUI_EVENT_SECONDARYUP, "_Exit")
GUICtrlCreatePic($fond, 0, 0, 700, 400)
GUICtrlSetState(-1, $GUI_DISABLE)
$Pic1 = GUICtrlCreatePic('', 10, 10, 257, 92)
GUICtrlSetOnEvent(-1, "_Events")
$Pic2 = GUICtrlCreatePic('', 406, 10, 193, 184)
GUICtrlSetOnEvent(-1, "_Events")
GUISetState()

_SetImage($Pic1, $autoitlogo)
_SetImage($Pic2, $img)

While 1
 Sleep(10)
Wend
        

;===========================
Func _Exit()
  Exit
EndFunc

Func _Events()
Switch @GUI_CtrlId
        Case $Pic1
            Msgbox(0,"", "cliqué 1")
        Case $Pic2
            Msgbox(0,"", "cliqué 2")
EndSwitch
EndFunc
 

Code : Tout sélectionner

#include <GDIPlus.au3>
#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>

_GDIPlus_Startup()

$autoitlogo = @tempdir & "\autoit_logo.png"
InetGet("http://affz.free.fr/autoit/autoit_logo.png", $autoitlogo)
$img = "c:\Program Files\AutoIt3\Examples\GUI\Torus.png"

$gui = _GUICreate_Alpha("gui_fond", $img)
$handle = WinGetHandle("gui_fond")
GUISetState()

$gui1 = GUICreate("cont", 400, 400, 0, 0, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_MDICHILD), $handle)
$exit = GUICtrlCreateButton("Exit", 100, 100, 50, 30)
GUISetBkColor(0xABCDEF)
_WinAPI_SetLayeredWindowAttributes($gui1, 0xABCDEF, 255)
GUISetState()

$gui2 = GUICreate("test2", 100, 100, -1, -1, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_MDICHILD), $handle)
$hImage = _GDIPlus_ImageLoadFromFile($autoitlogo)
SetBitMap($gui2, $hImage, 255)
GUISetState()

GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")

While 1
$msg = GUIGetMsg()
Select
  Case $msg = $exit
   _GDIPlus_Shutdown()
   Exit
EndSelect
WEnd

;=====================================================================

Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
    If ($hwnd = $handle) And ($iMsg = $WM_NCHITTEST) Then Return $HTCAPTION
EndFunc

Func _GUICreate_Alpha($sTitle, $sPath, $iX=-1, $iY=-1, $iOpacity=255)
    Local $hGUI, $hImage, $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend
    $hImage = _GDIPlus_ImageLoadFromFile($sPath)
    $width = _GDIPlus_ImageGetWidth($hImage)
    $height = _GDIPlus_ImageGetHeight($hImage)
    $hGUI = GUICreate($sTitle, $width, $height, $iX, $iY, $WS_POPUP, $WS_EX_LAYERED)
    
    $hScrDC = _WinAPI_GetDC(0)
    $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
    $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)
    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, "X", $width)
    DllStructSetData($tSize, "Y", $height)
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, "Alpha", $iOpacity)
    DllStructSetData($tBlend, "Format", 1)
    _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, 2)
    _WinAPI_ReleaseDC(0, $hScrDC)
    _WinAPI_SelectObject($hMemDC, $hOld)
    _WinAPI_DeleteObject($hBitmap)
    _WinAPI_DeleteObject($hImage)
    _WinAPI_DeleteDC($hMemDC)
EndFunc ;==>_GUICreate_Alpha

Func SetBitmap($hGUI, $hImage, $iOpacity)
    Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend
    $hScrDC = _WinAPI_GetDC(0)
    $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
    $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)
    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, "X", _GDIPlus_ImageGetWidth($hImage))
    DllStructSetData($tSize, "Y", _GDIPlus_ImageGetHeight($hImage))
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, "Alpha", $iOpacity)
    DllStructSetData($tBlend, "Format", 1) ;$AC_SRC_ALPHA = 1
    _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
    _WinAPI_ReleaseDC(0, $hScrDC)
    _WinAPI_SelectObject($hMemDC, $hOld)
    _WinAPI_DeleteObject($hBitmap)
    _WinAPI_DeleteDC($hMemDC)
EndFunc   ;==>SetBitmap