AutoIt Français

Bonjour,

Je suis actuellement en stage et on me demande de faire un script AutoIt afin de créer une GUI d'après un fichier txt.

J'ai trouvé ici même un script le faisant parfaitement mais la GUI comprend des menus et sous menu or, je doit afficher uniquement des boutons.

► Afficher le texte

J'ai donc modifier quelque peu et je suis arrivé à créer les boutons cependant je suis bloqué car je n'arrive pas à interagir avec eux.

► Afficher le texte

Il tire ses information d'un fichier txt présenté comme ceci:

► Afficher le texte

Je vous rappel que je suis un débutant tant en programmation qu'en AutoIt et que ça ne fait que depuis Lundi que j'ai commencé à apprendre ce langage.
Merci d'avance pour vos réponses.
Cordialement.

Hum manifestement tu n'as que 2 solutions
1- apprendre le langage Autoit pour comprendre ce qu'il y a dans les scripts, ça t'évitera d'utiliser un code inadapté et de faire un script qui est un grand n'importe quoi
2- si tu es pressé, aller dans la rubrique "demande de scripts" du forum. Là tu pourras obtenir rapidement un script sérieux et fait proprement, charge à toi ensuite de demander des renseignements pour savoir comment il fonctionne pour le cas où ton maître de stage te demanderait des explications ^^

Bonjour

Ayant conçût le script que vous avez utilisez je l'ai modifier selon votre souhait

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
;~ #AutoIt3Wrapper_Compile_Both=y
#AutoIt3Wrapper_UseX64=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Menu auto via un fichier txt par JL56", 623, 442, 192, 124)
Global $Button1 = GUICtrlCreateButton("quitter", 376, 292, 75, 25)
Global $nbr_de_bouton = 0
Global $bouton_et_valeur[300][2];tableau des handles et ligne de commande

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

_bouton() ; fonction pour la création de la gui avec bouton

;~ Global $Pic1 = GUICtrlCreatePic("\\filay\JRICHTER\MesDocuments\Ford\FORD\ford.JPG", -8, 0, 617, 433)

Do ;boucle de la gui
    $msg = GUIGetMsg()
;~ test du menu selectionné
    For $i = 1 To $nbr_de_bouton ; boucle sur le nombre d'élément
        If $msg = $bouton_et_valeur[$i][0] Then ; test si c'est ce menu ( handle ) qui est sélectioné
            MsgBox(0, "Programme", $bouton_et_valeur[$i][1]) ;boite de dialogue pour afficher la ligne de commande test pour vérifier ( ligne à supprimer )
;~          Run($bouton_et_valeur[$i][1]) ;éxecution de la valeur stocké dans le tableau
        EndIf
    Next


Until $msg = $GUI_EVENT_CLOSE Or $msg = $Button1

Exit


Func _bouton() ; fonction pour la création des boutons
    Local $i = 10
    Local $j = 10
    $file = FileOpen(@ScriptDir & "\boutonauto.txt", 0)
    If $file = -1 Then
        MsgBox(4096, "", "Il manque le fichier boutonauto.txt " & @ScriptDir & "\boutonauto.txt", 50)
        FileClose($file)
        Exit
    Else
        While 1
            $ligne = FileReadLine($file) ;lecture séquenciel du fichier
            If @error = -1 Then ExitLoop
            If StringLeft($ligne, 3) = "fin" Then ExitLoop ; arret de la boucle avec le mot fin

            $element = StringSplit($ligne, "=") ;decoupage de ligne en trois morceaux (séparés par =)
            If Not IsArray($element) Then ExitLoop ;vérification du decoupage
            If StringRight($element[1], 1) = "b" Then ;si le premier morceau est b alors
                $nbr_de_bouton = $nbr_de_bouton + 1
                $bouton_et_valeur[$nbr_de_bouton][0] = GUICtrlCreateButton($element[2], $i, $j, 75, 25);Création de l'élément et stockage du handle dans le tableau
                $bouton_et_valeur[$nbr_de_bouton][1] = $element[3]


        $i = $i + 95
                If $i > 520 Then
                    $i = 10
                    $j = $j + 40

                EndIf
            EndIf
        WEnd
        FileClose($file)
    EndIf
EndFunc   ;==>_menu

Le fichier txt doit s'éditer comme ceci

► Afficher le texte

De fait le script est plus simple il n'y pas de sous menu à gérer

@mickell
Désolé Je ne sais pas si mon script est un script sérieux et fait proprement

A+

JL56

@jl56
Ce que je voulais dire c'est que prendre un script spécifiquement conçu pour un menu et le bidouiller pour le forcer à fonctionner avec des boutons, quand on sait pas où on va ça reste du bricolage
Le résultat peut être sérieux et propre quand on est soi-même le concepteur du script de départ et/ou qu'on sait exactement ce qu'on fait
Si les modifs à faire sont conséquentes alors il vaut généralement mieux réécrire d'emblée un script adapté, ce que pratiquement tu as fait, d'ailleurs

Ok merci c'est super mais ça ne lance pas IE.

@mikell, comme je l'ai dis, je suis pas développeur et il me reste 5 semaines de stage. Je n'ai pas que ça comme projet donc je préfère avoir un script tout fait dont je comprend 50% et l'étudier petit à petit pour le comprendre entièrement de manière a ne pas bloquer sur un projet unique.

Edit: C'est bon j'avais pas remarqué la ligne commentée...

MERCI

maintenant go le comprendre de A à Z

Bonjour,

J'ai présenté "mon" script (Merci encore jl56) à mon tuteur hier et il a trouvé ça bien.

Il a proposé quelques améliorations comme le fait de rajouter des onglets pour trier ensuite les boutons en fonction de leur action.
Il a également proposé de modifier l'action du bouton "Quitter" afin de faire en sorte qu'il ferme la session (ceci est fait j'ai réussi ^^).

Je suis donc désolé de vous demander ça mais pour commencer, est'il possible de modifier l'action de la croix afin de faire en sorte qu'elle aussi ferme la session? car pour le moment elle n'a plus aucun effet pour moi.

J'ai trouvé comment créer des onglets (GuiCtrlCreateTab...) je suis entrain de voir comment fonctionne le script pour les boutons afin de le refaire pour les onglets et ensuite de les combiner.

J'ai cependant une question, lorsque je fait un onglet, celui ci ne prend pas l'image que je lui ai définit par (GUICtrlCreatePic). Comment faire?

Merci d'avance

Question bête : tu as mis un chemin relatif ou absolu ?

Bonjour

Pour l'action fermeture par la croix, il faux mettre ton action de fermeture de session après le
Until $msg = $GUI_EVENT_CLOSE Or $msg = $Button;cela veux dire , je continu la boucle tant que je n'ai pas fermer la fenêtre ou que je n'ai pas appuyer sur le bouton "quitter"

et avant le
EXIT

$msg = $GUI_EVENT_CLOSE correspond à la fermeture de la fenêtre

Pour l'image je ne sais pas désolé

A+ JL56

Voilà pour les tabs...

► Afficher le texte

Bonjour,

Merci à tous tout d'abord.

J'ai réussi à faire ce que je voulais: afficher une GUI créait d'après un fichier txt comportant des onglets et des boutons.
J'ai pas encore regardé pour l'image mais j'ai déjà un petit "problème": Lorsque je lance mon script, il me génère une GUI. Cependant, pour que les boutons du premier onglet apparaissent il me faut aller sur un autre onglet puis revenir sur le premier.

@jl56, Ok je vais voir ça pour la croix, je te tient au courant.

ps: Voici mon script

► Afficher le texte

Liste source:

► Afficher le texte

A mettre a votre nom d'utilisateur!

@jl56: Merci ça marche pour la fermeture de session, j'avais pas pensé à aussi simple

.

Il me reste plus qu'a régler le problème de l'affichage des boutons du premier onglet. Si quelqu'un à déjà eu un problème similaire

Faut juste mettre la fonction _bouton() pour créer les tabs avant le GUISetState

Code : Tout sélectionner

....
Global $TabSheet[300][2]
_bouton() ; fonction pour la création de la gui avec bouton
GUISetState(@SW_SHOW)

De quoi @mikell?

Tu as lu mon problème? Ma GUI s'affiche sauf que pour voir les boutons du premier onglet il me faut effectuer une action du genre aller sur le deuxième onglet et revenir sur le premier. Personnellement ça me gène pas plus que ça mais c'est pour les salariés que ça va être problématique, effectuer 2 clics de plus que la normal c'est compliqué...

Donc il me semble que ta réponse ne correspond pas à mon problème, après c'est peut être moi qui ai mal compris.

EDIT: Autant pour moi j'avais crus que tu parlais de la création mais je viens de regarder et effectivement j'affichais avant de faire donc forcément... Excuse moi pour le petit paragraphe juste au dessus et merci d'aider de petit newbe comme moi.

Tu as essayé de modifier ton script comme indiqué avant de râler ?

Sinon autre solution :

Code : Tout sélectionner

GUICtrlSetState($TabSheet[1][0], $GUI_SHOW)

@mikell, je viens d’éditer mon message précédent, j'avais pas compris pourquoi tu me disais ça et je pensais que j'avais déjà mis la fonction avant le GUISetState. ça m'apprendra à lire trop vite.

Nagroxx a écrit :...effectivement j'affichais avant de faire donc forcément...

Tu as aussi le droit de procéder comme ça, mais dans ce cas c'est la 2ème solution qui s'applique

Code : Tout sélectionner

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
_bouton() ; fonction pour la création de la gui avec bouton
GUICtrlSetState($TabSheet[1][0], $GUI_SHOW)

NB : faut pas préjuger la qualité de mes réponses d'après l'impression produite par mon 1er post dans ce sujet

Ah oki. Merci mais je pense que pour l'instant je vais rester sur la première méthode que tu m'as donnée. Elle donne le résultat voulu.

Petite question (j'en profite) est'il possible de définir une image par onglet?

Nagroxx a écrit :Je suis actuellement en stage et on me demande de faire un script AutoIt ...

Raison pour laquelle je fournis plusieurs solutions possibles

Pour les images, tu peux faire ça dans la fonction _bouton() en créant l'image après le TabItem mais avant les boutons
Important pour que les boutons fonctionnent, si c'est une image de fond :

Code : Tout sélectionner

GUICtrlSetState($image, $GUI_DISABLE)

mikell a écrit :Raison pour laquelle je fournis plusieurs solutions possibles

Je sais bien et j'en prend note mais je garde l'autre en service

mikell a écrit :Pour les images, tu peux faire ça dans la fonction _bouton() en créant l'image après le TabItem mais avant les boutons
Important pour que les boutons fonctionnent, si c'est une image de fond :
Code : Tout sélectionner
GUICtrlSetState($image, $GUI_DISABLE)

Ceci va me permette de mettre une seule et même image pour tout les onglets non?
Ou alors il faut que je stock les image dans un tableau pour qu'il les gère?

Car je voudrait une image genre Chrome, Firefox... pour l'onglet Internet, une image genre logo windows pour l'onglet contenant les boutons relatifs aux programmes windows...

Teste ça

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <TabConstants.au3>

Global $img[3] = ["C:\Program Files\AutoIt3\Examples\GUI\msoobe.jpg", _ 
            "C:\Program Files\AutoIt3\Examples\GUI\mslogo.jpg", _ 
            "C:\Program Files\AutoIt3\Examples\GUI\merlin.gif"]

Global $Form1 = GUICreate("Programmes de " & @UserName, 617, 433, 192, 124)
Global $Tab1 = GUICtrlCreateTab(0, 0, 617, 385)
Global $Button1 = GUICtrlCreateButton("quitter", 500, 390, 75, 25)
Global $nbr_de_bouton = 0
Global $bouton_et_valeur[300][2];tableau des handles et ligne de commande
Global $nbr_de_tab = 0
Global $TabSheet[300][2]

_bouton() ; fonction pour la création de la gui avec bouton

GUISetState(@SW_SHOW)


Do ;boucle de la gui
$msg = GUIGetMsg()
For $i = 1 To $nbr_de_bouton ; boucle sur le nombre d'élément
If $msg = $bouton_et_valeur[$i][0] Then ; test si c'est ce menu ( handle ) qui est sélectioné
; MsgBox(0, "Programme", $bouton_et_valeur[$i][1]) ;boite de dialogue pour afficher la ligne de commande test pour vérifier ( ligne à supprimer )
Run($bouton_et_valeur[$i][1]) ;éxecution de la valeur stocké dans le tableau
EndIf
Next
Until $msg = $GUI_EVENT_CLOSE or $msg = $Button1
;;Shutdown(0)
Exit


Func _bouton() ; fonction pour la création des boutons
Local $i = 10
Local $j = 40
$file = FileOpen(@ScriptDir & "\1.txt", 0)
If $file = -1 Then
MsgBox(4096, "", "Il manque le fichier " & @ScriptDir & "\" & @UserName & ".txt", 50)
FileClose($file)
Exit
Else
While 1
$ligne = FileReadLine($file) ;lecture séquenciel du fichier
If @error = -1 Then ExitLoop
If StringLeft($ligne, 3) = "fin" Then ExitLoop ; arret de la boucle avec le mot fin

$element = StringSplit($ligne, "|") ;decoupage de ligne en trois morceaux (séparés par |)
If Not IsArray($element) Then ExitLoop ;vérification du decoupage
If StringRight($element[1],1) = "t" Then
$nbr_de_tab = $nbr_de_tab +1
$TabSheet[$nbr_de_tab][0] = GUICtrlCreateTabItem($element[2]);Création de l'élément et stockage du handle dans le tableau

If $nbr_de_tab<4 Then
  GUICtrlCreatePic($img[$nbr_de_tab-1], 30, 30)
  GUICtrlSetState(-1, $GUI_DISABLE)
EndIf

Local $i = 10
Local $j = 40
Else
;If StringRight($element[1], 1) = "b" Then ;si le premier morceau est b alors
$nbr_de_bouton = $nbr_de_bouton + 1
$bouton_et_valeur[$nbr_de_bouton][0] = GUICtrlCreateButton($element[2], $i, $j, 75, 25);Création de l'élément et stockage du handle dans le tableau
$bouton_et_valeur[$nbr_de_bouton][1] = $element[3]
$i = $i + 95
If $i > 520 Then
$i = 10
$j = $j + 40
EndIf
;EndIf
EndIf
WEnd
FileClose($file)
EndIf
EndFunc ;==>_bouton

Merci ça fonctionne parfaitement!

Dans "GUICtrlCreatePic($img[$nbr_de_tab-1], 30, 30)" le "$nbr_de_tab-1" correspond à quoi? c'est le -1 qui m'intrigue ^^

EDIT: Ah non je suis trop C.. désolé ^^ c'est bon j'ai compris MDR

AutoIt Français

[R] Création d'une GUI d'après un fichier txt

[R] Création d'une GUI d'après un fichier txt

Re: [..] Création d'une GUI d'après un fichier txt

Re: [..] Création d'une GUI d'après un fichier txt

Re: [..] Création d'une GUI d'après un fichier txt

Re: [..] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt

Re: [R] Création d'une GUI d'après un fichier txt