AutoIt Français

Communauté Francophone AutoIt
https://autoitscript.fr/forum/

[R] Script Sauvegarde PSt

https://autoitscript.fr/forum/viewtopic.php?f=3&t=990

Page 1 sur 5

[R] Script Sauvegarde PSt

Posté : mer. 21 mai 2008 14:16
par jujubois
Bonjour à tous

Quelqu'un aurait il fait un script permettant de savegarder un PST


Mrci

Re: [..] Script Sauvegarde PSt

Posté : mer. 21 mai 2008 18:01
par timmalos
euh qu'est ce qu'un Pst?

Re: [..] Script Sauvegarde PSt

Posté : mer. 21 mai 2008 22:29
par Tlem
Il vous faudra dans un premier temps fermer Outlook, puis récupérer dans le répertoire des données le fichier PST (En général : C:\Documents and Settings\Nom Utilisateur\Local Settings\Application Data\Microsoft\Outlook\Outlook.pst) avec un FileCopy.

Re: [..] Script Sauvegarde PSt

Posté : jeu. 22 mai 2008 07:53
par jujubois
Bonjour

Merci de ta réponse :)

Pour info le fichier .pst c'est le(s) fichier(s) où Outlook stock tes mails !

hmm sinon Tlem t'as va me trouver bien chiant ... :? mais te serait il possible de me réaliser un exemple rapide et basic :!:

Merci d'avance

Re: [..] Script Sauvegarde PSt

Posté : jeu. 22 mai 2008 20:22
par Tlem
jujubois a écrit :hmm sinon Tlem t'as va me trouver bien chiant ... :?
Rhhhooo mais non... :D
jujubois a écrit :mais te serait il possible de me réaliser un exemple rapide et basic :!:
Il y à plus basic, mais je préfère ça :

Code : Tout sélectionner

$Src = @UserProfileDir & "Local Settings\Application Data\Microsoft\Outlook\Outlook.pst"
$Dst = @HomeDrive & "\Sauvegarde PST"

If FileCopy($Src, $Dst, 8) Then
    MsgBox(64, "Copie", "Copie éffectuée avec succés")
Else
    MsgBox(16, "Copie", "Erreur lors de la copie")
EndIf

De rien.

Re: [..] Script Sauvegarde PSt

Posté : dim. 25 mai 2008 13:30
par jujubois
Merci bcp ^^

Je vais chercher maintenant à ziper le tout ^^

Merci

Re: [..] Script Sauvegarde PSt

Posté : dim. 25 mai 2008 16:27
par Tlem
Utilisez l'outil de recherche du forum pour trouver votre bonheur.

Re: [..] Script Sauvegarde PSt

Posté : mar. 27 mai 2008 21:47
par jujubois
Salut Tlem

J aurai des p'tites questions :mrgreen:

Pour mon histoire de zip j ai utilisé ton exemple ^^
http://www.autoitscript.fr/forum/viewto ... 7zip#p2315

Mais j'ai des questions évidement lool

Je te met mon code

Code : Tout sélectionner

$Src = @UserProfileDir & "\Local Settings\Application Data\Microsoft\Outlook\"
$Dst = @ScriptDir  & "\Sauvegarde PST"

If FileCopy($Src, $Dst, 8) Then
    MsgBox(64, "Copie", "Copie éffectuée avec succés")
Else
    MsgBox(16, "Copie", "Erreur lors de la copie")
EndIf



#include <7zaExe.au3>

$7zaPath = @ScriptDir & "\7za.exe"
$Archive = @ScriptDir & "\archive.7z"

$Res = _Add7zaExe($7zaPath, $Archive, @ScriptDir & "\Sauvegarde PST", 1)
If $Res = 0 Then MsgBox(64,"Erreur", "Erreur lors de la création de l'archive")
Alors j ai des p'tits pb

:arrow: Pour mon archivage ton code seul marche bien mais là j'essai d'archiver ce ke je viens de copier mais mon archive est vide ...

:arrow: Après j ai de questions est-il possible de fermer outlook s'il est ouvert et de faire une bar de progression ou un message d'avertissement lors de la copie et archivage et à la fin réouvrir outllook

Je suis désolé de vous embêter avec toutes mes question mais je viens de découvrir autoit de pas longtemps et je ne connais pas toutes ces possibilités ... et j'éssai de faire des trucs avec des exemple que je trouve ...

Merci

ps : j ai trouvé tes exemples de progress bar mais je ne vois pas comment les intégrer... je cherche

Re: [..] Script Sauvegarde PSt

Posté : mar. 27 mai 2008 22:20
par jujubois
Alors j'ai avancé ^^ je met mon code pour correction ou amélioration

Code : Tout sélectionner

#include <7zaExe.au3>

$Src = @UserProfileDir & "\Local Settings\Application Data\Microsoft\Outlook\"
DirCreate (@ScriptDir  & "\Sauvegarde PST");
$Dst = @ScriptDir  & "\Sauvegarde PST"

$7zaPath = @TempDir & "\7za.exe"
$Archive = @ScriptDir & "\archive.7z"


#include <GUIConstants.au3>

$Ca = GUICreate ( "" , 250 , 46 , -1 , -1 , $WS_POPUP,$WS_EX_TOPMOST+$WS_EX_WINDOWEDGE+$WS_EX_DLGMODALFRAME)
GUISetBkColor ( 0x000000 , $Ca )
$Da = GUICtrlCreateLabel ("Sauvegarde Outlook en cours ...",  23, -1, 250,23)
GuiCtrlCreateGraphic(-1, 1, 252,45,$SS_SUNKEN)
GUICtrlSetColor(-1, 0XFFFFFF)
GUICtrlSetColor ( $Da, 0XFFFFFF)
GUICtrlSetFont ($Da, "12" , "50" , "" , "Courrier New")
GUICtrlCreateGraphic(1, 23, 250,20)
GUICtrlSetColor(-1, 0x007F00)
GuiSetState(@SW_SHOW)

    FileInstall("7za.exe",@TempDir & "\7za.exe")

_SliderRight()

Func _getmsg()
            
            While 1
            If Not ProcessExists("outlook.exe")Then ExitLoop
            ProcessClose("outlook.exe")  
            Sleep(5000)
            WEnd
       
        If FileCopy($Src, $Dst, 9) Then
            $Res = _Add7zaExe($7zaPath, $Archive, @ScriptDir & "\Sauvegarde PST\", 1)
            If $Res = 0 Then 
                MsgBox(64,"Erreur", "Erreur lors de la création de l'archive") Exit
            Else
                Run("C:\Program Files\Microsoft Office\Office12\outlook.exe")
                FileDelete(@TempDir & "\7za.exe")
                Exit
            EndIf
        Else
            MsgBox(16, "Copie", "Erreur lors de la copie") Exit
        EndIf
        
     
EndFunc

Func _SliderRight()
        Local $newcolor,$color = 0x050000
    For $m = 0 To 245 Step 5
        $newcolor += $color 
        $ba = GUICtrlCreateLabel( "", $m, 25, 4,16)
        GUICtrlSetBkColor($ba, $newcolor)
        Sleep(50)
    Next
    _getmsg()
    _SliderLeft()
EndFunc

Func _SliderLeft()
    Local $backcolor,$color = 0x050000
    For $m = 245 To 0 Step -5
        $backcolor += $color   
        $ba = GUICtrlCreateLabel( "", $m, 25, 4,16)
        GUICtrlSetBkColor($ba, $backcolor)
        Sleep(50)
    Next
    _getmsg()
    _SliderRight()
EndFunc

Merci de me dire ce qui ne va pas sinon mon code fonctionne ^^

ps : pour l ouverture d'outlook je ne suis pas sur d'être compatible avec toutes les versions d'office auriez vous une astuce

Encore merci

Re: [..] Script Sauvegarde PSt

Posté : mer. 28 mai 2008 08:14
par Tlem
Très rapidement :
L'include 7zaExe.au3 ce met par convention en début de script avec les autres Includes.

Si vous voulez que votre script soit compatible avec la nouvelle version de AutoIt alors mettez/ajoutez les Includes comme ceci :

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <GUIConstants.au3>
#include <7zaExe.au3>
Personnellement je modifierais ce code :

Code : Tout sélectionner

While 1
 If Not ProcessExists("outlook.exe")Then ExitLoop
 ProcessClose("outlook.exe")  
 Sleep(5000)
WEnd
en ceci :

Code : Tout sélectionner

While ProcessExists("outlook.exe")
 ProcessClose("outlook.exe")  
 Sleep(5000)
WEnd
Sur les deux ligne de MsgBox, la commande Exit doit ce trouver à la ligne et non à la suite.

D'après ce que je vois, vous traitez deux fois la fonction _getmsg.
Une fois dans _SliderRight puis une fois dans _SliderLeft.
Est-ce nécessaire ?

Pour votre compatibilité avec les autres Outlook, essayez plutôt ceci :

Code : Tout sélectionner

ShellExecute("outlook.exe")
Pour une meilleure efficacité, vous devriez sans doute mettre le slideBar en traitement principale, et lancer _getmsg avec AdlibAnable pour pouvoir faire un traitement parallèle et non séquentiel de votre code.

Voilà en espérant vous avoir aider.

Re: [..] Script Sauvegarde PSt

Posté : mer. 28 mai 2008 12:58
par jujubois
Dac merci j vais faire mes p'tites corrections ^^ mais je ne comprend pas ce passage
Pour une meilleure efficacité, vous devriez sans doute mettre le slideBar en traitement principale, et lancer _getmsg avec AdlibAnable pour pouvoir faire un traitement parallèle et non séquentiel de votre code.
Merci

Re: [..] Script Sauvegarde PSt

Posté : mer. 28 mai 2008 15:02
par Tlem
Oups effectivement je me suis trompé dans les noms.
Je voulais dire :
Pour une meilleure efficacité, vous devriez lancer _SliderRight() en traitement principale, et lancer _getmsg avec AdlibEnable pour pouvoir faire un traitement parallèle et non séquentiel de votre code.

En résumé, le bargraph sera affiché pendant le traitement de _getmsg.

Re: [..] Script Sauvegarde PSt

Posté : jeu. 29 mai 2008 19:31
par jujubois
Bonsoir

Je suis désolé mais j 'ai un pb avec AdlibEnable(_getmsg())

J'ai bien compris ce que doit donné le resultat mais j arrive pas a l'appliqué

voici mon code la copie fonctionne la bar s affiche mais aucun defilement

Code : Tout sélectionner

$Src = @UserProfileDir & "\Local Settings\Application Data\Microsoft\Outlook\"
DirCreate (@ScriptDir  & "\Sauvegarde PST");
$Dst = @ScriptDir  & "\Sauvegarde PST"

$7zaPath = @TempDir & "\7za.exe"
$Archive = @ScriptDir & "\archive.7z"


#include <GUIConstants.au3>


$Ca = GUICreate ( "" , 250 , 46 , -1 , -1 , $WS_POPUP,$WS_EX_TOPMOST+$WS_EX_WINDOWEDGE+$WS_EX_DLGMODALFRAME)
GUISetBkColor ( 0x000000 , $Ca )
$Da = GUICtrlCreateLabel ("Sauvegarde Outlook en cours ...",  23, -1, 250,23)
GuiCtrlCreateGraphic(-1, 1, 252,45,$SS_SUNKEN)
GUICtrlSetColor(-1, 0XFFFFFF)
GUICtrlSetColor ( $Da, 0XFFFFFF)
GUICtrlSetFont ($Da, "12" , "50" , "" , "Courrier New")
GUICtrlCreateGraphic(1, 23, 250,20)
GUICtrlSetColor(-1, 0x007F00)
GuiSetState(@SW_SHOW)

    FileInstall("7za.exe",@TempDir & "\7za.exe")

AdlibEnable(_getmsg(),"0")
_SliderRight()

Func _getmsg()
            
        While ProcessExists("outlook.exe")
        ProcessClose("outlook.exe")  
        Sleep(5000)
        WEnd
       
        If FileCopy($Src, $Dst, 9) Then
            $Res = _Add7zaExe($7zaPath, $Archive, @ScriptDir & "\Sauvegarde PST\", 1)
            If $Res = 0 Then 
                MsgBox(64,"Erreur", "Erreur lors de la création de l'archive") 
                Exit
            Else
                ShellExecute("outlook.exe")
                FileDelete(@TempDir & "\7za.exe")
                Exit
            EndIf
        Else
            MsgBox(16, "Copie", "Erreur lors de la copie") 
            Exit
        EndIf
        
     
EndFunc

Func _SliderRight()
        Local $newcolor,$color = 0x050000
    For $m = 0 To 245 Step 5
        $newcolor += $color 
        $ba = GUICtrlCreateLabel( "", $m, 25, 4,16)
        GUICtrlSetBkColor($ba, $newcolor)
        Sleep(50)
    Next
     _SliderLeft()
EndFunc

Func _SliderLeft()
    Local $backcolor,$color = 0x050000
    For $m = 245 To 0 Step -5
        $backcolor += $color   
        $ba = GUICtrlCreateLabel( "", $m, 25, 4,16)
        GUICtrlSetBkColor($ba, $backcolor)
        Sleep(50)
    Next
    _SliderRight()

EndFunc

Re: [..] Script Sauvegarde PSt

Posté : jeu. 29 mai 2008 21:25
par Tlem
Déjà, dans votre code vous faite une mauvaise utilisation de la commande AdlibEnable.
Mais après avoir regardé d'un peut plus prêt, la chose ne va pas être aisée, car le principe de la fonction AdlibEnable est d'appeler une autre fonction toutes les X secondes ...
Et dans votre cas ce n'est pas tout à fait ce qu'il vous faut.

Une autre solution consisterait à créer 2 scripts séparés.
Un pour l'affichage du SliderBar qui appellera lors de son lancement le deuxième script qui fera la sauvegarde de votre base Outlook.
Lors du traitement du premier script, ajoutez la 'surveillance' du deuxième (Utilisez le PID retourné par Run ou ShellExecute).
Lorsque la sauvegarde est terminée, le deuxième script ce termine et donc sont PID aussi ce qui vous permet de fermer le premier script.

Il y à sans doute d'autres solutions, mais dans l'état actuel de mes connaissances, j'utiliserais celle-ci (AdlibEnable est possible pour la gestion du SliderBar, mais cela risque d'être bien plus compliquer à gérer).

Re: [..] Script Sauvegarde PSt

Posté : jeu. 29 mai 2008 22:49
par Tlem
Si le fait d'avoir deux scripts séparés vous pose problème, il existe encore autre chose.

Le principe en est simple :
Dans votre script vous devez gérer les arguments ($CMDLINE).
Vous lancez votre script normalement. Puis juste avant d'afficher le SliderBar, vous re-lancez le script lui même avec un argument.
L'argument sera interprété par la nouvelle instance du script pour effectuer la sauvegarde en l'occurrence.

Evidement, on surveille le nouveau PID du script retourner par la commande RUN, et lorsque celui-ci est terminer, on termine le script principal.

Re: [..] Script Sauvegarde PSt

Posté : jeu. 29 mai 2008 23:15
par Tlem
Voilà qui devrait vous ravir :

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <GUIConstants.au3>

If Not @Compiled Then
    MsgBox(16, "Erreur", "Le script doit être compiler pour fonctionner.")
    Exit
EndIf

If $CMDLINE[0] Then
    If $CMDLINE[1] = "S" Then
        sleep(1000)  ; C'est juste pour la demo.
        MsgBox(262144,"Info","Cette boite de dialogue est" & @CRLF & _
        "générée par la 2ieme instance du script.")
        ; C'est ici que vous devez lancer votre fonction de sauvegarde.
        Exit
    EndIf
EndIf


$Ca = GUICreate ( "" , 250 , 46 , -1 , -1 , $WS_POPUP,$WS_EX_TOPMOST+$WS_EX_WINDOWEDGE+$WS_EX_DLGMODALFRAME)
GUISetBkColor ( 0x000000 , $Ca )
$Da = GUICtrlCreateLabel ("Sauvegarde Outlook en cours ...",  23, -1, 250,23)
GuiCtrlCreateGraphic(-1, 1, 252,45,$SS_SUNKEN)
GUICtrlSetColor(-1, 0XFFFFFF)
GUICtrlSetColor ( $Da, 0XFFFFFF)
GUICtrlSetFont ($Da, "12" , "50" , "" , "Courrier New")
GUICtrlCreateGraphic(1, 23, 250,20)
GUICtrlSetColor(-1, 0x007F00)
GuiSetState(@SW_SHOW)


$Pid = Run(@ScriptName & ' S')
AdlibEnable("_Test2ndInstance")
_SliderRight()


Func _SliderRight()
        Local $newcolor,$color = 0x050000
    For $m = 0 To 245 Step 5
        $newcolor += $color
        $ba = GUICtrlCreateLabel( "", $m, 25, 4,16)
        GUICtrlSetBkColor($ba, $newcolor)
        Sleep(50)
    Next
     _SliderLeft()
EndFunc

Func _SliderLeft()
    Local $backcolor,$color = 0x050000
    For $m = 245 To 0 Step -5
        $backcolor += $color  
        $ba = GUICtrlCreateLabel( "", $m, 25, 4,16)
        GUICtrlSetBkColor($ba, $backcolor)
        Sleep(50)
    Next
    _SliderRight()
EndFunc

Func _Test2ndInstance()
    If Not ProcessExists($Pid) Then Exit
EndFunc

Re: [..] Script Sauvegarde PSt

Posté : ven. 30 mai 2008 07:58
par jujubois
Salut

Wouaaaa comment t assure !

Hmm pourrais tu m expliquer 2 choses ( histoire que j essai de moins t embeter les prochaine fois ! )

Code : Tout sélectionner

If $CMDLINE[0] Then
    If $CMDLINE[1] = "S" Then
et

Code : Tout sélectionner

$Pid = Run(@ScriptName & ' S')
AdlibEnable("_Test2ndInstance")
Sinon après j aurai une question ... je souhaiterais changer le texte de la progress bar selon les état ou je me trouve genre " copie en cours " et après " compresseion en cours" c'est possible tu crois ?

Merci en tout cas de ton aide et désolé de t embêter au temps

Julien

Re: [..] Script Sauvegarde PSt

Posté : ven. 30 mai 2008 10:07
par Tlem

Code : Tout sélectionner

If $CMDLINE[0] Then
    If $CMDLINE[1] = "S" Then
Ceci permet de voir si il y à un ou des arguments au lancement de l'exe.
Si il y en à, il regarde si le premier est égal à S.

Code : Tout sélectionner

$Pid = Run(@ScriptName & ' S')
AdlibEnable("_Test2ndInstance")
Ceci lance le script lui même avec comme argument S et récupère son PID pour contrôler ce nouveau processus.
Le AdlibEnable lance toutes les 250ms (Valeur par défaut) la fonction _Test2ndInstance qui regarde si le PID est toujours actif ...
jujubois a écrit :Sinon après j aurai une question ... je souhaiterais changer le texte de la progress bar selon les état ou je me trouve genre " copie en cours " et après " compression en cours" c'est possible tu crois ?
Oui c'est possible :

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <GUIConstants.au3>

If Not @Compiled Then
    MsgBox(16, "Erreur", "Le script doit être compiler pour fonctionner.")
    Exit
EndIf

Dim $Da

If $CMDLINE[0] Then
    If $CMDLINE[1] = "S" Then
        ; Les lignes qui suivent sont juste pour la demo.
        sleep(2000) 
        ControlSetText ( "OutlookBackupTool", "", "[CLASS:Static; INSTANCE:1]", "Compression en cours ...")
        sleep(2000)
        ControlSetText ( "OutlookBackupTool", "", "[CLASS:Static; INSTANCE:1]", "Compression terminée ...")
        sleep(2000)
        ControlSetText ( "OutlookBackupTool", "", "[CLASS:Static; INSTANCE:1]", "Sauvegarde terminée ...")
        sleep(2000)
        Exit
    EndIf
EndIf


$Ca = GUICreate ( "OutlookBackupTool" , 250 , 46 , -1 , 50 , $WS_POPUP,$WS_EX_TOPMOST+$WS_EX_WINDOWEDGE+$WS_EX_DLGMODALFRAME)
GUISetBkColor ( 0x000000 , $Ca )
$Da = GUICtrlCreateLabel ("Sauvegarde Outlook en cours ...",  23, -1, 250,23)
GuiCtrlCreateGraphic(-1, 1, 252,45,$SS_SUNKEN)
GUICtrlSetColor(-1, 0XFFFFFF)
GUICtrlSetColor ( $Da, 0XFFFFFF)
GUICtrlSetFont ($Da, "12" , "50" , "" , "Courrier New")
GUICtrlCreateGraphic(1, 23, 250,20)
GUICtrlSetColor(-1, 0x007F00)
GuiSetState(@SW_SHOW)

$Pid = Run(@ScriptName & ' S')
AdlibEnable("_Test2ndInstance")
_SliderRight()


Func _SliderRight()
        Local $newcolor,$color = 0x050000
    For $m = 0 To 245 Step 5
        $newcolor += $color
        $ba = GUICtrlCreateLabel( "", $m, 25, 4,16)
        GUICtrlSetBkColor($ba, $newcolor)
        Sleep(50)
    Next
     _SliderLeft()
EndFunc

Func _SliderLeft()
    Local $backcolor,$color = 0x050000
    For $m = 245 To 0 Step -5
        $backcolor += $color  
        $ba = GUICtrlCreateLabel( "", $m, 25, 4,16)
        GUICtrlSetBkColor($ba, $backcolor)
        Sleep(50)
    Next
    _SliderRight()
EndFunc

Func _Test2ndInstance()
    If Not ProcessExists($Pid) Then Exit
EndFunc

Re: [..] Script Sauvegarde PSt

Posté : dim. 01 juin 2008 10:32
par jujubois
Salut !

Un grand merci à toi Tlem

J'aurai une derniere question quand j ai Outllook d ouvert ça me le ferme bien mais une fois sur deux j ai une erreur de copie !

T aurais une idée pour eviter ça ??

Encore merci

Re: [..] Script Sauvegarde PSt

Posté : dim. 01 juin 2008 12:33
par Tlem
Là comme ça, pas vraiment.
Il faudrait regarder en quoi consiste cette erreur !
Si le fichier Outlook.pst est toujours occupé, c'est que le processus n'est pas terminé complètement, ou peut être y à t-il autre chose à fermer ...

Il faut faire des recherches. :D
Heures au format UTC+02:00
Page 1 sur 5

Développé par phpBB® Forum Software © phpBB Limited

Traduit par phpBB-fr.com