AutoIt Français

Bonjour,

j'ai créé un code pour une double authentification. La fenêtre de génération du code est longue à se fermer (environ 15 secondes).
Je ne vois pas où je pèche....
Quelqu'un aurait il une idée?

Code: [Tout sélectionner] [Déplier/Replier]

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Global $hGUI, $hLabel, $hCode, $hButtonQuit

$hGUI = GUICreate("Code", 300, 140)
$hLabel = GUICtrlCreateLabel("", 10, 10, 280, 40, $SS_CENTER)
$hCode = GUICtrlCreateLabel("", 10, 60, 280, 40, $SS_CENTER)
$hButtonQuit = GUICtrlCreateButton("Quitter", 100, 100, 100, 30)

GUISetState(@SW_SHOW)

While 1
    Local $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE, $hButtonQuit
            ExitLoop
    EndSwitch

    Local $currentTime = @HOUR & ":" & @MIN & ":" & @SEC
    Local $nextMinute = @HOUR & ":" & @MIN + 1 & ":00"

    Local $timeDiff = _TimeDiff($currentTime, $nextMinute)
    GUICtrlSetData($hLabel, "Code valable pendant " & $timeDiff & " secondes")
    $code = Number(@YDAY) * Number(@MDAY) * Number(@HOUR) * Number(@MIN)
    GUICtrlSetData($hCode, "Code déverrouillage " & $code)

    Sleep(1000)
WEnd

Func _TimeDiff($currentTime, $nextMinute)
    Local $currentTimeArray = StringSplit($currentTime, ":")
    Local $nextMinuteArray = StringSplit($nextMinute, ":")

    Local $currentSeconds = $currentTimeArray[1] * 3600 + $currentTimeArray[2] * 60 + $currentTimeArray[3]
    Local $nextMinuteSeconds = $nextMinuteArray[1] * 3600 + $nextMinuteArray[2] * 60 + $nextMinuteArray[3]

    Local $diff = $nextMinuteSeconds - $currentSeconds
    Return $diff
EndFunc

GeSHi © Extension Codebox Plus

Merci d'avance.

Salut, ton problème est du à la fonction Sleep qui est dans la boucle principale de ton programme. Il faut savoir que quand on écoute les évènements dans boucle principale grâce à la fonction GUIGetMsg, il est inutile de d'insérer l'instruction Sleep puisque GUIGetMsg à l'avantage de gérer automatiquement le CPU. De plus, tu fais dormir pendent trop longtemps ton script jusqu'à une seconde: pas donc étonnant que des messages soient "loupés."
SUPPRIME tout simplement Sleep(1000) de la boucle principale et le tour est joué.

Merci en effet cela va mieux.
J'avais mis un sleep à 1secondes pour éviter l'effet de scintillement lors de l'actualisation du décompte.
Entre les deux c'est vrai que je préfère la rapidité.

Personnellement, j'opterai pour un Timer. Ce qui est beaucoup plus approprié dans ce contexte. Je te propose un exemple:

Code: [Tout sélectionner] [Déplier/Replier]

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Timers.au3>

Global $hGUI, $hLabel, $hCode, $hButtonQuit

$hGUI = GUICreate("Code", 300, 140)
$hLabel = GUICtrlCreateLabel("", 10, 10, 280, 40, $SS_CENTER)
$hCode = GUICtrlCreateLabel("", 10, 60, 280, 40, $SS_CENTER)
$hButtonQuit = GUICtrlCreateButton("Quitter", 100, 100, 100, 30)

_Timer_SetTimer($hGUI, 999, "UpdateCodeAndTimeRemaining") ; Calcul effectué toutes les secondes : 999 pour plus de précision.

Global Const $g_CODE_VALIDITY = 10 ;  Durée de validité du code : 10 secondes
Global $g_remainingTime = $g_CODE_VALIDITY + 1 
Global Const $g_CODE_PREFIX = "Code déverrouillage "

GUISetState(@SW_SHOW)

While 1
   Switch GUIGetMsg()
      Case $GUI_EVENT_CLOSE, $hButtonQuit
         ExitLoop
   EndSwitch
WEnd

_Timer_KillAllTimers($hGUI)
GUIDelete($hGUI)

Func UpdateCodeAndTimeRemaining($hWnd, $iMsg, $wParam, $lParam)
   $g_remainingTime -= 1
   Local $code = GUICtrlRead($hCode)

   If $g_remainingTime <= 0 Or $g_remainingTime >= $g_CODE_VALIDITY Then
      $g_remainingTime = $g_CODE_VALIDITY
      $code = Number(@YDAY) * Number(@MDAY) * Number(@HOUR) * Random(0, 9, 1)
   EndIf

   GUICtrlSetData($hLabel, "Code valable pendant " & $g_remainingTime & " secondes")

   $code = StringReplace($code, $g_CODE_PREFIX, "")
   GUICtrlSetData($hCode, $g_CODE_PREFIX & $code)
EndFunc   ;==>UpdateCodeAndTimeRemaining

Je vais regarder et essayer d'adapter à mon contexte.
Merci

AutoIt Français

[R]Lenteur à la fermeture d'une GUI

[R]Lenteur à la fermeture d'une GUI

Re: Lenteur à la fermeture d'une GUI

Re: Lenteur à la fermeture d'une GUI

Re: Lenteur à la fermeture d'une GUI

Re: Lenteur à la fermeture d'une GUI