AutoIt Français

Code : Tout sélectionner

Send("#+{RIGHT}")

Code : Tout sélectionner

; Récupération des différentes résolutions (dans le cas d'un multiscreen par exemple)
Func getResolutions()
	Local $resultat[1][6] = [[0, "", 1, 1, "-", "Macros"]], $i = 0, $dll = DllOpen("user32.dll")
	If $dll <> -1 Then
		While 1
			Local $struct = DllStructCreate("dword cb;char DeviceName[32];char DeviceString[128];dword StateFlags;char DeviceID[128];char DeviceKey[128]")
			DllStructSetData($struct, "cb", DllStructGetSize($struct))
			Local $retour = DllCall($dll, "int", "EnumDisplayDevices", "ptr", 0, "dword", $i, "ptr", DllStructGetPtr($struct), "dword", 0)
			If Not $retour[0] Then ExitLoop
			If Not BitAND(DllStructGetData($struct, "StateFlags"), 0x00000008) Then
				Local $device = DllStructCreate("char dmDeviceName[32];ushort dmSpecVersion;ushort dmDriverVersion;short dmSize;" & _
					"ushort dmDriverExtra;dword dmFields;long x;long y;dword dmDisplayOrientation;dword dmDisplayFixedOutput;" & _
					"short dmColor;short dmDuplex;short dmYResolution;short dmTTOption;short dmCollate;" & _
					"byte dmFormName[32];ushort LogPixels;dword dmBitsPerPel;int dmPelsWidth;dword dmPelsHeight;" & _
					"dword dmDisplayFlags;dword dmDisplayFrequency")
				DllStructSetData($device, "dmSize", DllStructGetSize($device))
				$retour = DllCall($dll, "int", "EnumDisplaySettings", "str", DllStructGetData($struct, "DeviceName"), "dword", -1, "ptr", DllStructGetPtr($device))
				If $retour[0] And DllStructGetData($device, "dmPelsWidth") > 0 And DllStructGetData($device, "dmPelsHeight") > 0 Then
					$resultat[0][0] = $resultat[0][0] + 1
					ReDim $resultat[$resultat[0][0]+1][6]
					$resultat[$resultat[0][0]][0] = DllStructGetData($device, "x")
					$resultat[$resultat[0][0]][1] = DllStructGetData($device, "y")
					$resultat[$resultat[0][0]][2] = DllStructGetData($device, "dmPelsWidth")
					$resultat[$resultat[0][0]][3] = DllStructGetData($device, "dmPelsHeight")
					$resultat[$resultat[0][0]][4] = $i
					$resultat[$resultat[0][0]][5] = DllStructGetData($struct, "DeviceName")
					If $resultat[$resultat[0][0]][0] = 0 And $resultat[$resultat[0][0]][1] = 0 Then
						$resultat[0][2] = $resultat[$resultat[0][0]][2]/@DesktopWidth
						$resultat[0][3] = $resultat[$resultat[0][0]][3]/@DesktopHeight
					EndIf
				EndIf
			EndIf
			$i += 1
		WEnd
		DllClose($dll)
	EndIf
	Return $resultat
EndFunc

; Déplacement d'une fenêtre d'un écran vers l'écran suivant
Func WinMoveToNextScreen($title="", $texte="")
	; Récupération du handle la fenêtre
	Local $handle = WinGetHandle($title, $texte)
	If @error Then Return SetError(1)
	; Vérif des résolutions
	Local $res = getResolutions()
	If Not IsArray($res) Or $res[0][0] < 2 Then Return SetError(2)
	Local $screen = 0, $pos = WinGetPos($handle), $point[2] = [$pos[0]+$pos[2]/2, $pos[1]+$pos[3]/2]
	; Trouver l'écran sur lequel est la fenêtre (on pointe le milieu)
	For $i = 1 To $res[0][0]
		If $res[$i][0] <= $point[0] And $point[0] <= $res[$i][0] + $res[$i][2] And $res[$i][1] <= $point[1] And $point[1] <= $res[$i][1] + $res[$i][3] Then
			$screen = $i
			ExitLoop
		EndIf
	Next
	If $screen = 0 Then Return SetError(3)
	; Calcul des ratios de la position/taille de la fenêtre par rapport à l'écran
	Local $factors[4] = [($pos[0]-$res[$screen][0])/$res[$screen][2], ($pos[1]-$res[$screen][1])/$res[$screen][3], $pos[2]/$res[$screen][2], $pos[3]/$res[$screen][3]]
	$nextscreen = $screen+1
	If $nextscreen > $res[0][0] Then $nextscreen = 1
	; Déplacement sur le nouvel écran en conservant les ratios
	Local $move = WinMove($handle, "", $res[$nextscreen][2]*$factors[0]+$res[$nextscreen][0], $res[$nextscreen][3]*$factors[1]+$res[$nextscreen][1], $res[$nextscreen][2]*$factors[2], $res[$nextscreen][3]*$factors[3])
	If $move = 0 Then Return SetError(4)
EndFunc

WinMoveToNextScreen("[ACTIVE]")