Page 1 sur 1
[..] Suppression de profil.
Posté : lun. 26 oct. 2015 11:27
par Loukazenska
Bonjour à tous,
J'ai un souci pour supprimer des profils sur mon poste; Je souhaite supprimer des profils dans "C:\users\" datant de plus d'un mois,
jusqu'ici aucun souci, quand je fais un test sur un dossier créer sur le bureau pour vérifier si tout fonctionne, ca marche et le script supprime bien les dossiers datant de plus d'un mois.( j'ai modifié la date des dossiers grâce à un petit logiciel).
Ensuite c'est la que le problème apparaît. Quand je veux supprimer des profils datant de plus d'un mois présent sur mon poste, impossible, il ne supprime rien, alors je suis bloqué et je sollicite votre aide.
Merci par avance.
Voici mon script :
Code : Tout sélectionner
#include <File.au3>
#include <Date.au3>
#RequireAdmin
dim $Chemin = "C:\Users\"
Local $search = FileFindFirstFile($Chemin&"*.")
If $search = -1 Then
MsgBox(0, "ERREUR !", "Pas de Profil à supprimer !")
Exit
EndIf
While 1
Local $profil = FileFindNextFile($search)
If @error Then ExitLoop
$date=filegettime($chemin & "/" & $profil)
If Abs(_datediff("D",$Date[0] & "/" & $date[1] & "/" & $date[2],_NowCalcDate())) > 30 then
MsgBox("","",$chemin&$profil)
DirRemove($chemin&$profil,1)
EndIf
WEnd
FileClose($search)
Re: [..] Suppression de profil.
Posté : mar. 27 oct. 2015 10:02
par TopXm
Hello
ça ne serait pas plus propre de passer par WMI ou encore en ligne de commande :
Exemple Forum US ?
Car là, tu laisses un paquet de traces (Registre entre autre) en ne shootant que les dossiers
Re: [..] Suppression de profil.
Posté : mar. 27 oct. 2015 15:14
par Oversid3
Et il n'y aurai pas aussi un soucis de droits par rapport a ces dossiers utilisateurs ?
Tu as essayé de lancer en mode admin le script ? Ou depuis un compte admin directement.
Re: [..] Suppression de profil.
Posté : mar. 27 oct. 2015 19:07
par jguinch
Au cas où, voici quelques fonctions et exemples qui te seront peut-être utiles :
► Afficher le texte
Code : Tout sélectionner
#include <WinAPI.au3>
#include <Security.au3>
#include <Array.au3>
; EXAMPLES ###############################################################################
; List of all profiles
$aProfiles = _GetUserProfileList()
_ArrayDisplay($aProfiles)
; Create a profile for the specifed user (administrator here)
_WinAPI_CreateProfile("S-1-5-21-3114055946-370887941-3244374214-5000", "administrator")
; Delete the specified user profile
_WinAPI_DeleteProfile("S-1-5-21-3114055946-370887941-3244374214-5000", "administrator")
; ########################################################################################
Func _WinAPI_CreateProfile($sUserSid, $sUserName)
Local $ret = DllCall("Userenv.dll", "long", "CreateProfile", "wstr", $sUserSid, "wstr", $sUserName, "wstr", "", "dword", 255)
If @error Then Return SetError(1, 0, -1)
Return $ret[3]
EndFunc
Func _WinAPI_DeleteProfile($sSidString, $sProfilePath, $sComputerName = Null)
Local $ret = DllCall("Userenv.dll", "bool", "DeleteProfile", "str", $sSidString, "str", $sProfilePath, "str", $sComputerName)
If @error Then Return SetError(1, 0, 0)
Return $ret[0]
EndFunc
; #FUNCTION# ====================================================================================================================
; Name ..........: _GetUserProfileList
; Description ...: Returns an array containing the users profiles
; Syntax ........: _GetUserProfileList()
; Parameters ....: None
; Return values .: A 2D array :
; $aArray[0][0] - Number of profiles
; $aArray[1][0] - 1st domain\username of the account associated to the profile
; $aArray[1][1] - 1st profile path
; $aArray[1][2] - 1st user SID
; $aArray[1][3] - 1st profile's modification date
; $aArray[n][0] - nth username
; ...
; Author ........: jguinch
; ===============================================================================================================================
Func _GetUserProfileList()
Local $sKey = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList"
Local $iCount = 0, $sSubKey, $sProfileImagePath, $aAccountInfos
Local $aReturn[1][4]
While 1
$iCount += 1
$sSubKey = RegEnumKey($sKey, $iCount)
If @error Then ExitLoop
If StringRegExp($sSubKey, "(?i)S-1-5-21-(\d+-){3}\d+") Then
$sProfileImagePath = StringReplace( _WinAPI_ExpandEnvironmentStrings ( RegRead($sKey & "\" & $sSubKey, "ProfileImagePath") ), "::", ":")
If FileExists($sProfileImagePath) Then
Redim $aReturn[ UBound($aReturn) + 1][4]
$aAccountInfos = _Security__LookupAccountSid($sSubKey)
If IsArray($aAccountInfos) Then $aReturn[ UBound($aReturn) - 1][0] = $aAccountInfos[1] & "\" & $aAccountInfos[0]
$aReturn[ UBound($aReturn) - 1][1] = $sProfileImagePath
$aReturn[ UBound($aReturn) - 1][2] = $sSubKey
$aReturn[ UBound($aReturn) - 1][3] = FileGetTime ($sProfileImagePath & "\ntuser.dat", 0, 1)
EndIf
EndIf
WEnd
$aReturn[0][0] = UBound($aReturn) - 1
Return $aReturn
EndFunc ; ===> _GetUserProfileList