AutoIt Français

Bonjour à tous !

Qui n'a jamais voulu regarder le contenu d'une variable pendant l'exécution de son script ? Voire même changer cette valeur à la volée ?
Tout ça sans devoir arrêter / modifier / relancer le script.

Si vous êtes dans ce cas, cet UDF est fait pour vous.

Utilisation :
-Appuyez sur la touche ² pour activer l'inspection.
-Entrez le nom d'une variable "$t1" pour l'exemple
-Cliquez sur la valeur à modifier
-Changez la valeur
-Fermer la fenêtre

PS : Vous pouvez aussi visualiser tout type de données (un Ubound par exemple) mais la modification ne s'effectuera pas.

► Afficher le texteUDF

Code : Tout sélectionner

#include-once
#include <Array.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiListView.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <StructureConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)

Global $Inspect_Gui
Global $Inspect_Liste
Global $Inspect_Variable
Global $Inspect_Edit
Global $Inspect_Item = -1
Global $Inspect_SubItem = 0
Global $Inspect_Combo
Global $Inspect_Check
Global $Inspect_HotKey = ""
Global $Inspect_TailleDebutListe = 80

Func Inspect_SetHotKey($Key)
    If($Inspect_HotKey = "") Then
        HotKeySet($Inspect_HotKey)
    EndIf
    $Inspect_HotKey = $Key
    HotKeySet($Inspect_HotKey, "Inspect_Inspect")
EndFunc

Func Inspect_InitGuiAff()
    If(IsHWnd($Inspect_Gui)) Then Return False
    Local $Taille[2] = [500, 400+$Inspect_TailleDebutListe]
    $Inspect_Gui = GUICreate("Inspect", $Taille[0], $Taille[1])
    GUISetOnEvent($GUI_EVENT_CLOSE, "Inspect_StopInspect", $Inspect_Gui)
    GUICtrlCreateLabel("Item à inspecter :", 20, 15, $Taille[0]-40, 15, $SS_CENTER)
    $Inspect_Combo = GUICtrlCreateCombo("", 20, 40, $Taille[0]-150, 20)
    GUICtrlSetOnEvent($Inspect_Combo, "Inspect_ComboChange")
    GUICtrlCreateButton("Ok", $Taille[0]-120, 39, 50, 23)
    GUICtrlSetState(-1, $GUI_DEFBUTTON)
    GUICtrlSetOnEvent(-1, "Inspect_ValideInspect")
    $Inspect_Check = GUICtrlCreateCheckbox("Auto Ok", $Taille[0]-65, 43, 60, 15)
    $Inspect_Liste = _GUICtrlListView_Create($Inspect_Gui, "", 0, $Inspect_TailleDebutListe, $Taille[0], $Taille[1]-$Inspect_TailleDebutListe, BitOR($LVS_EDITLABELS, $LVS_REPORT))
    _GUICtrlListView_AddColumn($Inspect_Liste, "Variable", 150)
    _GUICtrlListView_AddColumn($Inspect_Liste, "Valeur", 240)
    _GUICtrlListView_AddColumn($Inspect_Liste, "Type", 80)
    _GUICtrlListView_SetExtendedListViewStyle($Inspect_Liste, $LVS_EX_GRIDLINES)
    GUICtrlSetResizing($Inspect_Liste, $GUI_DOCKALL)
    OnAutoItExitRegister("inspect_quit")
EndFunc

Func Inspect_RemplireListeVar()
    If(Not(@Compiled)) Then
        Local $Variables = Inspect_SourcesGetVariables(@ScriptFullPath)
        GUICtrlSetData($Inspect_Combo, "")
        GUICtrlSetData($Inspect_Combo, $Variables[1], 1)
        For $i = 1 To $Variables[0]
            GUICtrlSetData($Inspect_Combo, StringLeft($Variables[$i], 50))
        Next
    EndIf
EndFunc

Func Inspect_Inspect()
    $Inspect_Variable = ""
    GUISetState(@SW_SHOW, $Inspect_Gui)
EndFunc

Func Inspect_ComboChange()
    If(BitAND(GUICtrlRead($Inspect_Check), $GUI_CHECKED)) Then
        Inspect_ValideInspect()
    EndIf
EndFunc

Func Inspect_ValideInspect()
    Local $Execute
    _GUICtrlListView_DeleteAllItems($Inspect_Liste)
    $Inspect_Variable = GUICtrlRead($Inspect_Combo)
    $Execute = Execute($Inspect_Variable)
    Local $Inspect_Items[1]
    Switch UBound($Execute, 0)
        Case 0
            $Inspect_Items[0] = _GUICtrlListView_AddItem($Inspect_Liste, $Inspect_Variable)
            _GUICtrlListView_AddSubItem($Inspect_Liste, $Inspect_Items[0], $Execute, 1)
            _GUICtrlListView_AddSubItem($Inspect_Liste, $Inspect_Items[0], VarGetType($Execute), 2)
        Case 1
            ReDim $Inspect_Items[UBound($Execute, 1)]
            For $i = 0 To UBound($Execute, 1)-1
                $Inspect_Items[$i] = _GUICtrlListView_AddItem($Inspect_Liste, $Inspect_Variable & "[" & $i & "]")
                _GUICtrlListView_AddSubItem($Inspect_Liste, $Inspect_Items[$i], $Execute[$i], 1)
                _GUICtrlListView_AddSubItem($Inspect_Liste, $Inspect_Items[$i], VarGetType($Execute[$i]), 2)
            Next
        Case 2
            ReDim $Inspect_Items[UBound($Execute, 1)][UBound($Execute, 2)]
            For $j = 0 To UBound($Execute, 1)-1
                For $i = 0 To UBound($Execute, 2)-1
                    $Inspect_Items[$j][$i] = _GUICtrlListView_AddItem($Inspect_Liste, $Inspect_Variable & "[" & $j & "][" & $i & "]")
                    _GUICtrlListView_AddSubItem($Inspect_Liste, $Inspect_Items[$j][$i], $Execute[$j][$i], 1)
                    _GUICtrlListView_AddSubItem($Inspect_Liste, $Inspect_Items[$j][$i], VarGetType($Execute[$j][$i]), 2)
                Next
            Next
    EndSwitch
    GUIRegisterMsg($WM_NOTIFY, "INSPECT_WM_NOTIFY")
    GUIRegisterMsg($WM_COMMAND, "INSPECT_WM_COMMAND")
    GUISetState(@SW_SHOW, $Inspect_Gui)
EndFunc

Func INSPECT_WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $Inspect_Liste
            Switch $iCode
                Case $NM_CLICK ; used for sub item edit
                    Local $aHit = _GUICtrlListView_SubItemHitTest($Inspect_Liste)
                    If ($aHit[0] <> -1) And ($aHit[1] > 0) Then
                        $Inspect_Item = $aHit[0]
                        $Inspect_SubItem = $aHit[1]
                        Local $iSubItemText = _GUICtrlListView_GetItemText($Inspect_Liste, $Inspect_Item, $Inspect_SubItem)
                        Local $iLen = 220
                        Local $aRect = _GUICtrlListView_GetSubItemRect($Inspect_Liste, $Inspect_Item, $Inspect_SubItem)
                        $Inspect_Edit = _GUICtrlEdit_Create($Inspect_Gui, $iSubItemText, $aRect[0] + 3, $aRect[1]+$Inspect_TailleDebutListe-2, $iLen, 17, BitOR($WS_CHILD, $WS_VISIBLE, $ES_AUTOHSCROLL, $ES_LEFT))
                        _GUICtrlEdit_SetSel($Inspect_Edit, 0, -1)
                        _WinAPI_SetFocus($Inspect_Edit)
                        HotKeySet("{ENTER}", "Inspect_FinEdit")
                    EndIf
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func Inspect_FinEdit()
    INSPECT_WM_COMMAND($Inspect_Gui, $WM_COMMAND, BitShift($EN_KILLFOCUS, -16), $Inspect_Edit)
EndFunc

Func INSPECT_WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $iCode = BitShift($wParam, 16)
    Switch $lParam
        Case $Inspect_Edit
            Switch $iCode
                Case $EN_KILLFOCUS
                    HotKeySet("{ENTER}")
                    Local $iText = _GUICtrlEdit_GetText($Inspect_Edit)
                    _GUICtrlListView_SetItemText($Inspect_Liste, $Inspect_Item, $iText, $Inspect_SubItem)
                    Local $Inspect_VariableTab = _GUICtrlListView_GetItemText($Inspect_Liste, $Inspect_Item)
                    Local $VarType = _GUICtrlListView_GetItemText($Inspect_Liste, $Inspect_Item, 2)
                    _WinAPI_DestroyWindow($Inspect_Edit)
                    $Inspect_Item = -1
                    $Inspect_SubItem = 0
                    Local $VarFormated = $iText
                    Switch $VarType
                        Case "Int32"
                            $VarFormated = Number($VarFormated)
                        Case "Bool"
                            If($VarFormated = "False") Then
                                $VarFormated = False
                            Else
                                $VarFormated = Not(Not($VarFormated))
                            EndIf
                        Case "Ptr"
                            $VarFormated = Ptr($VarFormated)
                        Case "Binary"
                            $VarFormated = StringToBinary(BinaryToString($VarFormated))
                    EndSwitch
                    Local $Assign = Execute($Inspect_Variable)
                    Local $Dim1
                    Local $Dim2
                    Switch UBound($Assign, 0)
                        Case 0
                            $Assign = $VarFormated
                        Case 1
                            $Dim1 = StringSplit($Inspect_VariableTab, "[", 3)
                            $Dim1 = $Dim1[1]
                            $Dim1 = StringSplit($Dim1, "]", 3)
                            $Dim1 = $Dim1[0]
                            $Assign[$Dim1] = $VarFormated
                        Case 2
                            $Dim1 = StringSplit($Inspect_VariableTab, "[", 3)
                            $Dim2 = $Dim1[2]
                            $Dim1 = $Dim1[1]
                            $Dim1 = StringSplit($Dim1, "]", 3)
                            $Dim1 = $Dim1[0]
                            $Dim2 = StringSplit($Dim2, "]", 3)
                            $Dim2 = $Dim2[0]
                            $Assign[$Dim1][$Dim2] = $VarFormated
                    EndSwitch
                    Assign(StringTrimLeft($Inspect_Variable, 1), $Assign)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func Inspect_StopInspect()
    GUISetState(@SW_HIDE, $Inspect_Gui)
EndFunc

Func Inspect_SourcesGetVariables($FileName)
    Local $Variables[1] = [0]
    Local $RegExp = "\s(\$[\w]+)"
    If(FileExists($FileName)) Then
        $Variables = StringRegExp(FileRead($FileName), $RegExp, 3)
        $Variables = _ArrayUnique($Variables)
        _ArraySort($Variables, 0, 1)
    EndIf
    Return $Variables
EndFunc

Func inspect_quit()
    _GUICtrlListView_Destroy($Inspect_Liste)
    GUIDelete($Inspect_Gui)
EndFunc

► Afficher le texteExemple

Lancez l'exemple, appuyez sur ², changez la valeur 4 en 8 par exemple et fermez la fenêtre, le ToolTip à bien changé !

Édit : Je viens de voir que je n'ai pas mis à jour le script depuis bien longtemps alors que celui-ci à changé (C'est chose faite maintenant !)
Le programme n'est plus mis en pause lors d'une visualisation de variable !

Super, c'est pratique ça ! Le programme n'est pas trop instable si on modifie les variables en utilisation ?

Effectivement c'ets super sympa !
RL' : Oui mais sa dépend la quel tu casse ^^.

Super cool!!!

Un seul mot : Efficace

Le programme sera aussi instable que la donnée que vous changerez ^^
Il sert juste à ne pas devoir rééditer le code source (et donc ajouter à celui-ci la modification dont vous voulez)
Donc c'est aussi instable à chaud que si ça avait été fait à froid.

Merci à tous pour vos messages ^^

Merci pour cette précision. Tu pourrais faire une variante qui affiche toutes les variables ?
Autre chose, elles sont actualisées automatiquement ou il faut relancer l'inspection à chaque changement d'état ?

Mais ça modifie le code source ou pas? Car si ç ale fait pas c'est pas plus utile.

J'ai pas test honnetement mais les tablaux marchent aussi?

1) Pour l'affichage de toutes les variables, je vais me pencher dessus.
2) Lorsque vous appuyez sur "²" le programme est mis en pause et ce n'est qu'à la validation que la variable est lu, donc il n'y a pas besoin de réactualiser.
3) Ça ne modifie en aucun cas le code source, ce n'est qu'un outils d'inspection
4) Les tableaux marchent (jusqu'à 2 dimensions) si quelqu'un à un problème avec plus de dimensions, je changerai cette limite.

Super idée, ça commençait à me souler de mettre des MsgBox partout pour connaitre la valeur des variables et vérifier si tout est OK

Juste une petite idée à rajouter au script si c'est possible ça serait que à chaque fois qu'une variable est utilisée, il mette une MsgBox pour en afficher la valeur de la variable et la ligne à la quel elle se trouve (parce que dans certains scripts je ne me souvient plus le nom de toutes les variables

)

Simplement indispensable !
Merci pour ce partage !
Ce serait sympa de pouvoir visualiser plusieurs variables en même temps !

Ca déboite, merci pour le partage !

J'me suis juste permis de personnaliser un petit peu au début de la fonction Inspect() parce que j'suis une andouille et que j'aime autant me simplifier la vie quand je dois taper le nom d'une variable : ^^

► Afficher le texte

Et un petit "If Not @Compiled Then {Script}" aussi parce que j'suis assez malin pour oublier de commenter si je veux compiler et partager ! :p

Modifications :
- Le script n'est plus mis en pause lors d'une inspection, de toute façon on ne pouvait pas savoir où en était le script lors de la pause.
- Ajout de la liste des variables dans la combobox (si le script n'est pas compilé). (via Inspect_RemplireListeVar())
- Choix du HotKeySet. (via Inspect_SetHotKey())

PS : Une autre utilisation peut être possible avec l'inspect.au3, au lieu d'entrer une variable, vous pouvez entrer un nom de fonction comme MsgBox(0, "", "test") ou une fonction personnelle.

AutoIt Français

[UDF] Variable inspect

[UDF] Variable inspect

Re: [UDF] Variable inspect

Re: [UDF] Variable inspect

Re: [UDF] Variable inspect

Re: [UDF] Variable inspect

Re: [UDF] Variable inspect

Re: [UDF] Variable inspect

Re: [UDF] Variable inspect

Re: [UDF] Variable inspect

Re: [UDF] Variable inspect

Re: [UDF] Variable inspect

Re: [UDF] Variable inspect

Re: [UDF] Variable inspect