AutoIt Français

Code : Tout sélectionner

; Examples
_ServiceSetStartMode('Dnscache', 'Disabled')
ConsoleWrite('_ServiceSetStartMode(Dnscache) @error : ' & @error & @CRLF & @CRLF)

_ServiceSetStartMode('Dnscache', 'Disaboule')
ConsoleWrite('_ServiceSetStartMode(Dnscache) @error : ' & @error & @CRLF)

; #FUNCTION# ====================================================================================================================
; Name .........:   _ServiceSetStartMode()
; Description ..:   Change Service StartMode
; Syntax .......:   _ServiceSetStartMode($iServName, $iValue, $iComputer)
; Parameters....:   $iServName  : Service Name
;                   $iValue     : Start Mode
;                               "Boot"          Device driver started by the operating system loader
;                                               (valid only for driver services).
;                               "System"        Device driver started by the operating system initialization process.
;                                               This value is valid only for driver services.
;                               "Automatic"     Service to be started automatically by the service control manager
;                                               during system startup.
;                               "Manual"        Service to be started by the Service Control Manager when a process
;                                               calls the StartService method.
;                               "Disabled"      Service that cannot be started.
;                   $iComputer  : Computer name (Default '.')
;
; Return values.:   Success - Return 0
;                   Failure - Return @error = 1 to 24 : ChangeStartMode error code
;                             for more details see
;                             http://msdn.microsoft.com/en-us/library/windows/desktop/aa384896%28v=vs.85%29.aspx
;                             Return @error = 25 for invalid input param
;                             Return @error = 26 for ObjGet Error
;                             Return @error = 27 for ExecQuery Error
; ===============================================================================================================================
Func _ServiceSetStartMode($iServName = '', $iValue = '', $iComputer = '.')
    ;Params Check
    Local $nRetVal, $oService, $StartModeValues = 'Boot/System/Automatic/Manual/Disabled'

    If $iServName = '' Or $iValue = '' Then Return SetError(25)
    If Not StringInStr($StartModeValues, $iValue) Then Return SetError(25)

    ;Open Service Object
    Local $ObjWMI = ObjGet("winmgmts:\\" & $iComputer & "\root\cimv2")
    If @error Then Return SetError(26)

    ;Obj Query service
    Local $oColServ = $ObjWMI.ExecQuery('Select * from Win32_Service Where Name = "' & $iServName & '"')
    If @error Then Return SetError(27)

    ;Update Service StartMode
    For $oService In $oColServ
        $nRetVal = $oService.ChangeStartMode($iValue)
    Next
    Return $nRetVal
EndFunc
 

Code : Tout sélectionner

; #FUNCTION# ====================================================================================================================
; Name...........:  _SetServiceDescription()
; Description ...:  Set Service Description (Cf HKLM\SYSTEM\CurrentControlSet\services\<ServiceName>\Description
; Syntax.........:  _SetServiceDescription($i_ServName, $i_Description, $i_ComputerName)
; Parameters ....:  $i_ServName         - Service Name (Ex : Dnscache) ServiceName is case sensitive
;                   $i_Description      - The new description to set
;                   $i_ComputerName     - The name of the computer (Default = '.')
;
; Return values .: Success - 1
;                  Failure - 0 and sets @error :
;                   1 - bads params
;                   2 - ChangeServiceConfig2 failed
;                   3 - OpenScManager failed
;                   4 - OpenService failed
;
; cf : http://msdn.microsoft.com/en-us/library/windows/desktop/ms681988%28v=vs.85%29.aspx
; ===============================================================================================================================
; Constants values
Local Const $nAPI = 'advapi32.dll'

Local Const $SC_MANAGER_CONNECT = 0x0001
Local Const $SERVICE_CHANGE_CONFIG = 0x0002
Local Const $SERVICE_CONFIG_DESCRIPTION = 1

Func _SetServiceDescription($i_ServName = '', $i_Description = '', $i_ComputerName = '.')
    If $i_ServName = '' Or $i_Description = '' Then Return SetError(1, 0)

    ;open service control manager
    Local $aSC = DllCall($nAPI, 'long', 'OpenSCManager', 'str', $i_ComputerName, _
                         'str', 'ServicesActive', 'long', $SC_MANAGER_CONNECT)
    If @error Then Return SetError(3, 0)

    ;open specified service
    Local $aServ = DllCall($nAPI, 'long', 'OpenService', 'long', $aSC[0], _
                              'str', $i_ServName, 'long', $SERVICE_CHANGE_CONFIG)
    If @error Then
        DllCall($nAPI, 'int', 'CloseServiceHandle', 'long', $aServ[0])
        Return SetError(4, 0)
    EndIf
    ;Set pointeur
    $ServDescription = DllStructCreate('ptr')
    ;Set string descript.
    $StrDes = DllStructCreate('char[260]')
    DllStructSetData($StrDes, 1, $i_Description)
    DllStructSetData($ServDescription, 1, DllStructGetPtr($StrDes))
    ;Set Description
    Local $nDes = DllCall($nAPI, 'long', 'ChangeServiceConfig2', 'long', $aServ[0], _
                           'long', $SERVICE_CONFIG_DESCRIPTION, 'long', _
                           DllStructGetPtr($ServDescription))
    ;close handles
    DllCall($nAPI, 'int', 'CloseServiceHandle', 'long', $aServ[0])
    DllCall($nAPI, 'int', 'CloseServiceHandle', 'long', $aSC[0])
    If $nDes = 0 Then Return SetError(2, 0)
    Return 1
EndFunc