[R] Contrôle d'erreur dans un GUI

[mokoto]

Bonjour,

J'essai de faire un programme qui permet d'utiliser 7zip rapidement.

Je suis bloqué avec le contrôle d'erreur quand je clique sur Lancer. En effet l'erreur reste en mémoire et du coup le programme ne peut plus fonctionner.

Voici le fichier ini :

[Chemin]
Adresse=C:\Program Files\7-Zip\7zG.exe
Destination=C:\Temp\Scripts\7zip auto\

Voici le code :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### 
Global $Form = GUICreate("Outil de compression codé rapide", 513, 63, 192, 114)
Global $Parcourir = GUICtrlCreateButton("Parcourir", 10, 10, 100, 25, $WS_GROUP)
Global $NomArchive = GUICtrlCreateInput("", 120, 10, 270, 25)
Global $Label1 = GUICtrlCreateLabel("Entrez le nom de l'archive", 120, 40, 125, 17)
Global $Lancer = GUICtrlCreateButton("Lancer", 400, 10, 100, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Global $File = ""

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
    Case $GUI_EVENT_CLOSE
    Exit

    Case $Parcourir

        $File = FileSelectFolder("Choisir le dossier ", "C:\", 2)

        If $File = "" Then
            MsgBox(0,"Erreur","Veuillez choisir un dossier")
        Else
            $Cible = $File & "\"
        EndIf

    Case $Lancer

        $NomArchive = GUICtrlRead($NomArchive)
        $Chemin = IniRead("config.ini","Chemin","Adresse","")
        $Destination = IniRead("config.ini","Chemin","Destination","")

        [b]If $File = "" OR $NomArchive = "" Then
            MsgBox (0,"Erreur","erreur")[/b]
        Else
            Run ($Chemin & " a -sfx " & Chr(34) & $Destination & $NomArchive & Chr(34) & " -mx5 -psecret -mhe " & Chr(34) & $Cible & Chr(34))
        Endif

 EndSwitch
WEnd

Il faudrait peut être réinitialiser le case $Lancer mais comment?

[zeshrek]

Hmmmm... Quelques choses me semblent bizares...
1/ Tes variables sont nommées n'importe comment :
-> $file contient le retour de FileSelectFolder qui comme son nom l'indique renvoie un dossier
-> $chemin contient la valeur de Adresse du fichier Ini, qui est en fait la référence a un executable
-> $Destination contient la valeur de Destination du fichier Ini, qui est en fait un chemin
2/ Et tant que j'y suisavec tes variables elles ne sont pas toutes déclarées ($nMsg, $Cible, $Chemin, $Destination...). Prend l'habitude de mettre un

Code : Tout sélectionner

AutoItSetOption("MustDeclareVars", 1)

au début de tes scripts, ca t'oblige a déclarer tes variables. C'est chi*nt au début, masi on en prend vite l'habitude et au final on gagne du temps, et de la cohérence.
3/ La ligne

Code : Tout sélectionner

$NomArchive = GUICtrlRead($NomArchive)

est la source de ton problème. On ne réaffecte pas a la variable qui contient l'ID d'un controle de la GUI la valeur du contenu de ce controle !!!
Ceci devrait mieux marcher:

Code : Tout sélectionner

        Case $Lancer
            $Archive = GUICtrlRead($NomArchive)
            $Chemin = IniRead("config.ini", "Chemin", "Adresse", "")
            $Destination = IniRead("config.ini", "Chemin", "Destination", "")

            If $File = "" Or $Archive = "" Then
                MsgBox(0, "Erreur", "erreur")
            Else
                Run($Chemin & " a -sfx " & Chr(34) & $Destination & $Archive & Chr(34) & " -mx5 -psecret -mhe " & Chr(34) & $Cible & Chr(34))
            EndIf

[mokoto]

Merci pour tes conseils, j'ai corriger les problèmes comme tu me l'as indiqué et ça fonctionne.

voilà le script :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
AutoItSetOption("MustDeclareVars", 1)
#Region ### START Koda GUI section ### Form=C:\Gestion\Scripts\7zip auto\Form1.kxf
Global $Form = GUICreate("Outil de compression codé rapide", 513, 63, 192, 114)
Global $Parcourir = GUICtrlCreateButton("Parcourir", 10, 10, 100, 25, $WS_GROUP)
Global $Archive = GUICtrlCreateInput("", 120, 10, 270, 25)
Global $Label1 = GUICtrlCreateLabel("Entrez le nom de l'archive", 120, 40, 125, 17)
Global $Lancer = GUICtrlCreateButton("Lancer", 400, 10, 100, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

;déclaration des variables
Global $SelectDossier = ""
Global $DossierCible = ""
Global $nMsg = ""
Global $NomArchive = ""
Global $Chemin7zip = ""
Global $CheminDestination = ""

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
    Case $GUI_EVENT_CLOSE
    Exit

    Case $Parcourir

        $SelectDossier = FileSelectFolder("Choisir le dossier ", "C:\", 2)

        If $SelectDossier = "" Then
            MsgBox(0,"Erreur","Veuillez choisir un dossier")
        Else
            $DossierCible = $SelectDossier & "\"
        EndIf

    Case $Lancer

        $NomArchive = GUICtrlRead($Archive)
        $Chemin7zip = IniRead("config.ini","Chemins","Chemin de 7zip","")
        $CheminDestination = IniRead("config.ini","Chemins","Chemin de destination","")

        If $SelectDossier = "" OR $NomArchive = "" Then
            MsgBox (0,"Erreur","Veuillez selectionner un dossier et/ou indiquer un nom pour l'archive à créer")
        Else
            Run ($Chemin7zip & " a -sfx " & Chr(34) & $CheminDestination & $NomArchive & Chr(34) & " -mx5 -psecret -mhe " & Chr(34) & $DossierCible & Chr(34))
        Endif

 EndSwitch
WEnd

[zeshrek]

Mieux c'est !

Il te reste plus qu'a le passer en [R]