[R] Gérer le déplacement d'images

[Rexspahr]

Bonjour à tous, j'ai un petit problème
Je suis en train de faire un jeu du genre shoot'em up, mais je vous explique le problème.


Voici le code : je vous écrit des commentaires en même temps :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>


#Region ### START Koda GUI section ### Form=

$gui = GUICreate("Shooter Béta 0.1", 1280, 780,-3, -3,BitOR($WS_MINIMIZEBOX,$WS_SYSMENU,$WS_DLGFRAME,$WS_POPUP,$WS_GROUP,$WS_CLIPSIBLINGS)) [color=#008000]; Je crée la fenêtre[/color]
GUICtrlCreatePic("Sky.gif", 0, 0, 0, 0) [color=#008000];Je charge le fond[/color]
Local $msg
Global $gui, $guiPos, $pic, $picPos, $Mouse_pos, $PosX, $PosY, $Tir1, $Pos_TirX, $Pos_TirY
$pic = GUICreate("", 34, 38, $PosX, $PosY, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_MDICHILD), $gui)
GUICtrlCreatePic("Ship.gif", 0, 0, 0, 0) [color=#008000]; je charge le vaisseau[/color]

GUISetState(@SW_SHOW, $pic)
GUISetState(@SW_SHOW, $gui)

#EndRegion ### END Koda GUI section ###

Opt('MustDeclareVars', 1)
Opt("WinTitleMatchMode", 2)

$Mouse_pos = MouseGetPos() [color=#008000]; je charge la position de la souris
[/color]
While 1
    HotKeySet("{ESC}","Quit") [color=#008000]; je quitte la fenêtre quand j 'appuie sur ESC[/color]
    HotKeySet("z","Tir1") [color=#008000]; quand j'appuie sur Z, je tire[/color]
    $PosX = $Mouse_pos[0] - 17 [color=#008000]; Je met un décalage par rapport au vaisseau pour avoir la souris centrée sur le vaisseau.[/color]
    $PosY = $Mouse_pos[1] - 19
    WinMove($pic, "", $PosX, $PosY) [color=#008000]; Je bouge le vaisseau en même temps que la souris[/color]
    $Mouse_pos = MouseGetPos()
    Sleep(10)

WEnd


Func Quit()
    Exit
EndFunc

Func Tir1()
    $Pos_TirX = $PosX + 9 [color=#008000]; je met un décalage pour avoir les tirs qui partent en face du vaisseau.[/color]
    $Pos_TirY = $PosY - 40
    $Tir1 = GUICtrlCreatePic("Tir1.gif", $Pos_TirX, $Pos_TirY, 14, 20)[color=#008000]; je charge l'image[/color]
    GUISetState(@SW_SHOW)

EndFunc

Mon problème est que je n'arrive pas à faire avancer les tirs tout en bougeant, car là, évidemment, ils ne bougent pas.
Je m'explique : je veux que l'image des tirs avance toute seule en diminuant sa position en Y de 10 par 10.
De plus quand j'appuie sur Z, les tirs ne s'affichent pas bien : voici un screenshot :
http://www.noelshack.com/1/1/shooter1-b3c2f99b61.jpg


Premièrement, la transparence n'est pas gérée, et deuxièmement, il faut appuyer plusieurs fois sur Z pour voir les tirs daigner s'afficher... ^^'


Merci d'avance pour votre aide !

[TommyDDR]

Pour faire avancer vos tir, regardez du coté de GUICtrlSetPos

Pour la transparence d'un gif, mettez la 1er pixel (haut gauche) de la couleur dont vous voulez que la transparence soit, c'est ce 1er pixel qui défini la couleur de la transparence de l'image.

[Rexspahr]

Merci beaucoup TommyDDR !

Je passe en résolu !


Edit : Euh en fait, ce n'est pas résolu ^^
Je ne vois pas comment gérer la transparence en utilisant le 1er pixel du haut...
Vous pourriez m'expliquer s'il vous plait ?

Par contre, le GUICtrlSetPos fonctionne très bien !

[TommyDDR]

Fonctionnement d'un gif :

Le pixel situé en haut a droite de l'image (1er pixel) définira la couleur de transparence de l'image.

CAD : Si vous mettez le 1er pixel en blanc : 0xFFFFFF alors, TOUS les pixel blanc apparaitront transparents.

Aller, cadeau :

[Rexspahr]

Ah d'accord !!!
Je n'avais pas compris cela comme ça !

je pensais qu'il fallait utiliser une fonction qui prenait le 1er pixel, et qui effacerait les pixel de la même couleur

Et bien merci beaucoup de l'aide !

[TommyDDR]

Bon, comme je trouvais votre fond joli, j'ai eu envi de gérer les tirs.

Je m'arrête là sinon je vais programmer un truc qui me prendra quelques jours ^^'
Je vous fourni le code.

► Afficher le textecode

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>


Opt("GUIOnEventMode", 1)
Opt('MustDeclareVars', 1)
Opt("WinTitleMatchMode", 2)

Dim $gui
Dim $Fond
Dim $Ship[3] = [640, 700, 0]
Dim $Sky
Dim $Mouse_pos
Dim $Tir[10][3]
Dim $bEtatTir = False
For $j = 0 To 9
    For $i = 0 To 2
        $Tir[$j][$i] = -1
    Next
Next

$gui = GUICreate("Shooter Béta 0.1", 1280, 770, 0, 0, $WS_POPUP) ; Je crée la fenêtre
GUISetOnEvent($GUI_EVENT_CLOSE, "quit")

$Fond = GUICtrlCreatePic("Sky.bmp", 0, 0, 0, 0) ;Je charge le fond
$Ship[2] = GUICtrlCreatePic("Ship.gif", $Ship[0], $Ship[1], 0, 0) ; je charge le vaisseau
GUICtrlSetCursor($Fond, 16)
GUICtrlSetCursor($Ship, 16)

GUISetState(@SW_SHOW, $gui)

HotKeySet("{ESC}","quit") ; je quitte la fenêtre quand j 'appuie sur ESC

While(True)
    If(_IsPressed("25")) Then
        If($Ship[0] > 0) Then
            $Ship[0] -= 10
            Move()
        EndIf
    EndIf
    If(_IsPressed("27")) Then
        If($Ship[0] < 1240) Then
            $Ship[0] += 10
            Move()
        EndIf
    EndIf
    If(_IsPressed("26")) Then
        If($Ship[1] > 0) Then
            $Ship[1] -= 10
            Move()
        EndIf
    EndIf
    If(_IsPressed("28")) Then
        If($Ship[1] < 730) Then
            $Ship[1] += 10
            Move()
        EndIf
    EndIf
    If(_IsPressed("20")) Then
        If(Not($bEtatTir)) Then
            $bEtatTir = True
            AdlibRegister("Tir", 100)
        EndIf
    Else
        If($bEtatTir) Then
            $bEtatTir = False
            AdlibUnRegister("Tir")
        EndIf
    EndIf
    Sleep(10)
WEnd

Func Move()
    GUICtrlSetPos($Ship[2], $Ship[0], $Ship[1]) ; Je bouge le vaisseau en même temps que la souris
EndFunc

Func Quit()
    Exit
EndFunc

Func Tir()
    Local $NextTir = GetNextTir()
    If(Not(@error)) Then
        $Tir[$NextTir][0] = $Ship[0] + 9 ; je met un décalage pour avoir les tirs qui partent en face du vaisseau.
        $Tir[$NextTir][1] = $Ship[1] - 20
        $Tir[$NextTir][2] = GUICtrlCreatePic("Tir.gif", $Tir[$NextTir][0], $Tir[$NextTir][1], 14, 20); je charge l'image
        AdlibRegister("BougerTir", 10)
    EndIf
EndFunc

Func GetNextTir()
    Local $Retour = -1
    For $i = 0 To UBound($Tir, 1)-1
        If($Tir[$i][0] = -1) Then
            $Retour = $i
            ExitLoop
        EndIf
    Next
    If($Retour = -1) Then
        SetError(1)
    EndIf
    Return $Retour
EndFunc

Func BougerTir()
    Local $ListeKill[UBound($Tir, 1)]
    For $i = 0 To UBound($Tir, 1)-1
        If($Tir[$i][0] <> -1) Then
            $Tir[$i][1] -= 10
            GUICtrlSetPos($Tir[$i][2], $Tir[$i][0], $Tir[$i][1])
            If($Tir[$i][1] <= -20) Then
                $ListeKill[$i] = True
            EndIf
        EndIf
    Next
    For $i = 0 To UBound($ListeKill, 1)-1
        If($ListeKill[$i]) Then
            KillTir($i)
        EndIf
    Next
EndFunc

Func KillTir($Numero)
    $Tir[$Numero][0] = -1
    $Tir[$Numero][1] = -1
    GUICtrlDelete($Tir[$Numero][2])
    $Tir[$Numero][2] = -1
    For $i = $Numero To UBound($Tir, 1)-2
        $Tir[$i][0] = $Tir[$i+1][0]
        $Tir[$i][1] = $Tir[$i+1][1]
        $Tir[$i][2] = $Tir[$i+1][2]
    Next
    $Tir[UBound($Tir, 1)-1][0] = -1
    $Tir[UBound($Tir, 1)-1][1] = -1
    $Tir[UBound($Tir, 1)-1][2] = -1
EndFunc
 

Et les images :

[Rexspahr]

Wouah, c'est juste très impressionnant !

Je vais profiter de votre code biensur, mais il ne fallait pas vous donner autant de mal !

En tout cas, je ne peux que vous redire merci

[TommyDDR]

Mais de rien ^^ cela m'a fait plaisir