[R] Section de IniWrite dynamique

[Laddy]

Bonjour à tous

j'ai un petit soucis de méthode, moi qui pensait que ça m'aiderait pour mon autre script avec Zeshrek, je me piège toute seule.
je voudrai créer un ini de façon "dynamique"
Je suis entrain de gréer une sorte de gestionnaire utilisateurs sur mes VM.
J'entre le nom, le nom de la vm et son status.
Et je crée mon ini et liste le contenu dans ma listview.
Mais voila si j'ajoute un nouvel utilisateur, il ecrase le premier.
Comment faire pour que le nom de ma section soit dynamique et change en fonction des entrées délà faite ?

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>


#Region ### START Koda GUI section ### Form=D:\Téléchargements\koda_1.7.3.0\Forms\UserCloneVDI.kxf
Global $UserCloneVDI = GUICreate("UserCloneVDI", 627, 389, 192, 124)
Global $User = GUICtrlCreateInput("", 184, 24, 185, 21)
Global $Utilisateur = GUICtrlCreateLabel("Utilisateur :", 104, 24, 56, 17)
Global $Nom = GUICtrlCreateLabel("Nom de la machine virtuelle : ", 16, 64, 143, 17)
Global $VM = GUICtrlCreateInput("", 184, 64, 185, 21)
Global $Add = GUICtrlCreateButton("Ajouter", 448, 64, 83, 25, $WS_GROUP)
Global $Supp = GUICtrlCreateButton("Supprimer", 544, 64, 75, 25, $WS_GROUP)
Global $Combo = GUICtrlCreateCombo("", 472, 24, 145, 25)
GUICtrlSetData(-1, "En cours|Terminer|Suspendu|Annuler")
Global $Status = GUICtrlCreateLabel("Status :", 408, 32, 40, 17)
Global $Fermer = GUICtrlCreateButton("Fermer", 536, 352, 75, 25, $WS_GROUP)
Global $ListView1 = GUICtrlCreateListView("", 8, 112, 610, 230)
_GUICtrlListView_AddColumn($ListView1, "Utilisateurs", 200)
_GUICtrlListView_AddColumn($ListView1, "VM", 200)
_GUICtrlListView_AddColumn($ListView1, "Status", 200) ; Liste déroulante ? [En cours], [Terminer], [Suspendu], [Annuler]

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
    Case $Add
    Ajouter()
    Case $Fermer
Exit
  Case $GUI_EVENT_CLOSE
   Exit

 EndSwitch
WEnd

Func Ajouter()
    GUICtrlCreateListViewItem(GUICtrlRead($User)  & "|" & GUICtrlRead($VM) & "|" &GuiCtrlRead($Combo), $ListView1)
    IniWrite(@ScriptDir & "\user.ini", "Utilisateur01", "Utilisateur", GUICtrlRead($User))
        IniWrite(@ScriptDir & "\user.ini", "Utilisateur01", "Vbox", GUICtrlRead($VM))
        IniWrite(@ScriptDir & "\user.ini", "Utilisateur01", "Status", GUICtrlRead($Combo))
EndFunc 
 

J'ai cherché sur le forum us et ici je n'ai pas encore trouvé d'exemples sur ce type de cas.

mon user.ini

[Utilisateur01]
Utilisateur=laddy
Vbox=xgnobox
Status=En cours

aimerait ceci

[Utilisateur01]
Utilisateur=laddy
Vbox=xgnobox
Status=En cours
[Utilisateur02]
Utilisateur=Pat
Vbox=xgnobox01
Status=Terminer

Merci à ceux qui m'éclaireront.

Laddy

[reverpi]

Il suffit de compter ton nombre de section avec IniReadSectionNames.
Ton nombre de sections correspond à ton nombre d'utilisateur.
Donc à 5 sections tu es à "Utlisateur05" donc tu créer "Utilisateur06"

[Laddy]

Bonjour
merci je vais regarder l'aide de cette commande, je n'ai jamais compté.
zeshrek va me botter les f***** c'est une chose qu'il m'avait expliqué apparement je ne l'ai pas bien comprise.... surtout sa réutilisation en dehors du tableau

[reverpi]

C'est la premiere valeur de ton tableau retourné ou bien tu utilise la fonction UBound sur ton tableau.

[Laddy]

Hmm que du chinois mais je vais chercher et je reviendrai si jamais demain
bonne soirée et merci

[bloodwolff]

Moi j'irais plus avec un truc du genre car il permet de supprimer des utilisateurs plus facilement ou même avec un stringreg sur un fileread

Code : Tout sélectionner

$Name = inireadsectionnames(blablabla)
If not @error then 
    $number = 0
    For $i = 0 to ubound($name)-1 
        if number(Stringtrimleft($name[$i], 11)) > $number then $number = number(Stringtrimleft($name[$i], 11))
    next
    $number += 1
Else 
    $number = 1
Endif

[TommyDDR]

Bonjour laddy,

j'avais un peu de temps devant moi donc j'ai repri votre code et y ai ajouté :

- Création d'une variable pour votre nom de fichier
- Bug d'écrasement d'utilisateur corrigé
- Chargement des utilisateurs du fichier ini au démarrage de l'appli

Si vous tenez vraiment à vos Utilisateur01, Utilisateur02, etc, je vous laisse chercher comment ajouter le "0"

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>


#Region ### START Koda GUI section ### Form=D:\Téléchargements\koda_1.7.3.0\Forms\UserCloneVDI.kxf
Global $UserCloneVDI = GUICreate("UserCloneVDI", 627, 389, 192, 124)
Global $User = GUICtrlCreateInput("", 184, 24, 185, 21)
Global $Utilisateur = GUICtrlCreateLabel("Utilisateur :", 104, 24, 56, 17)
Global $Nom = GUICtrlCreateLabel("Nom de la machine virtuelle : ", 16, 64, 143, 17)
Global $VM = GUICtrlCreateInput("", 184, 64, 185, 21)
Global $Combo = GUICtrlCreateCombo("", 472, 24, 145, 25)
GUICtrlSetData(-1, "En cours|Terminer|Suspendu|Annuler")
Global $Add = GUICtrlCreateButton("Ajouter", 448, 64, 83, 25, $WS_GROUP)
Global $Supp = GUICtrlCreateButton("Supprimer", 544, 64, 75, 25, $WS_GROUP)
Global $Status = GUICtrlCreateLabel("Status :", 408, 32, 40, 17)
Global $Fermer = GUICtrlCreateButton("Fermer", 536, 352, 75, 25, $WS_GROUP)
Global $ListView1 = GUICtrlCreateListView("", 8, 112, 610, 230)
_GUICtrlListView_AddColumn($ListView1, "Utilisateurs", 200)
_GUICtrlListView_AddColumn($ListView1, "VM", 200)
_GUICtrlListView_AddColumn($ListView1, "Status", 200) ; Liste déroulante ? [En cours], [Terminer], [Suspendu], [Annuler]
Dim $NomFichierIni = @ScriptDir & "\user.ini"
Dim $CompteurUtilisateurs = 0
ChargerUtilisateurs()

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $Add
            Ajouter(GUICtrlRead($User), GUICtrlRead($VM), GUICtrlRead($Combo))
        Case $Fermer
            Exit
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func Ajouter($User, $VM, $Etat)
    $CompteurUtilisateurs += 1
    GUICtrlCreateListViewItem($User & "|" & $VM & "|" & $Etat, $ListView1)
    IniWrite($NomFichierIni, "Utilisateur" & $CompteurUtilisateurs, "Utilisateur", $User)
    IniWrite($NomFichierIni, "Utilisateur" & $CompteurUtilisateurs, "Vbox", $VM)
    IniWrite($NomFichierIni, "Utilisateur" & $CompteurUtilisateurs, "Status", $Etat)
EndFunc

Func ChargerUtilisateurs()
    Local $NomSections
    Local $NomChamps
    If(FileExists($NomFichierIni)) Then
        $NomSections = IniReadSectionNames($NomFichierIni)
        For $i = 1 To $NomSections[0]
            $NomChamps = IniReadSection($NomFichierIni, $NomSections[$i])
            If($NomChamps[0][0] >= 3) Then
                Ajouter($NomChamps[1][1], $NomChamps[2][1], $NomChamps[3][1])
            EndIf
        Next
    EndIf
EndFunc

PS : Regardez aussi du coter des fonctions _SQLite...() si vous voulez passer par une Base De Données au lieu d'un ini.

[Laddy]

Trop fort TommyDDR et Bloodwolf
Un immense merci .
Non je ne tiens pas particulièrement au 0 devant utilisateur.
J'en étais à essayer de lister mes utilisateurs dans la gui, et en regardant ton code, je n'y étais pas du tout.
Je n'utilise pas de base de donnée SQL.

Me reste encore beaucoup de chose à faire : comme pouvoir modifier le status de la VM de l'utilisateur. et lancer via un clic droit la vm en question. Gloups.

[zeshrek]

zeshrek va me botter les f***** c'est une chose qu'il m'avait expliqué apparement je ne l'ai pas bien comprise.... surtout sa réutilisation en dehors du tableau

Ah ba non, ca on en avait pas parlé (quoi que bon, dans le code que je t'avais donné, il y avait ces 2 lignes qui auraient du te mettre sur la voie :

Code : Tout sélectionner

$var = IniReadSectionNames(@ScriptDir & "\MoveFile.ini") ; on lit le fichier ini en stockant dans le tableay $var[] les sections
$NbSectionsDuFichierIni = $var[0] ; on initialise le nombre de  sections avec $var[0] qui contient le nombre de sections

Hmmm... Tu passeras a mon bureau tout a l'heure pour recevoir ta punition...

[Laddy]

Zeshrek oui honte sur moi, j'ai vu qu'après la ligne qui aurait pu m'aider.

tant bien que mal j'ai ajouté le clic droit pour supprimer une ligne , pour le moment je n'ai pas fait la fonction j'ai pas encore trouvé comme faire.

[+] Ajout d'un champ $Patch (chemin de la vm) + bouton Parcourir
[-] suppression du bouton Supprimer pour la remplacer par le clic droit : Supprimer (je ne sais pas si je fais le bon choix ...

► Afficher le texteCode

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>

#cs
UserCloneVDI est un petit gestionnaire d'utilisateurs pour virtualbox.
Auteur : Laddy
Version : 0.1
Utilisateur - Nom VM associé - Status.
Merci TommyDDR

IniReadSectionName :
[Ex]http://www.autoitscript.fr/forum/viewtopic.php?f=6&t=6347&p=39579&hilit=inireadsectionnames#p39579
[A] http://www.autoitscript.fr/forum/viewtopic.php?f=3&t=6701

Projet : Démarrer la VM en fonction de l'utilisateur.

TODOlist :

Mettre des couleurs en fonction du status.
[En cours] --> Vert
[Teminer] --> Rouge
[Suspendu] --> Orange
[Annuler] -->Marron

Double Clic pour lancer la VM.

Func supprimer() -> une section dans le fichier ini
#ce

Global $User32Dll = DllOpen("user32.dll")
#Region ### START Koda GUI section ### Form=D:\Téléchargements\koda_1.7.3.0\Forms\UserCloneVDI.kxf
Global $UserCloneVDI = GUICreate("UserCloneVDI", 627, 437, 192, 124)
Global $User = GUICtrlCreateInput("", 184, 24, 185, 21)
Global $Utilisateur = GUICtrlCreateLabel("Utilisateur :", 104, 24, 56, 17)
Global $Nom = GUICtrlCreateLabel("Nom de la machine virtuelle : ", 16, 64, 143, 17)
Global $VM = GUICtrlCreateInput("", 184, 64, 185, 21)
Global $Combo = GUICtrlCreateCombo("", 472, 24, 145, 25)
GUICtrlSetData(-1, "En cours|Terminer|Suspendu|Annuler")
;Global $Add = GUICtrlCreateButton("Ajouter", 448, 64, 83, 25, $WS_GROUP)
;Global $Supp = GUICtrlCreateButton("Supprimer", 544, 64, 75, 25, $WS_GROUP)
Global $Add = GUICtrlCreateButton("Ajouter", 528, 128, 83, 25, $WS_GROUP)
Global $Status = GUICtrlCreateLabel("Status :", 408, 32, 40, 17)
Global $Fermer = GUICtrlCreateButton("Fermer", 536, 400, 75, 25, $WS_GROUP)
Global $Label = GUICtrlCreateLabel("Chemin", 112, 112, 39, 17)
Global $Path = GUICtrlCreateInput("", 184, 104, 185, 21)
Global $Parcourir = GUICtrlCreateButton("Parcourir", 392, 104, 75, 25, $WS_GROUP)
Global $ListView1 = GUICtrlCreateListView("", 8, 160, 610, 230)
_GUICtrlListView_AddColumn($ListView1, "Utilisateurs", 150)
_GUICtrlListView_AddColumn($ListView1, "VM", 150)
_GUICtrlListView_AddColumn($ListView1, "Status", 150) ; Liste déroulante ? [En cours], [Terminer], [Suspendu], [Annuler]
_GUICtrlListView_AddColumn($ListView1, "Chemin", 150) ; chemin VM
Global $List1context = GUICtrlCreateContextMenu($ListView1)
Global $MenuItem1 = GUICtrlCreateMenuItem("Supprimer", $List1context)
Global $hWnd_ListView = GUICtrlGetHandle($ListView1)
Dim $NomFichierIni = @ScriptDir & "\user.ini"
Dim $CompteurUtilisateurs = 0
ChargerUtilisateurs()

GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $Add
            Ajouter(GUICtrlRead($User), GUICtrlRead($VM), GUICtrlRead($Combo), GuiCtrlRead($Path))
 Case $MenuItem1
            Supprimer()
        Case $Parcourir
            BrowseDst()
        Case $Fermer
            Exit
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func BrowseDst()
    Local $message = "Sélectionne la destination de ton fichier VDI."
    Local $var = FileOpenDialog($message, @DesktopDir & "\", "Fichiers (*.vdi)")
    GUICtrlSetData($Path, $var)
EndFunc   ;==>BrowseDst


Func Ajouter($User, $VM, $Etat, $Path)
    $CompteurUtilisateurs += 1
    GUICtrlCreateListViewItem($User & "|" & $VM & "|" & $Etat & "|" & $Path, $ListView1)
    IniWrite($NomFichierIni, "Utilisateur" & $CompteurUtilisateurs, "Utilisateur", $User)
    IniWrite($NomFichierIni, "Utilisateur" & $CompteurUtilisateurs, "Vbox", $VM)
    IniWrite($NomFichierIni, "Utilisateur" & $CompteurUtilisateurs, "Status", $Etat)
    IniWrite($NomFichierIni, "Utilisateur" & $CompteurUtilisateurs, "Chemin", $Path)
EndFunc

Func ChargerUtilisateurs()
    Local $NomSections
    Local $NomChamps
    If(FileExists($NomFichierIni)) Then
        $NomSections = IniReadSectionNames($NomFichierIni)
        For $i = 1 To $NomSections[0]
            $NomChamps = IniReadSection($NomFichierIni, $NomSections[$i])
            If($NomChamps[0][0] >= 4) Then
                Ajouter($NomChamps[1][1], $NomChamps[2][1], $NomChamps[3][1], $NomChamps[4][1])
            EndIf
        Next
    EndIf
EndFunc

[color=#408000]Func Supprimer()
    Local $Ctrl_LV_Selected = _GUICtrlListView_GetSelectedIndices($hWnd_ListView)
    If MsgBox(52,"Restore restorepoint " & $Ctrl_LV_Selected ,"Warning!" & @CRLF & "Clicking yes will reboot your PC." & @CRLF & "(And possibly restore some restore point)" & @CRLF & "Are you sure you want to continue?") <> 6 Then Return
IniDelete($NomFichierIni, "section2")
EndFunc
[/color]
Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
    Local $tNMHEADER, $hWndFrom, $iCode
    $tNMHEADER = DllStructCreate($tagNMHEADER , $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHEADER, "hWndFrom"))
    $iCode = DllStructGetData($tNMHEADER, "Code")
    If _WinAPI_GetClassName($hWndFrom) = "SysHeader32" And $iCode = $NM_RCLICK Then Return 1
    Switch $hWndFrom
        Case $hWnd_ListView
            If _IsPressed("02", $User32Dll) Then Return 1
            Switch $iCode
                Case $NM_RCLICK
                    Local $iItem = DllStructGetData($tNMHEADER, "Item")
                    Local $Ctrl_LV_Selected = _GUICtrlListView_GetSelectedIndices($hWnd_ListView)
                    If $Ctrl_LV_Selected == "" Or $Ctrl_LV_Selected <> $iItem Then Return 1
            EndSwitch
        EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc
 

[zeshrek]

Je viens de parcourir ton code, et 3 choses me laissent perplexe :
1/ C'est moi ou tu as oublié les balises #cs et #ce au début et la la fin de ta zone de commentaires au début de ton source ?
2/ Dans la création de la GUI, pourquoi toutes tes lignes commencent par Global ? Soit tu déclares toutes tes variables au début du code (pour les globales, sinon c'est au début de la fonction concernée pour les locales), soit tu les déclares pas, mais ces global sont... perturbants, je dirais.
3/ Ton menu contextuel est attaché au listview (cf code en rouge ci dessous)

Code : Tout sélectionner

Global $List1context = GUICtrlCreateContextMenu([color=#FF0000]$ListView1[/color])
Global $MenuItem1 = GUICtrlCreateMenuItem("Supprimer", $List1context)
Global $hWnd_ListView = GUICtrlGetHandle([color=#FF0000]$ListView1[/color])

Il serait préférable de le lier a chaque ligne de la liste de facon a identifier celle sur laquelle tu as fait un clic droit.
Ou alors il te supprime d'office la ligne active.

Sinon, je n'ai pas trop le temps de me pencher sur ce script, je refais l'intégralité de l'autre script en partant de zero (ou presque), donc j'ai aps envie de me mélanger entre les deux
Toutefois, comme l'ajout est l'inverse d'un retrait, vu que tu as réussi la première, tu devrais arriver a faire la seconde...

[TommyDDR]

Merci TommyDDR

Ca fait plaisir de lire cela

Pour votre Combobox :

[Modification]

Code : Tout sélectionner

;On empêche l'utilisateur de saisir ce qu'il veut dans la combobox, il devra choisir l'un des choix proposé
Global $Combo = GUICtrlCreateCombo("", 472, 24, 145, 25, $CBS_DROPDOWNLIST)

[Ajout]

Code : Tout sélectionner

#include <ComboConstants.au3>

Pour votre bouton $Parcourir :
[Ajout]

Code : Tout sélectionner

;Mise en place du code
Case $Parcourir
Parcourir()

Code : Tout sélectionner

Func Parcourir()
    Local $Chemin = FileSelectFolder("Chemin de la VM", "", 6, "")
    If(Not(@error)) Then
        GUICtrlSetData($Path, $Chemin)
    EndIf
EndFunc

Pour votre input $Path :
[Modification]

Code : Tout sélectionner

;On ne peut plus écrire dans l'input, il faudra passer par le bouton "parcourir")
Global $Path = GUICtrlCreateInput("", 184, 104, 185, 21, $ES_READONLY)

[Laddy]

Zeshrek, nos messages se sont croisés, j'ai édité encore une fois mon code.

1.Oui j'ai oublié le #cs et #ce que j'ai corrigé.
2.Pour les Global c'est Koda Design qui les ajoute d'office, oh le vilain.
Je vais corriger et mettre Global en haut.
3. Le clic droit a lieu uniquement sur la ligne Active.
Si j'ai bien compris ce que j'ai bidouillé

Code : Tout sélectionner

Local $Ctrl_LV_Selected = _GUICtrlListView_GetSelectedIndices($hWnd_ListView)
 

Pour l'autre code je me suis complètement perdue, j'en rêve la nuit du code, tellement il me prend la tête.
Je pense que du moment ou tu maitrises le tableau à x dimensions, tu peux faire n'importe quoi en autoit.
Comme en batch, tu maitrises les boucles et rien ne te résiste.


TommyDDR,
Merci encore une fois ;D
Quel est la différence entre ta fonction Parcourir utilisant FileSelectFolder et FileOpenDialog ?
Je vais ajouter les paramètres proposés pour La combo et l'input Path

Edit : J'ai testé FileSelectFolder me sélectionne le dossier et non le fichier, et je souhaite le fichier vdi.

Mon ini me donne ceci :

Code : Tout sélectionner

[Utilisateur1]
Utilisateur=Bulkhulk
Vbox=XPPro
Status=En cours
Chemin=F:\XPPRo.vdi
 

[+] Correction Global
[+] Ajout paramètres $Comb, $Path.

► Afficher le texteCorrection Code

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#include <ComboConstants.au3>

#cs
UserCloneVDI est un petit gestionnaire d'utilisateurs pour virtualbox.
Auteur : Laddy
Version : 0.1
Utilisateur - Nom VM associé - Status.
Merci TommyDDR

IniReadSectionName :
[Ex]http://www.autoitscript.fr/forum/viewtopic.php?f=6&t=6347&p=39579&hilit=inireadsectionnames#p39579
[A] viewtopic.php?f=3&t=6701

Projet : Démarrer la VM en fonction de l'utilisateur.

TODOlist :

Mettre des couleurs en fonction du status.
[En cours] --> Vert
[Teminer] --> Rouge
[Suspendu] --> Orange
[Annuler] -->Marron

Double Clic pour lancer la VM.

Func supprimer() -> une section dans le fichier ini
#ce

Global $UserCloneVDI, $User, $VM, $Combo, $Add, $Fermer, $Path, $Parcourir, $ListView1, $List1context, $MenuItem1, $hWnd_ListView, $ES_READONLY
Global $User32Dll = DllOpen("user32.dll")

Dim $NomFichierIni = @ScriptDir & "\user.ini"
Dim $CompteurUtilisateurs = 0

#Region ### START Koda GUI section ### Form=D:\Téléchargements\koda_1.7.3.0\Forms\UserCloneVDI.kxf
$UserCloneVDI = GUICreate("UserCloneVDI", 627, 437, 192, 124)
$User = GUICtrlCreateInput("", 184, 24, 185, 21)
$Utilisateur = GUICtrlCreateLabel("Utilisateur :", 104, 24, 56, 17)
$Nom = GUICtrlCreateLabel("Nom de la machine virtuelle : ", 16, 64, 143, 17)
$VM = GUICtrlCreateInput("", 184, 64, 185, 21)
$Combo = GUICtrlCreateCombo("", 472, 24, 145, 25, $CBS_DROPDOWNLIST)
GUICtrlSetData(-1, "En cours|Terminer|Suspendu|Annuler")
;Global $Supp = GUICtrlCreateButton("Supprimer", 544, 64, 75, 25, $WS_GROUP)
$Add = GUICtrlCreateButton("Ajouter", 528, 128, 83, 25, $WS_GROUP)
$Status = GUICtrlCreateLabel("Status :", 408, 32, 40, 17)
$Fermer = GUICtrlCreateButton("Fermer", 536, 400, 75, 25, $WS_GROUP)
$Label = GUICtrlCreateLabel("Chemin", 112, 112, 39, 17)
$Path = GUICtrlCreateInput("", 184, 104, 185, 21, $ES_READONLY)
$Parcourir = GUICtrlCreateButton("Parcourir", 392, 104, 75, 25, $WS_GROUP)
$ListView1 = GUICtrlCreateListView("", 8, 160, 610, 230)
_GUICtrlListView_AddColumn($ListView1, "Utilisateurs", 150)
_GUICtrlListView_AddColumn($ListView1, "VM", 150)
_GUICtrlListView_AddColumn($ListView1, "Status", 150) ; Liste déroulante ? [En cours], [Terminer], [Suspendu], [Annuler]
_GUICtrlListView_AddColumn($ListView1, "Chemin", 150) ; chemin VM
$List1context = GUICtrlCreateContextMenu($ListView1)
$MenuItem1 = GUICtrlCreateMenuItem("Supprimer", $List1context)
$hWnd_ListView = GUICtrlGetHandle($ListView1)
ChargerUtilisateurs()

GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $Add
            Ajouter(GUICtrlRead($User), GUICtrlRead($VM), GUICtrlRead($Combo), GuiCtrlRead($Path))
 Case $MenuItem1
            Supprimer()
        Case $Parcourir
            BrowseDst()
        Case $Fermer
            Exit
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd


Func BrowseDst()
    Local $message = "Sélectionne la destination de ton fichier VDI."
    Local $var = FileOpenDialog($message, @DesktopDir & "\", "Fichiers (*.vdi)")
    GUICtrlSetData($Path, $var)
EndFunc   ;==>BrowseDst


Func Ajouter($User, $VM, $Etat, $Path)
    $CompteurUtilisateurs += 1
    GUICtrlCreateListViewItem($User & "|" & $VM & "|" & $Etat & "|" & $Path, $ListView1)
    IniWrite($NomFichierIni, "Utilisateur" & $CompteurUtilisateurs, "Utilisateur", $User)
    IniWrite($NomFichierIni, "Utilisateur" & $CompteurUtilisateurs, "Vbox", $VM)
    IniWrite($NomFichierIni, "Utilisateur" & $CompteurUtilisateurs, "Status", $Etat)
    IniWrite($NomFichierIni, "Utilisateur" & $CompteurUtilisateurs, "Chemin", $Path)
EndFunc

Func ChargerUtilisateurs()
    Local $NomSections
    Local $NomChamps
    If(FileExists($NomFichierIni)) Then
        $NomSections = IniReadSectionNames($NomFichierIni)
        For $i = 1 To $NomSections[0]
            $NomChamps = IniReadSection($NomFichierIni, $NomSections[$i])
            If($NomChamps[0][0] >= 4) Then
                Ajouter($NomChamps[1][1], $NomChamps[2][1], $NomChamps[3][1], $NomChamps[4][1])
            EndIf
        Next
    EndIf
EndFunc

Func Supprimer()
    Local $Ctrl_LV_Selected = _GUICtrlListView_GetSelectedIndices($hWnd_ListView)
IniDelete($NomFichierIni, "section2")


EndFunc

Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
    Local $tNMHEADER, $hWndFrom, $iCode
    $tNMHEADER = DllStructCreate($tagNMHEADER , $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHEADER, "hWndFrom"))
    $iCode = DllStructGetData($tNMHEADER, "Code")
    If _WinAPI_GetClassName($hWndFrom) = "SysHeader32" And $iCode = $NM_RCLICK Then Return 1
    Switch $hWndFrom
        Case $hWnd_ListView
            If _IsPressed("02", $User32Dll) Then Return 1
            Switch $iCode
                Case $NM_RCLICK
                    Local $iItem = DllStructGetData($tNMHEADER, "Item")
                    Local $Ctrl_LV_Selected = _GUICtrlListView_GetSelectedIndices($hWnd_ListView)
                    If $Ctrl_LV_Selected == "" Or $Ctrl_LV_Selected <> $iItem Then Return 1
            EndSwitch
        EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc
 

Pour la fonction de suppression je ne vois pas trop comment m'y prendre pour le moment.

[TommyDDR]

Au temps pour moi, je pensais qu'il vous fallai un dossier, dans ce cas, FileOpenDialog est ce qu'il vous faut en effet.

[Laddy]

Ah cool, j'ai eu un gros doute
Bon je me plonge de ma réflexion sur la suppression et je vais me prendre un doliprane.

[Laddy]

Bonjour
malheureusement après des jours des recherches, je n'ai pas trouvé d'exemples sur le forum pour m'aider, je n'y arrive pas grrr
c'est la solution de facilité mais je pense sérieusement à me contenter de ce script de base ..même en me référent au script de Zeshrek, pas réussi à mettre les champs de mon ini dans les colonnes du listview.
Mon idée était que si la ligne était sélectionnée , les champs input serait rempli
1. pour la suppression
2. pour une modification.

► Afficher le texteBricolage de code

Code : Tout sélectionner

; si la ligne est sélectionnée
Case Else
            Local $NomChamps, $NomSections
            $NomSections = IniReadSectionNames($NomFichierIni)

            For $i = 1 To $NomSections[0]
    $NomChamps = IniReadSection($NomFichierIni, $NomSections[$i])
                    GUICtrlSetData($User, $NomChamps[$i][1])
                    GUICtrlSetData($VM, $NomChamps[$i][2])
                    GUICtrlSetData($combo, $NomChamps[$i][3])
                    GUICtrlSetData($Path, $NomChamps[$i][4])


            Next
 

Je vais honteusement me cacher..

[GaRydelaMer]

Bonsoir

Alors vite fait ce soir:

J'ai renommer les variables et les fonctions pour être plus clair:

► Afficher le texte

Code : Tout sélectionner

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#Tidy_Parameters=/sf
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#Region ;**** Options AutoIt                            ****
Opt("MustDeclareVars", 1)
Opt("GUICloseOnESC", 1)
Opt("GUIOnEventMode", 0)
Opt("WinSearchChildren", 1)
Opt("WinTextMatchMode", 1)
Opt("WinTitleMatchMode", -2)
#EndRegion ;**** Options AutoIt                         ****
#Region ;**** Include AutoIt                            ****
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>

#include <Array.au3>
#include <Misc.au3>
#include <String.au3>

#include <GuiButton.au3>
#include <GUIComboBox.au3>
#include <GuiImageList.au3>
#include <GUIListBox.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#EndRegion ;**** Include AutoIt                         ****

#cs
    UserCloneVDI est un petit gestionnaire d'utilisateurs pour virtualbox.
    Auteur : Laddy
    Version : 0.1
    Utilisateur - Nom VM associé - Status.
    Merci TommyDDR

    IniReadSectionName :
    [Ex]http://www.autoitscript.fr/forum/viewtopic.php?f=6&t=6347&p=39579&hilit=inireadsectionnames#p39579
    [A] viewtopic.php?f=3&t=6701

    Projet : Démarrer la VM en fonction de l'utilisateur.

    TODOlist :

    Mettre des couleurs en fonction du status.
    [En cours] --> Vert
    [Teminer] --> Rouge
    [Suspendu] --> Orange
    [Annuler] -->Marron

    Double Clic pour lancer la VM.

    Func supprimer() -> une section dans le fichier ini
#ce

Global $NomFichierIni = @ScriptDir & "\user.ini"
Global $GUI, $User, $VM, $Etat, $Path, $ListView1, $hWnd_ListView
Global $bt_Add, $bt_Delete, $bt_Update, $bt_Close, $bt_Path, $bt_Execute
Global Enum $idCmd_Delete = 10000, $idCmd_Execute

Global $OSarch, $PathVirtualBox
If @OSArch = "X64" Then $OSarch = "64"
If RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Oracle\VirtualBox", "InstallDir") Then
    $PathVirtualBox = RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Oracle\VirtualBox", "InstallDir")
ElseIf RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\VirtualBox", "InstallDir") Then
    $PathVirtualBox = RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\VirtualBox", "InstallDir")
ElseIf RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\xVM VirtualBox", "InstallDir") Then
    $PathVirtualBox = RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\xVM VirtualBox", "InstallDir")
Else
    MsgBox(16, "VirtualBox", "Erreur d'installation ou le logiciel n'est pas installé sur ce poste.")
    Exit
EndIf

If @OSArch = "X64" Then $OSarch = "64"
;If StringRight($vbox_path, 1) = "\" Then $vbox_path = StringRegExpReplace($vbox_path, "\\$", "")
If RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Oracle\VirtualBox", "InstallDir") Then
    $PathVirtualBox = RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Oracle\VirtualBox", "InstallDir")
ElseIf RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\VirtualBox", "InstallDir") Then
    $PathVirtualBox = RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\VirtualBox", "InstallDir")
ElseIf RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\xVM VirtualBox", "InstallDir") Then
    $PathVirtualBox = RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\xVM VirtualBox", "InstallDir")
Else
    MsgBox(16, "VirtualBox", "Erreur d'installation ou le logiciel n'est pas installé sur ce poste.")
    Exit
EndIf

#Region ### START Koda GUI section ### Form=D:\Téléchargements\koda_1.7.3.0\Forms\UserCloneVDI.kxf
$GUI = GUICreate("UserCloneVDI", 634, 474, 192, 124)
GUICtrlCreateLabel("Utilisateur :", 104, 24, 56, 17)
$User = GUICtrlCreateInput("", 184, 24, 185, 21)
GUICtrlCreateLabel("Nom de la machine virtuelle :", 16, 64, 143, 17)
$VM = GUICtrlCreateInput("", 184, 64, 185, 21)
GUICtrlCreateLabel("Status :", 408, 32, 40, 17)
$Etat = GUICtrlCreateCombo("", 472, 24, 145, 25, BitOR($GUI_SS_DEFAULT_COMBO, $CBS_SIMPLE))
GUICtrlCreateLabel("Chemin", 112, 112, 39, 17)
$Path = GUICtrlCreateInput("", 184, 104, 185, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_READONLY))
$bt_Path = GUICtrlCreateButton("...", 377, 104, 25, 25)
$ListView1 = GUICtrlCreateListView("", 8, 170, 610, 265)
$bt_Add = GUICtrlCreateButton("Ajouter", 228, 140, 100, 25)
$bt_Delete = GUICtrlCreateButton("Supprimer", 514, 140, 100, 25)
$bt_Update = GUICtrlCreateButton("Appliquer", 119, 140, 100, 25)
$bt_Close = GUICtrlCreateButton("Fermer", 551, 440, 75, 25)
$bt_Execute = GUICtrlCreateButton("Exécuter", 333, 140, 100, 25)
_GUI_Init()
GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_NOTIFY, "_Events_WM_NOTIFY")
#EndRegion ### END Koda GUI section ###

Local $nMsg
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $bt_Close, $GUI_EVENT_CLOSE
            Exit
        Case $bt_Path
            GUI_BrowseDst()
        Case $bt_Add
            User_Add()
        Case $bt_Delete
            User_Delete()
        Case $bt_Execute
            User_Execute()
        Case $bt_Update
            User_Update()
    EndSwitch
WEnd

Func _Events_ContextMenu($hWnd, $idCommand)
    If $hWnd = $hWnd_ListView Then
        Switch $idCommand
            Case $idCmd_Delete
                User_Delete()
            Case $idCmd_Execute
                User_Execute()
        EndSwitch
    EndIf
EndFunc   ;==>_Events_ContextMenu
Func _Events_WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
    #forceref $hWnd, $Msg, $wParam, $lParam
    Local $tInfo, $Code
    $tInfo = DllStructCreate($tagNMHDR, $lParam)
    $hWnd = HWnd(DllStructGetData($tInfo, "hWndFrom"))
    $Code = DllStructGetData($tInfo, "Code")

    If $hWnd = $hWnd_ListView Then
        Switch $Code
            Case $LVN_COLUMNCLICK
                ;
            Case $NM_CLICK, $NM_DBLCLK
                GUI_UserView()
            Case $NM_RCLICK
                GUI_CreateContextMenu($hWnd)
        EndSwitch
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_Events_WM_NOTIFY
Func _GUI_Init()
    If Not FileExists($NomFichierIni) Then
        IniWrite($NomFichierIni, "Utilisateur_001", "Nom", "A définir")
    EndIf
    GUICtrlSetData($Etat, "En cours|Terminer|Suspendu|Annuler")

    $hWnd_ListView = GUICtrlGetHandle($ListView1)
    _GUICtrlListView_AddColumn($hWnd_ListView, "Utilisateur", 150)
    _GUICtrlListView_AddColumn($hWnd_ListView, "Nom", 150)
    _GUICtrlListView_AddColumn($hWnd_ListView, "VM", 100)
    _GUICtrlListView_AddColumn($hWnd_ListView, "Status", 100) ; Liste déroulante ? [En cours], [Terminer], [Suspendu], [Annuler]
    _GUICtrlListView_AddColumn($hWnd_ListView, "Chemin", 100) ; chemin VM

    Local $aSections, $iItem, $aUser
    $aSections = IniReadSectionNames($NomFichierIni)
    For $i = 1 To $aSections[0]
        $iItem = _GUICtrlListView_AddItem($hWnd_ListView, $aSections[$i])
        $aUser = IniReadSection($NomFichierIni, $aSections[$i])
        For $iSubItem = 1 To $aUser[0][0]
            _GUICtrlListView_AddSubItem($hWnd_ListView, $iItem, $aUser[$iSubItem][1], $iSubItem)
        Next
    Next
    _GUICtrlListView_SetItemSelected($hWnd_ListView, 0, True, True)
    GUI_UserView()
EndFunc   ;==>_GUI_Init

Func FileIni_SetListView($sSection, $iItem)
    Local $aUser = IniReadSection($NomFichierIni, $sSection)
    For $iSubItem = 1 To $aUser[0][0]
        _GUICtrlListView_SetItemText($hWnd_ListView, $iItem, $aUser[$iSubItem][1], $iSubItem)
    Next
EndFunc   ;==>FileIni_SetListView
Func FileIni_Write($sSection)
    IniWrite($NomFichierIni, $sSection, "Nom", GUICtrlRead($User))
    IniWrite($NomFichierIni, $sSection, "Vbox", GUICtrlRead($VM))
    IniWrite($NomFichierIni, $sSection, "Status", GUICtrlRead($Etat))
    IniWrite($NomFichierIni, $sSection, "Chemin", GUICtrlRead($Path))
EndFunc   ;==>FileIni_Write

Func GUI_BrowseDst()
    Local $message = "Sélectionne la destination de ton fichier VDI."
    Local $var = FileOpenDialog($message, @DesktopDir & "\", "Fichiers (*.vdi)")
    GUICtrlSetData($Path, $var)
EndFunc   ;==>GUI_BrowseDst
Func GUI_CreateContextMenu($hWnd)
    Local $aHit = _GUICtrlListView_HitTest($hWnd), $Item = $aHit[0]
    Local $hMenu = _GUICtrlMenu_CreatePopup(1)
    _GUICtrlMenu_AddMenuItem($hMenu, "Supprimer", $idCmd_Delete)
    _GUICtrlMenu_AddMenuItem($hMenu, "Executer", $idCmd_Execute)

    ; ========================================================================
    ; Shows how to capture the context menu selections
    ; ========================================================================
    Local $idCommand = _GUICtrlMenu_TrackPopupMenu($hMenu, $hWnd, -1, -1, 1, 1, 2)
    _GUICtrlMenu_DestroyMenu($hMenu)
    _Events_ContextMenu($hWnd, $idCommand)
EndFunc   ;==>GUI_CreateContextMenu
Func GUI_UserView()
    Local $aSelected = _GUICtrlListView_GetSelectedIndices($hWnd_ListView, True)
    If $aSelected[0] > 0 Then
        Local $iItem = $aSelected[1]
        GUICtrlSetData($User, _GUICtrlListView_GetItemText($hWnd_ListView, $iItem, 1))
        GUICtrlSetData($VM, _GUICtrlListView_GetItemText($hWnd_ListView, $iItem, 2))
        If _GUICtrlListView_GetItemText($hWnd_ListView, $iItem, 3) Then
            GUICtrlSetData($Etat, _GUICtrlListView_GetItemText($hWnd_ListView, $iItem, 3))
        Else
            GUICtrlSetData($Etat, "En cours")
        EndIf
        GUICtrlSetData($Path, _GUICtrlListView_GetItemText($hWnd_ListView, $iItem, 4))
    EndIf
EndFunc   ;==>GUI_UserView

Func User_Add()
    Local $sSection, $iCount = _GUICtrlListView_GetItemCount($hWnd_ListView) + 1
    While @error = 0
        $sSection = "Utilisateur_" & StringFormat("%03s", $iCount)
        $iCount += 1
        IniReadSection($NomFichierIni, $sSection)
    WEnd
    FileIni_Write($sSection)
    Local $iItem = _GUICtrlListView_AddItem($hWnd_ListView, $sSection)
    FileIni_SetListView($sSection, $iItem)
    _GUICtrlListView_SetItemSelected($hWnd_ListView, 0, True, True)
EndFunc   ;==>User_Add
Func User_Delete()
    Local $aSelected = _GUICtrlListView_GetSelectedIndices($hWnd_ListView, True)
    If $aSelected[0] > 0 Then
        Local $iItem = $aSelected[1]
        Local $sSection = _GUICtrlListView_GetItemText($hWnd_ListView, $iItem)
        IniDelete($NomFichierIni, $sSection)
        _GUICtrlListView_DeleteItem($hWnd_ListView, $iItem)
        $iItem = _Max(0, $iItem - 1)
        _GUICtrlListView_SetItemSelected($hWnd_ListView, $iItem, True, True)
        GUI_UserView()
    EndIf
EndFunc   ;==>User_Delete
Func User_Execute()
    Local $aSelected = _GUICtrlListView_GetSelectedIndices($hWnd_ListView, True)
    If $aSelected[0] > 0 Then
        Local $iItem = $aSelected[1]
        Local $User = _GUICtrlListView_GetItemText($hWnd_ListView, $iItem, 1)
        Local $VM = _GUICtrlListView_GetItemText($hWnd_ListView, $iItem, 2)
        Local $Etat = _GUICtrlListView_GetItemText($hWnd_ListView, $iItem, 3)
        Local $Path = _GUICtrlListView_GetItemText($hWnd_ListView, $iItem, 4)
        ;Run("vboxmanage.exe starvm '" & $VM "'")
        ConsoleWrite("RUN: vm=" & $VM & " nom=" & $User & " Etat=" & $Etat & " Path=" & $Path & @LF)
        Local $Retour_Commande = "OK"
        Switch $Retour_Commande
            Case "OK"
                _GUICtrlListView_SetItemText($hWnd_ListView, $iItem, "Terminer", 3)
            Case "Cancel"
                _GUICtrlListView_SetItemText($hWnd_ListView, $iItem, "Annuler", 3)
            Case Else
                _GUICtrlListView_SetItemText($hWnd_ListView, $iItem, "En Cours", 3)
        EndSwitch
        GUI_UserView()
    EndIf
EndFunc   ;==>User_Execute
Func User_Update()
    Local $aSelected = _GUICtrlListView_GetSelectedIndices($hWnd_ListView, True)
    If $aSelected[0] > 0 Then
        Local $iItem = $aSelected[1]
        Local $sSection = _GUICtrlListView_GetItemText($hWnd_ListView, $iItem)
        FileIni_Write($sSection)
        FileIni_SetListView($sSection, $iItem)
    EndIf
EndFunc   ;==>User_Update

J'ai pas eue le temps de commenter le code mais je peux t'aider à le comprendre ici

[Laddy]

Bonjour GaRydelaMer
quelle surprise ce matin de voir ta réponse, c'est ce que je cherchais à faire, j'ai pris la matinée pour lire ton code je n'en suis pas encore à bout.
Il ya plein de commande que je ne connais pas encore faut que je les étudies. Si je bloque je te contacte pour que tu m'expliques.

Merci tu fais une heureuse.
Me restera à ajouter un truc pour lancer la vm (vboxmanage.exe starvm "$VM") et hop ! mais avant je dois étudier ton code ;D

[GaRydelaMer]

Re,

pas de soucis le plaisir est pour moi.

On peut encore l'optimiser.

Pour ensuite lancer ta commande, tu peux rajouter un bouton ou même une entrée dans le contextMenu de la listview.

Pour l'ajouter vers la ligne 164 tu peux remplacer l'exemple Print qui fait rien, et l'exécution de la commande dans la fonction: _Events_ContextMenu() ligne 102 sans oublier de déclarer la commande dans la déclaration de Enum:
Global Enum $idCmd_Delete = 10000, $idCmd_Print, $idCmd_Execute

Tu créer une fonction pour exécuter que tu peux relier a un bouton:

Code : Tout sélectionner

;; dans la boucle de début
;       Case $bt_Execute
;           User_Execute()


Func User_Execute()
    Local $aSelected = _GUICtrlListView_GetSelectedIndices($hWnd_ListView, True)
    If $aSelected[0] > 0 Then
        Local $iItem = $aSelected[1]
        Local $VM = _GUICtrlListView_GetItemText($hWnd_ListView, $iItem, 2)     
        Run("vboxmanage.exe starvm '" & $VM "'")
    EndIf
EndFunc

Je connais pas la syntaxe exacte de ton programme vboxmanage.exe

[Laddy]

Coucou

j'en étais arrivé ici , c'est un peu de bricolage d'après ton code j'ai des choses inutiles.
ça prouvre que je n'ai pas encore tout bien compris le code

Code : Tout sélectionner

If @OSArch = "X64" Then $OSarch = "64"
;If StringRight($vbox_path, 1) = "\" Then $vbox_path = StringRegExpReplace($vbox_path, "\\$", "")

If RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Oracle\VirtualBox", "InstallDir") Then
    $PathVirtualBox = RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Oracle\VirtualBox", "InstallDir")
ElseIf RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\VirtualBox", "InstallDir") Then
    $PathVirtualBox = RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\VirtualBox", "InstallDir")
ElseIf RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\xVM VirtualBox", "InstallDir") Then
    $PathVirtualBox = RegRead("HKEY_LOCAL_MACHINE" & $OSarch & "\SOFTWARE\Sun\xVM VirtualBox", "InstallDir")
Else
    MsgBox(16, "VirtualBox", "Erreur d'installation ou le logiciel n'est pas installé sur ce poste.")
    Exit
EndIf

Case $NM_DBLCLK
    Start_Vm()

Func Start_Vm()
    Local $aSections, $iItem, $aUser
     Local $aSelected = _GUICtrlListView_GetSelectedIndices($hWnd_ListView, True)
    If $aSelected[0] > 0 Then
        Local $iItem
        $iItem = $aSelected[1]
    $aSections = IniReadSectionNames($NomFichierIni)
    For $i = 1 To $aSections[0]
        $aUser = IniReadSection($NomFichierIni, $aSections[$i])
        For $iSubItem = 1 To $aUser[0][0]
        Local $toto = _GUICtrlListView_GetItemText($hWnd_ListView, $iItem, 2)

;Run('"' & $PathVirtualBox & 'VBoxManage.exe starvm '" & $toto "'")
        Next
    Next
    EndIf
    ConsoleWrite($toto)
    EndFunc
 

ça me retourne bien le $VM