[..] Copier/Coller automatique de supports USB

[Lolo31]

Bonjour,

Mon niveau en informatique étant de « simple utilisateur bureautique », je fais appel à vos connaissances.

Je recherche un logiciel qui permette, si c'est possible, d'effectuer systématiquement une copie physique de tout support introduit dans le port USB (clé, disque externe).
Le principe serait le suivant :
1- un support usb quelconque et non préparé est introduit dans le port USB
2- dès l'introduction du support dans le port USB, ouverture automatique de l'application qui indiquerait l'espace utilisé sur la source et l'espace libre sur le disque de destination ;
2- sans ouvrir le support, une validation par un clic sur un bouton ou une touche du clavier pour activer le "copier/coller" ;
3- Automatiquement, création d'un nouveau dossier pour la copie dans un répertoire prédéfini de l'ordinateur ;
4- A l'image de "Supercopier", pendant la copie, il serait intéressant d'avoir un indicateur de progression de copie et le temps restant ;
5- A l’issue de la copie, il faudrait une fenêtre qui indique que la copie est terminée.

La manipulation de cette application doit être extrêmement simplifiée et sa mise en action doit être rapide.

J’ai vu l’application Allway Sync qui est très intéressante mais il faut faire plusieurs manipulations et donc des risques important de se tromper. Il ne s’agit pas de transférer les dossiers de l’ordinateur vers le port USB mais bien l’inverse.

S'il est possible de configurer, de simplifier, de modifier et de verrouiller ce type d'application pour réduire au maximum le risque d'erreur de manipulations, cela m'intéresse énormément.

Toutes les suggestions et solutions constructives sont les biens venues.

Cordialement, Lolo31.

[timmalos]

Message Deplacé dans la Partie Appropriée, pas besoin de recreer .

[Tlem]

Merci de prendre connaissance de ceci : Règles de présentation

En ce qui concerne votre projet, voici une première partie de code qui vous aidera à détecter l'insertion d'un périphérique USB :
http://www.autoitscript.fr/forum/viewto ... =21&t=2506

[Stigmate]

En mode bidouillage je fais sa avec "DriveGetDrive"

[Lolo31]

Bonjour,

est-il possible d'utiliser un des multiples programmes de sauvegarde et de le modifier pour qu'il réponde à mes attentes ?

De ce que j'ai pu voir, ces programmes de sauvegarde sont conçus pour copier les données du disque dur vers un support or je souhaite faire l'inverse.
COPIER LE SUPPORT SUR LE DISQUE DUR de façon automatique sans avoir à effectuer des manipulations qui font perdre du temps et surtout impliquent des risques d'erreur qu'on ne peut pas se permettre.
Je dois récupérer des données et non pas en donner par mégarde.

Cordialement, Lolo31.

[Yogui]

En suivant les indications de Tlem j'ai fais ce script.

► Afficher le texte

Code : Tout sélectionner

$strComputer = "."
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\cimv2")

$colEvents = $objWMIService.ExecNotificationQuery _
        ("Select * From __InstanceOperationEvent Within 5 Where " _
         & "TargetInstance isa 'Win32_LogicalDisk'")

While 1
    $objEvent = $colEvents.NextEvent
    If $objEvent.TargetInstance.DriveType = 2 Then
        Select
            Case $objEvent.Path_.Class() = "__InstanceCreationEvent"
                ConsoleWrite("Drive " & $objEvent.TargetInstance.DeviceId & "has been added." & @CR)
                ProgressCopy($objEvent.TargetInstance.DeviceId,@MyDocumentsDir &"\copieUSB\",1)
            Case $objEvent.Path_.Class() = "__InstanceDeletionEvent"
                ConsoleWrite("Drive " & $objEvent.TargetInstance.DeviceId & "has been removed." & @CR)
        EndSelect
    EndIf
WEnd


Func ProgressCopy($current, $destination, $UseMultiColour = 0, $attrib = "-R", $overwrite = 1, $Run1 = 0)
    Dim $WS_EX_TOOLWINDOW, $WS_EX_TOPMOST, $SS_LEFTNOWORDWRAP, $PBS_SMOOTH, $WS_EX_TOOLWINDOW
    ;FirstTimeRun Get original DirSize and set up Gui
    If $Run1 = 0 Then
        Global $OverallQty, $Overall, $source, $overallpercent, $Progress0Text, $progressbar1, $Progress1Text, $progressbar2, $Progress2Text, $LocalPercent
        DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 0)
        If Not FileExists($destination) Then DirCreate($destination); This is why it was failing, the dir did not exist
        $source = $current
        If StringRight($current, 1) = '' Then $current = StringTrimRight($current, 1)
        If StringRight($destination, 1) <> '' Then $destination = $destination & "\"
        $tosearch = $current
        $Overall = DirGetSize($tosearch, 1)
        $OverallQty = $Overall[1]
        Global Const $PrCopyGui = GUICreate("Copie des Fichiers", 420, 100, -1, -1, -1, $WS_EX_TOOLWINDOW + $WS_EX_TOPMOST)
        $Progress0Text = GUICtrlCreateLabel("Veuillez patienter", 10, 5, 400, 20, $SS_LEFTNOWORDWRAP)
        $progressbar1 = GUICtrlCreateProgress(10, 20, 400, 20)
        GUICtrlSetColor(-1, 32250)
        $Progress1Text = GUICtrlCreateLabel("", 10, 44, 400, 20, $SS_LEFTNOWORDWRAP)
        $progressbar2 = GUICtrlCreateProgress(10, 60, 400, 20, $PBS_SMOOTH)
        $Progress2Text = GUICtrlCreateLabel("", 10, 82, 400, 20, $SS_LEFTNOWORDWRAP)
        GUISetFont(10, 600)
        ;$Progress2Text2 = GUICtrlCreateLabel("", 150, 62, 400, 20)
        GUICtrlSetColor(-1, 32250); not working with Windows XP Style if not using windows classic style or dllcall above
        GUISetState(@SW_SHOW)
        GUICtrlSetData($Progress1Text, "Répertoire de travail " & $tosearch)
        $Run1 = 1
    EndIf
    $Size = DirGetSize($current, 3)
    $Qty = $Size[1]
    Local $search = FileFindFirstFile($current & "\*.*")
    While 1
        Dim $file = FileFindNextFile($search)
        If @error Or StringLen($file) < 1 Then ExitLoop
        If Not StringInStr(FileGetAttrib($current & "\" & $file), "D") And ($file <> "." Or $file <> "..") Then
            $Qty -= 1
            $LocalPercent = 100 - (($Qty / $Size[1]) * 100)
            $OverallQty -= 1
            $overallpercent = 100 - (($OverallQty / $Overall[1]) * 100)
            GUICtrlSetData($Progress0Text, "Progression Totale " & Int($overallpercent) & "% Completer")
            GUICtrlSetData($progressbar1, $overallpercent)
            GUICtrlSetData($progressbar2, $LocalPercent)
            GUICtrlSetData($Progress2Text, "Copie du Fichier " & $file)
            If $UseMultiColour Then
                GUICtrlSetColor($progressbar2, _ChangeColour($LocalPercent))
                GUICtrlSetColor($progressbar1, _ChangeColour($overallpercent))
            EndIf
            FileCopy($current & "\" & $file, $destination & StringTrimLeft($current, StringLen($source)) & "\" & $file, $overwrite)
            FileSetAttrib($destination & StringTrimLeft($current, StringLen($source)) & "\" & $file, $attrib)
        EndIf
        If StringInStr(FileGetAttrib($current & "\" & $file), "D") And ($file <> "." Or $file <> "..") Then
            DirCreate($destination & StringTrimLeft($current, StringLen($source)) & "\" & $file)
            FileSetAttrib($destination & StringTrimLeft($current, StringLen($source)) & "\" & $file, $attrib)
            GUICtrlSetData($Progress1Text, $current & "\" & $file)
            ProgressCopy($current & "\" & $file, $destination, $UseMultiColour, $attrib, $overwrite, 1)
        EndIf
    WEnd
    FileClose($search)
    ;when overall percent = 100 set end gui text, delete gui and reset run1 to 0
    If $overallpercent = 100 Then
        GUICtrlSetData($Progress0Text, "Progression Totale complètée à 100%")
        GUICtrlSetData($progressbar1, 100)
        GUICtrlSetData($progressbar2, 100)
        GUICtrlSetData($Progress2Text, "Terminer !")
        Sleep(2000)
        GUIDelete($PrCopyGui)
        $Run1 = 0
    EndIf
EndFunc   ;==>ProgressCopy
Func _ChangeColour($start)
    $Redness = Int(255 - ($start / 100 * 512))
    If $Redness < 0 Then $Redness = 0
    $Greeness = Int(($start / 100 * 512) - 257)
    If $Greeness < 0 Then $Greeness = 0
    $Blueness = Int(255 - ($Redness + $Greeness))
    Return ($Redness * 256 * 256) + ($Greeness * 256) + $Blueness
EndFunc   ;==>_ChangeColour
 

[Tlem]

Voici une version plus light :

► Afficher le texte

Code : Tout sélectionner

$Destination = "E:\Copy_USB\"

$strComputer = "."
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\cimv2")

$colEvents = $objWMIService.ExecNotificationQuery _
        ("Select * From __InstanceOperationEvent Within 5 Where " _
         & "TargetInstance isa 'Win32_LogicalDisk'")

While 1
    $objEvent = $colEvents.NextEvent
    If $objEvent.TargetInstance.DriveType = 2 Then
        Select
            Case $objEvent.Path_.Class() = "__InstanceCreationEvent"
                $Drv = $objEvent.TargetInstance.DeviceId
                $Destination = $Destination & DriveGetSerial($Drv) & "\"
                If Not FileExists($Destination) Then DirCreate($Destination)
                _FileCopy($Drv & "\*.*", $Destination)
                TrayTip("USB_Copie", "Le média USB à été copié sur :" & @CRLF & $Destination, 5, 1)

        EndSelect
    EndIf
WEnd

Func _FileCopy($fromFile, $tofile)
     $winShell = ObjCreate("shell.application")
     $winShell.namespace ($tofile).CopyHere ($fromFile)
EndFunc   ;==>_FileCopy

[Yogui]

j'aime bien la fonction de copie qui change de couleur ça occupe ...

[Lolo31]

Bonjour Yogui et Tlem,

j'ai essayé vos programmes respectifs. Il s'avère que les deux se complètent.

Je me permets de vous exprimer les côtés positifs et négatifs de chacun de vos programmes en fonction de mes désidératas.

Yogui : l'interface me plait énormément.
Toutefois, j'observe 2 points négatifs :
1- Chaque nouvelle copie vient se coller dans un même répertoire. D'où le mélange de toutes les clés copiées. Je souhaiterai que pour chaque clé USB corresponde un sous-répertoire nommé par exemple "E:\USB\Copie 01" et que pour la suivante ce soit "E:\USB\Copie 02" etc...

2- Lorsque j'ai introduit une deuxième, j'ai eu le message d'erreur suivant :
Line 37 (File "E:\Copier Coller\Copy 1.au3"):
Global Const $PrCopyGui=GUICreate("Copie des Fichiers", 420,100, -1, -1,-1, $WS_EX_TOOLWINDOW + $WS_EX_TOPMOST)
Global Const^ERROR
Error: Can not redeclare a constant.

E:\Copier Coller\Copy 1.au3 correspond à votre programme et le répertoire dans lequel il se trouve.

J'ai cliqué sur "OK" et l'application s'est fermée. Je l'ai réactivée, la copie suivante s'est bien passée et 2 clés plus tard, même message d'erreur. ???

Tlem : L'application fonctionne très bien à un détail près :
La 1ère copie se met directement sous la racine "E:\Copy USB" avec tous les dossiers et fichiers copiés, la 2ème se place dans un sous-répertoire qui se situe dans le répertoire précédent et les dossiers et fichiers de la clé précédente et ainsi de suite en cascade. Comme cité ci-dessus, je souhaiterai que pour chaque nouvelle clé introduite un sous-répertoire par clé soit créé. ex : E:\Copy USB\001, la suivante E:\Copy USB\002 ...etc

Si vous pouviez amener quelques améliorations, cela serait super :
- La numérotation croissante des répertoires pour chaque clé est importante car je dois pouvoir savoir à quel collaborateur chacune correspond.
- Avant le lancement de la copie, est-il possible de rajouter la possibilité de valider ou de refuser la copie ?
- La vitesse de copie dépend de quel paramètre ? Peut-elle être accélérée ?
- En plus des clés USB, est-il possible de rajouter la copie des supports CD-DVD, PCMCIA, Express card, en fait de tout support qui serait introduit dans l'ordinateur ?
- Petit détail, entre les 2 interfaces, j'ai une préférence pour celle de Yogui et ses couleurs.

Vous remerciant pour votre aide, cordialement, Lolo31.

[Tlem]

Le comportement du script que j'ai donné semble étrange, car à la base il est sensé créer un dossier portant le numéro de série de la clé USB et d'y faire la copie

Pour la confirmation de copie, rajoutez quelques lignes de code avant la copie du média pour valider ou nom le lancement de la copie.

Petite remarque : La numérotation croissante n'est pas envisageable, car si vous placez un média USB, le script ne peut savoir si c'est la 1, la 2, la 3 ... sans point de repère.
Il faudrait donc ce baser sur un label ou comme je l'ai fait sur le numéro de série.

Pour la vitesse, elle est dépendante de la rapidité de votre média.
Pour l'insertion de média, cela doit être possible en modifiant dans le code le type de média inséré.
Je pense qu'en supprimant la ligne suivante, cela devrait fonctionner :

Code : Tout sélectionner

If $objEvent.TargetInstance.DriveType = 2 Then

Ne pas oublier de supprimer le EndIf qui lui est associé.

[Lolo31]

Bonjour Tlem,

hors mis le problème d'emplacement de la clé "Copier" et de sa numérotation, l'application me convient.

1- "Pour la confirmation de copie, rajoutez quelques lignes de code avant la copie du média pour valider ou nom le lancement de la copie."

Mon problème est que je ne sais absolument pas programmer et de ce fait je ne vois pas ce qu'il faut faire. Quelles lignes de code dois-je rajouter et où ?

2- Petite remarque : La numérotation croissante n'est pas envisageable, car si vous placez un média USB, le script ne peut savoir si c'est la 1, la 2, la 3 ... sans point de repère.
Il faudrait donc ce baser sur un label ou comme je l'ai fait sur le numéro de série

- Le problème est que cette numérotation est la condition Sine qua non pour ce programme.
- Est-ce qu'il y a une possibilité de faire en sorte que le logiciel détecte le nombre de sous-répertoires dans le répertoire de destination (ici : E:\Copy USB\).
Si cela est possible, une clé copiée aurait pour nom de sous-répertoire "nombre de sous-répertoire+1".
- Quel programme utilisent les disques durs multimédia OTG qui lors d'une copie de clés créent automatiquement un répertoire de type "DSC00001", "DSC00002" etc.

3- Pour l'insertion de média, cela doit être possible en modifiant dans le code le type de média inséré.

Pouvez-vous préciser ? Quel code ? Quoi mettre et où ?

Merci pour votre réactivité, cordialement, Lolo31.

[Lolo31]

Bonjour Tlem,

dans le message précédent, j'ai dit ce qui suit :

[ Petite remarque : La numérotation croissante n'est pas envisageable, car si vous placez un média USB, le script ne peut savoir si c'est la 1, la 2, la 3 ... sans point de repère.
Il faudrait donc ce baser sur un label ou comme je l'ai fait sur le numéro de série

- Le problème est que cette numérotation est la condition Sine qua non pour ce programme.
- Est-ce qu'il y a une possibilité de faire en sorte que le logiciel détecte le nombre de sous-répertoires dans le répertoire de destination (ici : E:\Copy USB\).
Si cela est possible, une clé copiée aurait pour nom de sous-répertoire "nombre de sous-répertoire+1".
- Quel programme utilisent les disques durs multimédia OTG qui lors d'une copie de clés créent automatiquement un répertoire de type "DSC00001", "DSC00002" etc. ]

Est-il envisageable et surtout réalisable que la nomination des sous-répertoires correspondant aux clés copiées prenne pour référence la date et l'heure de l'horloge interne de l'ordinateur ?
Auquel cas, le sous-répertoire aurait pour nom : Année Mois Jour/Heure Minute Seconde et le tri se ferait naturellement dans l'ordre croissant.

(Je tiens à préciser que je ne suggère que des suppositions de travail qui sont peut-être réalisables ou non. C'est vous les experts.)

Cordialement, Lolo31.

[Tlem]

Je me suis bien amusé avec les objets WMI ...
Voici quelque chose qui ressemble à ce que vous demandez :

► Afficher le texte

Code : Tout sélectionner

$Destination = "E:\Copy_USB\"

$strComputer = "."
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\cimv2")

$colEvents = $objWMIService.ExecNotificationQuery _
        ("Select * From __InstanceOperationEvent Within 5 Where " _
         & "TargetInstance isa 'Win32_LogicalDisk'")

While 1
    $objEvent = $colEvents.NextEvent
    If $objEvent.TargetInstance.DriveType = 2 Or $objEvent.TargetInstance.DriveType = 5 Then
        Select
            Case $objEvent.TargetInstance.FileSystem <> ""
                $Drv = $objEvent.TargetInstance.DeviceId
                $Res = MsgBox(36, "USB_Copie", "Désirez-vous copier du média " & $Drv & " sur votre disque dur ?")
                If $Res = 6 Then
                    $DstDir = @YEAR & @MON & @MDAY & @HOUR & @MIN & @SEC & "\"
                    If Not FileExists($Destination & $DstDir) Then DirCreate($Destination & $DstDir)
                    _FileCopy($Drv & "\*.*", $Destination & $DstDir)
                    MsgBox(64, "USB_Copy", "Copie terminée dans le dossier :" & @CRLF & $Destination & $DstDir)
                EndIf
        EndSelect
    EndIf
WEnd

Func _FileCopy($fromFile, $tofile)
    $winShell = ObjCreate("shell.application")
    $winShell.namespace($tofile).CopyHere($fromFile)
EndFunc   ;==>_FileCopy

[Lolo31]

Bonjour Tlem,

votre programme répond tout à fait à mes souhaits et c'est excellent.

Toutefois, pour être parfait, je me permets une fois de plus d'apporter 3 petites critiques et 2 souhaits pour le petit +.

1- A la fin de la copie, il y a une fenêtre qui s'ouvre pour dire que la copie est terminée. Etant donné que la fenêtre de la phase "Copie" se ferme quand cette dernière est finie avec succès, cela me suffit.
Est-il possible d'annuler la fenêtre qui dit "copie terminée" ?

2- Quand la copie est terminée et que je retire la clé USB ou que je retire la clé en cours de copie ou lors d'un refus d'une copie, la fenêtre "désirez-vous copier ..." s'ouvre une 2ème fois.
Est-ce fait exprès ? Si oui, pourquoi ?
Si cela ne sert pas, puisque lors d'une nouvelle introduction, l'application s'active à nouveau, est-il possible de la supprimer ?

3- Concernant la copie des CD-DVD :
* la préparation de Windows pour la copie met un certain temps. Est-il possible de réduire au minimum ce temps ou est-ce une procédure qui est incompressible ?
* Si je stoppe la copie du CD-DVD, l'application se met en mode pause. Je dois donc réactiver l'icône ce qui ne se produit pas avec un support USB. Est-il possible d'y remédier ?

4 - Au démarrage, l'icône de l'application se place normalement en bas à droite de l'écran.
Quand je veux la désactiver, je clique droit et exit.
Est-il possible d'accélérer sa fermeture ?

5- Pour une question de pure esthétique, que dois-je faire pour coupler votre programme avec la présentation qu'a créée Yogui ?

Je me rend compte que je demande peut-être beaucoup mais en effectuant les modifications, je serai aux anges.

D'ors et déjà, je suis comme un gamin avec un nouveau jouet. Bravo.
Cordialement, Lolo31.

[Tlem]

1- Oui c'est possible.

2 - Non / Je ne sais pas / Faut voir.

3 - Cela ne peut être changé. / Sans doute, il faut chercher un peut.

4 - Oui par un raccourci clavier.

5 - Je n'ai pas regardé la présentation de Yogui donc je ne peut répondre.

Vous pouvez aussi avec se super jouet, faire des recherches et l'adapter à vos besoins. Même si vos connaissances sont limitées, vous pouvez au moins faire un minimum de travail.

Si vous venez ici uniquement pour demander un script fonctionnel et correspondant à une demande particulière, je pense que cela peut ce négocier.
La philosophie du forum est l'entre aide sur AutoIt et non la fabrication de scripts sur demande.

[Lolo31]

Bonjour Tlem,

je pense qu'il y a un malentendu de ma part qui est dû à 2 choses :
1- le titre du forum : "Demande de création de scripts"
2- la phrase d'introduction du forum : "Sur ce forum, un utilisateur peut demander la création d'un script complet."

Vous remerciant à vous ainsi qu'à Yogui pour votre aide très efficace.

Cordialement, Lolo31.

[Tlem]

C'est effectivement ce qu'il est écrit.
Et je pense que par le script que je vous ait proposé, je répond aux 5 demandes de votre premier message.

Mais vous oubliez le titre principal du forum : Communauté Française AutoIt