[...] Probleme que je comprend pas

[lucar14]

bonjour a tous alors voila j'ai créer une interface graphique avec koda et ensuite recuperer les code pour autoit mais mon probleme c'est que quand je fais une boucle infini avec le boutton 1, je ne trouve pas comment la stopper avec le bouton 2 est ce que quelqu'un peut m'aider . voici mon code:

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section ### Form=C:\Users\lucas\Desktop\test.kxf
Global $Form1 = GUICreate("test", 180, 217, 377, 174)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
GUISetOnEvent($GUI_EVENT_MINIMIZE, "Form1Minimize")
GUISetOnEvent($GUI_EVENT_MAXIMIZE, "Form1Maximize")
GUISetOnEvent($GUI_EVENT_RESTORE, "Form1Restore")
Global $Button1 = GUICtrlCreateButton("start", 0, 120, 89, 41)
GUICtrlSetOnEvent(-1, "Button1Click")
Global $Button2 = GUICtrlCreateButton("stop", 88, 120, 89, 41)
GUICtrlSetOnEvent(-1, "Button2Click")
Global $Pic1 = GUICtrlCreatePic("C:\Users\lucas\Desktop\", 0, 8, 177, 97)
GUICtrlSetOnEvent(-1, "Pic1Click")
Global $Button3 = GUICtrlCreateButton("quitter", 0, 168, 177, 41)
GUICtrlSetOnEvent(-1, "Button3Click")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    Sleep(100)
WEnd

Func Button1Click() ;bouttont start
    While 2
        Send("{TAB}")
        Sleep(1000)
    WEnd
EndFunc   ;==>Button1Click
Func Button2Click() ;boutton stop
        Break(0)
EndFunc   ;==>Button2Click
Func Button3Click() ;boutton quitter
Exit
EndFunc   ;==>Button3Click
Func Form1Close() ;croix rouge
    Exit
EndFunc   ;==>Form1Close
Func Form1Maximize()

EndFunc   ;==>Form1Maximize
Func Form1Minimize()

EndFunc   ;==>Form1Minimize
Func Form1Restore()

EndFunc   ;==>Form1Restore
Func Pic1Click()

EndFunc   ;==>Pic1Click

PS:c'est koda qui ma tous créer comme sa sauf bien sur la boucle
merci de votre compréhension

[TomAijerrie]

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

[color=#000000]global $tab = False[/color]
Opt("GUIOnEventMode", 1)
#Region ### START Koda GUI section ### Form=C:\Users\lucas\Desktop\test.kxf
Global $Form1 = GUICreate("test", 180, 217, 377, 174)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
Global $Button1 = GUICtrlCreateButton("start", 0, 120, 89, 41)
GUICtrlSetOnEvent(-1, "Button1Click")
Global $Button2 = GUICtrlCreateButton("stop", 88, 120, 89, 41)
GUICtrlSetOnEvent(-1, "Button2Click")
Global $Pic1 = GUICtrlCreatePic(@DesktopDir, 0, 8, 177, 97)
Global $Button3 = GUICtrlCreateButton("quitter", 0, 168, 177, 41)
GUICtrlSetOnEvent(-1, "Button3Click")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    Sleep(100)
WEnd

Func Button1Click() ;bouttont start
[color=#000000]    $tab = True
    While $tab[/color]
        Send("{TAB}")
        Sleep(1000)
    WEnd
EndFunc   ;==>Button1Click
Func Button2Click() ;boutton stop
[color=#000000]        $tab = False[/color]
EndFunc   ;==>Button2Click
Func Button3Click() ;boutton quitter
    Exit
EndFunc   ;==>Button3Click
Func Form1Close() ;croix rouge
    Exit
EndFunc   ;==>Form1Close 

C'est pour faire quoi ?

[lucar14]

Pour le moment je debute donc c'est pour tester et voir vraiment le fonctionnement

[foliolur]

Essaye de voir avec ce script :

https://www.autoitscript.com/forum/topi ... exit-loop/

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>

GUICreate("Test",220,100) ;, -1,-1, $WS_CAPTION, $WS_EX_TOPMOST)
$progressbar = GUICtrlCreateProgress (10,15,200,20,$PBS_SMOOTH)
$procent = GUICtrlCreateLabel ('0 %', 10,40,200,20,$SS_CENTER)
$start = GUICtrlCreateButton ("Start",35,68,70,22)
$stop = GUICtrlCreateButton ("Stop",115,68,70,22)
GUICtrlSetState($stop,$GUI_DISABLE)
GUISetState()

$run = 0
$i = 0

While 1
  $msg = GUIGetMsg()

  If $msg = $GUI_EVENT_CLOSE Then ExitLoop

  If $msg = $start Then 
    $run = 1 
    GUICtrlSetState($start,$GUI_DISABLE)
    GUICtrlSetState($stop,$GUI_ENABLE)
  EndIf

  If $msg = $stop Then 
    $run = 0
    GUICtrlSetState($start,$GUI_ENABLE)
    GUICtrlSetState($stop,$GUI_DISABLE)
  EndIf

  If $run Then
    $i = $i + 1
    If $i > 100 Then $i = 0

    GUICtrlSetData ($progressbar,$i)
    GUICtrlSetData ($procent,$i & ' %')
    Sleep(100)
  EndIf
Wend
 

le problème la c'est que tu initialise deux boucles différentes.
Du coup tu peut pas sortir avec ton boutton2 vue que t'es pas dans ta while 1

[lucar14]

Ah d'accord et une petite idée comment je pourrais mettre les deux dans la meme boucle ? Et merci pour le lien .

[walkson]

Bonjour,
En reprenant votre exemple du départ:

► Afficher le texte

Code : Tout sélectionner

    #include <ButtonConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <StaticConstants.au3>
    #include <WindowsConstants.au3>


    Opt("GUIOnEventMode", 1)
    #Region ### START Koda GUI section ### Form=C:\Users\lucas\Desktop\test.kxf
    Global $Form1 = GUICreate("test", 180, 217, 377, 174)
    GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
    Global $Button1 = GUICtrlCreateButton("start", 0, 120, 89, 41)
    GUICtrlSetOnEvent(-1, "Button1Click")
    Global $Button2 = GUICtrlCreateButton("stop", 88, 120, 89, 41)
    GUICtrlSetOnEvent(-1, "Button2Click")
    Global $Pic1 = GUICtrlCreatePic(@DesktopDir, 0, 8, 177, 97)
    Global $Button3 = GUICtrlCreateButton("quitter", 0, 168, 177, 41)
    GUICtrlSetOnEvent(-1, "Button3Click")
    GUISetState(@SW_SHOW)
    #EndRegion ### END Koda GUI section ###
    global $tab = False, $a = 0

    While 1
        Sleep(100)
        If $tab Then
            tab()
        EndIf

    WEnd

    Func Button1Click() ;bouttont start
        $tab = True

    EndFunc   ;==>Button1Click
    Func Button2Click() ;boutton stop
            $tab = False

    EndFunc   ;==>Button2Click
    Func tab()
            $a = $a + 1
            ToolTip(">>>  "& $a,100,200)
            Send("{TAB}")
            Sleep(1000)

    EndFunc

    Func Button3Click() ;boutton quitter
        Exit
    EndFunc   ;==>Button3Click
    Func Form1Close() ;croix rouge
        Exit
    EndFunc   ;==>Form1Close

Dans ce cas, nous sommes en Opt("GUIOnEventMode", 1), c'est à dire que les commandes sont passées par GUICtrlSetOnEvent(-1, "Button1Click") par exemple
La boucle While 1 sert à faire tourner indéfiniment le script jusqu'au moment GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
Dans l'exemple de foliolur , nous sommes en Opt("GUIOnEventMode", 0) ou sans de précision, c'est à dire que les commandes sont passées à l'intérieur de la boucle While 1 dont on peut sortir avec un exit ou un exitloop
Dans votre exemple, vous sortez de la première boucle par le button1 et vous rentrez dans la deuxième boucle mais sans condition de sortie et donc elle tourne sans fin et bloque tout.

[orax]

Il y a également cette page du wiki qui me semble en rapport avec la question de départ => Interrupting a running function – mais ça risque d'être un peu complexe si tu débutes. Grosso-modo ça montre diverses méthodes pour interrompre une boucle.