[R] Aide sur EzMySql pour completer l'exemple

[jl56]

Bonjour à tous,

Je test actuellement EzMySql pour pouvoir utiliser un script avec une base SQL
J'ai lu beaucoup cette semaine sur les bases SQL mais je ne voudrais pas m'investir de suite dans ce system car je n'aurais probablement pas à le faire à terme. Il y a des collègues qui vont développer un site avec PHP et Mysql.

Je dois leur démontrer qu'il est possible d'utiliser une base MYSQL avec mes scripts afin de ramener les infos dans la base ou de les lires
J'ai donc installé WAMP et lancé l'exemple je l'ai modifié pour mon test avec la création de 2 tables ( une Client et l'autre PC )

► Afficher le texte

Code : Tout sélectionner

#include "EzMySql.au3"
#include <Array.au3>


;~ MsgBox(0,"",@LogonDomain)
If Not _EzMySql_Startup() Then
    MsgBox(0, "Error Starting MySql", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
    Exit
EndIf

$Pass = ""

If Not _EzMySql_Open("", "root", $Pass, "", "3306") Then
    MsgBox(0, "Error opening Database", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
    Exit
EndIf

If Not _EzMySql_Exec("CREATE DATABASE IF NOT EXISTS EzMySqlTest") Then
    MsgBox(0, "Error opening Database", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
    Exit
EndIf

If Not _EzMySql_SelectDB("EzMySqlTest") Then
    MsgBox(0, "Error setting Database to use", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
    Exit
EndIf

_EzMySql_Exec("DROP TABLE TestTable")
_EzMySql_Exec("DROP TABLE TestTable_pc")


$sMySqlStatement = "CREATE TABLE IF NOT EXISTS TestTable (" & _
        "RowID INT NOT NULL AUTO_INCREMENT," & _
        "CLIENT TEXT NOT NULL ," & _
        "Age INT NOT NULL ," & _
        "EyeColour TEXT NOT NULL ," & _
        "HairColour TEXT NOT NULL ," & _
        "PRIMARY KEY (`RowID`) );"

If Not _EzMySql_Exec($sMySqlStatement) Then
    MsgBox(0, "Error Creating Database Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
    Exit
EndIf

$sMySqlStatement = "CREATE TABLE IF NOT EXISTS TestTable_PC (" & _
        "CLIENT TEXT NOT NULL ," & _
        "Nom TEXT NOT NULL ," & _
        "IP TEXT NOT NULL );"

If Not _EzMySql_Exec($sMySqlStatement) Then
    MsgBox(0, "Error Creating Database Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
    Exit
EndIf




Local $aEyeColours[7] = ["Amber", "Blue", "Brown", "Grey", "Green", "Hazel", "Red"]
Local $aHairColours[6] = ["Brown", "Black", "Blond", "Grey", "Green", "Pink"]

Local $sMySqlStatement = ""

For $i = 1 To 50 Step 1
    Local $sMySqlStatement = ""
    $sMySqlStatement = "INSERT INTO TestTable (CLIENT,Age,EyeColour,HairColour) VALUES (" & _
            "'Person" & $i & "'," & _
            "'" & Random(1, 100, 1) & "'," & _
            "'" & $aEyeColours[Random(0, 6, 1)] & "'," & _
            "'" & $aHairColours[Random(0, 5, 1)] & "');"
    If Not _EzMySql_Exec($sMySqlStatement) Then
        MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
        Exit
    EndIf

    Local $sMySqlStatement_pc = ""

    For $j = 1 To 10 Step 1
        $sMySqlStatement_pc &= "INSERT INTO TestTable_PC (CLIENT,Nom,IP) VALUES (" & _
                "'Person" & $i & "'," & _
                "'NomPC" & $j & "'," & _
                "'" & "192.168." & $i & "." & $j & "');"
    Next

    If Not _EzMySql_Exec($sMySqlStatement_pc) Then
        MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
        Exit
    EndIf

Next



$aOk = _EzMySql_GetTable2d("SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person2';")
$error = @error
If Not IsArray($aOk) Then MsgBox(0, $sMySqlStatement_pc & " error ", $error)
_ArrayDisplay($aOk, "2d Array PC de Person2")



;~ Ajout client *****************
Local $sMySqlStatement = ""
$sMySqlStatement = "INSERT INTO TestTable (CLIENT,Age,EyeColour,HairColour) VALUES (" & _
        "'Person" & 51 & "'," & _
        "'" & Random(1, 100, 1) & "'," & _
        "'" & $aEyeColours[Random(0, 6, 1)] & "'," & _
        "'" & $aHairColours[Random(0, 5, 1)] & "');"
If Not _EzMySql_Exec($sMySqlStatement) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
    Exit
EndIf

;~ Ajout PC1 et PC2 dur client Person51 *****************
$sMySqlStatement_pc = ""
$sMySqlStatement_pc &= "INSERT INTO TestTable_PC (CLIENT,Nom,IP) VALUES (" & _
        "'Person51'," & _
        "'NomPC1'," & _
        "'192.168.51.1');"
$sMySqlStatement_pc &= "INSERT INTO TestTable_PC (CLIENT,Nom,IP) VALUES (" & _
        "'Person51'," & _
        "'NomPC2'," & _
        "'192.168.51.2');"

If Not _EzMySql_Exec($sMySqlStatement_pc) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
    Exit
EndIf



$aOk = _EzMySql_GetTable2d("SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person51';")
$error = @error
If Not IsArray($aOk) Then MsgBox(0, $sMySqlStatement_pc & " error ", $error)
_ArrayDisplay($aOk, "2d Array PC de Person51")




; modidification couleur cheveux du client Person4
$sMySqlStatement = "update TestTable set Haircolour = 'Roux' where CLIENT = 'Person4';"
If Not _EzMySql_Exec($sMySqlStatement) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
;~  Exit
EndIf

; verif modif couleur roux pour Person4
$aOk = _EzMySql_GetTable2d("SELECT CLIENT,haircolour FROM TestTable WHERE CLIENT = 'Person4';")
$error = @error
If Not IsArray($aOk) Then MsgBox(0, $sMySqlStatement & " error", $error)
_ArrayDisplay($aOk, "2d Array Names of certain eyecolour")

; Suppression de pc5 du client Person7
$sMySqlStatement_pc = "delete from testTable_pc where nom = 'NomPC5' and client = 'Person7';"
If Not _EzMySql_Exec($sMySqlStatement_pc) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg()&" error 157 ")
    Exit
EndIf
; verif supression de NomPC5
$aOk = _EzMySql_GetTable2d("SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person7';")
$error = @error
If Not IsArray($aOk) Then MsgBox(0, $sMySqlStatement_pc & " error ", $error&" error 163 ")
_ArrayDisplay($aOk, "2d Array PC de Person7")

; Modification de l'IP du PC3 du client Person9
$sMySqlStatement_pc = "update TestTable_pc set ip = '192.168.45.89' where nom = 'NomPC3' and client = 'Person9';"
If Not _EzMySql_Exec($sMySqlStatement_pc) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
    Exit
EndIf
; verif modif
$aOk = _EzMySql_GetTable2d("SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person9';")
$error = @error
If Not IsArray($aOk) Then MsgBox(0, $sMySqlStatement_pc & " error ", $error)
_ArrayDisplay($aOk, "2d Array PC de Person9")

; Suppression du client Person3
$sMySqlStatement = "delete from TestTable where CLIENT = 'Person3';"
If Not _EzMySql_Exec($sMySqlStatement) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg()& " error 180")
    Exit
EndIf
; verif suppression
$aOk = _EzMySql_GetTable2d("SELECT CLIENT,haircolour FROM TestTable WHERE CLIENT = 'Person3';")
$error = @error
If Not IsArray($aOk) Then MsgBox(0, $sMySqlStatement & " error", $error& " error 186")
_ArrayDisplay($aOk, "2d Array supp client Person3")

;~  et des PC de client Person3
$sMySqlStatement_pc = "delete from TestTable_pc where CLIENT = 'Person3';"
If Not _EzMySql_Exec($sMySqlStatement_pc) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg()& " error 193")
    Exit
EndIf
; verif suppression
$aOk = _EzMySql_GetTable2d("SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person3';")
$error = @error
If Not IsArray($aOk) Then MsgBox(0, $sMySqlStatement_pc & " error ", $error& " error 198")
_ArrayDisplay($aOk, "2d Array PC de Person3")


;~ SELECT CLIENT,Nom,IP FROM TestTable WHERE CLIENT like '%1%' and haircolour = 'Green';


$aOk = _EzMySql_GetTable2d("SELECT CLIENT,EyeColour,haircolour FROM TestTable WHERE client like '%1%' and (haircolour like '%E%' or haircolour like '%o%') ;")
;~ $aOk = _EzMySql_GetTable2d("SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person9';")
$error = @error
If Not IsArray($aOk) Then MsgBox(0, $sMySqlStatement & " error", $error& " error 207")
_ArrayDisplay($aOk, "Client 1 et (e ou o)")
MsgBox(0, "nbr enregistrement",_EzMySql_Rows())


$aOk = _EzMySql_GetTable2d("SELECT CLIENT,haircolour FROM TestTable;")
;~ $aOk = _EzMySql_GetTable2d("SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person9';")
$error = @error
If Not IsArray($aOk) Then MsgBox(0, $sMySqlStatement & " error", $error& " error 207")
_ArrayDisplay($aOk, "2d Array Client tout")
MsgBox(0, "nbr enregistrement",_EzMySql_Rows())

MsgBox(0, "Fin test","fin")



_EzMySql_Exec("DROP TABLE TestTable")
_EzMySql_Exec("DROP TABLE TestTable_pc")
_EzMySql_Close()
_EzMySql_ShutDown()
Exit






 

Pouvez vous, SVP, m'aider à terminer les 4 dernières étapes ( Suppression,modification dans les 2 tables )
Je ne vois pas comment aborder ces points. Cela me permettra d'avoir un exemple complet pour être autonome.

Merci

Jl56

[sozary]

Changer une info:

Code : Tout sélectionner

$sMySqlStatement_pc="UPDATE TestTable_pc SET Person9="";"
If Not _EzMySql_Exec($sMySqlStatement_pc) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
    Exit
EndIf

Supprimer un truc:

Code : Tout sélectionner

$sMySqlStatement_pc="DELETE FROM TestTable_pc WHERE Person9="";"
If Not _EzMySql_Exec($sMySqlStatement_pc) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _EzMySql_ErrMsg())
    Exit
EndIf

[jchd]

Sozary, ton SQL ne veut rien dire.

jl56

Tes colonnes rowid forcent automatiquement leur unicité, donc ta contrainte UNIQUE est inutile dans les deux tables.

; modification couleur cheveux du client Person4
update testtable set haircolour = 'Blue' where client = 'Person4';

; Suppression de Nompc5 du client Person7
delete from testable_pc where nom = 'NomPC5' and client = 'Person7';

; Modification de l'IP du NomPC3 du client Person9
update testables_pc set ip = '192.168.45.89' where nom = 'NpmPC3' and client = 'Person9';

; Suppression du client Person3
delete from testtable where client = 'Person3';
;~ et des PC de client 3
delete from testable_pc where client = 'Person3';

[jl56]

Bonjour à tous,

Merci à vous deux pour vos réponses

J'ai modifié et complété le script d'exemple ça fonctionne bien merci JCHD

@JCHDT u parles de la clé unique

Tes colonnes rowid forcent automatiquement leur unicité, donc ta contrainte UNIQUE est inutile dans les deux tables.

J'ai copié bêtement l'exemple fournie avec EzMySql est-ce que cela pose un problème que faut il faire ?

Autre demande comment sélectionner sur la table testtable les clients qui contienne le caractère 1 dans le nom et dont les cheveux sont green
c'est pour pouvoir faire une présélection genre tout les clients ou il a dans le nom exemple dupont et qui sont du Morbihan

Merci encore

A+ JL56

[jchd]

J'ai copié bêtement l'exemple fournie avec EzMySql est-ce que cela pose un problème que faut il faire ?

Tu peux élaguer, ça ne sert à rien même si ce n'est pas nocif.

Autre demande comment sélectionner sur la table testtable les clients qui contienne le caractère 1 dans le nom et dont les cheveux sont green
c'est pour pouvoir faire une présélection genre tout les clients ou il a dans le nom exemple dupont et qui sont du Morbihan

SELECT CLIENT,Nom,IP FROM TestTable WHERE CLIENT like '%1%' and haircolour = 'Green';

[jl56]

Bonjour à tous, très matinal ( j'ai bu trop de café hier)

@JCHD
Merci ça fonctionne très bien, j'ai corrigé le code, pour l'exemple, sur mon premier post

J'ai carrément supprimer rowid de la table testtable_pc je ne sais pas si c'est une bonne id zut idée.

J'ai cru lire, lors de mes lectures sur MYSQL, qu'il fallait toujours mettre une colonne ID
la correspondance entre les 2 tables c'est la colonne CLIENT est-ce il faut mettre primary key sur ces colonnes ?

Merci de vos remarques

A+ JL56

[jchd]

Je te l'ai transposé sur SQLite, ce qui te permet de tester du SQL en local et surtout en temps réel si tu utilises un gestionnaire comme SQLite Expert (la version gratuite suffit amplement).

Tu vois qu'on peut parfaitement virer les rowid, déclarer client comme clé primaire sur la table clients et créer une clé composite (client, nom) unique sur la table pc. On pourrait aussi bien considérer ip comme unique et créer l'index primaire sur (ip). Tout dépend de la sémantique des colonnes et des relations entre tables. En outre, une clé étrangère (foreign key) lie les colonnes client. Maintenant, si on supprime un client, SQL supprimera automatiquement ses PCs (clause on delete cascade). La clause on update cascade assure la cohérence automatique lors de la modification du nom d'un client dans la table client. Je te laisse jouer avec tout ça.

On a toujours intérêt à encadrer une insertion massive par une transaction et faire un rollback si ça se passe mal au milieu de ça. En plus, c'est beaucoup plus véloce.

► Afficher le texte

Code : Tout sélectionner

#include <SQLite.au3>
#include <SQLite.dll.au3>
#include <Array.au3>


;~ MsgBox(0,"",@LogonDomain)
_SQLite_Startup()
If @error Then
    MsgBox(0, "Error Starting SQLite", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
    Exit
EndIf

;~ $Pass = ""

_SQLite_Open("testsql.sq3")
If @error Then
    MsgBox(0, "Error opening Database", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
    Exit
EndIf

;~ If Not _SQLite_Exec("CREATE DATABASE IF NOT EXISTS SQLiteTest") Then
;~     MsgBox(0, "Error opening Database", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
;~     Exit
;~ EndIf

;~ If Not _SQLite_SelectDB("SQLiteTest") Then
;~     MsgBox(0, "Error setting Database to use", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
;~     Exit
;~ EndIf

_SQLite_Exec(-1, "DROP TABLE if exists TestTable")
_SQLite_Exec(-1, "DROP TABLE if exists TestTable_pc")


$sSQLiteStatement = "CREATE TABLE IF NOT EXISTS TestTable (" & _
        "CLIENT TEXT NOT NULL primary key, " & _
        "Age INT NOT NULL, " & _
        "EyeColour TEXT NOT NULL, " & _
        "HairColour TEXT NOT NULL);"

If _SQLite_Exec(-1, $sSQLiteStatement) Then
    MsgBox(0, "1 Error Creating Database Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
    Exit
EndIf

$sSQLiteStatement = "CREATE TABLE IF NOT EXISTS TestTable_PC (" & _
        "CLIENT TEXT NOT NULL references testtable(client) on delete cascade on update cascade deferrable initially deferred, " & _
        "Nom TEXT NOT NULL, " & _
        "IP TEXT NOT NULL, " & _
        "CONSTRAINT [pk] PRIMARY KEY ([CLIENT], [Nom]));"

If _SQLite_Exec(-1, $sSQLiteStatement) Then
    MsgBox(0, "2 Error Creating Database Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
    Exit
EndIf




Local $aEyeColours[7] = ["Amber", "Blue", "Brown", "Grey", "Green", "Hazel", "Red"]
Local $aHairColours[6] = ["Brown", "Black", "Blond", "Grey", "Green", "Pink"]

Local $sSQLiteStatement = ""

_SQLite_Exec(-1, "begin")
For $i = 1 To 50 Step 1
    Local $sSQLiteStatement = ""
    $sSQLiteStatement = "INSERT INTO TestTable (CLIENT, Age, EyeColour, HairColour) VALUES (" & _
            "'Person" & $i & "'," & _
            "'" & Random(1, 100, 1) & "'," & _
            "'" & $aEyeColours[Random(0, 6, 1)] & "'," & _
            "'" & $aHairColours[Random(0, 5, 1)] & "');"
    If _SQLite_Exec(-1, $sSQLiteStatement) Then
        MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
_SQLite_Exec(-1, "rollback")
        Exit
    EndIf

    Local $sSQLiteStatement_pc = ""

    For $j = 1 To 10 Step 1
        $sSQLiteStatement_pc &= "INSERT INTO TestTable_PC (CLIENT, Nom, IP) VALUES (" & _
                "'Person" & $i & "'," & _
                "'NomPC" & $j & "'," & _
                "'" & "192.168." & $i & "." & $j & "');"
    Next

    If _SQLite_Exec(-1, $sSQLiteStatement_pc) Then
        MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
_SQLite_Exec(-1, "rollback")
        Exit
    EndIf

Next
_SQLite_Exec(-1, "commit")


Local $aRows, $iRows, $iCols
_SQLite_GetTable2d(-1, "SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person2';", $aRows, $iRows, $iCols)
$error = @error
If $error Then MsgBox(0, $sSQLiteStatement_pc & " error ", $error)
_ArrayDisplay($aRows, "2d Array PC de Person2")



;~ Ajout client *****************
Local $sSQLiteStatement = ""
$sSQLiteStatement = "INSERT INTO TestTable (CLIENT, Age, EyeColour, HairColour) VALUES (" & _
        "'Person" & 51 & "'," & _
        "'" & Random(1, 100, 1) & "'," & _
        "'" & $aEyeColours[Random(0, 6, 1)] & "'," & _
        "'" & $aHairColours[Random(0, 5, 1)] & "');"
If _SQLite_Exec(-1, $sSQLiteStatement) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
    Exit
EndIf

;~ Ajout PC1 et PC2 dur client Person51 *****************
$sSQLiteStatement_pc = ""
$sSQLiteStatement_pc &= "INSERT INTO TestTable_PC (CLIENT, Nom, IP) VALUES (" & _
        "'Person51'," & _
        "'NomPC1'," & _
        "'192.168.51.1');"
$sSQLiteStatement_pc &= "INSERT INTO TestTable_PC (CLIENT,Nom,IP) VALUES (" & _
        "'Person51'," & _
        "'NomPC2'," & _
        "'192.168.51.2');"

If _SQLite_Exec(-1, $sSQLiteStatement_pc) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
    Exit
EndIf



_SQLite_GetTable2d(-1, "SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person51';", $aRows, $iRows, $iCols)
$error = @error
If $error Then MsgBox(0, $sSQLiteStatement_pc & " error ", $error)
_ArrayDisplay($aRows, "2d Array PC de Person51")




; modidification couleur cheveux du client Person4
$sSQLiteStatement = "update TestTable set Haircolour = 'Roux' where CLIENT = 'Person4';"
If _SQLite_Exec(-1, $sSQLiteStatement) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
;~  Exit
EndIf

; verif modif couleur roux pour Person4
_SQLite_GetTable2d(-1, "SELECT CLIENT,haircolour FROM TestTable WHERE CLIENT = 'Person4';", $aRows, $iRows, $iCols)
$error = @error
If $error Then MsgBox(0, $sSQLiteStatement & " error", $error)
_ArrayDisplay($aRows, "2d Array haircolour of Person4")

; Suppression de pc5 du client Person7
$sSQLiteStatement_pc = "delete from testTable_pc where nom = 'NomPC5' and client = 'Person7';"
If _SQLite_Exec(-1, $sSQLiteStatement_pc) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg() & " error 157 ")
    Exit
EndIf
; verif supression de NomPC5
_SQLite_GetTable2d(-1, "SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person7';", $aRows, $iRows, $iCols)
$error = @error
If $error Then MsgBox(0, $sSQLiteStatement_pc & " error ", $error&" error 163 ")
_ArrayDisplay($aRows, "2d Array PC de Person7")

; Modification de l'IP du PC3 du client Person9
$sSQLiteStatement_pc = "update TestTable_pc set ip = '192.168.45.89' where nom = 'NomPC3' and client = 'Person9';"
If _SQLite_Exec(-1, $sSQLiteStatement_pc) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
    Exit
EndIf
; verif modif
_SQLite_GetTable2d(-1, "SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person9';", $aRows, $iRows, $iCols)
$error = @error
If $error Then MsgBox(0, $sSQLiteStatement_pc & " error ", $error)
_ArrayDisplay($aRows, "2d Array PC de Person9")

; Suppression du client Person3
$sSQLiteStatement = "delete from TestTable where CLIENT = 'Person3';"
If _SQLite_Exec(-1, $sSQLiteStatement) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg()& " error 180")
    Exit
EndIf
; verif suppression
_SQLite_GetTable2d(-1, "SELECT CLIENT,haircolour FROM TestTable WHERE CLIENT = 'Person3';", $aRows, $iRows, $iCols)
$error = @error
If $error Then MsgBox(0, $sSQLiteStatement & " error", $error& " error 186")
_ArrayDisplay($aRows, "2d Array supp client Person3")

;~  et des PC de client Person3
$sSQLiteStatement_pc = "delete from TestTable_pc where CLIENT = 'Person3';"
If _SQLite_Exec(-1, $sSQLiteStatement_pc) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg()& " error 193")
    Exit
EndIf
; verif suppression
_SQLite_GetTable2d(-1, "SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person3';", $aRows, $iRows, $iCols)
$error = @error
If $error Then MsgBox(0, $sSQLiteStatement_pc & " error ", $error& " error 198")
_ArrayDisplay($aRows, "2d Array PC de Person3")


;~ SELECT CLIENT,Nom,IP FROM TestTable WHERE CLIENT like '%1%' and haircolour = 'Green';


_SQLite_GetTable2d(-1, "SELECT CLIENT,EyeColour,haircolour FROM TestTable WHERE client like '%1%' and (haircolour like '%E%' or haircolour like '%o%') ;", $aRows, $iRows, $iCols)
;~ $aOk = _SQLite_GetTable2d("SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person9';")
$error = @error
If $error Then MsgBox(0, $sSQLiteStatement & " error", $error& " error 207")
_ArrayDisplay($aRows, "Client 1 et (e ou o)")
MsgBox(0, "nbr enregistrement", UBound($aRows))


_SQLite_GetTable2d(-1, "SELECT CLIENT,haircolour FROM TestTable;", $aRows, $iRows, $iCols)
;~ $aOk = _SQLite_GetTable2d("SELECT CLIENT,Nom,IP FROM TestTable_pc WHERE CLIENT = 'Person9';")
$error = @error
If $error Then MsgBox(0, $sSQLiteStatement & " error", $error& " error 207")
_ArrayDisplay($aRows, "2d Array Client tout")
MsgBox(0, "nbr enregistrement", UBound($aRows))

MsgBox(0, "Fin test","fin")



_SQLite_Exec(-1, "DROP TABLE TestTable")
_SQLite_Exec(-1, "DROP TABLE TestTable_pc")
_SQLite_Close()
_SQLite_ShutDown()

[jl56]

@JCHD

Merci beaucoup

Je vais effectivement jouer avec tout ça
je passe en résolu ce post
Je dois faire comme je l'ai dis un exemple de fonctionnement avec un script ensuite j'aurais un peu de temps pour refaire un script sur cet exemple avec une gui.

Merci pour tout, j'ai ce qu'il me faut pour travailler

A+ JL56

[jl56]

Bonjour à tous

@JHCD

J'en appel a tes compétences en sql

Dans mon script a base de ezmysql
je voulais renseigner un champ texte à base d'un fichier TXT ou contenue dans une variable voir code

► Afficher le texte

Code : Tout sélectionner

$mp_fichier_synoptique = $mp_fichier_synoptique & ""
                $mp_fichier_synoptique = $mp_fichier_synoptique & "lib=*************  Ce synoptique est un exemple *********** =Exemple" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "int=Orange=fti/sdgsdg4545" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "             mot de passe kjLerrer   " & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "             N° de compte   123456" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "             ligne support ADSL ( c'est la ligne du fax )0297123456" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & " mod=xyxel=Cable jaune" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & " vpn=Liaison VPN vers le site de Nantes -----> IPWAN 15.68.74.1= cle preshared  jlr56@ouy" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ' rou=P01 Routeur TZ105 "192.168.2.20"=Cable bleu' & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "     swi=Dlink DGS 1024D =installé le 02/12/2013" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "             dans le local technique" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & '         bor=Borne Wifi "192.168.2.30"= ssid jlr' & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "                             TPlink tp869n" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "                         login admin" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "                             mot de passe OMR44or!" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "                         cle wifi   45dgg45s64dgs6dg " & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & '         srv=P08 Serveur AD SRV2012 "192.168.2.10" =IBM X3400 M3' & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "             DHCP de 192.168.2.150 à 192.168.2.199" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "             Windows 2012 R2" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "             mise en place en 02/12/2013" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "             Branché sur le switch avec un cable vert" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & '         imp=P09 Copieur zerox RCH "192.168.2.56"=workcenter' & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "         pos=Groupe de poste=Groupe poste bureautique" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & '             pos= Poste fax "192.168.2.15"=Fujitsut x102' & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & '             pos= Poste accueil "192.168.2.116"=lenovo' & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "             pos= Poste compta=en dhcp" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & '         nas=Nas Archive SRVNAS "192.168.2.40"=archivage et sauvegarde' & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "         lib=Port 5 à 6 libre=libre" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "         lib==" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "         lib=---------------  dans le bureau de direction --------- =" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "         swi=P07 vers DGS 1005= Switch ( derriere l'imprimante ) pour brancher 2 appareils sur une prise" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "             imp=Brother 5380N 192.168.2.55= fax et couleur" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "             pos=Poste medecin = en DHCP" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "         lib==" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "         lib==" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & '         imp=P11 Copieur zerox Etage 1 "192.168.2.57"=workcenter' & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "fin" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; Exemple de fichier pour générer automatiquement un synoptique simplifié de reseau" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; Chaque élément d'un réseau peut étre représenté. Ils sont définie par des mots clé de 3 lettres en minuscule" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; nas =NAS" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; imp =Imprimante/copieur" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; srv =Serveur" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; pos =Poste/platine" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; swi =SWITCH" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; rou =routeur" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; int =Internet" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; mod =MODEM" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; vpn =VPN" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; bor =Borne WIFI " & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; lib = pour ce qui n'est pas définie" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; Chaque élément sera noté sur une ligne qui sera constitué de 2 à 3 morceaux séparer par le signe egal" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; Le 1er morceau est le mot clé, le 2emm morceau est le nom et l'info que vous voulez afficher dans l'arborescence" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; et enfin le 3emm est un commentaire qui s'affiche, dans un champ sur la droite, lorsque l'on clique sur l'élément" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; une ligne précédé de ; ne sera pas prise en compte" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; une ligne qui n'a pas 1 fois le signe = sera ajouté au commentaire de l'élément précédent" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; pour placer les éléments dans l'arborecense, ajouter des tabulations selon votre choix en début de ligne(voir exemple ci-dessous)" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; hormis pour les commentaires ou les tabulations seront supprimées a l'affichage" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; il ne doit pas avoir plus de 2 tabulations d'écart avec l'élément précédent" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; ce type de fichier est facile a saisir et l'arboresecence est trés visuel même dans le TXT" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & "; vous pouvez finir le synoptique avec le mot fin" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";Subtilité du nom d'affichage ( le 2em morceau )" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";Si vous notez une adresse IP entre des guillemets une correspondance sera faite avec la liste des mot de passe" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";Afin d'ajouter un menu contextuel pour lancer une action, exemple un Ping " & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";et aussi afficher login et mot de passe dans le commentaire" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";Enfin si le nom commence par Groupe la sous-arborescence ne sera pas développé" & @CRLF
                $mp_fichier_synoptique = $mp_fichier_synoptique & ";Ceci afin de clarifier l'affichage du synoptique en regroupant par exemple des postes ou des imprimantes" & @CRLF

Mais je rencontre un problème d'erreur de syntaxe
J'ai bien compris qu'il avait un problème de caractère dans ma variable et qu'il faut utiliser des escapes
j'ai donc testé $mp_fichier_synoptique = _EzMySql_Real_Escape_String($mp_fichier_synoptique) trouvé sur le forum
ainsi que _SQLite_Escape ou ce que tu as conçut _SQLite_FastEncode

mais cela ne fonctionne pas, j'ai pourtant lu quelque part qu'une variable texte dans mysql pouvait largement contenir un livre entier
dans un livre il y forcement des ; ' " = etc ...

as tu STP une suggestion ?


sinon est ce que sqlite est compatible avec une base mysql ( j'ai lu que mysql est multi utilisateur ce dont j'ai besoin d'ou mon choix ) ?

Merci

A+ JL56

[jchd]

Les fonctions *_Escape acceptent une variable, la convertissent en string (normalement), doublent les simples quotes incluses et renvoient une chaîne à inclure directement dans la commande ; elle est alors encadrée de simple qoutes, pour en faire un littéral utilisable tel quel.

Code : Tout sélectionner

ConsoleWrite(_SQLite_FastEscape("O'Reilly") & @LF)

Ton code doit donc être dans ce genre (j'ai corrigé ce qui me piquait les yeux) :

► Afficher le texte

Code : Tout sélectionner

Local $mp_fichier_synoptique
$mp_fichier_synoptique &= "lib=*************  Ce synoptique est un exemple *********** =Exemple" & @CRLF
$mp_fichier_synoptique &= "int=Orange=fti/sdgsdg4545" & @CRLF
$mp_fichier_synoptique &= "             mot de passe kjLerrer   " & @CRLF
$mp_fichier_synoptique &= "             N° de compte   123456" & @CRLF
$mp_fichier_synoptique &= "             ligne support ADSL ( c'est la ligne du fax )0297123456" & @CRLF
$mp_fichier_synoptique &= " mod=xyxel=Cable jaune" & @CRLF
$mp_fichier_synoptique &= " vpn=Liaison VPN vers le site de Nantes -----> IPWAN 15.68.74.1= cle preshared  jlr56@ouy" & @CRLF
$mp_fichier_synoptique &= ' rou=P01 Routeur TZ105 "192.168.2.20"=Cable bleu' & @CRLF
$mp_fichier_synoptique &= "     swi=Dlink DGS 1024D =installé le 02/12/2013" & @CRLF
$mp_fichier_synoptique &= "             dans le local technique" & @CRLF
$mp_fichier_synoptique &= '         bor=Borne Wifi "192.168.2.30"= ssid jlr' & @CRLF
$mp_fichier_synoptique &= "                             TPlink tp869n" & @CRLF
$mp_fichier_synoptique &= "                         login admin" & @CRLF
$mp_fichier_synoptique &= "                             mot de passe OMR44or!" & @CRLF
$mp_fichier_synoptique &= "                         cle wifi   45dgg45s64dgs6dg " & @CRLF
$mp_fichier_synoptique &= '         srv=P08 Serveur AD SRV2012 "192.168.2.10" =IBM X3400 M3' & @CRLF
$mp_fichier_synoptique &= "             DHCP de 192.168.2.150 à 192.168.2.199" & @CRLF
$mp_fichier_synoptique &= "             Windows 2012 R2" & @CRLF
$mp_fichier_synoptique &= "             mise en place en 02/12/2013" & @CRLF
$mp_fichier_synoptique &= "             Branché sur le switch avec un cable vert" & @CRLF
$mp_fichier_synoptique &= '         imp=P09 Copieur zerox RCH "192.168.2.56"=workcenter' & @CRLF
$mp_fichier_synoptique &= "         pos=Groupe de poste=Groupe poste bureautique" & @CRLF
$mp_fichier_synoptique &= '             pos= Poste fax "192.168.2.15"=Fujitsut x102' & @CRLF
$mp_fichier_synoptique &= '             pos= Poste accueil "192.168.2.116"=lenovo' & @CRLF
$mp_fichier_synoptique &= "             pos= Poste compta=en dhcp" & @CRLF
$mp_fichier_synoptique &= '         nas=Nas Archive SRVNAS "192.168.2.40"=archivage et sauvegarde' & @CRLF
$mp_fichier_synoptique &= "         lib=Port 5 à 6 libre=libre" & @CRLF
$mp_fichier_synoptique &= "         lib==" & @CRLF
$mp_fichier_synoptique &= "         lib=---------------  dans le bureau de direction --------- =" & @CRLF
$mp_fichier_synoptique &= "         swi=P07 vers DGS 1005= Switch ( derrière l'imprimante ) pour brancher 2 appareils sur une prise" & @CRLF
$mp_fichier_synoptique &= "             imp=Brother 5380N 192.168.2.55= fax et couleur" & @CRLF
$mp_fichier_synoptique &= "             pos=Poste medecin = en DHCP" & @CRLF
$mp_fichier_synoptique &= "         lib==" & @CRLF
$mp_fichier_synoptique &= "         lib==" & @CRLF
$mp_fichier_synoptique &= '         imp=P11 Copieur zerox Etage 1 "192.168.2.57"=workcenter' & @CRLF
$mp_fichier_synoptique &= "fin" & @CRLF
$mp_fichier_synoptique &= ";" & @CRLF
$mp_fichier_synoptique &= ";" & @CRLF
$mp_fichier_synoptique &= "; Exemple de fichier pour générer automatiquement un synoptique simplifié de reseau" & @CRLF
$mp_fichier_synoptique &= ";" & @CRLF
$mp_fichier_synoptique &= "; Chaque élément d'un réseau peut étre représenté. Ils sont définis par des mots clé de 3 lettres en minuscule" & @CRLF
$mp_fichier_synoptique &= ";" & @CRLF
$mp_fichier_synoptique &= "; nas = NAS" & @CRLF
$mp_fichier_synoptique &= "; imp = Imprimante/copieur" & @CRLF
$mp_fichier_synoptique &= "; srv = Serveur" & @CRLF
$mp_fichier_synoptique &= "; pos = Poste/platine" & @CRLF
$mp_fichier_synoptique &= "; swi = SWITCH" & @CRLF
$mp_fichier_synoptique &= "; rou = routeur" & @CRLF
$mp_fichier_synoptique &= "; int = Internet" & @CRLF
$mp_fichier_synoptique &= "; mod = MODEM" & @CRLF
$mp_fichier_synoptique &= "; vpn = VPN" & @CRLF
$mp_fichier_synoptique &= "; bor = Borne WIFI " & @CRLF
$mp_fichier_synoptique &= "; lib = pour ce qui n'est pas défini" & @CRLF
$mp_fichier_synoptique &= ";" & @CRLF
$mp_fichier_synoptique &= ";" & @CRLF
$mp_fichier_synoptique &= "; Chaque élément sera noté sur une ligne qui sera constituée de 2 à 3 morceaux séparés par le signe égale" & @CRLF
$mp_fichier_synoptique &= "; Le 1er morceau est le mot-clé, le 2nd morceau est le nom et l'info que vous voulez afficher dans l'arborescence" & @CRLF
$mp_fichier_synoptique &= "; et enfin le 3ème est un commentaire qui s'affiche, dans un champ sur la droite, lorsque l'on clique sur l'élément" & @CRLF
$mp_fichier_synoptique &= ";" & @CRLF
$mp_fichier_synoptique &= "; une ligne précédée de ; ne sera pas prise en compte" & @CRLF
$mp_fichier_synoptique &= "; une ligne qui n'a pas 1 fois le signe = sera ajoutée au commentaire de l'élément précédent" & @CRLF
$mp_fichier_synoptique &= "; pour placer les éléments dans l'arborescence, ajouter des tabulations selon votre choix en début de ligne (voir exemple ci-dessous)" & @CRLF
$mp_fichier_synoptique &= "; hormis pour les commentaires ou les tabulations seront supprimées à l'affichage" & @CRLF
$mp_fichier_synoptique &= "; il ne doit pas avoir plus de 2 tabulations d'écart avec l'élément précédent" & @CRLF
$mp_fichier_synoptique &= "; ce type de fichier est facile a saisir et l'arborescence est trés visuelle même dans le TXT" & @CRLF
$mp_fichier_synoptique &= ";" & @CRLF
$mp_fichier_synoptique &= "; vous pouvez finir le synoptique avec le mot fin" & @CRLF
$mp_fichier_synoptique &= ";" & @CRLF
$mp_fichier_synoptique &= ";Subtilité du nom d'affichage ( le 2nd morceau )" & @CRLF
$mp_fichier_synoptique &= ";Si vous notez une adresse IP entre des guillemets une correspondance sera faite avec la liste des mots de passe" & @CRLF
$mp_fichier_synoptique &= ";Afin d'ajouter un menu contextuel pour lancer une action, exemple un Ping " & @CRLF
$mp_fichier_synoptique &= ";et aussi afficher login et mot de passe dans le commentaire" & @CRLF
$mp_fichier_synoptique &= ";" & @CRLF
$mp_fichier_synoptique &= ";Enfin si le nom commence par Groupe la sous-arborescence ne sera pas développée" & @CRLF
$mp_fichier_synoptique &= ";Ceci afin de clarifier l'affichage du synoptique en regroupant par exemple des postes ou des imprimantes" & @CRLF

; modidification couleur cheveux du client Person4
$sSQLiteStatement = "update TestTable set Haircolour = " & _SQLite_FastEscape($mp_fichier_synoptique) & " where CLIENT = 'Person4';"
If _SQLite_Exec(-1, $sSQLiteStatement) Then
    MsgBox(0, "Error inserting data to Table", "Error: " & @error & @CR & "Error string: " & _SQLite_ErrMsg())
;~  Exit
EndIf

; verif modif couleur pour Person4
_SQLite_GetTable2d(-1, "SELECT CLIENT,haircolour FROM TestTable WHERE CLIENT = 'Person4';", $aRows, $iRows, $iCols)
$error = @error
If $error Then MsgBox(0, $sSQLiteStatement & " error", $error)
_ArrayDisplay($aRows, "2d Array haircolour of Person4")

En effet, j'avais omis de te parler d'escape des variables string dans mes réponses précédentes.

[jl56]

Bonjour à tous,

Merci JHCD j'avais une erreur de syntaxe en plus du problème escape
Avec ton aide j'ai pu résoudre les 2

Merci

A+ JL56