[..] Probleme FileGetSize() et FileGetVersion() avec RunAs

[technicoman]

j'aimerais bien partager avec vous mon problème avec la création d'un scripte qui permet de comparer deux fichiers, le premier existe sur le serveur et le 2eme localement sur le pc client.

l'objectif de la comparaison c'est d’écraser le fichier qui existe sur le pc client par celui qui existe au serveur (en cas de la différence).

le problème c'est que le fichier concerné existe dans un dossier (sur le serveur) qui est partagé en $ avec un seul utilisateur admin (avec un mot de passe).



alors comment je pourai reccuperer le FileGetSize() et FileGetVersion() depuis un dossier partagé en reseau sur le serveur avec des droits limités et sachant que RunAs ne lance que des programmes et non pas des fonctions?



voila mon scripte:

► Afficher le texte

Code : Tout sélectionner

#include <FileConstants.au3>
#include <Constants.au3>

$srv = "\\serveur\dossier$\test.exe"
$loc = "d:folder\"
$user = "user"
$domaine = "serveur"
$pass = "pass@@ssapl"
$flg = 2

 ; qu'est ce que je pourai mettre ici afin de executer le reste de scripte avec des droits d'administrateurs

 ;RunAs($user,$domaine,$pass, $flg, ...) >> je sais pas si ça va fonctionner ou non et comment?

      if not FileExists($srv) then
            MsgBox($MB_SYSTEMMODAL, "Erreur !", "File Serveur is not exist...")
         Else

            Local $iFileSize  = FileGetSize($loc)
            Local $iFileSize1  = FileGetSize($srv)

            Local $sFileVersion  = FileGetVersion($loc)
            Local $sFileVersion1 = FileGetVersion($srv)

            if $iFileSize <> $iFileSize1 Or $sFileVersion <> $sFileVersion1  then

               FileCopy($pcserveur ,$pcloc, 1)
               MsgBox($MB_SYSTEMMODAL, "msg !", "copie ")
            else
               MsgBox($MB_SYSTEMMODAL, "msg !", "non")
            endif
      EndIf
 

merci d'avance pour votre aide.

[Tlem]

Bonjour.
Merci de lire ceci => http://www.autoitscript.fr/forum/viewto ... f=35&t=595

A bientôt.

[jguinch]

@technicoman : tu comptes poster sur tous les forum AutoIt ? => http://www.autoitscript.com/forum/topic ... vec-runas/
Donc choisis sur quel forum tu souhaites poursuivre ce post, ça ne sert à rien de l'avoir en double...
Si tu as du mal avec l'anglais, ce sera certainement plus simple pour toi de poster ici.

[Tlem]

Si tu as du mal avec l'anglais, ce sera certainement plus simple pour toi de poster ici.

Effectivement il serait bien que technicoman évite le multi-postage ...

Sinon, pour résoudre le problème, une des solutions serait de relancer le script avec les droits admin.
D'après ce que j'ai vu dans le code, le login et mot de passe admin sont déclarés au début du script, donc l'idée serait de contrôler si le script à ou nom les droits admin. Si pas de droits (If Not IsAdmin) alors on relance le script avec RunAs + login/pass admin et on quitte le script non admin.

[technicoman]

@technicoman : tu comptes poster sur tous les forum AutoIt ? => http://www.autoitscript.com/forum/topic ... vec-runas/
Donc choisis sur quel forum tu souhaites poursuivre ce post, ça ne sert à rien de l'avoir en double...
Si tu as du mal avec l'anglais, ce sera certainement plus simple pour toi de poster ici.

Tout a fait raison monsieur j'ai mal choisi le forum et j'ai même pas fait attention que le forum était en anglais et c'est carrément loin de la multipostage.
Je me suis orienté vers vous afin de trouver une solution de mon problème avec des gens Compétants et qui metrisent bien ma langue

[jguinch]

OK. Donc merci d'indiquer sur le forum US que le fil se poursuit sur le forum français.

Pour ton problème, un simple DriveMapAdd devrait suffire je pense...

[technicoman]

OK. Donc merci d'indiquer sur le forum US que le fil se poursuit sur le forum français.

Pour ton problème, un simple DriveMapAdd devrait suffire je pense...

Salut Monsieur c'est déjà clôturé sur le forum US.

merci pour ta réaction immédiate mais j'essaie d’éviter la connexion des lecteurs réseau sur les postes clients et surtout avec ce dossier qui contient des données confidentielles.

j'ai réussi a créer le code qui permet de copie le fichier depuis le serveur :

Code : Tout sélectionner

RunAs($user,$domaine,$pass, $flg, @ComSpec & " /c " & "xcopy " & '"' & $srv & '"' & ' "' & $loc & '"' & " /Y","",@SW_HIDE)

mais il me reste comment je peux vérifier l’existence de fichier et le FileGetSize(), FileGetVersion() pour comparer les deux fichiers sachant que le dossier est tjr partagé avec un seul utilisateur.

[Tlem]

Puisque ma solution ne vous convient pas, vous pouvez toujours lancer une commande RunAs() qui lancera une ligne de code AutoIt avec les droits Admin ...
Pour ça, regardez les options de la ligne de commande AutoIt !

Envoyé de mon appareil mobile avec Tapatalk.

[jguinch]

Ce que tu peux faire, c'est utiliser RunAs pour exécuter une ligne de code qui fera la copie si la taille ou la date du fichier source est différente.


Ca peut donner un truc comme ça :

► Afficher le texte

Code : Tout sélectionner

#pragma compile(AutoItExecuteAllowed, True)

$sUsername = "myUser"
$sDomain = "myDomain
$sPassword = "P@$$w0rd"
$sLocalFile = @ScriptDir & "\myProgram.exe"
$sRemoteFile = "\\server\share\dir\myProgram.exe"


$line = """If FileGetVersion('" & $sLocalFile & "') <> FileGetVersion('" & $sRemoteFile & "') OR " & _
        "FileGetSize('" & $sLocalFile & "') <> FileGetSize('" & $sRemoteFile & "') " & _ 
        "Then FileCopy('" & $sLocalFile & "', '" & $sRemoteFile & "', 1)"""
RunAsWait($sUsername, $sDomain, $sPassword, 0, @AutoItExe & ' /AutoIt3ExecuteLine ' & $line)

 

[technicoman]

Ce que tu peux faire, c'est utiliser RunAs pour exécuter une ligne de code qui fera la copie si la taille ou la date du fichier source est différente.


Ca peut donner un truc comme ça :

► Afficher le texte

Code : Tout sélectionner

#pragma compile(AutoItExecuteAllowed, True)

$sUsername = "myUser"
$sDomain = "myDomain
$sPassword = "P@$$w0rd"
$sLocalFile = @ScriptDir & "\myProgram.exe"
$sRemoteFile = "\\server\share\dir\myProgram.exe"


$line = """If FileGetVersion('" & $sLocalFile & "') <> FileGetVersion('" & $sRemoteFile & "') OR " & _
        "FileGetSize('" & $sLocalFile & "') <> FileGetSize('" & $sRemoteFile & "') " & _ 
        "Then FileCopy('" & $sLocalFile & "', '" & $sRemoteFile & "', 1)"""
RunAsWait($sUsername, $sDomain, $sPassword, 0, @AutoItExe & ' /AutoIt3ExecuteLine ' & $line)

 

Merci beaucoup pour votre aide , le programme se compile et s'exécute sans problème mais sans aucune résultat. j'ai modifié juste la ligne de Filecopy tel que la copie soit dans le sens inverse (depuis le serveur vers le poste client). mais sa marche pas.

[jguinch]

Montre nous ton code stp.

Edit : pour y voir plus clair, tu peux aussi faire un truc comme ça, qui devrait être plus facile à débugger :

► Afficher le texte

Code : Tout sélectionner

$sUsername = "myUser"
$sDomain = "myDomain
$sPassword = "P@$$w0rd"
$sLocalFile = @ScriptDir & "\myProgram.exe"
$sRemoteFile = "\\server\share\dir\myProgram.exe"

$sArgCopy = "-update"



If $CmdLine[0] > 0 And $CmdLine[1] = $sArgCopy Then
    Switch _UpdateFile()
        Case 0
            MsgBox(0, "", "La mise à jour du fichier n'est pas nécessaire")
        Case 1
            MsgBox(16, "", "La mise à jour du fichier a été échoué")
        Case 2
            MsgBox(0, "", "La mise à jour du fichier a été effectuée")
    EndSwitch
    
Else
    If @Compiled Then
        RunAsWait($sUsername, $sDomain, $sPassword, 0, @ScriptFullPath & " " & $sArgCopy)
    Else
        MsgBox(16, "", "Le programme doit être compilé")
    EndIf
EndIf


Func _UpdateFile()
    If FileGetVersion($sLocalFile) <> FileGetVersion($sRemoteFile) OR FileGetSize($sLocalFile) <> FileGetSize($sRemoteFile) Then
        Return 1 + FileCopy($sRemoteFile, $sLocalFile, 1)
    EndIf
    
    Return 0
EndFunc