[R] Iniwrite petit problème

[sozary]

Bonjour à tous!!

J'ai un petit soucis avec un IniWrite qui ne fonctionne pas, alors que je l'utilise avant pour autre chose et que cela marche !

Voici mon code:

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include "functions.au3"
#Include <Icons.au3>



#Region ### START Koda GUI section ### Form=
        Global $Form2 = GUICreate("Audio Quizz! -Profil-", 443, 351, 527, 394)
        GUISetIcon("C:\Users\Mehdi\Desktop\Lou Trendel\ressources\icone.ico", -1)
        GUISetFont(12, 400, 0, "Century Gothic")
        Global $Button0 = GUICtrlCreateButton("Changer nom", 136, 40, 171, 33)
        Global $Button1 = GUICtrlCreateButton("Changer prénom", 136, 79, 171, 33)
        Global $Button2 = GUICtrlCreateButton("Changer avatar", 136, 126, 171, 33)
        Global $Label1 = GUICtrlCreateLabel("Prévisualisation", 152, 176, 121, 25)
        Global $Pic5= GUICtrlCreatePic("", 160, 224, 100, 100)
        GUISetState(@SW_SHOW)
        #EndRegion ### END Koda GUI section ###




    While 1
     $nMsg = GUIGetMsg()
     Switch $nMsg
         Case $GUI_EVENT_CLOSE

        Exit
         case $Button0
             Do
                 $nom=InputBox("Audio Quiz","Quel est votre nom?")
             Until $nom<>""
             MsgBox(64,"Audio Quizz","Nom changé!")
            IniWrite("Config.ini","Profil","nom",$nom)
        case $Button1
             Do
                 $prenom=InputBox("Audio Quiz","Quel est votre prénom?")
             Until $prenom<>""
             MsgBox(64,"Audio Quizz","Prénom changé!")
            IniWrite("Config.ini","Profil","prenom",$prenom)
         Case $Button2
            Local $file
             $file=FileOpenDialog("Audio Quizz - Avatar -",@DesktopDir,"Images (*.jpg;*.png)",$FD_FILEMUSTEXIST)
             If @error Then
                 MsgBox(48,"Audio Quizz","Aucun fichier sélectionné!")
             Else
                 If _VerifImg($file)=-1 Then
                     MsgBox(48,"Audio Quizz","Image trop grande.")
                Else
                     MsgBox(64,"Audio Quizz","Avatar changé!")

                     IniWrite("Config.ini","Profil","avatar","mm") ;ICI NE MARCHE PAS!
                     Switch StringSplit($file,".")[UBound(StringSplit($file,"."))-1]
                         Case "jpg"
                            GUICtrlSetData($Pic5,$file)
                         Case "png"
                            _SetImage($Pic5, $file)

                    EndSwitch
                EndIf
            EndIf
     EndSwitch
    WEnd

De plus, quand je récupère l'erreur avec une msgbox, il me dit 1, donc que tout c'est bien passé, or non!
L'image s'affiche elle bien dans la prévisualisation*

[TT22]

Ne devrais tu pas mettre

Code : Tout sélectionner

IniWrite("Config.ini","Profil","avatar",$file)

au lieu de

Code : Tout sélectionner

IniWrite("Config.ini","Profil","avatar","mm")

?

[sozary]

si, mais le "mm" était un test, car avec $file sa ne marche pas! mais avec le mm aussi

[walkson]

Bonjour,
C'est très étrange en effet et si vous désactivez FileOpenDialog() le Ini s'écrit normalement

[mikell]

Probablement c'est le FileOpenDialog qui modifie le @WorkingDir
Donc ou bien tu mets le chemin complet du ini dans le IniWrite, ou bien tu mets juste avant

Code : Tout sélectionner

FileChangeDir(@ScriptDir)

Edit
D'une manière générale il est recommandé d'utiliser de préférence des chemins complets

[walkson]

je viens de tester

Code : Tout sélectionner

$file = FileOpenDialog("",@DesktopDir,"all(*.*)")
IniWrite(@DesktopDir & "\configu.ini","section1","key1",$file)

et pas de problème.
Je crois qu'il faut compléter le chemin du Ini dans votre script

[mikell]

watson, tu as lu mon post ?
Classiquement on trouve ça

Code : Tout sélectionner

Global $ini = "chemin\Config.ini"
;....
IniWrite($ini, ...etc)

[walkson]

j'ai lu trop vite...

[sozary]

Ah! Mais il me dit error parsing functioncall

[sozary]

Problème résolus! Merci mikell, j'avais pas vu un piti fichier ini se créer dans mon sous dossier avec tous mes essais dedans !
Merci!!