[..] Ajout masque GDIPlus

[TommyDDR]

Bonjour,

Je suis actuellement sur de la manipulation d'image (en RAM).
J'ai fait un programme qui me permet d'ajouter un filtre sur une image (exemple : la rendre plus rouge, moins verte, etc...), il fonctionne très bien mais sur de petites images (16*16) dès que l'on passe à des images pus grande (35 * 35 par exemple), le traitement dure 270ms, ce qui est beaucoup trop long pour de la "retouche en direct".
Un flag est aussi possible pour indiquer que la couleur du pixel aux coordonnées 0, 0 ne sera pas traitée.

Voici le script :

► Afficher le texteexemple

Code : Tout sélectionner

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include "ImageManip.au3"

Opt("MustDeclareVars", 1)
Opt("GuiOnEventMode", 1)

Global $gui
Global $icon
Global $slider[3]
Global $tailleIcon =    [16, 16]
Global $taille[2] =     [410, $tailleIcon[1]+150]
;~ Global $cheminIcon = @ScriptDir & "\Cadenas.ico"
Global $cheminIcon =    @ScriptDir & "\Colors.ico"
Global $colorsName =    ["Rouge", "Vert", "Bleu"]
Global $bitmap
Global $bordure =       5
Global $changing =      False

$gui =          GUICreate("", $taille[0], $taille[1])
                GUISetOnEvent($GUI_EVENT_CLOSE, "quit", $gui)
$icon =         GUICtrlCreatePicPng($cheminIcon, ($taille[0]-$tailleIcon[0])/2, 20, $tailleIcon[0], $tailleIcon[1])
                For $i = 0 To UBound($slider, 1)-1
$slider[$i] =       GUICtrlCreateLabel($colorsName[$i] & " :", $bordure, 50+$tailleIcon[1]+$bordure+$i*30, 40, 20)
$slider[$i] =       GUICtrlCreateSlider(2*$bordure+40, 50+$tailleIcon[1]+$bordure+$i*30, $taille[0]-(2*$bordure+40), 20)
                    GUICtrlSetLimit($slider[$i], 255, -255)
                Next
                GUISetState(@SW_SHOW, $gui)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While(True)
    Sleep(10)
WEnd

Func WM_NOTIFY($hwnd, $msg, $wParam, $lParam)
    Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    Local $iEvent = DllStructGetData($tNMHDR, "Code")
    Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    If(Not($changing) And $hwnd = $gui And $iEvent = -12) Then
        Local $found = -1
        For $i = 0 To UBound($slider, 1)-1
            If($wParam = $slider[$i]) Then
                $found = $i
                ExitLoop
            EndIf
        Next
        If($found >= 0) Then
            Local $timer = TimerInit()
            If(IsPtr($bitmap)) Then _GDIPlus_BitmapDispose($bitmap)
            $bitmap = _GDIPlus_BitmapCreateFromFile($cheminIcon)
            Local $readRed =    GUICtrlRead($slider[0])
            Local $readGreen =  GUICtrlRead($slider[1])
            Local $readBlue =   GUICtrlRead($slider[2])
            Local $red =        "0x" & Hex(String(Abs($readRed)), 2) & "0000"
            Local $green =      "0x00" & Hex(String(Abs($readGreen)), 2) & "00"
            Local $blue =       "0x0000" & Hex(String(Abs($readBlue)), 2)
            ConsoleWrite($red & ", " & $green & ", " & $blue & @CRLF)
            $changing = True
            ImageSetMask($bitmap, $red, $readRed >= 0)
            ImageSetMask($bitmap, $green, $readGreen >= 0)
            ImageSetMask($bitmap, $blue, $readBlue >= 0)
            GUICtrlSetPng($icon, $bitmap)
            $changing = False
            ConsoleWrite(TimerDiff($timer) & @CRLF)
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc

Func quit()
    Exit
EndFunc
 

► Afficher le texteImageManip.au3

Code : Tout sélectionner

#include <GDIPlus.au3>
#include <Math.au3>

_GDIPlus_Startup()
OnAutoItExitRegister("_exit_iconmanip")

Func ImageSetMask($iconName, $mask, $add = True, $trans = True)
    $mask = "0x" & Hex($mask, 8)
    Local $bitmap = IsPtr($iconName) ? $iconName : _GDIPlus_BitmapCreateFromFile($iconName)
    Local $transCol = $trans ? "0x" & Hex(_GDIPlus_BitmapGetPixel($bitmap, 0, 0), 8) : -1
    For $y = 0 To _GDIPlus_ImageGetHeight($bitmap)-1
        For $x = 0 To _GDIPlus_ImageGetWidth($bitmap)-1
            Local $color = "0x" & Hex(_GDIPlus_BitmapGetPixel($bitmap, $x, $y), 8)
;~          ConsoleWrite($color & "->")
            If($color <> $transCol) Then
                If($add) Then
                    $color = ColorAddProportion($color, $mask)
                Else
                    $color = ColorSubProportion($color, $mask)
                EndIf
                _GDIPlus_BitmapSetPixel($bitmap, $x, $y, $color)
            EndIf
;~          ConsoleWrite($color & ", ")
        Next
;~      ConsoleWrite(@CRLF)
    Next
    Return $bitmap
EndFunc

Func ColorAddProportion($color, $mask)
    Local $colors[2][3] = [ [_WinAPI_GetRValue($color), _WinAPI_GetGValue($color), _WinAPI_GetBValue($color)], _
                            [_WinAPI_GetRValue($mask), _WinAPI_GetGValue($mask), _WinAPI_GetBValue($mask)]]

    Local $retour = StringTrimRight($color, 6)
    For $i = 0 To UBound($colors, 2)-1
        $retour &= Hex($colors[0][$i]+$colors[1][$i]-Floor(($colors[0][$i]*$colors[1][$i])/255), 2)
    Next
    Return $retour
EndFunc

Func ColorSubProportion($color, $mask)
    Local $colors[2][3] = [ [_WinAPI_GetRValue($color), _WinAPI_GetGValue($color), _WinAPI_GetBValue($color)], _
                            [_WinAPI_GetRValue($mask), _WinAPI_GetGValue($mask), _WinAPI_GetBValue($mask)]]
    Local $retour = StringTrimRight($color, 6)
    For $i = 0 To UBound($colors, 2)-1
        $retour &= Hex($colors[0][$i]-Floor(($colors[0][$i]*$colors[1][$i])/255), 2)
    Next
    Return $retour
EndFunc

Func ColorAdd($color, $mask)
    Local $colors[2][3] = [ [_WinAPI_GetRValue($color), _WinAPI_GetGValue($color), _WinAPI_GetBValue($color)], _
                            [_WinAPI_GetRValue($mask), _WinAPI_GetGValue($mask), _WinAPI_GetBValue($mask)]]

    Local $retour = StringTrimRight($color, 6)
    For $i = 0 To UBound($colors, 2)-1
        $retour &= Hex(_Min($colors[0][$i]+$colors[1][$i], 255), 2)
    Next
    Return $retour
EndFunc

Func ColorSub($color, $mask)
    Local $colors[2][3] = [ [_WinAPI_GetRValue($color), _WinAPI_GetGValue($color), _WinAPI_GetBValue($color)], _
                            [_WinAPI_GetRValue($mask), _WinAPI_GetGValue($mask), _WinAPI_GetBValue($mask)]]

    Local $retour = "0x"
    For $i = 0 To UBound($colors, 2)-1
        $retour &= Hex(_Max($colors[0][$i]-$colors[1][$i], 0), 2)
    Next
    Return $retour
EndFunc

Func GUICtrlCreatePicPng($file, $x, $y, $w = Default, $h = Default, $disable = Default, $xSub = Default, $ySub = Default)
    Local $hImg = $file
    Local $dispose = False
    If(Not(IsPtr($hImg))) Then
        $dispose = True
        $hImg = _GDIPlus_ImageLoadFromFile($file)
    EndIf
    If($w = Default) Then $w = IsPtr($hImg) ? _GDIPlus_ImageGetWidth($hImg) : 1
    If($h = Default) Then $h = IsPtr($hImg) ? _GDIPlus_ImageGetHeight($hImg) : 1
    If($disable = Default) Then $disable = False
    If($xSub = Default) Then $xSub = 0
    If($ySub = Default) Then $ySub = 0
    Local $id = GUICtrlCreatePic("", $x-$xSub*$w, $y-$ySub*$h, $w, $h)
    GUICtrlSetPng($id, $hImg, $dispose)
    If($disable) Then GUICtrlSetState($id, $GUI_DISABLE)
    Return $id
EndFunc

Func GUICtrlSetPng($id, $file, $dispose = True)
    Local $retour = False
    Local $hImg = $file
    If(FileExists($file)) Then
        $hImg = _GDIPlus_ImageLoadFromFile($file)
        $dispose = True
    EndIf
    If(IsPtr($hImg)) Then
        Local $hBmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImg)
        _WinAPI_DeleteObject(GUICtrlSendMsg($id, 0x0172, 0, $hBmp))
        If($dispose) Then _GDIPlus_ImageDispose($hImg)
        _WinAPI_InvalidateRect(GUICtrlGetHandle($id))
        $retour = True
    EndIf
    Return $retour
EndFunc

Func _exit_iconmanip()
    _GDIPlus_Shutdown()
EndFunc

Et les images qui vont avec (testez avec Cadenas.ico puis Colors.ico pour voir les différents temps de traitement)

Ma question est donc : Peut ajouter un "masque" sur une image de façon plus rapide, tout en gardant la possibilité de ne pas traiter une couleur précise (en 0, 0) ?

Merci.

[yohan8]

ImageMagick permet de faire de la retouche d'image et est pilotable avec autoit. Je doute que faire appel à un autre programme permettrait de gagner du temps mais tu peux toujours essayer.

[TommyDDR]

J'ai oublié : Je ne veux pas passer par un programme externe surtout si je vous dit que 260ms est beaucoup trop long ^^.

(Pour la petite histoire : Je me sers entre autre de cette fonction pour créer des "images boutons" qui changent leur luminosité au survol / clic de la souris.)

La question est donc toujours : "Comment appliquer un masque à une image tout en épargnant une couleur donnée ?"

[walkson]

Bonsoir,
Je vais peut être dire une bêtise mais _WinAPI_CreateColorAdjustment () ne conviendrait pas ? L'exemple de l'aide ressemble beaucoup à ton script...
Et à mon avis, cela devrait être plus rapide

[TommyDDR]

En effet, la rapidité de _WinAPI_CreateColorAdjustment est ce que je recherche.
Malheureusement (sauf si je me trompe) je n'ai pas trouvé de quoi mettre une couleur "à ne pas traiter" et je ne comprends pas trop le fonctionnement, dans le mien si je mets le rouge à fond, et que je mets le vert et le bleu à 0, l'image est toute rouge, dans le _WinAPI_CreateColorAdjustment ce n'est pas le même rendu.

[walkson]

Bonjour,
Avez vous essayé d'inverser les couleurs ?
Dans le test ci-dessous, j'obtiens le bleu avec 255,0,0 alors qu'il devrait être rouge

► Afficher le texte

Code : Tout sélectionner

 #include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
Opt("GUIOnEventMode", 1)
Global $Splash = SplashTextOn("SPLASH","lecture",400,400,10,305,1,"Comic Sans MS",72,800)
Global $hGUI = GUICreate("_WinAPI_DrawLine", 400, 400,500)
GUISetOnEvent(-3, "SpecialEvents")
GUISetState()
drawline()
While 1
    Sleep(100)
WEnd

Func SpecialEvents()
    Exit
EndFunc
Func drawline()
    $hDC = _WinAPI_GetDC($Splash)
    $hPen = _WinAPI_CreatePen($PS_SOLID, 16, _WinAPI_RGB(255,0, 0))
    $hPen1 = _WinAPI_CreatePen($PS_SOLID, 8, _WinAPI_RGB(51,51, 204))
    $hPen2 = _WinAPI_CreatePen($PS_SOLID, 2, _WinAPI_RGB(0,255, 255))
    Local $X = 400, $Y = 400
    Local Const $PI = 3.141592653589793
    Local $fDegToRad = $PI / 180
For $yy = 1 To 3

$cycle = 360
$ptX = 200
$ptY = 290
$speed = 50
$pas = 10
    If $yy = 1 Then
    $Orig1 = _WinAPI_SelectObject($hDC, $hPen)
    $X1 = 100
    $Y1 = 100
    EndIf
    If $yy = 2 Then
    $Orig1 = _WinAPI_SelectObject($hDC, $hPen1)
    $X1 = 80
    $Y1 = 80
    EndIf
    If $yy = 3 Then
    $Orig1 = _WinAPI_SelectObject($hDC, $hPen2)
    $X1 = 60
    $Y1 = 60
    EndIf

    _WinAPI_DrawLine($hDC, $ptX, $ptY, $ptX, $ptY )
        For $A = 0 To $cycle Step $pas
    Local $Cos2 = Round($X1 * Cos($A * $fDegToRad),2)
    Local $Sin2 = Round($Y1 * Sin($A * $fDegToRad),2)
            _WinAPI_LineTo($hDC, $ptX + $Cos2 ,$ptY + $Sin2   )
            _WinAPI_MoveTo($hDC,  $ptX ,$ptY  )
            ToolTip($A,100,100)
            ConsoleWrite($A & " / " & $Sin2 & " / " & $Cos2 & @CRLF)
            sleep($speed)
        Next

Next

    _WinAPI_DeleteObject($hPen2)
    _WinAPI_DeleteObject($hPen1)
    _WinAPI_DeleteObject($hPen)
    _WinAPI_ReleaseDC($Splash, $hDC)
EndFunc

 

ps: je n'ai pas encore testé _WinAPI_CreateColorAdjustment, je suis donc dans la supposition...

[TommyDDR]

Oui, j'ai regardé l'exemple fourni et j'avais aussi remarqué l'inversion.