[R] Tracking Colissimos (générer des boutons avec un CSV)

[juju29]

bien le bonjour !

je suis entrain de me faire un script pour me simplifier la vie, le suivie de mes colissimos.

j ai pour le moment reussi a extraire et creer un fichier qui rassemble le nom de mes clients et le numero colissimo.

j'ai la page web colissomo qui s'affiche
j'ai mes boutons qui se créent en fonction du nombre de ligne du fichier csv, et qui prennent le nom du client
mes liens vers le site colissimo se génèrent correctement.

mais problèmes je n'arrive pas a faire en sorte que mes boutons dirigent vers l'adresse générée.

je vous demande donc un coup de main, des indices ou même une solution ( avec explications si possible pour alimenter mon cerveau )

merci d'avance ! ( et soyez indulgents !! )

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>
#include <array.au3>
#include <file.au3>

Local $oIE = _IECreateEmbedded()

GUICreate("Colissimo", 1040, 650, _
        (@DesktopWidth - 1100), (@DesktopHeight - 670), _
        $WS_OVERLAPPEDWINDOW + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
GUICtrlCreateObj($oIE, 50, 10, 750, 600)
$ya = 0
Local $idButton_Home = GUICtrlCreateButton("Start", 230, 610, 100, 30)
Local $idButton_Stop = GUICtrlCreateButton("Stop", 340, 610, 100, 30)



GUISetState(@SW_SHOW) ;Show GUI

_IENavigate($oIE, "http://www.colissimo.fr")
_IEAction($oIE, "stop")


While 1
    Local $iMsg = GUIGetMsg()
    Select
        Case $iMsg = $GUI_EVENT_CLOSE
            ExitLoop
         Case $iMsg = $idButton_Home
; dans le futur : sauvegarde a J+10 en pdf des pages HTML
;           $sPdf = "test.pdf"
;RunWait(@ScriptDir & '\wkhtmltopdf.exe "' & $Html & '" "' & $sPdf & '"')


Dim $oneDarray
_FileReadToArray(@ScriptDir & "\" & "test.csv", $oneDarray)
$columnsCounter = stringsplit($oneDarray[1],";")
Dim $twoDarray[$oneDarray[0] + 1][$columnsCounter[0] + 1]
For $x = 1 to ($oneDarray[0])
$oneRow = stringsplit($oneDarray[$x],";")
For $y = 1 to ($columnsCounter[0])
$twoDarray[$x][$y] = $oneRow[$y]
Next
Next 

$Fichier = "test.csv"
Local $count = _FileCountLines($Fichier)
;  MsgBox(0, "", $count)
For $i = 1 To $count
;  MsgBox(0, "", $twoDarray[$i][4] & $twoDarray[$i][5])
  Local $id = GUICtrlCreateButton($twoDarray[$i][4], 930, $ya+20, 100, 30)
  $ya = $ya+40
  $html = "http://www.colissimo.fr/portail_colissimo/suivre.do?colispart=" & $twoDarray[$i][5]
            _IENavigate($oIE, $html)
Next
        Case $iMsg = $idButton_Stop
            _IEAction($oIE, "stop")
    EndSelect
WEnd

GUIDelete()

Exit
 

mon fichier test.csv ( aucune information n'est réelle bien sur )

► Afficher le texte

2014;08;29;Aglaee ;242171530;OK!
2014;08;30;Sidonie ;242171531;OK!
2014;09;02;Goldarak ;245145338;OK!
2014;09;02;Albator ;245164111;OK!
2014;09;02;Popori ;245175825;OK!
2014;09;02;FraggelRock ;245185818;OK!
2014;09;02;Candy ;245185957;OK!
2014;09;03;Maya ;246102406;OK!
2014;09;03;LegumeMan ;246160027;OK!
2014;09;03;GrosChat ;246170812;OK!
2014;09;03;Glouton ;246175848;OK!
2014;09;03;DurAMou ;247094058;OK!

[Faco]

Salut,
alors ton soucis c'est que tu crée tes boutons mais dans ton while/switch tu ne capte pas les événements sur tes bouton que tu crée a la volé.
Utilise une liste ou une listview au lieu de créer des boutons.

[mikell]

Une idée...

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>
#include <array.au3>
#include <file.au3>

Local $oIE = _IECreateEmbedded()
Local $ya = 0

GUICreate("Colissimo", 1040, 650, _
        (@DesktopWidth - 1800), (@DesktopHeight - 1000), _
        $WS_OVERLAPPEDWINDOW + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
GUICtrlCreateObj($oIE, 50, 10, 750, 600)
Local $idButton_Stop = GUICtrlCreateButton("Stop", 340, 610, 100, 30)

Dim $oneDarray
_FileReadToArray(@ScriptDir & "\" & "test.csv", $oneDarray)
$columnsCounter = stringsplit($oneDarray[1],";")
Dim $twoDarray[$oneDarray[0]][$columnsCounter[0]]
For $x = 1 to $oneDarray[0]
   $oneRow = stringsplit($oneDarray[$x],";")
   For $y = 1 to ($columnsCounter[0])
      $twoDarray[$x-1][$y-1] = $oneRow[$y]
   Next
Next
 _ArrayDisplay($twoDarray)

GUISetState(@SW_SHOW) ;Show GUI

_IENavigate($oIE, "http://www.colissimo.fr")
_IEAction($oIE, "stop")

Local $count = UBound($twoDarray)-1
Local $buttons[$count]
For $i = 0 To $count-1
     $buttons[$i] = GUICtrlCreateButton($twoDarray[$i][3], 930, $ya+20, 100, 30)
     $ya = $ya+40
Next


While 1
    Local $iMsg = GUIGetMsg()

   For $i = 0 to $count-1
       Switch $iMsg
          Case $buttons[$i]
                 $html = "http://www.colissimo.fr/portail_colissimo/suivre.do?colispart=" & $twoDarray[$i][4]
                 SplashTextOn ("", "Checking  " & $twoDarray[$i][3] & "  ...", 300, 55, -1, -1, 49)
                _IENavigate($oIE, $html)
                 SplashOff()
      EndSwitch
  Next

    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            ExitLoop

        Case $idButton_Stop
            _IEAction($oIE, "stop")
    EndSwitch
WEnd
 

Mais ça serait mieux en mode évènementiel

[Faco]

un exemple avec un listview ( juste un exemple, c'est pas beau du tous la gestion des tableaux comme ça) :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>
#include <array.au3>
#include <file.au3>
#include <GuiListView.au3>

Global $FormClient = GUICreate("Liste client", 292, 438, -1, -1)
Global $hListView = GUICtrlCreateListView("", 8, 8, 193, 344, $LVS_NOCOLUMNHEADER)
Global $ButtonConect = GUICtrlCreateButton("ButtonConect", 208, 192, 75, 25)
Global $ButtonQuit = GUICtrlCreateButton("ButtonQuit", 208, 312, 75, 25)
GUISetState(@SW_SHOW)

_chargeListView()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $ButtonConect
            Local $text =  _GUICtrlListView_GetItemTextString($hListView, 1)
            If Not @error Then
                MsgBox(0,"","GO to : " & $text &@CRLF)
            EndIf
        Case $ButtonQuit
            Exit
    EndSwitch
WEnd

Func _chargeListView()
    Dim $oneDarray
    _FileReadToArray(@ScriptDir & "\" & "test.csv", $oneDarray)
    $columnsCounter = stringsplit($oneDarray[1],";")
    Dim $twoDarray[$oneDarray[0]][$columnsCounter[0]]
    For $x = 1 to $oneDarray[0]
        $oneRow = stringsplit($oneDarray[$x],";")
        For $y = 1 to $columnsCounter[0]
            $twoDarray[$x-1][$y-1] = $oneRow[$y]
        Next
    Next
    _GUICtrlListView_InsertColumn($hListView, 0, "Column 1", 150)
    For $i = 0 To UBound($twoDarray)-1
        _GUICtrlListView_AddItem($hListView, $twoDarray[$i][3])
    Next
EndFunc
 

[juju29]

Merci , c'est juste énorme l'aide que vous m’apportez !!
je v analyser tous ça pour progresser )


encore merci !