[R] Désactiver bouton droit de la souris

[aulus]

Bonjour,

Parmi les fonctions Misc Management, je ne vois pas de fonction désactivant l'un ou l'autre bouton de la souris. Je souhaiterais désactiver le bouton droit à l'ouverture de mon programme puis le réactiver à sa fermeture. J'ai trouvé sur le net quelques codes empêchant tous clics, mais je voudrais conserver l'usage du clic gauche.

Merci de vos idées.

[jguinch]

Regarde du côté de l'UDF BlockInputEx.

Code : Tout sélectionner

_BlockInputEx(2, "{MMOVE}|{MPDOWN}|{MPUP}|{MWDOWN}|{MWUP}|{MWSCROLL}|{MSPDOWN}|{MSPUP}")

[mikell]

ou de l'udf MouseOnEvent
citée ici
http://www.autoitscript.com/forum/topic ... ght-click/

[aulus]

Merci à tous deux.

J'ai testé la solution suggérée par jguinch avec le code suivant. Mais, avec l'argument 2, les 2 boutons de la souris sont désactivés :

► Afficher le texte

Code : Tout sélectionner

#include-once
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Global $ah_MouseKeyboard_WinHooks[7]

MsgBox(0,"","Start blocking for 5 seconds...")
[b]_BlockInputEx(2)[/b]
Sleep(5000)
_BlockInputEx(0)
MsgBox(0,"","Input unblocked now.") ; execution is terminated after response to this statement???
MsgBox(0,"","Input unblocked now 2.") ; this statement is not executed???
Exit


;This is only for testing, so if anything go wrong, the script will exit after 10 seconds.
;AdlibEnable("_Quit", 10000)
Func _BlockInputEx($iBlockMode = -1, $sExclude = '', $sInclude = '', $hWindows = '')
    If $iBlockMode < -1 Or $iBlockMode > 8 Then Return SetError(1, 0, 0) ;Only -1, 0, 1 and 2 modes are supported.

    If $iBlockMode = -1 Then Return _BlockInput_UnhookWinHooks_Proc()

    Local $pStub_KeyProc = 0, $pStub_MouseProc = 0, $hHook_Keyboard = 0, $hHook_Mouse = 0
    Local $hHook_Module = _WinAPI_GetModuleHandle(0)

    For $i = 0 To 3
        If $ah_MouseKeyboard_WinHooks[$i] > 0 Then
            _BlockInput_UnhookWinHooks_Proc()
            ExitLoop
        EndIf
    Next

    If $iBlockMode = 1 Or $iBlockMode = 2 Then
        $pStub_MouseProc = DllCallbackRegister("_MouseHook_Proc", "int", "int;ptr;ptr")
        $hHook_Mouse = _WinAPI_SetWindowsHookEx($WH_MOUSE_LL, DllCallbackGetPtr($pStub_MouseProc), $hHook_Module, 0)
    EndIf

    If $iBlockMode = 1 Or $iBlockMode = 3 Then
        $pStub_KeyProc = DllCallbackRegister("_KeyBoardHook_Proc", "int", "int;ptr;ptr")
        $hHook_Keyboard = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($pStub_KeyProc), $hHook_Module, 0)
    ElseIf $iBlockMode = 4 Then
        $pStub_KeyProc = DllCallbackRegister("_KeyBoardHook_Proc", "int", "int;ptr;ptr")
        $hHook_Keyboard = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($pStub_KeyProc), $hHook_Module, 0)
        If $sExclude = 1 Then
            $sExclude = '0x70|0x71|0x72|0x73|0x74|0x75|0x76|0x77|0x78|0x79|0x7A|0x7B|0x7C|0x7D|0x7E|0x7F' & _
                    '|0x80H|0x81H|0x82H|0x83H|0x84H|0x85H|0x86H|0x87H'
        ElseIf $sInclude = 1 Then
            $sInclude = '0x70|0x71|0x72|0x73|0x74|0x75|0x76|0x77|0x78|0x79|0x7A|0x7B|0x7C|0x7D|0x7E|0x7F' & _
                    '|0x80H|0x81H|0x82H|0x83H|0x84H|0x85H|0x86H|0x87H'
        EndIf
    ElseIf $iBlockMode = 5 Then
        $pStub_KeyProc = DllCallbackRegister("_KeyBoardHook_Proc", "int", "int;ptr;ptr")
        $hHook_Keyboard = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($pStub_KeyProc), $hHook_Module, 0)
        If $sExclude = 1 Then
            $sExclude = '0x41|0x42|0x43|0x44|0x45|0x46|0x47|0x48|0x49|0x4A|0x4B|0x4C|0x4D|0x4E|0x4F|0x50' & _
                    '|0x51|0x52|0x53|0x54|0x55|0x56|0x57|0x58|0x59|0x5A'
        ElseIf $sInclude = 1 Then
            $sInclude = '0x41|0x42|0x43|0x44|0x45|0x46|0x47|0x48|0x49|0x4A|0x4B|0x4C|0x4D|0x4E|0x4F|0x50' & _
                    '|0x51|0x52|0x53|0x54|0x55|0x56|0x57|0x58|0x59|0x5A'
        EndIf
    ElseIf $iBlockMode = 6 Then
        If $sExclude = 1 Then
            $sExclude = '0x30|0x31|0x32|0x33|0x34|0x35|0x36|0x37|0x38|0x39|0x60|0x61|0x62|0x63|0x64|0x65' & _
                    '|0x66|0x67|0x68|0x69'
        ElseIf $sInclude = 1 Then
            $sInclude = '0x30|0x31|0x32|0x33|0x34|0x35|0x36|0x37|0x38|0x39|0x60|0x61|0x62|0x63|0x64|0x65' & _
                    '|0x66|0x67|0x68|0x69'
        EndIf
    ElseIf $iBlockMode = 7 Then
        If $sExclude = 1 Then
            $sExclude = '0x25|0x26|0x27|0x28'
        ElseIf $sInclude = 1 Then
            $sInclude = '0x25|0x26|0x27|0x28'
        EndIf
    ElseIf $iBlockMode = 8 Then
        If $sExclude = 1 Then
            $sExclude = '0x08|0x09|0x0C|0x0D|0x10|0x11|0x12|0x13|0x14|0x1B|0x20|0x21|0x22|0x23|0x24' & _
                    '|0x29|0x2A|0x2B|0x2C|0x2D|0x2E|0x5B|0x5C|0x6A|0x6B|0x6C|0x6D|0x6E|0x6F|0x90|0x91|0xA0' & _
                    '|0xA1|0xA2|0xA3|0xA4|0xA5|0xBA|0xBB|0xBC|0xBD|0xBE|0xBF|0xC0|0xDB|0xDC|0xDD'
        ElseIf $sInclude = 1 Then
            $sInclude = '0x08|0x09|0x0C|0x0D|0x10|0x11|0x12|0x13|0x14|0x1B|0x20|0x21|0x22|0x23|0x24' & _
                    '|0x29|0x2A|0x2B|0x2C|0x2D|0x2E|0x5B|0x5C|0x6A|0x6B|0x6C|0x6D|0x6E|0x6F|0x90|0x91|0xA0' & _
                    '|0xA1|0xA2|0xA3|0xA4|0xA5|0xBA|0xBB|0xBC|0xBD|0xBE|0xBF|0xC0|0xDB|0xDC|0xDD'
        EndIf
    EndIf

    $ah_MouseKeyboard_WinHooks[0] = $pStub_KeyProc
    $ah_MouseKeyboard_WinHooks[1] = $pStub_MouseProc
    $ah_MouseKeyboard_WinHooks[2] = $hHook_Keyboard
    $ah_MouseKeyboard_WinHooks[3] = $hHook_Mouse
    $ah_MouseKeyboard_WinHooks[4] = "|" & $sInclude & "|"
    $ah_MouseKeyboard_WinHooks[5] = "|" & $sExclude & "|"
    $ah_MouseKeyboard_WinHooks[6] = "|" & $hWindows & "|"

    Return 1
EndFunc   ;==>_BlockInputEx

;KeyBoard hook processing function
Func _KeyBoardHook_Proc($nCode, $wParam, $lParam)
    If $nCode < 0 Then Return _WinAPI_CallNextHookEx($ah_MouseKeyboard_WinHooks[4], $nCode, $wParam, $lParam)

    Local $KBDLLHOOKSTRUCT = DllStructCreate("dword vkCode;dword scanCode;dword flags;dword time;ptr dwExtraInfo", $lParam)
    Local $vkCode = "0x" & Hex(DllStructGetData($KBDLLHOOKSTRUCT, "vkCode"), 2)

    Local $sInclude = $ah_MouseKeyboard_WinHooks[4]
    Local $sExclude = $ah_MouseKeyboard_WinHooks[5]
    Local $hWnds = $ah_MouseKeyboard_WinHooks[6]

    If $sInclude <> "||" Then ;Include proc
        If StringInStr($sInclude, "|" & $vkCode & "|") And _
                ($hWnds = "||" Or StringInStr($hWnds, "|" & WinGetHandle("[ACTIVE]") & "|")) Then Return 1 ;Block processing!
    Else ;Exclude proc
        If Not StringInStr($sExclude, "|" & $vkCode & "|") And _
                ($hWnds = "||" Or StringInStr($hWnds, "|" & WinGetHandle("[ACTIVE]") & "|")) Then Return 1 ;Block processing!
    EndIf

    _WinAPI_CallNextHookEx($ah_MouseKeyboard_WinHooks[2], $nCode, $wParam, $lParam) ;Continue processing
EndFunc   ;==>_KeyBoardHook_Proc

;Mouse hook processing function
Func _MouseHook_Proc($nCode, $wParam, $lParam)
    If $nCode < 0 Then Return _WinAPI_CallNextHookEx($ah_MouseKeyboard_WinHooks[3], $nCode, $wParam, $lParam) ;Continue processing

    Return 1 ;Block processing!
EndFunc   ;==>_MouseHook_Proc

;Releases callbacks and Unhook Windows hooks
Func _BlockInput_UnhookWinHooks_Proc()
    If $ah_MouseKeyboard_WinHooks[0] > 0 Then DllCallbackFree($ah_MouseKeyboard_WinHooks[0])
    If $ah_MouseKeyboard_WinHooks[1] > 0 Then DllCallbackFree($ah_MouseKeyboard_WinHooks[1])

    If $ah_MouseKeyboard_WinHooks[2] > 0 Then _WinAPI_UnhookWindowsHookEx($ah_MouseKeyboard_WinHooks[2])
    If $ah_MouseKeyboard_WinHooks[3] > 0 Then _WinAPI_UnhookWindowsHookEx($ah_MouseKeyboard_WinHooks[3])

    For $i = 0 To 3
        $ah_MouseKeyboard_WinHooks[$i] = 0
    Next

    Return 1
EndFunc   ;==>_BlockInput_UnhookWinHooks_Proc

;Called when script exits to release resources.
Func OnAutoItExit()
    _BlockInputEx(0)
EndFunc
 

Quant à la solution suggérée par Mikell, elle plante :

► Afficher le texte

Code : Tout sélectionner

#include "..\MouseOnEvent.au3"

_BlockMouseClicksInput(0)

ToolTip('MouseClicks are disabled')
Sleep(5000)

_BlockMouseClicksInput(1)

ToolTip('MouseClicks are enabled')
Sleep(3000)

Func _BlockMouseClicksInput($iOpt = 0)
    If $iOpt = 0 Then
        _MouseSetOnEvent($MOUSE_PRIMARYUP_EVENT, "__Dummy", 0, 1)
        _MouseSetOnEvent($MOUSE_PRIMARYDOWN_EVENT, "__Dummy", 0, 1)
        _MouseSetOnEvent($MOUSE_SECONDARYUP_EVENT, "__Dummy", 0, 1)
        _MouseSetOnEvent($MOUSE_SECONDARYDOWN_EVENT, "__Dummy", 0, 1)
    Else
        ;_MouseSetOnEvent($MOUSE_PRIMARYUP_EVENT)
        ;_MouseSetOnEvent($MOUSE_PRIMARYDOWN_EVENT)
        _MouseSetOnEvent($MOUSE_SECONDARYUP_EVENT)
        _MouseSetOnEvent($MOUSE_SECONDARYDOWN_EVENT)
    EndIf
EndFunc
 

[jguinch]

Bin en fait j'avais mis une ligne de code dans mon précédent post... T'as pas testé ?

[aulus]

J'ai testé chaque argument, l'un après l'autre. J'obtiens toujours une désactivation totale de la souris.

[jguinch]

Est-ce que t'as testé mon code tel quel ? C'était ça l'idée.

Code : Tout sélectionner

_BlockInputEx(2, "{MMOVE}|{MPDOWN}|{MPUP}|{MWDOWN}|{MWUP}|{MWSCROLL}|{MSPDOWN}|{MSPUP}")

[aulus]

Oui, c'est pareil : les deux boutons ne réagissent plus.

[jguinch]

C'est bizarre, chez moi ça marche, avec ce code :

► Afficher le texte

Code : Tout sélectionner

#include <BlockInputEx.au3>

;================== Block Mouse only Example ==================

HotKeySet("{ESC}", "_Quit") ;This will trigger an exit.

;Here we block only *Mouse* input (without keyboard).
_BlockInputEx(2, "{MMOVE}|{MPDOWN}|{MPUP}|{MWDOWN}|{MWUP}|{MWSCROLL}|{MSPDOWN}|{MSPUP}")

;This is only for testing, so if anything go wrong, the script will exit after 10 seconds.
AdlibRegister("_Quit", 10000)

While 1
    Sleep(100)
WEnd

Func _Quit()
    Exit
EndFunc
 

Mais petite question : tu veux bloquer le clic-droit dans ton application uniquement, ou globalement ?
Car si c'est juste pour ton application, il faut plutôt regarder du côté de la solution proposée par Mikell...

[aulus]

Bonjour,
L'UDF BlockInputEx.au3 que j'ai téléchargé ne doit pas être bien bon. L'include BlockInputEx.au3 n'est pas trouvé par mon programme. C'est pourquoi dans mon exemple ci-dessus, j'ai ajouté l'UDF au code de mon programme. Où avez-vous trouvé votre UDF ?

Je souhaiterais que le bouton droit de la souris reste inactif globalement. Mon souci est le suivant : mon programme ouvre une visionneuse. J'ai l'intention de choisir une visionneuse qui ne permette pas d'éditer les images. C'est quasiment introuvable. J'imagine donc ouvrir une visionneuse dont les fonctions d'édition s'obtiennent par un menu affiché par le clic droit de la souris. En désactivant celle-ci, j'obtiendrai ce que je veux.

[jguinch]

Bin j'ai téléchargé le ZIP qui est dans le lien que j'ai posté : BlockInputEx_UDF_1.8.zip...
Sinon, pour ta visionneuse, c'est pour quel type d'images ? Tu peux peut-être te faire ta propre visionneuse avec une GUI en plein écran (avec fond noir) par exemple.

[aulus]

Votre UDF fonctionne... Grand merci.
Je ne comprends pas pourquoi mon programme indique qu'il ne peut pas l'ouvrir ? Je l'appelle pourtant bien par #include 'BlockInputEx.au3' ! Enfin j'ai paré à ce problème en incluant les fonctions de l'UDF dans mon code.

J'avais pensé créer ma propre visionneuse. Mais programmer le redimensionnement de la photo en fonction du redimensionnement de la fenêtre, le déplacement de la photo trop grande dans la fenêtre, l'augmentation ou la diminution du contraste, sont en dehors de mes compétences. J'ai besoin de ces fonctions, car les photos affichent des pages de textes.