[R] Modification WM_NOTIFY

[Ks10]

Bonsoir,

Récemment j'ai fait appel à vous pour obtenir des informations concernant le WM_NOTIFY et cela a bien fonctionné.
Mon double clique fonctionne sans problème.

Maintenant j'aimerais approfondir les choses et détecter ce fameux double clique à plusieurs endroit dans mon programme.

La situation auxquels je fait référence est simple :
- Je possède 2 listview dans mon programme qui s'affiche lorsque nous cliquons sur un boutons.
J'aimerais que les doubles cliques soit détecter sur ce contrôle peu importe la listview qui est afficher donc voilà comment j'ai procéder.

► Afficher le texte

Code : Tout sélectionner

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $hWndListViewTwo, $tInfo
    $hWndListViewTwo = GuiCtrlGetHandle($List2)
    $hWndListView = GUICtrlGetHandle($List3)
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom

        Case $hWndListViewTwo
            Switch $iCode
                Case $NM_DBLCLK
                         $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                         $index = DllStructGetData($tInfo, "Index")
                                $iIndex = _GUICtrlListView_GetSelectedIndices($List2)
                                If ($iIndex) <> "" Then
                                    $sel  = _GUICtrlListView_GetItemText($List2,Int($iIndex)) 
                                        GUISetState(@SW_SHOW, $Form3)
                                            GUICtrlSetState($bck_mail, $GUI_SHOW)
                                            GUICtrlSetState($ext_mail, $GUI_SHOW)
                                            GUICtrlSetState($mail_date, $GUI_SHOW)
                                            GUICtrlSetState($Input_date, $GUI_SHOW)
                                            GUICtrlSetState($mail_emetteur, $GUI_SHOW)
                                            GUICtrlSetState($Input_emetteur, $GUI_SHOW)
                                            GUICtrlSetState($mail_objet, $GUI_SHOW)
                                            GUICtrlSetState($Input_objet, $GUI_SHOW)
                                            GUICtrlSetState($mail_message, $GUI_SHOW)
                                            GUICtrlSetState($input_message, $GUI_SHOW)
                                            GUICtrlSetState($btn_repond, $GUI_SHOW)
                                            GUICtrlSetState($btn_del, $GUI_SHOW)
                                            GUICtrlSetData($Input_date, "")
                                            GUICtrlSetData($Input_emetteur, "")
                                            GUICtrlSetData($Input_objet, "")
                                            GUICtrlSetData($input_message, "")
                                                                Endif  
EndSwitch


        Case $hWndListView
            Switch $iCode
                Case $NM_DBLCLK
                         $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                         $index = DllStructGetData($tInfo, "Index")
                                $iIndex = _GUICtrlListView_GetSelectedIndices($List3)
                                If ($iIndex) <> "" Then
                                    $sel  = _GUICtrlListView_GetItemText($List3,Int($iIndex))
                                        GUISetState(@SW_SHOW, $Form3)
                                            GUICtrlSetState($bck_mail, $GUI_SHOW)
                                            GUICtrlSetState($ext_mail, $GUI_SHOW)
                                            GUICtrlSetState($mail_date, $GUI_SHOW)
                                            GUICtrlSetState($Input_date, $GUI_SHOW)
                                            GUICtrlSetState($mail_emetteur, $GUI_SHOW)
                                            GUICtrlSetState($Input_emetteur, $GUI_SHOW)
                                            GUICtrlSetState($mail_objet, $GUI_SHOW)
                                            GUICtrlSetState($Input_objet, $GUI_SHOW)
                                            GUICtrlSetState($mail_message, $GUI_SHOW)
                                            GUICtrlSetState($input_message, $GUI_SHOW)
                                            GUICtrlSetState($btn_repond, $GUI_SHOW)
                                            GUICtrlSetState($btn_del, $GUI_SHOW)
                                            GUICtrlSetData($Input_date, "")
                                            GUICtrlSetData($Input_emetteur, "")
                                            GUICtrlSetData($Input_objet, "")
                                            GUICtrlSetData($input_message, "")
ENdif

           EndSwitch
EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Avec ce code mon programme ne génère aucune erreur, le double clique est détecté sur la " $List3 " mais lorsque ma $List2 est présente aucun clique n'est détecté.

Où est mon erreur ?
Pouvez vous me donner plus de détail sur la structure de cette fonction , sa façon d'être construite et sa façon de la modifier ?

Merci d'avance

[jguinch]

A priori c'est OK...
Il doit y avoir un truc qui déconne dans le reste du code. Est-ce que tu as bien défini $list2 et $list3 en variables Global ? Tu ne les a pas créer en Local quelque part ailleurs ?
Comment gère-tu l'affichage les listviews lors du clic sur le bouton ?

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>



GUICreate("", 600, 500)
$List2 = GUICtrlCreateListView("test", 10, 10, 200, 400)
GUICtrlCreateListViewItem("ligne1", $List2)
GUICtrlCreateListViewItem("ligne2", $List2)

$List3 = GUICtrlCreateListView("test", 220, 10, 200, 400)
GUICtrlCreateListViewItem("ligne1", $List3)
GUICtrlCreateListViewItem("ligne2", $List3)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

GUISetState()

While GUIGetMsg() <> -3

WEnd


Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $hWndListViewTwo, $tInfo
    $hWndListViewTwo = GuiCtrlGetHandle($List2)
    $hWndListView = GUICtrlGetHandle($List3)
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom

        Case $hWndListViewTwo
            Switch $iCode
                Case $NM_DBLCLK
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    $index = DllStructGetData($tInfo, "Index")
                    $iIndex = _GUICtrlListView_GetSelectedIndices($List2)
                    If ($iIndex) <> "" Then
                        ConsoleWrite("DDBLCLK $List2 : Index=" & $iIndex & @CRLF)
                    Endif  
            EndSwitch


        Case $hWndListView
            Switch $iCode
                Case $NM_DBLCLK
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    $index = DllStructGetData($tInfo, "Index")
                    $iIndex = _GUICtrlListView_GetSelectedIndices($List3)
                    If ($iIndex) <> "" Then
                        ConsoleWrite("DDBLCLK $List3 : Index=" & $iIndex & @CRLF)
                    EndIf

            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY
 

[mikell]

A noter aussi, tu peux condenser

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

GUICreate("", 600, 500)
$List2 = GUICtrlCreateListView("test", 10, 10, 200, 400)
GUICtrlCreateListViewItem("ligne1", $List2)
GUICtrlCreateListViewItem("ligne2", $List2)
$List3 = GUICtrlCreateListView("test", 220, 10, 200, 400)
GUICtrlCreateListViewItem("ligne1", $List3)
GUICtrlCreateListViewItem("ligne2", $List3)
GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While GUIGetMsg() <> $GUI_EVENT_CLOSE
   Sleep(10)
WEnd


Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $hWndListViewTwo, $tInfo
    $hWndListViewTwo = GuiCtrlGetHandle($List2)
    $hWndListView = GUICtrlGetHandle($List3)
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hWndListViewTwo, $hWndListView
            Switch $iCode
                Case $NM_DBLCLK
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    $index = DllStructGetData($tInfo, "Index")
                    $iIndex = _GUICtrlListView_GetSelectedIndices($hWndFrom)  ; ou ($iIDFrom)
                    If ($iIndex) <> "" Then
                        If $iIDFrom = $List2 Then ConsoleWrite("DDBLCLK $List2 : Index=" & $iIndex & @CRLF)
                        If $iIDFrom = $List3 Then ConsoleWrite("DDBLCLK $List3 : Index=" & $iIndex & @CRLF)
                    Endif  
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY
 

[Ks10]

La première méthode que tu a donné fonctionne correctement et répond parfaitement à mes attentes.
Mon soucis venez d'une variable confondu x)

Merci beaucoup
Sujet Résolu.