[..] Coloriser un sub item d'une listview

[Ouraios]

Bonjour à tous voilà je me suis récemment à l'autoit et j'aimerai coloriser le texte d'un subitem de ma listview, j'ai cherché pendant 3 bonnes heures sur tous les forums Autoit j'ai trouvé des choses utilisant des DllStruct mais sans explication ni rien donc c'est un peu la galère ^^'
En vous remerciant d'avance de votre aide !

Voilà mon code :

► Afficher le texte

Code : Tout sélectionner

#include <DateTimeConstants.au3>
#include <GuiToolbar.au3>
#include <ProgressConstants.au3>
#include <SliderConstants.au3>
#include <ToolbarConstants.au3>
#include <ListBoxConstants.au3>
#include <GUIConstantsEx.au3>
#include <AVIConstants.au3>
#include <TreeViewConstants.au3>
#include <ButtonConstants.au3>
#include <GUIListBox.au3>
#Include <GuiComboBox.au3>
#include <ComboConstants.au3>
#include <Constants.au3>
#Include <Array.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>
#include <ListViewConstants.au3>
#include <File.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>
#include <INet.au3>
#include <IE.au3>
#include <Date.au3>

Global $Form1 = GUICreate("La Bourse c'est EASY", 611, 418, -1, -1)
Global $Combo1 = GUICtrlCreateCombo("A", 8, 8, 113, 25, BitOR($WS_VSCROLL,$CBS_DROPDOWN,$CBS_AUTOHSCROLL,$CBS_DROPDOWNLIST))
GUICtrlSetData(-1, "B|C|D|E|F|G|H|I|J|K|L|M|N|O|P|Q|R|S|T|U|V|W|X|Y|Z")

Global $liste = GUICtrlCreateListView("", 8, 40, 593, 369)
_GUICtrlListView_SetExtendedListViewStyle($liste, BitOR($GUI_SS_DEFAULT_LISTVIEW,$WS_EX_CLIENTEDGE,$LVS_EX_GRIDLINES,$LVS_EX_FULLROWSELECT, $LVS_EX_DOUBLEBUFFER))

_GUICtrlListView_AddColumn($liste, "Nom", 200, 2)
_GUICtrlListView_AddColumn($liste, "Cotation", 60, 2)
_GUICtrlListView_AddColumn($liste, "Var", 60, 2)
_GUICtrlListView_AddColumn($liste, "Ouverture", 60, 2)
_GUICtrlListView_AddColumn($liste, "+ Haut", 60, 2)
_GUICtrlListView_AddColumn($liste, "+ Bas", 60, 2)
_GUICtrlListView_AddColumn($liste, "Var/1janv", 60, 2)
_GUICtrlListView_AddColumn($liste, "Volume", 60, 2)

Global $Button1 = GUICtrlCreateButton("Lancer la recupération", 128, 8, 121, 25)

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            _RECUP(GUICtrlRead($Combo1))
    EndSwitch
WEnd


;Fonction de recupération de info
Func _RECUP($lettre)
Global $sources, $nom, $cot

_GUICtrlListView_DeleteAllItems($liste)

$sources = _INetGetSource("http://www.boursorama.com/bourse/actions/cours_az.phtml?MARCHE=SRD&pea=0&peapme=0&sort%5Blibelle%5D=ASC&page=1&LETTRE="& $lettre &"") ;ATTENTION DEPASSEMENT DE LA RECHERCHE SUR LE BANDEAU DE DROITE DU MENU !! NOM en supplement sur les resultats Cf. PJ MAIL
$nom = StringRegExp($sources, '(href="/cours.phtml\?symbole=(.*?)">(.*?)</a></td>)',3)

;Verification date et heure pour enlever le " (c)" ou pas selon le cas
If _DateDayOfWeek(@WDAY) = "Saturday" OR _DateDayOfWeek(@WDAY) = "Sunday"  OR (_DateTimeFormat(_NowCalc(), 4)>= "17:30" Or _DateTimeFormat(_NowCalc(), 4)<= "09:00" ) Then
  $cot = StringRegExp($sources, '(?i)<td class="tdv-last"   align="right" ><span id="(.*?)"><span class="cotation">(.*?) \(c\)</span></span></td>',3)
Else
  $cot = StringRegExp($sources, '(?i)<td class="tdv-last"   align="right" ><span id="(.*?)"><span class="cotation">(.*?)</span></span></td>',3)
EndIf
;[...] A COMPLETER DE PLUS EN PLUS ... Ta formulation de StringRegExp BUG sur la suite ... utilise plutot la mienne ... Attention aux espaces qui foutent la m....

_ADD()
EndFunc

;Fonction de traitrement des informations
Func _ADD()
    Local $count
    Local $i_n, $i_v, $i

    $count = UBound($nom, $UBOUND_ROWS) ;Recupère la taille REEL de l'Array
    $count = $count/3

    $i_n = 2 ;Pt de depart de l'Array des nom
    $i_v = 1 ;Pt de depart de l'Array des cotations
    $i = 0

    While $i < $count
        GUICtrlCreateListViewItem($nom[$i_n] &"|"& $cot[$i_v], $liste) ;MODE = Retrait de " (c)"
        $i_n = $i_n + 3 ;Valeur suivante à N+3 pour les Nom
        $i_v = $i_v + 2 ;Valeur suivante à N+2 pour les cotations
        $i = $i + 1
    WEnd
    
EndFunc

[mikell]

Pas de problème, mais tu veux colorer le texte d'un seul subitem d'une ligne, ou de tous les subitems d'une colonne ? statiquement ou au clic ? ou sous condition ?

[Ouraios]

je veux colorer seulement les subitems des colonnes variations et variations/janvier selon si leur valeur est negative ou positive, (si negatif couleur rouge, si positif couleur verte) pour chacun subitem de chacune de ces deux colonnes

[mikell]

Voilà
Ton code m'intéresse donc je me suis permis de l'optimiser un poil notamment au niveau des regex (prise en compte des actions non cotées ou suspendues et élimination auto. de l'éventuel (c) de clôture)
Si tu veux des explications sur des détails du code n'hésite pas

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <Constants.au3>
#Include <Array.au3>
#include <EditConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>
#include <INet.au3>

Global $Form1, $Combo1, $liste, $Button1

$Form1 = GUICreate("La Bourse c'est EASY", 660, 418, -1, -1)
$Combo1 = GUICtrlCreateCombo("A", 8, 8, 113, 25, _ 
    BitOR($WS_VSCROLL,$CBS_DROPDOWN,$CBS_AUTOHSCROLL,$CBS_DROPDOWNLIST))
GUICtrlSetData(-1, "B|C|D|E|F|G|H|I|J|K|L|M|N|O|P|Q|R|S|T|U|V|W|X|Y|Z")
$liste = GUICtrlCreateListView("", 8, 40, 650, 369)
_GUICtrlListView_SetExtendedListViewStyle($liste, BitOR($GUI_SS_DEFAULT_LISTVIEW, _ 
    $WS_EX_CLIENTEDGE,$LVS_EX_GRIDLINES,$LVS_EX_FULLROWSELECT, $LVS_EX_DOUBLEBUFFER))
_GUICtrlListView_AddColumn($liste, "Nom", 200, 2)
_GUICtrlListView_AddColumn($liste, "Cotation", 60, 2)
_GUICtrlListView_AddColumn($liste, "Var", 60, 2)
_GUICtrlListView_AddColumn($liste, "Ouverture", 60, 2)
_GUICtrlListView_AddColumn($liste, "+ Haut", 60, 2)
_GUICtrlListView_AddColumn($liste, "+ Bas", 60, 2)
_GUICtrlListView_AddColumn($liste, "Var/1janv", 60, 2)
_GUICtrlListView_AddColumn($liste, "Volume", 60, 2)
$Button1 = GUICtrlCreateButton("Lancer la recupération", 128, 8, 121, 25)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            _RECUP(GUICtrlRead($Combo1))
    EndSwitch
WEnd

;======================================================================
Func _RECUP($lettre)    ; Fonction de recupération des infos
Local $sources, $bloc_actions, $nom, $last, $var, $open, $high, $low, $var_an, $vol

GuiCtrlSendMsg($liste, $LVM_DELETEALLITEMS, 0, 0)
SplashTextOn("", "Chargement...", 280, 55, -1, -1, 49)

$sources = _INetGetSource("http://www.boursorama.com/bourse/actions/cours_az.phtml?MARCHE=SRD&pea=0&peapme=0&sort%5Blibelle%5D=ASC&page=1&LETTRE="& $lettre &"") 
;; FileWrite($lettre & ".txt", $sources)
$blocs_actions = StringRegExp($sources, '(?s)<tbody>(.+?)</tbody>', 3)
If not IsArray($blocs_actions) Then
   SplashOff()
   Return Msgbox(0,"", "chargement impossible")
EndIf
$bloc_actions = $blocs_actions[0]

$nom = StringRegExp($bloc_actions, 'tdv-libelle.+?title="([^"]+)', 3)
;~ _ArrayDisplay($nom)
$last = StringRegExp($bloc_actions, 'tdv-last.+?cotation">([^\h<]+)', 3)
$var = StringRegExp($bloc_actions, 'tdv-var".+?span.+?>([^<]+)', 3)
$open = StringRegExp($bloc_actions, 'tdv-open.+?cotation">([^<]+)', 3)
$high = StringRegExp($bloc_actions, 'tdv-high.+?cotation">([^<]+)', 3)
$low = StringRegExp($bloc_actions, 'tdv-low.+?cotation">([^<]+)', 3)
$var_an = StringRegExp($bloc_actions, 'tdv-var_an.+?span.+?>([^<]+)', 3)
$vol = StringRegExp($bloc_actions, 'tdv-tot_volume.+?span.+?>([^<]+)', 3)

SplashOff()
_GUICtrlListView_BeginUpdate($liste)
For $i = 0 to UBound($nom)-1
    GUICtrlCreateListViewItem($nom[$i] &"|"& $last[$i] &"|"& $var[$i] &"|"& $open[$i] &"|"& _ 
            $high[$i] &"|"& $low[$i] &"|"& $var_an[$i] &"|"& $vol[$i], $liste)
Next
_GUICtrlListView_EndUpdate($liste)
EndFunc


Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
    Local $tNMHDR, $hWndFrom, $iCode, $hListView = GuiCtrlGetHandle($liste)
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    Switch $hWndFrom
        Case $hListView
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                    Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                    If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                    If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW

                    Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                    Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                    Local $iColor, $hDC, $text
                    If $iSubItem = 2 OR $iSubItem = 6 Then
                        $text = StringReplace(_GUICtrlListView_GetItemText($hListView, $iItem, $iSubItem), "%", "")
                        If Number($text) < 0 Then 
                             $iColor = RGB2BGR(0xcc0000)
                        ElseIf Number($text) > 0 Then
                             $iColor = RGB2BGR(0x009900)
                        EndIf
                    Else
                        $iColor = RGB2BGR(0x000000)
                    EndIf
                    DllStructSetData($tCustDraw, "clrText", $iColor)
                    Return $CDRF_NEWFONT                       
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY


Func RGB2BGR($iColor)
    Return BitAND(BitShift(String(Binary($iColor)), 8), 0xFFFFFF)
EndFunc   ;==>RGB2BGR()

 

Edit le 30/6
correction du regex pour $var -- manquait un guillemet...

[jguinch]

$UBOUND_ROWS c'est dans la beta ça non ?

[mikell]

C'est dans les constantes de la fonction UBound (cf.fichier d'aide) je sais pas depuis quand mais ça existe dans la 3.3.12.0
Encore un coup de guinness

[jguinch]

Ah oui, j'avais lu quelques échanges sur le forum US à ce sujet...
J'étais resté sur la 3.3.10.2, je vais upgrader un coup.

[Ouraios]

Hum est tu pourrais me commenter ligne par ligne la fonction WM_NOTIFY ?
et plus particulièrement les DllStruct
Merci d'avance

Et merci beaucoup pour ton aide !

[mikell]

Hum tu vas passer du temps de lecture

Quelques informations générales :
WM_NOTIFY (message)
"Sent by a common control to its parent window when an event has occurred or the control requires some information."
http://msdn.microsoft.com/en-us/library ... 85%29.aspx

NM_CUSTOMDRAW (notification code)
"Sent by a list-view control to notify its parent windows about drawing operations. This notification code is sent in the form of a WM_NOTIFY message."
http://msdn.microsoft.com/en-us/library ... 85%29.aspx

$tagNMLVCUSTOMDRAW (structure)
"Contains information specific to an NM_CUSTOMDRAW (list view) notification code sent by a list-view control."
(intègre les structures NMCUSTOMDRAW et NMHDR)
http://msdn.microsoft.com/en-us/library ... 85%29.aspx
ou
90% des explications ici : Fichier d'aide > User Defined Function Reference > StructureConstants

CDRF_NOTIFYSUBITEMDRAW, CDRF_NEWFONT etc (constantes)
These constants are used as return values by a control in response to an NM_CUSTOMDRAW notification code.
http://msdn.microsoft.com/en-us/library ... 85%29.aspx

et le WM_NOTIFY commenté

► Afficher le texte

Code : Tout sélectionner

Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)

    Local $tNMHDR, $hWndFrom, $iCode, $hListView = GuiCtrlGetHandle($liste)
          ; création de la structure qui contient les infos sur le message 
    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
          ; lecture des infos
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    Switch $hWndFrom   ; check les infos
        Case $hListView
            Switch $iCode
                Case $NM_CUSTOMDRAW
                         ; création de la structure qui contient les infos de type d'écriture de la listview
                    Local $tCustDraw = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
                         ; check à quel stade en est l'écriture
                    Local $iDrawStage = DllStructGetData($tCustDraw, "dwDrawStage")
                    If $iDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
                    If $iDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW

                         ; c'est à ce stade (CDDS_SUBITEM) que les subitems sont écrits
                         ; on intercepte les données concernant l'item et subitem en cours d'écriture
                    Local $iSubItem = DllStructGetData($tCustDraw, "iSubItem")
                    Local $iItem = DllStructGetData($tCustDraw, "dwItemSpec")
                    Local $iColor, $hDC, $text

                          ; check ces données et pose les conditions
                    If $iSubItem = 2 OR $iSubItem = 6 Then     ; subitem d'index base 0 (colonne) 2 ou 6 
                             ; dans notre cas la récupération de ce handle est inutile
                   ;~     $hDC = DllStructGetData($tCustDraw, "hdc")
                             ; check le texte du subitem et enlève le "%"
                        $text = StringReplace(_GUICtrlListView_GetItemText($hListView, $iItem, $iSubItem), "%", "")
                             ; envoie la condition
                        If Number($text) < 0 Then 
                             $iColor = RGB2BGR(0xcc0000)   ; rouge
                        Else
                             $iColor = RGB2BGR(0x009900)   ; vert
                        EndIf
                    Else
                        $iColor = RGB2BGR(0x000000)   ; noir
                    EndIf
                        ; inscrit la nouvelle donnée (couleur) dans la structure
                    DllStructSetData($tCustDraw, "clrText", $iColor)
                    Return $CDRF_NEWFONT      ; actualise la police utilisée dans le subitem                 
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

 

Edit
Merci de mettre un [R] dans le titre du 1er post si le sujet est résolu