[R] Listview item et groupe

julie · #1

bonjour
j'ai un petit soucis une fois de plus avec les listview
je n'arrive pas a afficher plus de 1 information par groupe

je m'explique je vous ai preparer un exemple qui decris la situation actuelle pour que c soit plus simple pour vous de m'aider vous pouvez le telecharger je l'ai mis en lien

j'aimerai que le script lise les key "debut" et "retour" de toute les section presente dans le fichier data.ini
et si les date inscrite dans ces key font parti des 30 prochain jours alors on affiche les info
pour le moment le script fonctionne plus ou moins comme ca sauf que vous allez le voir par vous meme ca marche pas forcement bien
comme la section 3 qui devrait etre afficher alors quelle ne l'ai pas

j'ai suremetn mal proceder j'ai fait une boucle qui me creez mes 30 groupe correspondant au 30 prochain jours

je pense que le soucis viendrai de _GUICtrlListView_SetItemGroupID que je gere peut etre pas correctement

merci pour votre aide

julie · #2

Personne a une petite idée de mon problème ?

julie · #3

Pas de réponse je suis maudite ..... Pourquoi ...

#4

Têt ben que c'est parce qu'on comprend rien à ce qu'est censée afficher la listview, rapport à la clarté des explications

julie · #5

Je suis en voiture j'essai de texpliqier clairement quand je rentre

julie · #6

alors voila pour faire simple j'ai un fichier .ini sous cette forme
(attention le fichier .ini a changer par rapport a mon premier poste)

Code : Tout sélectionner

[section1]
debut=samedi 7 juin 2014
retour=samedi 14 juin 2014
[section2]
debut=samedi 14 juin 2014
retour=jeudi 19 juin 2014
[section3]
debut=dimanche 8 juin 2014
retour=mercredi 11 juin 2014
[section4]
debut=samedi 7 juin 2014
retour=jeudi 12 juin 2014

et de ce fichier .ini j'aiemerai y recuperer les information pour quelle y soit ranger comme sur la photo si dessous

► Afficher le texte

le fichier .ini est souvent modifier, des section et des dates sont ajouter ou supprimer regulierement
j'aimerai que seul les 30 prochaines dates a partir d'aujourdh'ui puisse etre afficher

j'aurai pu le faire moi meme ce n'est pas compliquer sauf que j'aurai aimer pour un point de vue de rapidite ne lire qu'une seule fois le fichier.ini
et si la date lue ce trouve dans les 30 prochain jours aors on l'ajoute a sont groupe correspondant

et c'est un peu ce que j'ai voulu faire en créant les 30 groupes pour pouvoir ensuite envoyer facilement les information en fonction de leur date

oulah je me perd meme a vous expliquer ce que j'aimerai pouvoir faire

si je ne me suis toujours pas faire comprise je tenterais ... heu je sais pas ce que je tenterais

et biensur mon code que j'ai commencer qui ne fonctionne pas bien mais qui peut peut etre vous mettre sur la piste

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ListviewConstants.au3>
#include <Date.au3>
#include <GuiListView.au3>

Global $locsiniconfirmer = @ScriptDir & "\data.ini"
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 708, 588, 192, 124)
$listview_info_today = GUICtrlCreateListView("Activité|type|", 10, 50, 693, 400)
GUICtrlSetFont(-1, 10, 400, 0, "Verdana")
_GUICtrlListView_JustifyColumn($listview_info_today, 0, 2)
_GUICtrlListView_JustifyColumn($listview_info_today, 1, 2)
_GUICtrlListView_JustifyColumn($listview_info_today, 2, 2)
_GUICtrlListView_JustifyColumn($listview_info_today, 3, 2)
GUICtrlSendMsg($listview_info_today, $LVM_SETCOLUMNWIDTH, 0, 250)
GUICtrlSendMsg($listview_info_today, $LVM_SETCOLUMNWIDTH, 1, 200)
GUICtrlSendMsg($listview_info_today, $LVM_SETCOLUMNWIDTH, 2, 150)
GUICtrlSendMsg($listview_info_today, $LVM_SETCOLUMNWIDTH, 3, 110)

_GUICtrlListView_EnableGroupView($listview_info_today)


$nb_jour_a_afficher = 30

for $i = 0 to $nb_jour_a_afficher
        $date = _CalcDateToDateStandard(_DateAdd('d',$i, _NowCalcDate()))
        _GUICtrlListView_InsertGroup($listview_info_today, -1, $i, $date,1)

        ;GUICtrlCreateListViewItem("ajout item "&$i&"|||", $listview_info_today)
    ; _GUICtrlListView_SetItemGroupID($listview_info_today, $i, $i)
    next


;_ArrayAdd($avArray_date,_CalcDateToDateStandard(_DateAdd('d',$i, _NowCalcDate())))
$aArray_nom_section = IniReadSectionNames($locsiniconfirmer)


    If Not @error Then
$var_date_today = _DateStandardToCalcDate( _NowDate())
        For $i = 1 To $aArray_nom_section[0]
          $date_departt = _DateLong2Short(IniRead($locsiniconfirmer,$aArray_nom_section[$i],"debut","mercredi 28 mai 2014"))
         $day_diff = _DateDiff("D",$var_date_today,$date_departt)
         if $day_diff >= 0 And $day_diff <= 30 Then
                $nom_cliengt = IniRead($locsiniconfirmer,$aArray_nom_section[$i],"nom_client","nom client inconnu")
               GUICtrlCreateListViewItem("Départ location"&"|"&$aArray_nom_section[$i]&"|", $listview_info_today)
               _GUICtrlListView_SetItemGroupID($listview_info_today, $day_diff, $day_diff)
         EndIf

             $date_retourtt = _DateLong2Short(IniRead($locsiniconfirmer,$aArray_nom_section[$i],"retour","mercredi 28 mai 2014"))
         $day_diff = _DateDiff("D",$var_date_today,$date_retourtt)
         if $day_diff >= 0 And $day_diff <= 30 Then
                $nom_cliengt = IniRead($locsiniconfirmer,$aArray_nom_section[$i],"nom_client","nom client inconnu")
               GUICtrlCreateListViewItem("Retour location"&"|"&$aArray_nom_section[$i]&"|", $listview_info_today)
               _GUICtrlListView_SetItemGroupID($listview_info_today, $day_diff, $day_diff)
               EndIf



        Next
    EndIf





GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func _DateLong2Short($str, $lang = "en")
    Local $aMonth[13] = ["", "Janvier", "Février", "Mars", "Avril", "Mai", "Juin", "Juillet", _
            "Août", "Septembre", "Octobre", "Novembre", "Décembre"]
    Local $split = StringSplit($str, " ")
    For $mois = 1 To 12
        If $split[3] = $aMonth[$mois] Then ExitLoop
    Next
    If $lang = "fr" Then
        Return StringFormat("%02d/%02d/%04d", $split[2], $mois, $split[4])
    Else
        Return StringFormat("%04d/%02d/%02d", $split[4], $mois, $split[2])
    EndIf
EndFunc   ;==>_DateLong2Short
_DateAdd
Func _CalcDateToDateStandard($sDate);    yyyy/mm/dd  => dd/mm/yyyy
    If Not StringRegExp($sDate, "^\d{4}/\d{2}/\d{2}$") Then Return SetError(1, 0)
    Local $ArrD = StringSplit($sDate, '/')
    If $ArrD[0] <> 3 Then Return SetError(2, 0)
    Return $ArrD[3] & '/' & $ArrD[2] & '/' & $ArrD[1]
EndFunc   ;==>_CalcDateToDateStandard

Func _DateStandardToCalcDate($sDate);  dd/mm/yyyy => yyyy/mm/dd
    Local $ArrD = StringSplit($sDate, '/')
    If $ArrD[0] <> 3 Then Return SetError(2, 0)
    Return $ArrD[3] & '/' & $ArrD[2] & '/' & $ArrD[1]
EndFunc   ;==>_DateStandardToCalcDate

merci

#7

Oué oué ... ça me rappelle quelque chose ce code

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ListviewConstants.au3>
#include <Date.au3>
#include <GuiListView.au3>

Global $locsiniconfirmer = @ScriptDir & "\data.ini"

$Form1 = GUICreate("Form1", 708, 588, 192, 124)
$listview_info_today = GUICtrlCreateListView("Activité|tr|cc|cbv", 10, 50, 693, 400)
GUICtrlSetFont(-1, 10, 400, 0, "Verdana")
_GUICtrlListView_JustifyColumn($listview_info_today, 0, 2)
_GUICtrlListView_JustifyColumn($listview_info_today, 1, 2)
_GUICtrlListView_JustifyColumn($listview_info_today, 2, 2)
_GUICtrlListView_JustifyColumn($listview_info_today, 3, 2)
GUICtrlSendMsg($listview_info_today, $LVM_SETCOLUMNWIDTH, 0, 250)
GUICtrlSendMsg($listview_info_today, $LVM_SETCOLUMNWIDTH, 1, 200)
GUICtrlSendMsg($listview_info_today, $LVM_SETCOLUMNWIDTH, 2, 150)
GUICtrlSendMsg($listview_info_today, $LVM_SETCOLUMNWIDTH, 3, 110)

_GUICtrlListView_EnableGroupView($listview_info_today)

$nb_jour_a_afficher = 30

$aArray_nom_section = IniReadSectionNames($locsiniconfirmer)
If Not @error Then

$var_date_today = _DateStandardToCalcDate( _NowDate())
$item_index = 0

For $k = 0 to $nb_jour_a_afficher
        $date = _CalcDateToDateStandard(_DateAdd('d', $k, _NowCalcDate()))
        _GUICtrlListView_InsertGroup($listview_info_today, -1, $k, $date, 1)

        For $i = 1 To $aArray_nom_section[0]
        $date_departt = _DateLong2Short(IniRead($locsiniconfirmer,$aArray_nom_section[$i],"debut","mercredi 28 mai 2014"))
         $day_diff = _DateDiff("D",$var_date_today,$date_departt)
         if $day_diff = $k Then
            $nom_cliengt = IniRead($locsiniconfirmer,$aArray_nom_section[$i],"nom_client","nom client inconnu")
            GUICtrlCreateListViewItem("Départ location"&"|"&$aArray_nom_section[$i]&"|"&$nom_cliengt&"|", $listview_info_today)
                  _GUICtrlListView_SetItemGroupID($listview_info_today, $item_index, $k)
            $item_index += 1
         EndIf

        $date_retourtt = _DateLong2Short(IniRead($locsiniconfirmer,$aArray_nom_section[$i],"retour","mercredi 28 mai 2014"))
         $day_diff = _DateDiff("D",$var_date_today,$date_retourtt)
         if $day_diff = $k Then
            $nom_cliengt = IniRead($locsiniconfirmer,$aArray_nom_section[$i],"nom_client","nom client inconnu")
            GUICtrlCreateListViewItem("Retour location"&"|"&$aArray_nom_section[$i]&"|"&$nom_cliengt&"|", $listview_info_today)
                _GUICtrlListView_SetItemGroupID($listview_info_today, $item_index, $k)
            $item_index += 1
        EndIf
           Next
Next
EndIf

GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func _DateLong2Short($str, $lang = "en")
    Local $aMonth[13] = ["", "Janvier", "Février", "Mars", "Avril", "Mai", "Juin", "Juillet", _
            "Août", "Septembre", "Octobre", "Novembre", "Décembre"]
    Local $split = StringSplit($str, " ")
    For $mois = 1 To 12
        If $split[3] = $aMonth[$mois] Then ExitLoop
    Next
    If $lang = "fr" Then
        Return StringFormat("%02d/%02d/%04d", $split[2], $mois, $split[4])
    Else
        Return StringFormat("%04d/%02d/%02d", $split[4], $mois, $split[2])
    EndIf
EndFunc   ;==>_DateLong2Short

Func _CalcDateToDateStandard($sDate);    yyyy/mm/dd  => dd/mm/yyyy
    If Not StringRegExp($sDate, "^\d{4}/\d{2}/\d{2}$") Then Return SetError(1, 0)
    Local $ArrD = StringSplit($sDate, '/')
    If $ArrD[0] <> 3 Then Return SetError(2, 0)
    Return $ArrD[3] & '/' & $ArrD[2] & '/' & $ArrD[1]
EndFunc   ;==>_CalcDateToDateStandard

Func _DateStandardToCalcDate($sDate);  dd/mm/yyyy => yyyy/mm/dd
    Local $ArrD = StringSplit($sDate, '/')
    If $ArrD[0] <> 3 Then Return SetError(2, 0)
    Return $ArrD[3] & '/' & $ArrD[2] & '/' & $ArrD[1]
EndFunc   ;==>_DateStandardToCalcDate

julie · #8

oui tu dois connaitre les fonction que j'ai utiliser etant donner que c'est toi qui me les avait passer

merci beaucoup pour cette aide

AutoIt Français

[R] Listview item et groupe

[R] Listview item et groupe

Re: [..] Listview item et groupe

Re: [..] Listview item et groupe

Re: [..] Listview item et groupe

Re: [..] Listview item et groupe

Re: [..] Listview item et groupe

Re: [..] Listview item et groupe

Re: [..] Listview item et groupe