[R] Supprimer des entrées d'une listview avec checkbox

[franco]

Bonjour

Je suis en train de coder un outil qui me liste les dossiers vides à partir d'un chemin donné.
Cette partie fonctionne.

J'affiche donc le résultat dans une listview avec checkbox (case à cocher). J'affiche aussi résultat par résultat dans une barre d'état. A la fin dans la barre d'état, j'affiche le nombre de dossiers vides.
Cette partie fonctionne.

Donc, je coche les items, donc des dossiers vides.
Je décide donc de les supprimer, en actualisation le nombre de dossiers vides dans la barre d'état.
==> C'est cette partie qui beugue.

En effet, si j'en coche plusieurs et que je choisis de les supprimer, plusieurs sont supprimés mais pas la totalité.

Exemple :
Je trouve 22 dossiers vides.
J'en coches 12 dossiers et je choisis de les supprimer : seuls 6 sont supprimés.
Le reste reste coché...

Etant donné que je supprime l'entrée dans la listview, les entrées des dossiers non supprimés ne sont pas effacés.


Voici le code :

► Afficher le textecode

Code : Tout sélectionner

#include<Array.au3>
#include <ProgressConstants.au3>
#include<_FileListToArrayNT.au3>
#include <GUIConstantsEx.au3>
#include <GUIlistView.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#include <GuiStatusBar.au3>

Global $Form1 = GUICreate("Form1", 400, 325, 192, 124)

GUICtrlCreateLabel("Lister le bureau des dossiers vides", 5, 10, 300, 20)
GUICtrlSetFont(-1, 9, 400, 0, "comic sans ms")
$ListDesktopLV = GUICtrlCreateListView("", 0, 40, 400, 200, -1, $LVS_EX_CHECKBOXES)
$ListDesktopBT = GUICtrlCreateButton("Lister", 310, 10, 80, 20)

$DelThisDir = GUICtrlCreateButton("Supprimer la sélection", -100, -100, 100, 20)
$raz = GUICtrlCreateButton("Actualiser", -100, -100, 100, 20)
$ExitTool = GUICtrlCreateButton("Quitter", -100, -100, 100, 20)

$hStatus = _GUICtrlStatusBar_Create($Form1)
_GUICtrlStatusBar_SetText($hStatus, "En attente...")

GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $ListDesktopBT
            $Progress = GUICtrlCreateProgress(0, 260, 400, 20, $PBS_MARQUEE)
            GUICtrlSendMsg($Progress, 0x0400 + 10, 1, Number(30)) ; on envoie la ProgressBar
            _ListDesktop(@DesktopDir)
            GUICtrlDelete($Progress)
            GUICtrlSetPos($DelThisDir, 10, 260, 120, 20)
            GUICtrlSetPos($raz, 140, 260, 120, 20)
            GUICtrlSetPos($ExitTool, 270, 260, 120, 20)

        Case $DelThisDir
            For $i = 1 To _GUICtrlListView_GetItemCount($ListDesktopLV)
                Sleep(10)
                If _GUICtrlListView_GetItemChecked($ListDesktopLV, $i - 1) Then
                    DirRemove(_GUICtrlListView_GetItemTextString($ListDesktopLV, $i - 1))
                    Sleep(500)
                    If Not FileExists(_GUICtrlListView_GetItemTextString($ListDesktopLV, $i - 1)) Then _GUICtrlListView_DeleteItem($ListDesktopLV, $i - 1)
                EndIf
            Next
            _GUICtrlStatusBar_SetText($hStatus, "dossiers vides : " & _GUICtrlListView_GetItemCount($ListDesktopLV))

        case $raz
            _GUICtrlListView_DeleteColumn($ListDesktopLV, 0)
    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($ListDesktopLV))

    EndSwitch
WEnd

Func _ListDesktop($DesktopDir)
    GUICtrlSetPos($DelThisDir, -100, -100, 100, 20)
    GUICtrlSetPos($raz, -100, -100, 100, 20)
    GUICtrlSetPos($ExitTool, -100, -100, 100, 20)
    _GUICtrlListView_DeleteColumn($ListDesktopLV, 0)
    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($ListDesktopLV))
    _GUICtrlListView_AddColumn($ListDesktopLV, "Liste des dossiers vides", 400)
    $ListDesktopDir = _FileListToArrayNT($DesktopDir, "*.*", 2, 2, True, "Temp")
    For $i = 1 To $ListDesktopDir[0]
        Sleep(10)
        $size = DirGetSize($ListDesktopDir[$i], 1)
        If $size[0] = 0 And $size[1] = 0 And $size[2] = 0 Then
            _GUICtrlStatusBar_SetText($hStatus, $ListDesktopDir[$i])
            GUICtrlCreateListViewItem($ListDesktopDir[$i], $ListDesktopLV)
        EndIf
    Next
    _GUICtrlStatusBar_SetText($hStatus, "dossiers vides : " & _GUICtrlListView_GetItemCount($ListDesktopLV))
EndFunc   ;==>_ListDesktop
 

Pouvez-vous m'aider ?
Merci

@plusche

[jguinch]

Quand tu supprimes un item de la listview, les index se décalent :
Si tu as ça au départ :
- [x] c:\tmp\folder1 : Index 0
- [x] c:\tmp\folder2 : Index 1
- [x] c:\tmp\folder3 : Index 2
Tu te retrouves avec ça dès la suppression du premier dossier :
- [x] c:\tmp\folder2 : Index 0
- [x] c:\tmp\folder3 : Index 1

Donc ta boucle saute un item à chaque fois.

Ce que tu peux faire, c'est soit décrément de $i de 1 à chaque suppression, soit refaire ta boucle autrement...

Code : Tout sélectionner

If Not FileExists(_GUICtrlListView_GetItemTextString($ListDesktopLV, $i - 1)) Then
  _GUICtrlListView_DeleteItem($ListDesktopLV, $i - 1)
  $i -= 1
EndIf

[mikell]

Démonstration
Lance ce script et coche les 3 ou 4 derniers

► Afficher le texte

Code : Tout sélectionner

#include<Array.au3>
#include <ProgressConstants.au3>
#include<_FileListToArrayNT.au3>
#include <GUIConstantsEx.au3>
#include <GUIlistView.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#include <GuiStatusBar.au3>

Global $Form1 = GUICreate("Form1", 400, 325, 192, 124)

GUICtrlCreateLabel("Lister le bureau des dossiers vides", 5, 10, 300, 20)
GUICtrlSetFont(-1, 9, 400, 0, "comic sans ms")
$ListDesktopLV = GUICtrlCreateListView("", 0, 40, 400, 200, -1, $LVS_EX_CHECKBOXES)
$ListDesktopBT = GUICtrlCreateButton("Lister", 310, 10, 80, 20)

$DelThisDir = GUICtrlCreateButton("Supprimer la sélection", -100, -100, 100, 20)
$raz = GUICtrlCreateButton("Actualiser", -100, -100, 100, 20)
$ExitTool = GUICtrlCreateButton("Quitter", -100, -100, 100, 20)

$hStatus = _GUICtrlStatusBar_Create($Form1)
_GUICtrlStatusBar_SetText($hStatus, "En attente...")

GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $ListDesktopBT
            $Progress = GUICtrlCreateProgress(0, 260, 400, 20, $PBS_MARQUEE)
            GUICtrlSendMsg($Progress, 0x0400 + 10, 1, Number(30)) ; on envoie la ProgressBar
            _ListDesktop(@DesktopDir)
            GUICtrlDelete($Progress)
            GUICtrlSetPos($DelThisDir, 10, 260, 120, 20)
            GUICtrlSetPos($raz, 140, 260, 120, 20)
            GUICtrlSetPos($ExitTool, 270, 260, 120, 20)

        Case $DelThisDir
            For $i = 1 To _GUICtrlListView_GetItemCount($ListDesktopLV)
               Sleep(10)
                If _GUICtrlListView_GetItemChecked($ListDesktopLV, $i - 1) Then
  msgbox(0,"", "on est sur la ligne  " & $i & "  de la listview")

                 ;   DirRemove(_GUICtrlListView_GetItemTextString($ListDesktopLV, $i - 1))
                 ;   Sleep(500)
                 ;   If Not FileExists(_GUICtrlListView_GetItemTextString($ListDesktopLV, $i - 1)) Then _GUICtrlListView_DeleteItem($ListDesktopLV, $i - 1)
_GUICtrlListView_DeleteItem($ListDesktopLV, $i - 1)
                EndIf
            Next
            _GUICtrlStatusBar_SetText($hStatus, "dossiers vides : " & _GUICtrlListView_GetItemCount($ListDesktopLV))

        case $raz
            _GUICtrlListView_DeleteColumn($ListDesktopLV, 0)
    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($ListDesktopLV))

    EndSwitch
WEnd

Func _ListDesktop($DesktopDir)
    GUICtrlSetPos($DelThisDir, -100, -100, 100, 20)
    GUICtrlSetPos($raz, -100, -100, 100, 20)
    GUICtrlSetPos($ExitTool, -100, -100, 100, 20)
    _GUICtrlListView_DeleteColumn($ListDesktopLV, 0)
    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($ListDesktopLV))
    _GUICtrlListView_AddColumn($ListDesktopLV, "Liste des dossiers vides", 400)
    $ListDesktopDir = _FileListToArrayNT($DesktopDir, "*.*", 2, 2, True, "Temp")
  $a = 1
   For $i = 1 To $ListDesktopDir[0]
        Sleep(10)
        $size = DirGetSize($ListDesktopDir[$i], 1)
        If $size[0] = 0 And $size[1] = 0 And $size[2] = 0 Then
            _GUICtrlStatusBar_SetText($hStatus, $ListDesktopDir[$i])
            GUICtrlCreateListViewItem($a & "  " & $ListDesktopDir[$i], $ListDesktopLV)
           $a += 1
        EndIf
    Next
    _GUICtrlStatusBar_SetText($hStatus, "dossiers vides : " & _GUICtrlListView_GetItemCount($ListDesktopLV))
EndFunc   ;==>_ListDesktop

C'est la bonne vieille blague de _ArrayDelete ...
Je suis sûr que tu vas trouver la seule ligne à modifier

[franco]

Salut

Et merci pour l'aide apportée

« Je suis sûr que tu vas trouver la seule ligne à modifier »
En fait, j'ai juste rajouté une ligne grâce aux indications donné par toi-même et par jguinch.

Par rapport au fait du décalage des index et la décrémentation (je ne sais pas si je l'ai bien écrit )


Voici ce que j'ai comme code pour le bouton DelThisDir

Code : Tout sélectionner

Case $DelThisDir
            For $i = 1 To _GUICtrlListView_GetItemCount($ListDesktopLV)
                Sleep(10)
                If _GUICtrlListView_GetItemChecked($ListDesktopLV, $i - 1) Then
                    DirRemove(_GUICtrlListView_GetItemTextString($ListDesktopLV, $i - 1))
                    If Not FileExists(_GUICtrlListView_GetItemTextString($ListDesktopLV, $i - 1)) Then _GUICtrlListView_DeleteItem($ListDesktopLV, $i - 1)
                EndIf
            Next
            _GUICtrlStatusBar_SetText($hStatus, "dossiers vides : " & _GUICtrlListView_GetItemCount($ListDesktopLV))

Je rajoute donc la décrémentation, c'est à dire $i -= 1

Code : Tout sélectionner

        Case $DelThisDir
            For $i = 1 To _GUICtrlListView_GetItemCount($ListDesktopLV)
                Sleep(10)
                If _GUICtrlListView_GetItemChecked($ListDesktopLV, $i - 1) Then
                    DirRemove(_GUICtrlListView_GetItemTextString($ListDesktopLV, $i - 1))
                    If Not FileExists(_GUICtrlListView_GetItemTextString($ListDesktopLV, $i - 1)) Then _GUICtrlListView_DeleteItem($ListDesktopLV, $i - 1)
                    [b][u]$i -= 1[/u][/b]
                EndIf
            Next
            _GUICtrlStatusBar_SetText($hStatus, "dossiers vides : " & _GUICtrlListView_GetItemCount($ListDesktopLV))

Cela fonctionne.

Mais vu que tu as parlé de "modification de ligne", peut-être que j'ai tort, dans le sens que l'ajout de cette ligne n'était pas nécessaire.

Quoiqu'il en soit, voici le code complet, si ça peut servir à d'autres.

► Afficher le textecode

Code : Tout sélectionner

#include<Array.au3>
#include <ProgressConstants.au3>
#include<_FileListToArrayNT.au3>
#include <GUIConstantsEx.au3>
#include <GUIlistView.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#include <GuiStatusBar.au3>

Global $Form1 = GUICreate("Form1", 400, 325, 192, 124)

GUICtrlCreateLabel("Lister le bureau des dossiers vides", 5, 10, 300, 20)
GUICtrlSetFont(-1, 9, 400, 0, "comic sans ms")
$ListDesktopLV = GUICtrlCreateListView("", 0, 40, 400, 200, -1, $LVS_EX_CHECKBOXES)
$ListDesktopBT = GUICtrlCreateButton("Lister", 310, 10, 80, 20)

$DelThisDir = GUICtrlCreateButton("Supprimer la sélection", -100, -100, 100, 20)
$raz = GUICtrlCreateButton("Actualiser", -100, -100, 100, 20)
$ExitTool = GUICtrlCreateButton("Quitter", -100, -100, 100, 20)

$hStatus = _GUICtrlStatusBar_Create($Form1)
_GUICtrlStatusBar_SetText($hStatus, "En attente...")

GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $ListDesktopBT
            $Progress = GUICtrlCreateProgress(0, 260, 400, 20, $PBS_MARQUEE)
            GUICtrlSendMsg($Progress, 0x0400 + 10, 1, Number(30)) ; on envoie la ProgressBar
            _ListDesktop(@DesktopDir)
            GUICtrlDelete($Progress)
            GUICtrlSetPos($DelThisDir, 10, 260, 120, 20)
            GUICtrlSetPos($raz, 140, 260, 120, 20)
            GUICtrlSetPos($ExitTool, 270, 260, 120, 20)

        Case $DelThisDir
            For $i = 1 To _GUICtrlListView_GetItemCount($ListDesktopLV)
                Sleep(10)
                If _GUICtrlListView_GetItemChecked($ListDesktopLV, $i - 1) Then
                    DirRemove(_GUICtrlListView_GetItemTextString($ListDesktopLV, $i - 1))
                    If Not FileExists(_GUICtrlListView_GetItemTextString($ListDesktopLV, $i - 1)) Then _GUICtrlListView_DeleteItem($ListDesktopLV, $i - 1)
                    $i -= 1
                EndIf
            Next
            _GUICtrlStatusBar_SetText($hStatus, "dossiers vides : " & _GUICtrlListView_GetItemCount($ListDesktopLV))

        Case $raz
            _GUICtrlListView_DeleteColumn($ListDesktopLV, 0)
            _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($ListDesktopLV))

    EndSwitch
WEnd

Func _ListDesktop($DesktopDir)
    GUICtrlSetPos($DelThisDir, -100, -100, 100, 20)
    GUICtrlSetPos($raz, -100, -100, 100, 20)
    GUICtrlSetPos($ExitTool, -100, -100, 100, 20)
    _GUICtrlListView_DeleteColumn($ListDesktopLV, 0)
    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($ListDesktopLV))
    _GUICtrlListView_AddColumn($ListDesktopLV, "Liste des dossiers vides", 400)
    $ListDesktopDir = _FileListToArrayNT($DesktopDir, "*.*", 2, 2, True, "Temp")
    For $i = 1 To $ListDesktopDir[0]
        Sleep(10)
        $size = DirGetSize($ListDesktopDir[$i], 1)
        If $size[0] = 0 And $size[1] = 0 And $size[2] = 0 Then
            _GUICtrlStatusBar_SetText($hStatus, $ListDesktopDir[$i])
            GUICtrlCreateListViewItem($ListDesktopDir[$i], $ListDesktopLV)

        EndIf
    Next
    _GUICtrlStatusBar_SetText($hStatus, "dossiers vides : " & _GUICtrlListView_GetItemCount($ListDesktopLV))
EndFunc   ;==>_ListDesktop
 

@+ et merci
Je passe en résolu.

[TommyDDR]

Une chose à savoir sur les boucles for (en AutoIt, en java par exemple, ça n'est pas le même fonctionnement -> à investiguer) :

Code : Tout sélectionner

For $i = 0 To XXX

XXX ne sera calculé UNE SEULE ET UNIQUE FOIS à l'entrée de la boucle, donc votre

Code : Tout sélectionner

_GUICtrlListView_GetItemCount($ListDesktopLV)

ne sera pas recalculé entre chaque tour de boucle.

C'est pour ça qu'en général, lorsque l'on veut supprimer un élément se situant dans "l'objet" où l'on itère, il est préférable de le faire en commençant par la fin.

Il est aussi fortement déconseillé de modifier la variable de la boucle For (ici : $i), si vous avez besoin de modifier $i, c'est que vous n'avez pas choisi la bonne boucle. Évitez les $i -= 1, votre code n'en sera que meilleur

Code : Tout sélectionner

For $i = _GUICtrlListView_GetItemCount($ListDesktopLV) To 1 Step -1

[jguinch]

@TommyDDR : je me disais aussi que c'était pas très propre le truc que j'avais proposé...

[mikell]

lorsque l'on veut supprimer un élément se situant dans "l'objet" où l'on itère, il est préférable de le faire en commençant par la fin.

Code : Tout sélectionner

For $i = _GUICtrlListView_GetItemCount($ListDesktopLV) To 1 Step -1

Ben oui c'était ça la ligne à modifier

Le cas d'école c'est _ArrayDelete, comme par exemple dans ce code si on veut éliminer les index impairs :

► Afficher le texte

Code : Tout sélectionner

#include <Array.au3>

Local $avArray[7] = ["0", "1", "2", "3", "4", "5", "6"]
_ArrayDisplay($avArray, "départ")
For $i = 0 to UBound($avArray)-1
    If Mod($i, 2) = 1 Then _ArrayDelete($avArray, $i)
Next
_ArrayDisplay($avArray, "raté")

Local $avArray[7] = ["0", "1", "2", "3", "4", "5", "6"]
For $i = UBound($avArray)-1 to 0 step -1
    If Mod($i, 2) = 1 Then _ArrayDelete($avArray, $i)
Next
_ArrayDisplay($avArray, "réussi")
 

[franco]

Salut à tous

Merci pour vos éclaircissements.

Je vais pouvoir l'améliorer.
Encore merci.

@+