[R] Default clique droit dans une listview .

[julie]

bonjour a tous

aujourd'hui je suis devant un probleme j'aimerai savoir comment faire pour ne garder que l'essentiel pour visualiser les fichier contenu dans un dossier je n'ai trouver aucun sujet parlant de ca je m'explique

► Afficher le texte

vous pouvez apercevoir dans l'image ci dessus un dossier et ce qui est entouré en rouge est ce que j'aimerai qui apparaisse et seulement ca
pour que ca ressemple a ceci

► Afficher le texte

ps (a l'heure ou j'ecris ces ligne je m'appercois que ce que je demande n'est pas un probleme une listview et une boucle qui liste les fichier et le tour est joué, mais un probleme ce pose j'aimerai garder le menu qui s'affiche quand don fait un clique droit, voir photo ci dessous

► Afficher le texte

et la le vrai probleme ce pose :S si quelqu'un a une idee de comment garder ce menu ?

alors ci quelqu'un a une petite je suis preneuse merci beaucoup

[julie]

edit j'ai trouver ca sur le forum us pour lister les fichier d'un dossier ce que je recherche donc mais le probleme du clique droit est toujours present :/

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <File.au3>

Content(@ScriptDir & "\annexe\client 1")
;Content(FileSelectFolder("SELECT FOLDER",""))
Exit

Func Content($directory)
    Local $FileList, $item, $File_Name, $File_size, $File_t, $File_time

    ; _FileListToArray
    $FileList=_FileListToArray($directory,'*.*',  0) ; files and directories
    If @Error=1 Then
        MsgBox (0,"","No Files Found.")
    EndIf

    GUICreate("Directory " & $directory, 800, 250, 100, 200, -1, $WS_EX_ACCEPTFILES)
    GUISetBkColor(0x00E0FFFF)  ; will change background color

    $listview = GUICtrlCreateListView("Name                                               |Size           |Type       |creation Time (YYYY/MM/DD HH:MM:SS             ", 10, 10, 780, 190);,$LVS_SORTDESCENDING)

    for $n = 1 to UBound($FileList)-1
        $File_Name = $FileList[$n]
        $File_size = FileGetSize ( $directory & "\" & $File_Name)
        $File_t =  FileGetTime($directory & "\" & $File_Name, 1) ; creation Time
        $File_time = $File_t[0] & "/" & $File_t[1] & "/" & $File_t[2] & " " & $File_t[3] & ":" & $File_t[4] & ":" & $File_t[5] ; detailed
        $item = GUICtrlCreateListViewItem( $File_Name & "|" & $File_size & "|" & $File_time, $listview)
        If FileGetAttrib ($directory & "\" & $File_Name) = "D" Then
            GUICtrlSetImage($item, "shell32.dll", 4)
        Else
            If GUICtrlSetImage(-1, $directory & "\" & $File_Name, 1) = 0 Then ; If a default icon cannot be found
                ; the default icon of the file should be set here
                GUICtrlSetImage($item, "shell32.dll", 1) ; set icon  of shell32.dll
            EndIf
        EndIf
    Next
    GUISetState()

    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE
EndFunc   ;==>Content
 

[Hugues]

Salut,

Regarde le fichier d'aide avec la fonction "GUICtrlCreateContextMenu()":

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>

Example1()
Example2()

; ****************
; * First sample *
; ****************
Func Example1()
    ;right click on gui to bring up context Menu.
    ;right click on the "ok" button to bring up a controll specific context menu.

    GUICreate("My GUI Context Menu", 300, 200)

    Local $contextmenu = GUICtrlCreateContextMenu()

    Local $button = GUICtrlCreateButton("OK", 100, 100, 70, 20)
    Local $buttoncontext = GUICtrlCreateContextMenu($button)
    GUICtrlCreateMenuItem("About button", $buttoncontext)

    Local $newsubmenu = GUICtrlCreateMenu("new", $contextmenu)
    GUICtrlCreateMenuItem("text", $newsubmenu)

    GUICtrlCreateMenuItem("Open", $contextmenu)
    GUICtrlCreateMenuItem("Save", $contextmenu)
    GUICtrlCreateMenuItem("", $contextmenu) ; separator

    GUICtrlCreateMenuItem("Info", $contextmenu)

    GUISetState()

    ; Run the GUI until the dialog is closed
    While 1
        Local $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
    GUIDelete()
EndFunc   ;==>Example1


; *****************
; * Second sample *
; *****************
Func Example2()
    Local $hGui, $OptionsBtn, $OptionsDummy, $OptionsContext, $msg
    Local $OptionsExit, $HelpBtn, $HelpDummy, $HelpContext, $HelpAbout
    $hGui = GUICreate("My GUI", 170, 40)

    $OptionsBtn = GUICtrlCreateButton("&Options", 10, 10, 70, 20, $BS_FLAT)

    ; At first create a dummy control for the options and a contextmenu for it
    $OptionsDummy = GUICtrlCreateDummy()
    $OptionsContext = GUICtrlCreateContextMenu($OptionsDummy)
    GUICtrlCreateMenuItem("Common", $OptionsContext)
    GUICtrlCreateMenuItem("File", $OptionsContext)
    GUICtrlCreateMenuItem("", $OptionsContext)
    $OptionsExit = GUICtrlCreateMenuItem("Exit", $OptionsContext)


    $HelpBtn = GUICtrlCreateButton("&Help", 90, 10, 70, 20, $BS_FLAT)

    ; Create a dummy control and a contextmenu for the help too
    $HelpDummy = GUICtrlCreateDummy()
    $HelpContext = GUICtrlCreateContextMenu($HelpDummy)
    GUICtrlCreateMenuItem("Website", $HelpContext)
    GUICtrlCreateMenuItem("", $HelpContext)
    $HelpAbout = GUICtrlCreateMenuItem("About...", $HelpContext)


    GUISetState()

    While 1
        $msg = GUIGetMsg()

        Switch $msg
            Case $OptionsExit, $GUI_EVENT_CLOSE
                ExitLoop

            Case $OptionsBtn
                ShowMenu($hGui, $msg, $OptionsContext)

            Case $HelpBtn
                ShowMenu($hGui, $msg, $HelpContext)

            Case $HelpAbout
                MsgBox(64, "About...", "GUICtrlGetHandle-Sample")
        EndSwitch
    WEnd
    GUIDelete()
EndFunc   ;==>Example2


; Show a menu in a given GUI window which belongs to a given GUI ctrl
Func ShowMenu($hWnd, $CtrlID, $nContextID)
    Local $arPos, $x, $y
    Local $hMenu = GUICtrlGetHandle($nContextID)

    $arPos = ControlGetPos($hWnd, "", $CtrlID)

    $x = $arPos[0]
    $y = $arPos[1] + $arPos[3]

    ClientToScreen($hWnd, $x, $y)
    TrackPopupMenu($hWnd, $hMenu, $x, $y)
EndFunc   ;==>ShowMenu


; Convert the client (GUI) coordinates to screen (desktop) coordinates
Func ClientToScreen($hWnd, ByRef $x, ByRef $y)
    Local $stPoint = DllStructCreate("int;int")

    DllStructSetData($stPoint, 1, $x)
    DllStructSetData($stPoint, 2, $y)

    DllCall("user32.dll", "int", "ClientToScreen", "hwnd", $hWnd, "ptr", DllStructGetPtr($stPoint))

    $x = DllStructGetData($stPoint, 1)
    $y = DllStructGetData($stPoint, 2)
    ; release Struct not really needed as it is a local
    $stPoint = 0
EndFunc   ;==>ClientToScreen


; Show at the given coordinates (x, y) the popup menu (hMenu) which belongs to a given GUI window (hWnd)
Func TrackPopupMenu($hWnd, $hMenu, $x, $y)
    DllCall("user32.dll", "int", "TrackPopupMenuEx", "hwnd", $hMenu, "int", 0, "int", $x, "int", $y, "hwnd", $hWnd, "ptr", 0)
EndFunc   ;==>TrackPopupMenu
 

[mikell]

Yo julie
Ce que tu demandes n'est pas très clair, peut-être ça ?

► Afficher le texte

Code : Tout sélectionner

$oIE=ObjCreate("Shell.Explorer.2")
$gui = GUICreate("", 500, 300, -1, -1, -1, 0x80) 
$gX = GUICtrlCreateObj($oIE, 50, 50, 400, 200)
GUISetState()
$oIE.Navigate("@ScriptDir & "\annexe\client 1")
$gui_handle = WinGetHandle($gui, "")
$handle = ControlGetHandle($gui_handle, "", "[CLASS:SysListView32; INSTANCE:1]")
ControlListView ($gui_handle, "", $handle, "ViewChange", "details") 

While GuiGetMsg()<>-3
Wend

Mais je ne suis pas sûr de la classe pour un W7

[jguinch]

La classe est bonne.
Le problème se situe plutôt au niveau de la ligne 5

[julie]

mikell c'est juste parfait c'est exactement ce que je voulais une fois de plus tu as resolu mon pbm et je t'en remercie

ps ( j'ai juste changer le chemin comme ceci et ca focntionne niquel )

Code : Tout sélectionner

$oIE=ObjCreate("Shell.Explorer.2")
$gui = GUICreate("", 500, 300, -1, -1, -1, 0x80)
$gX = GUICtrlCreateObj($oIE, 50, 50, 400, 200)
GUISetState()
$oIE.Navigate(@ScriptDir & "\annexe\client 1")
$gui_handle = WinGetHandle($gui, "")
$handle = ControlGetHandle($gui_handle, "", "[CLASS:SysListView32; INSTANCE:1]")
ControlListView ($gui_handle, "", $handle, "ViewChange", "details")

While GuiGetMsg()<>-3
Wend

super cool comme d'hab merci