[..] x64 & x86 reconnaitre l'architecture d'un processus

[Yoyo86220]

Bonjour,

je souhaite reconnaitre si un processus est un processus x86 ou x64 (j'ai un windows x64) il est possible de lancer des processus x86 donc je voudrais savoir l'architecture d'un processus lancé.

c'est possible?

[bob]

Peut-être en utilisant des macros :
@CPUArch
Exemple : MsgBox(1,"",@CPUArch)

D'après l'aide :
"Returns "X86" when the CPU is a 32-bit CPU and "X64" when the CPU is 64-bit."

(Euh ! je n'ai pas répondu à la question... )

Peut-être alors @AutoItX64 (?) :
1 programme compilé en x64 m'affiche 1 ds 1 msgbox et 0 s'il est compilé en x86.
A vous d'essayer...

[jguinch]

Bonjour.
Peut-être que le gestionnaire des tâches est suffisant ? Tous les processus qui tournent en 32 bits sont nommés avec *32.

Sinon, avec WinApiEx, il y a la fonction _WinAPI_IsWow64Process qui permet de savoir si un process est 64 bits.

Exemple :

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>

Global Const $__WINVER = __WINVER()
Global $plist[1][2]


$n = 0
Local $list = ProcessList()
For $i = 1 To $list[0][0]

    $n += 1
    ReDim $plist[$n][2]
    $plist[$n - 1][0] = $list[$i][1]
    $plist[$n - 1][1] = $list[$i][0]
    If _WinAPI_IsWow64Process($list[$i][1]) Then $plist[$n - 1][1] &= " *32"
    
Next

_ArrayDisplay($plist)





Func _WinAPI_IsWow64Process($PID = 0)

    If Not $PID Then
        $PID = @AutoItPID
    EndIf

    Local $hProcess = DllCall('kernel32.dll', 'ptr', 'OpenProcess', 'dword', __Iif($__WINVER < 0x0600, 0x00000400, 0x00001000), 'int', 0, 'dword', $PID)

    If (@error) Or (Not $hProcess[0]) Then
        Return SetError(1, 0, 0)
    EndIf

    Local $Ret = DllCall('kernel32.dll', 'int', 'IsWow64Process', 'ptr', $hProcess[0], 'int*', 0)

    If (@error) Or (Not $Ret[0]) Then
        $Ret = 0
    EndIf
    _WinAPI_CloseHandle($hProcess[0])
    If Not IsArray($Ret) Then
        Return SetError(1, 0, 0)
    EndIf
    Return $Ret[2]
EndFunc   ;==>_WinAPI_IsWow64Process



Func __Iif($fTest, $iTrue, $iFalse)
    If $fTest Then
        Return $iTrue
    Else
        Return $iFalse
    EndIf
EndFunc   ;==>__Iif


Func __WINVER()

    Local $tOSVI = DllStructCreate('dword;dword;dword;dword;dword;wchar[128]')

    DllStructSetData($tOSVI, 1, DllStructGetSize($tOSVI))

    Local $Ret = DllCall('kernel32.dll', 'int', 'GetVersionExW', 'ptr', DllStructGetPtr($tOSVI))

    If (@error) Or (Not $Ret[0]) Then
        Return SetError(1, 0, 0)
    EndIf
    Return BitOR(BitShift(DllStructGetData($tOSVI, 2), -8), DllStructGetData($tOSVI, 3))
EndFunc   ;==>__WINVER

Func _WinAPI_CloseHandle($hObject)
    Local $aResult = DllCall("kernel32.dll", "bool", "CloseHandle", "handle", $hObject)
    If @error Then Return SetError(@error, @extended, False)
    Return $aResult[0]
EndFunc   ;==>_WinAPI_CloseHandle