[..] GUI avec sélection de checkbox pour un menu d'install

[izarra64]

Bonjour à tous !
Alors voilà, j'aurais eu besoin de préparer un script rapidement pour proposer une liste d'application à installer (une trentaine) à partir d'une interface/menu.
en gros, ce que je souhaite faire est :
- à partir d'un tableau,ou d'un fichier .ini, ou encore mieux de la liste des sous dossiers, récupérer l'ensemble des noms des applications à proposer en installation
- chaque application est classée dans un sous dossier contenant un fichier install.cmd qui peut installer l'application du sous-dossier en cours en mode silcencieux (j'ai donc 30 sous dossiers avec dans chacun un install.cmd)
- Dans une fenêtre unique (GUI) afficher pour chaque entrée (chaque sous dossier lus ou récupérés) une checkbox avec le nom de l'application
- positionner par défaut, la coche dans quelques unes de ces applications
- Plus bas dans la GUI, proposer une checkbox pour cocher automatiquement une partie de plusieurs de ces applis.
par défaut
- et bien sur, porposer un Bouton VALIDER qui se chargera alors de lancer le install.cmd pour chaque application qui aura été cochée !

A titre d'exemple : on affiche sans règles particulières les 30 noms d'applications disponibles
En bas de la GUI, on affiche une CheckBox qui sera censée cocher/décocher les 4 applis ci dessous
App1=7zip
App2=VLC
App7=CCleaner
App8=FlashPlayer

En bas de la GUI, on affiche une CheckBox qui sera censée cocher/décocher les applis ci dessous (genre de groupe)
App11=CamStudio
App12=OpenOffice

En bas de la GUI, on affiche une CheckBox qui sera censée cocher/décocher les applis ci dessous (genre de groupe)
App21=Winamp
App22=Audacity

Aussi, une option de pouvoir Tout cocher/décocher

Certain de votre expérience sans faille, je suis sûr que cela devrait pouvoir se faire ?
Merci d'avance !
Bonne journée !!

[mikell]

Ce que je te propose là c'est une base de script, facile à adapter
L'idée : tu as des dossiers appelés app1, app2, app3 ... etc, avec dans chacun un fichier install.cmd et un fichier nom_du_soft_à_installer.exe

Le script compte d'abord les dossiers, adapte la taille de la gui à ce nombre, et crée les checkbox
Ensuite il crée une array 2D, où il stocke les infos des checkbox (ID de la chkb et nom du dossier correspondant)
Le bouton "valider" lit les checkbox, puis crée une 2ème array qui ne contient que les infos des checkbox cochées
Cette 2ème array est ensuite utilisée par la fonction d'installation

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#Include <File.au3>
#Include <Array.au3>

Global $check_all, $valids, $valid_nb
$FileList = _FileListToArray(@ScriptDir, "app*", 2)  [color=#00b000]; liste les dossiers app1, app2, app3 etc[/color]
;_ArrayDisplay($FileList,"liste dossiers")  [color=#00b000]; vérification[/color]

$nb = $FileList[0]        [color=#00b000] ; nb de dossiers trouvés[/color]
Dim $checks[$nb][2]       [color=#00b000] ; crée une array pour les checkbox (ID + dossier)[/color]
$gui = GuiCreate("install", 200, 100+$nb*20, -1, -1)
For $i = 1 to $nb   [color=#00b000] ; pour chaque dossier trouvé[/color]
    $name = ""
    $search = FileFindFirstFile(@scriptdir & "\" & $FileList[$i] & "\*.exe") [color=#00b000]  ; trouve l'exe[/color]
    While 1
        $file = FileFindNextFile($search)  [color=#00b000] ; prend le nom de l'exe[/color]
        If @error Then ExitLoop
        $name = StringTrimRight($file, 4)   [color=#00b000]  ; récupère le nom du soft[/color]
    Wend
    FileClose($search)
    $checks[$i-1][0] = GuiCtrlCreateCheckbox($name, 10, $i*20, 180, 20)
    $checks[$i-1][1] = $FileList[$i]
Next
_ArrayDisplay($checks,"verif $checks")  [color=#00b000]; vérification[/color]
$check_all_btn = GuiCtrlCreateCheckbox("Check all", 10, $i*20+20, 180, 20)
$btn_valid = GuiCtrlCreateButton("Valider", 50, $i*20+50, 70, 25)
GuiSetState()

While 1
$msg = GuiGetMsg()
Switch $msg
    Case $GUI_EVENT_CLOSE
        Exit
    Case $btn_valid
        Dim $valids[$nb][2]   [color=#00b000]; crée une array pour les checkbox cochées (ID + dossier)[/color]
        $valid_nb = 0              [color=#00b000]; nb de checkbox cochées[/color]
        For $i = 0 To $nb-1    [color=#00b000]; pour chaque checkbox[/color]
            If BitAnd(GUICtrlRead($checks[$i][0]), $GUI_CHECKED) = $GUI_CHECKED Then
                $valids[$valid_nb][0] = $checks[$i][0]  [color=#00b000] ; stocke l'ID de la checkbox[/color]
                $valids[$valid_nb][1] = $checks[$i][1]   [color=#00b000]; stocke le nom du dossier[/color]
                $valid_nb += 1   
            EndIf
        Next
        Redim $valids[$valid_nb][2]
            _ArrayDisplay($valids,"verif $valids")  [color=#00b000]; vérification[/color]
        _Run_Install()      [color=#00b000]; lance l'install[/color]
    Case $check_all_btn
        $check_all = not $check_all
        If $check_all Then
            For $i = 0 To $nb-1
                GUICtrlSetState($checks[$i][0], $GUI_CHECKED)
            Next
        Else
            For $i = 0 To $nb-1
                GUICtrlSetState($checks[$i][0], $GUI_UNCHECKED)
            Next
        EndIf
EndSwitch
Wend

Func _Run_Install()
For $i = 0 To $valid_nb-1
    ShellExecuteWait(@scriptdir & "\" & $valids[$i][1] & "\install.cmd")    [color=#00b000]; lance app1\install.cmd , etc[/color]
Next
Msgbox(0,"", "install terminé")
EndFunc
 

Manque juste la gestion d'erreur
Faire des groupes ne présente guère d'intérêt puisqu'il y a les checkbox, mais si tu veux les faire quand même c'est pas difficile à rajouter au script, suffit de prendre modèle sur le 'Case $check_all' , exemple :

► Afficher le texte

Code : Tout sélectionner

Global $groupe1
....
  Case $check_groupe_1     [color=#00b000]; checkbox qui controle les chckb 1, 4, 7[/color]
        $groupe1 = not $groupe1    [color=#00b000] ; variable 'interrupteur'[/color]
        Dim $array_groupe1[3] = [1, 4, 7]
        If $groupe1 Then           
             For $i In $array_groupe1       [color=#00b000];  coche les chckb 1, 4, 7[/color]  
                    GUICtrlSetState($checks[$i-1][0], $GUI_CHECKED)
             Next
        Else                        
             For $i In $array_groupe1      [color=#00b000];  décoche les chckb 1, 4, 7[/color] 
                    GUICtrlSetState($checks[$i-1][0], $GUI_UNCHECKED)
             Next
        EndIf

[izarra64]

Salut Mikell
un seul mot ! MERCI !
C top, c'est exactement ce que je voulais !
j'ai adapté un peu ton script pour qu'il ne m'affiche que le nom des dossiers au lieu de l'exe qui s'y trouve
surtout que je peux y avoir aussi des MSI !
Donc c'est top !! trop content !!
je vais maintenant voir comment adapter un peu mieux la mise en forme, vu que j'ai plusieurs dizaines d'applis (jusque 40) et dans une seule liste/colonne, on ne voit pas toutes les options !!
je vais essayer de faire un compteur pour affecter la GUI en paquet de 15 lignes par colonnes MAX !
Et rajouter une checkbox de groupe par colonne (ça sera plus facile à lire pour le user final)

dernière question peut être stp !
plutot que de lire les dossiers en cours, quel moyen le plus simple/rapide pourrais je utiliser pour afficher les choix et construire les checkbox en passant par un fichier (INI ou autre)
cela me permettrait de ne plus gérer que ce fichier INI et le script passé en EXE marcherait dans n'importe quel cas de figure !
chaque ligne d'application contient en premier le nom du dossier dans lequel se trouve le install.cmd
ainsi que le numéro de version
et j'aimerais alors que la checkbbox affiche le Nom du dossier, ainsi que la version !
je pensais à quelque chose comme ça ci dessous
pourrais tu m'indiquer comment lire ce fichier au plus simple afin d'en affecter le contenu dans les tableaux dans le script ?

► Afficher le texte

Config.ini
[TITRE GUI]
Titre=Ma GUI pour mon lanceur d'install
[Groupes]
Groupe1=Applications Communes
Groupe2=Multimedia
Groupe3=Bureautique
Groupe4=Gestion

[Groupe1]
7zip,V9.20
VLC,V2.02
FlashPlayer,V11
Java,V7u9

[Groupe2]
Audacity,V 2.01
CCleaner,V 3.23

[Groupe3]
OpenOffice,v3.4
PDFCreator,v1.31

[Groupe4]
Winamp,5.20
iTunes,v13

[mikell]

Utiliser un ini est évidemment possible (les fonctions ini d'autoit sont simples), mais comme tu vas le voir, utiliser un ini + le fait de classer les softs par groupes = modifs conséquentes du script
Le script est toujours aussi souple mais un brin plus compliqué, faut pas se perdre dans les arrays et les boucles For
Si tu t'y perds je te commenterai le script
Tu remarqueras qu'on laisse complètement tomber le _FileListToArray

Ton cahier des charges est un peu flou concernant l'arborescence dossier/fichiers à cibler, donc j'utilise dans cet exemple des dossiers de la forme 7zip\install.cmd, Audacity\install.cmd, etc

Pour le ini, mettre le titre de la gui dedans ne présente aucun intérêt, et avec une syntaxe correcte ça donne ça (dans les groupes, les clés doivent avoir le même nom que le dossier correspondant)

► Afficher le texteConfig.ini

Code : Tout sélectionner

;Config.ini

[Groupes]
Groupe1=Applications Communes
Groupe2=Multimedia
Groupe3=Bureautique
Groupe4=Gestion

[Groupe1]
7zip=V9.20
VLC=V2.02
FlashPlayer=V11
Java=V7u9

[Groupe2]
Audacity=V 2.01
CCleaner=V 3.23

[Groupe3]
OpenOffice=v3.4
PDFCreator=v1.31

[Groupe4]
Winamp=5.20
iTunes=v13

Enfin, pour le problème de taille de gui, comme j'avais ça sous la main je te propose une solution élégante, la barre de scroll
Le script :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
;#include <StructureConstants.au3>
#include <GUIScrollBars.au3>
#include <ScrollBarConstants.au3>
;#Include <File.au3>
#Include <Array.au3>

Global $array_softs[1][3]          ; 0=chckbox du soft, 1=dossier du soft, 2=version
Global $array_groupes[1][3]        ; 0=chckbox du groupe, 1=nom du groupe, 2=liste des softs du groupe
Global $ini = "Config.ini", $gui, $gui2, $check_all, $valids, $valid_nb

$gui = GuiCreate("install", 200, 390, -1, 20)
GuiCtrlCreateLabel("Programmes", 60, 10, 100, 18)
_ListZeGroups()
GuiSwitch($gui)
$check_all_btn = GuiCtrlCreateCheckbox("Check all", 10, 320, 180, 20)
$btn_valid = GuiCtrlCreateButton("Valider", 50, 350, 70, 25)
GuiSetState()

GUIRegisterMsg($WM_VSCROLL, "WM_VSCROLL")
_GUIScrollBars_Init($gui2)
_GUIScrollBars_ShowScrollBar($gui2, $SB_HORZ, False)
_GUIScrollBars_SetScrollInfoMax($gui2, $SB_VERT, 30)

;_ArrayDisplay($array_groupes,"groupes") 
;_ArrayDisplay($array_softs,"liste dossiers/softs") 


While 1
$msg = GuiGetMsg()

For $i = 0 to UBound($array_groupes)-1
    If $msg = $array_groupes[$i][0] Then
      $split = StringSplit($array_groupes[$i][2], "#")
    ;_ArrayDisplay($split,$array_groupes[$i][1]) 

      For $j = 1 to $split[0]     
        For $k = 1 to $array_softs[0][0]
          If $split[$j] = $array_softs[$k][1] Then
            If BitAnd(GUICtrlRead($array_groupes[$i][0]), $GUI_CHECKED) = $GUI_CHECKED Then
                GUICtrlSetState($array_softs[$k][0], $GUI_CHECKED)
            Else
                GUICtrlSetState($array_softs[$k][0], $GUI_UNCHECKED)
            EndIf
          EndIf
        Next
      Next
    EndIf
Next

Switch $msg
    Case $GUI_EVENT_CLOSE
        Exit
    Case $check_all_btn
        $check_all = not $check_all
        If $check_all Then
            For $i = 0 to UBound($array_groupes)-1
                GUICtrlSetState($array_groupes[$i][0], $GUI_CHECKED)
            Next
            For $i = 1 To $array_softs[0][0]
                GUICtrlSetState($array_softs[$i][0], $GUI_CHECKED)
            Next
        Else
            For $i = 0 to UBound($array_groupes)-1
                GUICtrlSetState($array_groupes[$i][0], $GUI_UNCHECKED)
            Next
            For $i = 0 To $array_softs[0][0]
                GUICtrlSetState($array_softs[$i][0], $GUI_UNCHECKED)
            Next
        EndIf
    Case $btn_valid
        Dim $valids[$array_softs[0][0]][2]   
        $valid_nb = 0
        For $i = 1 To $array_softs[0][0]
            If BitAnd(GUICtrlRead($array_softs[$i][0]), $GUI_CHECKED) = $GUI_CHECKED Then
                $valids[$valid_nb][0] = $array_softs[$i][0]
                $valids[$valid_nb][1] = $array_softs[$i][1]
                $valid_nb += 1
            EndIf
        Next
        Redim $valids[$valid_nb][2]
            _ArrayDisplay($valids,"verif $valids")
        _Run_Install()      ; lance l'install
EndSwitch
Wend





Func _ListZeGroups()
Local $h = 10, $n = 1, $g = 0, $str, $sections = IniReadSectionNames($ini)
Local $a_groupes = IniReadSection($ini, "Groupes")   ; groupe1, groupe2, etc
$gui2 = GUICreate("Child", 200, 280, 0, 30, $WS_CHILD, $WS_EX_CLIENTEDGE, $gui)
For $i = 1 to $sections[0]
      For $j = 1 To $a_groupes[0][0]
      If $sections[$i] = $a_groupes[$j][0] Then
         $str = ""
         $g += 1
         Redim $array_groupes[$g][3]
         $array_groupes[$g-1][0] = GUICtrlCreateCheckbox($sections[$i], 10, $h, 300, 20)
         GUICtrlSetResizing(-1, 802)
         $array_groupes[$g-1][1] = $sections[$i]
         $h += 20
         $zisgroup = IniReadSection($ini, $sections[$i])
         For $k = 1 to $zisgroup[0][0]
                  $n += 1
                  Redim $array_softs[$n][3]
                  $array_softs[$n-1][1] = $zisgroup[$k][0]
                  $array_softs[$n-1][2] = $zisgroup[$k][1]
                  $array_softs[$n-1][0] = GUICtrlCreateCheckbox("  "& $zisgroup[$k][0] &"  "& $zisgroup[$k][1], 40, $h, 400, 20)
                      GUICtrlSetResizing(-1, 802)
                  $h += 18
              $str &= $zisgroup[$k][0] & "#"
         Next
         $array_groupes[$g-1][2] = StringTrimRight($str, 1)
         $h += 15
     EndIf
     Next
Next
$array_softs[0][0] = $n-1
GuiSetState()
EndFunc


Func _Run_Install()
For $i = 0 To $valid_nb-1
    ShellExecuteWait(@scriptdir & "\" & $valids[$i][1] & "\install.cmd")    ; app1\install.cmd , etc
Next
Msgbox(0,"", "install terminé")
EndFunc


Func WM_VSCROLL($hWnd, $Msg, $wParam, $lParam)
    #forceref $Msg, $wParam, $lParam
    Local $nScrollCode = BitAND($wParam, 0x0000FFFF)
    Local $index = -1, $yChar, $yPos
    Local $Min, $Max, $Page, $Pos, $TrackPos

    For $x = 0 To UBound($aSB_WindowInfo) - 1
        If $aSB_WindowInfo[$x][0] = $hWnd Then
            $index = $x
            $yChar = $aSB_WindowInfo[$index][3]
            ExitLoop
        EndIf
    Next
    If $index = -1 Then Return 0

    Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
    $Min = DllStructGetData($tSCROLLINFO, "nMin")
    $Max = DllStructGetData($tSCROLLINFO, "nMax")
    $Page = DllStructGetData($tSCROLLINFO, "nPage")
    ; Save the position for comparison later on
    $yPos = DllStructGetData($tSCROLLINFO, "nPos")
    $Pos = $yPos
    $TrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")

    Switch $nScrollCode
        Case $SB_TOP ; user clicked the HOME keyboard key
            DllStructSetData($tSCROLLINFO, "nPos", $Min)
        Case $SB_BOTTOM ; user clicked the END keyboard key
            DllStructSetData($tSCROLLINFO, "nPos", $Max)
        Case $SB_LINEUP ; user clicked the top arrow
            DllStructSetData($tSCROLLINFO, "nPos", $Pos - 1)
        Case $SB_LINEDOWN ; user clicked the bottom arrow
            DllStructSetData($tSCROLLINFO, "nPos", $Pos + 1)
        Case $SB_PAGEUP ; user clicked the scroll bar shaft above the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $Pos - $Page)
        Case $SB_PAGEDOWN ; user clicked the scroll bar shaft below the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $Pos + $Page)
        Case $SB_THUMBTRACK ; user dragged the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $TrackPos)
    EndSwitch

    DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    $Pos = DllStructGetData($tSCROLLINFO, "nPos")

    If ($Pos <> $yPos) Then
        _GUIScrollBars_ScrollWindow($hWnd, 0, $yChar * ($yPos - $Pos))
        $yPos = $Pos
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_VSCROLL
 

Là encore, manque juste la gestion d'erreur

[Izarra4autoit]

Bonjour Mikell !

Après plusieurs mois d'utilisation de la dernière modification du script - merci encore !
je voudrais maintenant aller un peu plus loin car j'ai maintenant une quarantaine de softs à prendre en compte
l'utilisation du fichier INI est parfaite
je me sens beaucoup moins à l'ise avec le scrolling et j'aimerais modifier ce dernier script de la manière suivante
- afficher une GUI prenant 80% de la taille de l'écran
- créer 5 colonnes pouvant contenir chacune 20 options/lignes maxi
- ce qui me fera gérer 5 groupes (chacun avec 20 options max)
- sans barre de scrolling
- et bien sur, toujours le même mode op (a chaque sous dossier correspond un install.cmd) ca marche nickel

j'ai du mal à définir l'emplacement d'affichage de chaque colonne !
pourrais tu m'y aider ?
merci !!