[..] Notificateur de message Gmail ,Hotmail,Free ...

[orax]

Orax, votre script ne marche pas chez moi, même en mettant mes propres URLs.

Vous n'auriez pas oublié l'UDF ? http://www.autoitscript.com/forum/index ... t&id=22263 ; il faut aussi s'être authentifié avec IE précédemment. Si le nombre de messages n'est pas trouvé, ça affiche "Erreur", "Probablement non connecté". Sinon si c'est une autre erreur ça affiche simplement la ligne où s'est produite l'erreur -> MsgBox(0, "", @ScriptLineNumber).

[BeCool]

Je n'ai pas oublié l'UDF mais quand je lance le script pour le tester, dans la console, il me met ce message d'erreur :

Code : Tout sélectionner

C:\Program Files\AutoIt3\Include\WinINetConstants.au3(29,136) : ERROR: $tagSYSTEMTIME previously declared as a 'Const'
Global Const $tagSYSTEMTIME = "word Year; word Month; word DayOfWeek; word Day; word Hour; word Minute; word Second; word Milliseconds"

Message que je ne comprend pas ... :s

[orax]

Je n'ai pas oublié l'UDF mais quand je lance le script pour le tester, dans la console, il me met ce message d'erreur :

C'est que vous avez peut-être ajouté d'autres #includes que #include <WinINet.au3> dans le script. Il met ce message puisque la constante a déjà été déclarée (dans un autre fichier probablement). Si vous créé un script vide et que vous ne mettiez que mon script, ça devrait marcher.

[BeCool]

Pour Gmail ça marche mais pas pour hotmail :p

Et effectivement, le fait qu'il y ait d'autres includes, votre script n'aimait pas trop ça ^^

[pierrotm777]

Bonjour à tous ,

Si je test le script (dernière version d'autoit) , voici ce que j'obtiens :

Code : Tout sélectionner

C:\tmp\AutoIt\Gmail\WinINetConstants.au3(5,102) : ERROR: undefined macro.
Global Const $AU3_UNICODE = Number($AU3_VERSION[2] & "." & $AU3_VERSION[3]) >= 2.13 Or @AutoItUnicode
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\tmp\AutoIt\Gmail\gmail_hotmail_1.au3 - 1 error(s), 0 warning(s)
 

[orax]

Si je test le script (dernière version d'autoit) , voici ce que j'obtiens :

Dans WinINetConstants.au3 (ligne 5) vous devez supprimer " Or @AutoItUnicode". Ce n'est pas de ma faute, c'est de la faute de celui qui a créé le script , la macro @AutoItUnicode a dû être supprimée depuis.

[pierrotm777]

C'est déjà mieux,

j'ai une erreur " Probablement non connceté" . Où doit on configurer son mail et passwd svp ?

[orax]

vous devez être déjà connecté avec IE

Vous devez vous authentifié avec IE auparavant (en cochant "Mémoriser mon adresse de messagerie et mon mot de passe"). Mais laissez tomber ce script, je vais faire un truc fonctionnel.

[pierrotm777]

OK Merci et au plaisir

[orax]

Voici un code qui, chez moi en tout cas, semble fonctionnel. Par contre vous avez toujours besoin de vous authentifier à l'avance avec IE ; il faudra que je revoie les fonctions pour pouvoir s'authentifier automatiquement mais je poste quand même le code incomplet pour s'assurer qu'il fonctionne...
Chose importante : si le contenu des pages change alors il faudra peut-être refaire les expressions régulière. Enfin bref, cette méthode n'est vraiment pas parfaite... mais vu que vous ne souhaitez pas utiliser openssl...

Il n'y a plus besoin de l'UDF WinInet (je voulais m'en servir pour faire des PUT mais vu que j'ai utilisé IE pour m'authentifier, je n'ai plus besoin de l'udf).

► Afficher le texte

Code : Tout sélectionner

#include <Inet.au3>
#include <IE.au3>

Global Const $UTILISATEUR_HOTMAIL = "orax@hotmail.com"
Global Const $MOT_DE_PASSE_HOTMAIL = "mouarf"

Global Const $UTILISATEUR_GMAIL = "orax@hotmail.com"
Global Const $MOT_DE_PASSE_GMAIL = "mouarf"

Global Const $URL_HOTMAIL = "http://mail.live.com/?rru=inbox"
Global Const $URL_GMAIL = "http://mail.google.com/mail/h/"

Global $dbg = True ; déboguage...

Global $urlMessages_hotmail
Global $urlMessages_gmail

; boucle principale
While 1
    uhuh()
    
    Sleep(60 * 1000 * 15) ; 15 mins
WEnd

Func uhuh()
    Local $nbMessages, $msg
    
    If $dbg Then ConsoleWrite(@CRLF & "+> Vérifie les messages sur Hotmail :" & @CRLF)
    $nbMessages = verifieMessages_hotmail()
    If $nbMessages Then $msg = $nbMessages & " messages sur hotmail !" & @CRLF
    
    If $dbg Then ConsoleWrite(@CRLF & "+> Vérifie les messages sur Gmail :" & @CRLF)
    $nbMessages = verifieMessages_gmail()
    If $nbMessages Then $msg &= $nbMessages & " messages sur gmail !" & @CRLF
    
    If $nbMessages Then TrayTip("Nouveau messages", $msg, 5000, 1)
EndFunc   ;==>uhuh

Func verifieMessages_hotmail()
    Local $nbMessages
    Local $urlMessages
    
    $urlMessages = recupereUrlMessage_hotmail()
    
    If Not $urlMessages Then
        ; si non authentifié alors on lance l'authentification
        authentification_hotmail()
        
        $urlMessages = recupereUrlMessage_hotmail()
        
        If @error Or Not $urlMessages Then
            ConsoleWriteError(@ScriptLineNumber)
            
            Exit -1
        EndIf
    EndIf

    ; récupère le code source de l'adresse de base des messages
    $html = ouvreUrl($urlMessages)

    ; récupère le nombre de messages
    $expReg = StringRegExp($html, _
            '(?i)<div\s+class="PageNavigationMsgRange">\s*(\d+)\s+messages\s*</div>', _
            3)
    
    If Not UBound($expReg) Then
        ; non connecté
        MsgBox(0, "Erreur", "Probablement non connecté")
        
        Exit -1
    Else
        $nbMessages = $expReg[0]
    EndIf
    
    Return $nbMessages
EndFunc   ;==>verifieMessages_hotmail

Func verifieMessages_gmail()
    Local $nbMessages
    Local $urlMessages

    $urlMessages = recupereUrlMessage_gmail()

    If Not $urlMessages Then
        ; si non authentifié alors on lance l'authentification
        authentification_gmail()
        
        $urlMessages = recupereUrlMessage_gmail()
        
        If @error Or Not $urlMessages Then
            ConsoleWriteError(@ScriptLineNumber)
            
            Exit -1
        EndIf
    EndIf

    ; récupère le code source de l'adresse de base des messages
    $html = ouvreUrl($urlMessages, 1)

    ; récupère le nombre de messages
    $expReg = StringRegExp($html, _
            '(?i)<a\s+href="\?"\s+accesskey="i">\s*Bo..?te\s+de\s+r..?ception&nbsp;\((\d+)\)\s*</a>', _
            3)
    
    If Not UBound($expReg) Then
        ; non connecté
        MsgBox(0, "Erreur", "Probablement non connecté")
        
        Exit -1
    Else
        $nbMessages = $expReg[0]
    EndIf

    Return $nbMessages
EndFunc   ;==>verifieMessages_gmail

Func recupereUrlMessage_hotmail()
    If $dbg Then dbg("recupereUrlMessage_hotmail", @ScriptLineNumber)
    
    Local Const $pathExpReg = '(?i)<iframe\s+id="UIFrame"\s+onload="uiFrameLoad\(\)"\s+src="(http&#58;&#47;&#47;[\w\.]+\.mail\.live\.com.*?)"'
    Local $html, $expReg, $url = $URL_HOTMAIL

    ; récupère le code source de la page
    If $urlMessages_hotmail Then
        If $dbg Then dbg("recupere code source via _INetGetSource à " & $urlMessages_hotmail, @ScriptLineNumber)
        
        $html = _INetGetSource($urlMessages_hotmail)
        
        ; récupère l'URL des messages
        $expReg = StringRegExp($html, $pathExpReg, 3)
        
        If Not UBound($expReg) Then
            ; si l'URL des messages $urlMessages_... n'était pas la bonne
            ; alors il faut la récupérer
            If $dbg Then dbg("le code source via _INetGetSource n'a pu être récupérer ; tente de récupérer l'URL", @ScriptLineNumber)
            
            ouvreUrl($url)
            
            $urlMessages_hotmail = $url
        EndIf
    Else
        $html = ouvreUrl($url)
        
        $urlMessages_hotmail = $url
    EndIf

    ; récupère l'URL des messages
    If Not UBound($expReg) Then
        $expReg = StringRegExp($html, $pathExpReg, 3)
        
        If Not UBound($expReg) Then
            ; non connecté
            ConsoleWriteError("Probablement non connecté (hotmail)" & @CRLF)
            
            Return SetError(1, "", "")
        EndIf
    EndIf

    $url = codageHtmlVersTxt($expReg[0])
    
    Return $url
EndFunc   ;==>recupereUrlMessage_hotmail

Func authentification_hotmail()
    If $dbg Then dbg("authentification_hotmail", @ScriptLineNumber)

    Local $oIE = _IECreateEmbedded()
    Local $gui = GUICreate("", 0, 0)
    Local $GUIActiveX = GUICtrlCreateObj($oIE, 0, 0, 0, 0)

    _IENavigate($oIE, "https://login.live.com/")

    Local $o_form = _IEFormGetObjByName($oIE, "f1")
    Local $o_login = _IEFormElementGetObjByName($o_form, "login")
    Local $o_password = _IEFormElementGetObjByName($o_form, "passwd")
    Local $o_signin = _IEFormElementGetObjByName($o_form, "SI")

    _IEFormElementRadioSelect($o_form, "1", "LoginOptions") ; coche "Mémoriser mon adresse de messagerie et mon mot de passe"

    _IEFormElementSetValue($o_login, $UTILISATEUR_HOTMAIL)
    _IEFormElementSetValue($o_password, $MOT_DE_PASSE_HOTMAIL)

    _IEAction($o_signin, "click")

    _IELoadWait($oIE)

    GUIDelete($gui)
EndFunc   ;==>authentification_hotmail

Func recupereUrlMessage_gmail()
    If $dbg Then dbg("recupereUrlMessage_gmail", @ScriptLineNumber)
    
    Local Const $urlDefaut = "http://mail.google.com/"
    Local $html, $expReg, $url = $URL_GMAIL
    
    ; récupère le code source de la page
    If $urlMessages_gmail Then
        If $dbg Then dbg("recupere code source via _INetGetSource à " & $urlMessages_gmail, @ScriptLineNumber)
        
        $html = _INetGetSource($urlMessages_gmail)
        
        ; vérifie que l'URL des messages est bonne
        If StringLeft($url, StringLen($urlDefaut)) <> $urlDefaut Then
            ; si l'URL des messages $urlMessages_... n'était pas la bonne
            ; alors il faut la récupérer
            If $dbg Then dbg("le code source via _INetGetSource n'a pu être récupérer ; tente de récupérer l'URL", @ScriptLineNumber)
            
            $html = ouvreUrl($url, 1)
            
            $urlMessages_gmail = $url
        EndIf
    Else
        $html = ouvreUrl($url, 1)
        
        $urlMessages_gmail = $url
    EndIf
    
    ; récupère le code source de la page
    $html = ouvreUrl($url, 1)

    ; vérifie que l'URL des messages est bonne
    If StringLeft($url, StringLen($urlDefaut)) <> $urlDefaut Then
        ; non connecté
        ConsoleWriteError("Probablement non connecté (gmail)" & @CRLF)
        
        Return SetError(1, "", "")
    EndIf
    
    Return $url
EndFunc   ;==>recupereUrlMessage_gmail

Func authentification_gmail()
    If $dbg Then dbg("authentification_gmail", @ScriptLineNumber)

    Local $oIE = _IECreateEmbedded()
    Local $gui = GUICreate("", 0, 0)
    Local $GUIActiveX = GUICtrlCreateObj($oIE, 0, 0, 0, 0)
    
    _IENavigate($oIE, "https://www.google.com/accounts/ServiceLogin?service=mail")

    Local $o_gaia_loginform = _IEFormGetObjByName($oIE, "gaia_loginform")
    Local $o_email = _IEFormElementGetObjByName($o_gaia_loginform, "Email")
    Local $o_passwd = _IEFormElementGetObjByName($o_gaia_loginform, "Passwd")
    Local $o_signin = _IEFormElementGetObjByName($o_gaia_loginform, "signIn")

    _IEFormElementSetValue($o_email, $UTILISATEUR_GMAIL)
    _IEFormElementSetValue($o_passwd, $MOT_DE_PASSE_GMAIL)

    _IEAction($o_signin, "click")

    _IELoadWait($oIE)

    GUIDelete($gui)
EndFunc   ;==>authentification_gmail

Func ouvreUrl(ByRef $url, $nbRedirections = 0)
    If $dbg Then dbg("ouvreUrl " & $url & " " & $nbRedirections, @ScriptLineNumber)

    Local $html, $i = 1, $expReg
    
    While 1
        ; récupère le code source
        $html = _INetGetSource($url)

        ; vérifie s'il y a une redirection
        $expReg = StringRegExp($html, '(?i)<base\s+href=["''](.*?)["'']/?>', 3)

        If UBound($expReg) Then
            If $expReg[0] = $url Then
                ExitLoop
            Else
                ; spécifie la nouvelle URL
                $url = $expReg[0]
            EndIf
        Else
            ExitLoop
        EndIf
        
        If $nbRedirections And $nbRedirections = $i Then ExitLoop
        
        $i += 1
        
        Sleep(10)
    WEnd
    
    Return $html
EndFunc   ;==>ouvreUrl

; peut être amélioré je pense...
Func codageHtmlVersTxt($codeHtml)
    Local $i
    Local $expReg = StringRegExp($codeHtml, "\&\#(\d+);", 3)
    
    For $i = 0 To UBound($expReg) - 1
        $codeHtml = StringReplace($codeHtml, _
                "&#" & $expReg[$i] & ";", _
                Chr($expReg[$i]), _
                1)
    Next
    
    Return $codeHtml
EndFunc   ;==>codageHtmlVersTxt

Func dbg($msg, $scriptLineNumber)
    ConsoleWrite("(" & $scriptLineNumber & ") : " & $msg & @CRLF)
EndFunc   ;==>dbg

Edité : script mis à jour (le 08/05 à 15h). Il est fonctionnel. verifieMessages_hotmail() et verifieMessages_gmail() renvoie le nombre de message et se connecte avec utilisateur/mdp si besoin (à configurer en haut du script dans les Global Const).

Edité (2) : évitez d'utiliser ce script puisqu'apparemment il ne marche plus (c'était à prévoir si le code HTML des sites change entre temps) et ce n'est vraiment pas un bon exemple... Pour GMail il y a beaucoup plus simple, voyez le message de pierrotm777, plus bas.

[laurent68]

bonjour,

http://www.poppeeper.com/ fait cela tres bien.

5 mn pour l'install + la config

[pierrotm777]

bonjour,

http://www.poppeeper.com/ fait cela tres bien.

5 mn pour l'install + la config

Je ne doute pas qu'il le fasse trés bien .

Mais je ne veux pas un exe tout fait , mais un script autoit
fait sur mesure afin de pouvoir l'intégrer dans un FrontEnd Carpc .

[pierrotm777]

Bien que ce sujet soit fermé , j'ai trouvé sur le forum us la réponse à ma question, alors pour ceux qui sont intéréssé.

http://www.autoitscript.com/forum/index ... pic=111853