[R] FileRead ne renvoit rien

[Faco]

dans ce cas coder dans un répertoire autre que le bureau, ce sera plus propre déjà

[TommyDDR]

Envoyez nous votre adresse postale, on pourra venir voir plus précisément ce qu'il se passe.

[iCitron]

C'est donc forcément un problème d'autorisation, de permissions, de compatibilité ou autre.
Des idées, des conseils? (A part de passer à w7)

[iCitron]

Envoyez nous votre adresse postale, on pourra venir voir plus précisément ce qu'il se passe.

En cas donnez moi la votre, et je vous envoie mon pc par colis?

(HUMOUR)
Non, plus sérieusement, je peux vous laisser passer par teamviewer si ça peut aider.

[orax]

Regarde les messages d'erreurs renvoyés.

► Afficher le texte

Code : Tout sélectionner

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <WinAPI.au3>
#include <WinAPIError.au3>

#RequireAdmin


Global Const $TEST_TXT = @ScriptDir & '\test.txt'

FileExists($TEST_TXT)
If @error Then _err('FileExists')

$file = FileOpen($TEST_TXT, $FO_READ)
If $file <> -1 Then
    $fileContent = FileRead($file)
    If $fileContent Then
        MsgBox($MB_OK, 'Content:', $fileContent)
    Else
        _err('FileRead : erreur ou fichier vide.')
    EndIf
Else
    _err('FileOpen')
EndIf
FileClose($file)

$fileContent = FileRead($TEST_TXT)
If $fileContent Then
    MsgBox($MB_OK, 'Content:', $fileContent)
Else
    _err('FileRead : erreur ou fichier vide.')
EndIf

$pid = Run(@ComSpec & ' /C dir ' & $TEST_TXT, @ScriptDir, @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($pid)
$stdout = StdoutRead($pid)
MsgBox($MB_OK, 'Test avec DIR', $stdout)

$pid = Run(@ComSpec & ' /C type ' & $TEST_TXT, @ScriptDir, @SW_HIDE, $STDOUT_CHILD)
ProcessWaitClose($pid)
$stdout = StdoutRead($pid)
MsgBox($MB_OK, 'Test avec TYPE', ($stdout) ? $stdout : 'Fichier vide !')


Func _err($msg = '', $codeRetour = '', $error = @error, $extended = @extended, $ligne = @ScriptLineNumber)
    $msgErr = 'Erreur (' & $ligne & ') : [' & @ScriptName & '] @error = ' & $error & ' @extended = ' & $extended & ' — ' & _
            'Erreur ' & _WinAPI_GetLastError() & ' "' & StringStripWS(_WinAPI_GetLastErrorMessage(), $STR_STRIPTRAILING) & '" — "' & $msg & '"'

    ConsoleWriteError($msgErr & @CRLF)
    $r = MsgBox($MB_YESNO + $MB_ICONERROR, Default, _
            'script : "' & @ScriptFullPath & '"' & @CRLF & @CRLF & _
            $msgErr & @CRLF & @CRLF & _
            'Continuer l’exécution du script ?')
    If $r = $IDNO Then
        If Not $error Then $error = -1
        Exit $error
    EndIf

    If @NumParams >= 2 Then
        ; Garde les codes d'erreur et retourne $codeRetour spécifié dans les paramètres.
        Return SetError($error, $extended, $codeRetour)
    Else
        ; Garde les codes d'erreur et retourne $error (@error).
        Return SetError($error, $extended, $error)
    EndIf
EndFunc   ;==>_err
 

Il y a aussi une autre chose à laquelle j'avais pensé : c'est le verrouillage pour l'accès en lecture du fichier. En d'autres termes un processus peut verrouiller l'accès en lecture au fichier. Il me semblait bien que ceci était possible à faire mais je voulais avoir la confirmation — que j'ai trouvée ici : http://msdn.microsoft.com/en-us/library ... 90%29.aspx « This code example opens the file in Binary mode for reading; other processes cannot read file. »

[TommyDDR]

Je doute que ça soit un problème de droit, sinon FileExist renverrait quand même true.
Pour rappel, vous voyez sur votre bureau ce qui se trouve dans :

Code : Tout sélectionner

C:\Users\VotreProfile\Desktop

ET

Code : Tout sélectionner

C:\Users\Public\Desktop

Mais ce n'est pas pour ça que les fichiers sont dans le même dossier.

Avez vous essayé autre part que sur le bureau ?

Pour savoir si le fichier se trouve réellement à coté de votre script, exécutez ça :

Code : Tout sélectionner

Global $search = FileFindFirstFile("*")
Global $file
While(True)
    $file = FileFindNextFile($search)
    If(@error) Then ExitLoop
    ConsoleWrite((@extended ? "Dossier" : "Fichier") & " : " & $file & @LF)
WEnd
FileClose($search)

Vous devriez voir votre txt dans la console.

[jguinch]

Ah oui Tommy, je vois bien le coup du bureau public Ca c'est vraiment le truc à la con
Avec ça aussi, ça devrait t'aider :

Code : Tout sélectionner

ShellExecute( @DesktopDir )
ShellExecute( @DesktopCommonDir )

[Alaghir]

Ah oui pas con le coup du bureau public, ça ne m'a pas effleuré l'esprit

[iCitron]

Problème résolu, un bureau public, c’était ça

Merci à tous !

[TommyDDR]

Pour vous servir.