[R] WinClose sur un PID

[unisev]

Bonjour,

J'utilise un script AutoIt (c'est mon premier) pour lancer et arrêter des programmes.

Je lance parfois plusieurs instances d'un même programme et j'identifie chaque session par son PID (renvoyé par la commande Run)

Le soucis c'est que mes programme se terminent "mieux" quand je les ferment avec la croix plutôt qu'avec ProcessClose().

Du coup ma question :

Comment utiliser WinClose() sur un PID ?

[unisev]

Une réponse ici :
http://www.autoitscript.fr/forum/viewto ... f=3&t=3869

[jguinch]

Voilà une solution :

► Afficher le texte

Code : Tout sélectionner

$iPid = Run("notepad.exe")
$hWin = _WinWaitPID($iPid)
Sleep(3000)
WinClose($hWin)
 
 
; #FUNCTION# ====================================================================================================================
; Name ..........: _WinWaitPID
; Description ...: Pauses execution of the script until a window associated with the specifed PID exists
; Syntax ........: _WinWaitPID($iPid[, $iFlagActive = 0[, $iTimeout = 0]])
; Parameters ....: $iPid                - Process ID (PID).
;                  $iFlagActive         - [optional] . 0 = (default) Returns as soons as the window appears.
;                                                      1 = Waits for the window to be active.
;                  $iTimeout            - Timeout in seconds if the window does not exist. Default is 0 (no timeout).
; Return values .: Success = a handle to the window.
;                  Failure = 0 if timeout occured
; Author ........: jguinch
; ===============================================================================================================================
Func _WinWaitPID($iProcessID, $iFlagActive = 0, $iTimeout = 0)
    Local $hTimer = TimerInit()
    $iTimeout = $iTimeout * 1000
 
    While 1
        If $iTimeout AND TimerDiff($hTimer) >= $iTimeout Then Return 0
 
        Local $aWinList = WinList()
        For $i = 1 To $aWinList[0][0]
            If $aWinList[$i][0] <> "" And BitAND(WinGetState($aWinList[$i][1]), 2) Then
                If WinGetProcess($aWinList[$i][1]) = $iProcessID Then
                    If $iFlagActive Then
                        If WinActive($aWinList[$i][1]) Then Return $aWinList[$i][1]
                    Else
                        Return $aWinList[$i][1]
                    EndIf
                EndIf
 
            EndIf
        Next
        Sleep(10)
 
    WEnd
EndFunc ; ===> _WinWaitPID
 

[mikell]

Une autre...

[walkson]

Et encore une autre (du forum us)

► Afficher le texte

Code : Tout sélectionner

; Returns an array of all Windows associated with a given process
Func WinHandFromPID($prog, $winTitle = "", $timeout = 5)
    Local $secs = TimerInit()
        $pid = ProcessExists($prog)
        If $pid = "" Then Exit MsgBox(0,"Erreur","programme non reconnu")
    Do
        If $winTitle = "" Then
            $wins = WinList()
        Else
            $wins = WinList($winTitle)
        EndIf

        For $i = UBound($wins) - 1 To 1 Step -1
            ;ConsoleWrite(">>>" & $wins[$i][1] & @CR)
            If (WinGetProcess($wins[$i][1]) <> $pid) Or (BitAND(WinGetState($wins[$i][1]), 2) = 0) Then _ArrayDelete($wins, $i)
        Next
        $wins[0][0] = UBound($wins) - 1
        If $wins[0][0] Then Return SetError(0, 0, $wins)
        Sleep(1000)
    Until TimerDiff($secs) >= $timeout * 1000
    Return SetError(1, 0, $wins)
EndFunc   ;==>WinHandFromPID

[unisev]

Merci à tous,

Je suis toujours sur la solution de mon premier lien, ça fonctionne pour ce que je fait .

En tout cas vos réponses donnent envie de revenir sur ce forum !