[R] Problème sur la sortie de scripts

[caropost]

Bonjour à tous, je sollicite une nouvelle fois votre aide

J'ai Script1.exe qui fait appel à une fonction MyFunction(arg1, arg2, arg3) qui se trouve dans Script2.exe. Une fois que MyFunction a fini son exécution, le programme continu sur Script1.exe.
Dans MyFunction, j'utilise la fonction Expect qui est définie ici : https://www.autoitscript.com/forum/topi ... ntry890269
Le but est que si le mot n'est pas trouvé, un message d'erreur s'affiche et lorsqu'on clic sur "OK" on sort des 2 scripts. Je l'ai donc un peu modifiée :

► Afficher le texteExpect

Code : Tout sélectionner

func _Expect($match_text, $_plinkhandle)
   local $text
   local $sBuffertext
   local $count = 0
   Local $exit = False
   local $found
   local $iBegin = TimerInit()
   While 1
      if TimerDiff($iBegin) > $_plink_timeout then return false
      if $count = 10 Then
         MsgBox(0, "Erreur", '"' & $match_text & '"' & " n'a pas été trouvé.")
         $exit = True
         ClipPut($exit)
         Exit
      EndIf
      $text = StdoutRead($_plinkhandle)
      $sBuffertext = $sBuffertext & $text
      if $_plink_logging Then
         filewriteline($_plink_logfile_handle,"**********************NEW SECTION************************")
         FileWriteLine($_plink_logfile_handle, "expect : " & $match_text)
         FileWriteLine($_plink_logfile_handle, "read : " & $text)
;          filewriteline($_plink_logfile_handle,"**********************END SECTION************************")
      endif
      $count = $count+1
      $found = StringRegExp($text,$match_text)
      If $found = 1 Then
;         If $_plink_display_messages Then MsgBox(4096, $match_text, $text, $_plink_display_message_time)
         ExitLoop
      Endif
      sleep(1000)
   Wend
   ClipPut($exit)
   return $sBuffertext
EndFunc

J'ai commencé par faire un simple "exit" si le mot n'était pas trouvé mais je ne faisais que sortir de Script2.exe et le programme continuait sur Script1.exe, ce qu'on ne veut pas.
Pour cela, j'ai ajouté la variable $exit. Je la met à "FALSE" de base mais lorsqu'un mot n'est pas trouvé, je la variable devient "TRUE". Et dans Script1.exe, j'ai mis ceci :

Code : Tout sélectionner

ShellExecuteWait(Script2.exe', $var1 & ' ' & $var2 & ' ' & $var3, $directory)
$exit = ClipGet()
Local $exit = ClipGet()
If $exit = True Then Exit

Sachant que j'ai déclaré au début du script que $exit = False. Avec un MsgBox, je vois bien que $exit prend True ou False correctement mais dans les 2 cas, il sort des 2 scripts, même si MyFunction va jusqu'au bout correctement
Sauriez-vous m'aider svp ?

[mikell]

Code : Tout sélectionner

ClipPut(False)
$c = ClipGet()

If IsBool($c) Then Msgbox(0,"bool", $c)
If IsString($c) Then Msgbox(0,"string", $c)
If $c = True Then Msgbox(0,"test", $c)

[orax]

► Afficher le texte

Code : Tout sélectionner

Func _Expect($match_text, $_plinkhandle)
    Local $text
    Local $sBuffertext
    Local $count = 0
    Local $found
    Local $iBegin = TimerInit()
    While 1
        If TimerDiff($iBegin) > $_plink_timeout Then Return False
        If $count = 10 Then
            MsgBox(16, "Erreur", '"' & $match_text & '"' & " n'a pas été trouvé.")
            Exit 1
        EndIf
        $text = StdoutRead($_plinkhandle)
        $sBuffertext = $sBuffertext & $text
        If $_plink_logging Then
            FileWriteLine($_plink_logfile_handle, "**********************NEW SECTION************************")
            FileWriteLine($_plink_logfile_handle, "expect : " & $match_text)
            FileWriteLine($_plink_logfile_handle, "read : " & $text)
            ;          filewriteline($_plink_logfile_handle,"**********************END SECTION************************")
        EndIf
        $count = $count + 1
        $found = StringRegExp($text, $match_text)
        If $found = 1 Then
            ;         If $_plink_display_messages Then MsgBox(4096, $match_text, $text, $_plink_display_message_time)
            ExitLoop
        EndIf
        Sleep(1000)
    WEnd
    Return $sBuffertext
EndFunc   ;==>_Expect

Si Script1 quitte avec une valeur différente de 0 (0 est la valeur de retour par défaut) alors Script2 s'arrêtera.

Code : Tout sélectionner

Local $exit = ShellExecuteWait('Script2.exe', $var1 & ' ' & $var2 & ' ' & $var3, $directory)
If $exit Then Exit

[caropost]

Que ce soit True ou False j'ai les fenêtres "String" et "test" qui s'ouvrent...
J'ai fais une petite modification :

Code : Tout sélectionner

If IsBool($c) Then Msgbox(0,"bool", $c)
If IsString($c) Then Msgbox(0,"string", $c)
If $c = True Then
   Msgbox(0,"test true", $c)
Else
   Msgbox(0,"test false", $c)

Et bien que j'obtenais "False" dans la fenêtre String", il m'ouvrait la fenêtre "test true" oO
Par contre, si je mets :

Code : Tout sélectionner

If $c = "True" Then
   Msgbox(0,"test true", $c)
Else
   Msgbox(0,"test false", $c)

Là c'est bien reconnu... Merci

[caropost]

► Afficher le texte

Code : Tout sélectionner

Func _Expect($match_text, $_plinkhandle)
    Local $text
    Local $sBuffertext
    Local $count = 0
    Local $found
    Local $iBegin = TimerInit()
    While 1
        If TimerDiff($iBegin) > $_plink_timeout Then Return False
        If $count = 10 Then
            MsgBox(16, "Erreur", '"' & $match_text & '"' & " n'a pas été trouvé.")
            Exit 1
        EndIf
        $text = StdoutRead($_plinkhandle)
        $sBuffertext = $sBuffertext & $text
        If $_plink_logging Then
            FileWriteLine($_plink_logfile_handle, "**********************NEW SECTION************************")
            FileWriteLine($_plink_logfile_handle, "expect : " & $match_text)
            FileWriteLine($_plink_logfile_handle, "read : " & $text)
            ;          filewriteline($_plink_logfile_handle,"**********************END SECTION************************")
        EndIf
        $count = $count + 1
        $found = StringRegExp($text, $match_text)
        If $found = 1 Then
            ;         If $_plink_display_messages Then MsgBox(4096, $match_text, $text, $_plink_display_message_time)
            ExitLoop
        EndIf
        Sleep(1000)
    WEnd
    Return $sBuffertext
EndFunc   ;==>_Expect

Si Script1 quitte avec une valeur différente de 0 (0 est la valeur de retour par défaut) alors Script2 s'arrêtera.

Code : Tout sélectionner

Local $exit = ShellExecuteWait('Script2.exe', $var1 & ' ' & $var2 & ' ' & $var3, $directory)
If $exit Then Exit

Je n'avais pas vu ton post lorsque j'ai posté mon précédent, je ne l'ai vu qu'hier et effectivement ça fonctionne bien Merci beaucoup parce que ça m'a permit de faire facilement quelque chose qui était prévu dans une V2