[R] Listview avec case à cocher mais indépendante

[franco]

Bonjour.

Je sais faire les listview avec des checkbox.
Le souci : j'aimerais qu'une seule case soit cochée.

Plus précisément, je ne veux pas qu'on puisse cocher plusieurs cases à la fois.
En gros, si une case est cochée, les autres sont automatiquement décochées.

Est-ce possible ?


Mon script est déjà codé.
Je vous joins un script minimaliste :

► Afficher le textecode

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
Global $Form1 = GUICreate("Form1", 466, 120, 192, 124)
$DNS_LV = GUICtrlCreateListView("test1|test2|test3",10,10,400,100, -1, $LVS_EX_CHECKBOXES + $WS_EX_CLIENTEDGE + $LVS_EX_GRIDLINES)
GUICtrlCreateListViewItem("1|2|3",$DNS_LV)
GUICtrlCreateListViewItem("4|5|6",$DNS_LV)
GUICtrlCreateListViewItem("7|8|9",$DNS_LV)
GUISetState(@SW_SHOW)


While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit

 EndSwitch
WEnd
 

Et le script détaillé :

► Afficher le textecode

Code : Tout sélectionner

#include <file.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>
$FMDNS_Dir = @TempDir & "\FindMyDNS"
DirRemove($FMDNS_Dir, 1)
DirCreate($FMDNS_Dir)
;~ _ListDNS()

Global $Form1 = GUICreate("Form1", 900, 400, 192, 124)

$DNS_LV = GUICtrlCreateListView("Clé|Interface (CLSID)|NameServer/DhcpNameServer",10,50,400,200, -1, $LVS_EX_CHECKBOXES + $WS_EX_CLIENTEDGE + $LVS_EX_GRIDLINES)
_ListDNS()
GUICtrlSendMsg($DNS_LV, $LVM_SETCOLUMNWIDTH, 0, $LVSCW_AUTOSIZE)
GUICtrlSendMsg($DNS_LV, $LVM_SETCOLUMNWIDTH, 1, $LVSCW_AUTOSIZE)
GUICtrlSendMsg($DNS_LV, $LVM_SETCOLUMNWIDTH, 2, $LVSCW_AUTOSIZE)
$width1 = _GUICtrlListView_GetColumnWidth($DNS_LV,0)
$width2 = _GUICtrlListView_GetColumnWidth($DNS_LV,1)
$width3 = _GUICtrlListView_GetColumnWidth($DNS_LV,2)
_GUICtrlListView_SetColumnWidth($DNS_LV,0,$width1+10)
_GUICtrlListView_SetColumnWidth($DNS_LV,1,$width2+10)
_GUICtrlListView_SetColumnWidth($DNS_LV,2,$width3+10)
$width = $width1+$width2+$width3+30
WinMove($Form1,"",10,10,$width+30)
GUICtrlSetPos ( $DNS_LV, 10,50 ,$width)




GUISetState(@SW_SHOW)


While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit

 EndSwitch
WEnd










Func _ListDNS()
    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($DNS_LV))
$FileKeyInterfaces = $FMDNS_Dir & "\KeyInterfaces.txt"
$FileKeyInterfaces2 = $FMDNS_Dir & "\KeyInterfaces2.txt"


$kDNS1 = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters\Interfaces"
$kDNS2 = "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\Tcpip\Parameters\Interfaces"
$kDNS3 = "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet002\Services\Tcpip\Parameters\Interfaces"


Global $a = 1
$tFKI = FileOpen($FileKeyInterfaces, 2)
While 1
    $KeyInterfaces = RegEnumKey($kDNS1, $a)
    If $KeyInterfaces = "" Then
        $a = 1
        ExitLoop
    EndIf
    FileWriteLine($tFKI, $kDNS1 & "\" & $KeyInterfaces)
    $a += 1
WEnd
While 1
    $KeyInterfaces = RegEnumKey($kDNS2, $a)
    If $KeyInterfaces = "" Then
        $a = 1
        ExitLoop
    EndIf
    FileWriteLine($tFKI, $kDNS2 & "\" & $KeyInterfaces)
    $a += 1
WEnd
While 1
    $KeyInterfaces = RegEnumKey($kDNS3, $a)
    If $KeyInterfaces = "" Then
        $a = 1
        ExitLoop
    EndIf
    FileWriteLine($tFKI, $kDNS3 & "\" & $KeyInterfaces)
    $a += 1
WEnd
FileClose($tFKI)


$tFKI2 = FileOpen($FileKeyInterfaces2, 2)
For $i = 1 To _FileCountLines($FileKeyInterfaces)
    If RegRead(FileReadLine($FileKeyInterfaces, $i), "NameServer") <> "" Then FileWriteLine($tFKI2, FileReadLine($FileKeyInterfaces, $i) & "|" & RegRead(FileReadLine($FileKeyInterfaces, $i), "NameServer"))
    If RegRead(FileReadLine($FileKeyInterfaces, $i), "DhcpNameServer") <> "" Then FileWriteLine($tFKI2, FileReadLine($FileKeyInterfaces, $i) & "|" & RegRead(FileReadLine($FileKeyInterfaces, $i), "DhcpNameServer"))
Next


FileWriteLine($tFKI2, "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters" & "|" & "FAI" &"|"& RegRead("HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters", "DhcpNameServer"))
FileClose($tFKI2)
_ReplaceStringInFile($FileKeyInterfaces2,$kDNS1&"\",$kDNS1&"|")
_ReplaceStringInFile($FileKeyInterfaces2,$kDNS2&"\",$kDNS2&"|")
_ReplaceStringInFile($FileKeyInterfaces2,$kDNS3&"\",$kDNS3&"|")
FileMove($FileKeyInterfaces2,$FileKeyInterfaces,1)

For $i = 1 to _FileCountLines($FileKeyInterfaces)
    GUICtrlCreateListViewItem(FileReadLine($FileKeyInterfaces,$i),$DNS_LV)
    Next

EndFunc

Merci de m'éclairer ma petite lanterne.


++

[jbnh]

Bon c'est pas terrible terrible, mais ca pourrait donner une piste :

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>


Global $Form1 = GUICreate("Form1", 466, 120, 192, 124)
$DNS_LV = GUICtrlCreateListView("test1|test2|test3",10,10,400,100, -1, $LVS_EX_CHECKBOXES + $WS_EX_CLIENTEDGE + $LVS_EX_GRIDLINES)
$one = GUICtrlCreateListViewItem("1|2|3",$DNS_LV)
$two = GUICtrlCreateListViewItem("4|5|6",$DNS_LV)
$three = GUICtrlCreateListViewItem("7|8|9",$DNS_LV)
GUISetState(@SW_SHOW)


While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE  
   Exit
  Case $one
      If _IsChecked($one) Then
          GUICtrlSetState ($two, $GUI_UNCHECKED)
          GUICtrlSetState ($three, $GUI_UNCHECKED)
      endif 
 EndSwitch
WEnd
 
Func _IsChecked($idControlID)
    Return BitAND(GUICtrlRead($idControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked

Par contre l'unicité d'un check est gérée par les radio button...

[walkson]

Une autre solution toujours pas terrible

► Afficher le texte

Code : Tout sélectionner

    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    #include <GuiListView.au3>
    Global $Form1 = GUICreate("Form1", 466, 120, 192, 124)
    $DNS_LV = GUICtrlCreateListView("test1|test2|test3",10,10,400,100, -1, BitOR($LVS_EX_CHECKBOXES , $WS_EX_CLIENTEDGE , $LVS_EX_GRIDLINES))
    $aa = GUICtrlCreateListViewItem("1|2|3",$DNS_LV)
    $bb = GUICtrlCreateListViewItem("4|5|6",$DNS_LV)
    $cc = GUICtrlCreateListViewItem("7|8|9",$DNS_LV)
    GUISetState(@SW_SHOW)


    While 1
     $nMsg = GUIGetMsg()

     Switch $nMsg
      Case $GUI_EVENT_CLOSE
       Exit
        Case $aa
            _GUICtrlListView_SetItemChecked ( $DNS_LV, -1,False  )
            _GUICtrlListView_SetItemChecked ( $DNS_LV, 0,True  )
        Case $bb
            _GUICtrlListView_SetItemChecked ( $DNS_LV, -1,False  )
            _GUICtrlListView_SetItemChecked ( $DNS_LV, 1,True  )
        Case $cc
            _GUICtrlListView_SetItemChecked ( $DNS_LV, -1,False  )
            _GUICtrlListView_SetItemChecked ( $DNS_LV, 2,True  )

     EndSwitch
    WEnd

[Edit] peut être mieux ainsi surtout s'il y a beaucoup d'items

Code : Tout sélectionner

        Case $aa To $cc
            $y = 0
            For $i = $aa To $cc
                If $i = $nMsg Then ExitLoop
                $y += 1
            Next
            _GUICtrlListView_SetItemChecked ( $DNS_LV, -1,False  )
            _GUICtrlListView_SetItemChecked ( $DNS_LV, $y,True  )

[franco]

Salut à tous et merci de m'avoir répondu.

Le seul souci, c'est que je ne sais pas combien j'aurais d'item dans ma listview.


Du coup, je voulais utiliser ces deux fonctions :
_GUICtrlListView_GetItemChecked
_GUICtrlListView_SetItemChecked

En faisant comme ceci :
- Je détecte l'item sélectionné
- Je décoche donc les items précédents
- Je décoche donc les items suivants

Dans le cas présent, j'ai détecté l'item sélectionné.
Puis j'ai tout désélectionné.
Pour enfin resélectionner l'item détecté.

Et donc, faut que je mette cela dans la boucle while 1


Un exemple :

► Afficher le textecode

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

Global $Form1 = GUICreate("Form1", 466, 150, 192, 124)
$DNS_LV = GUICtrlCreateListView("test1|test2|test3", 10, 10, 400, 120, -1, $LVS_EX_CHECKBOXES + $WS_EX_CLIENTEDGE + $LVS_EX_GRIDLINES)
GUICtrlCreateListViewItem("1|2|3", $DNS_LV)
GUICtrlCreateListViewItem("4|5|6", $DNS_LV)
GUICtrlCreateListViewItem("7|8|9", $DNS_LV)
GUICtrlCreateListViewItem("10|11|12", $DNS_LV)
For $i = 1 To _GUICtrlListView_GetItemCount($DNS_LV)
    _GUICtrlListView_SetItemChecked($DNS_LV, $i, False)
Next

GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
$a = _GUICtrlListView_GetItemCount($DNS_LV)
        For $i = 0 To _GUICtrlListView_GetItemCount($DNS_LV)-1
        If _GUICtrlListView_GetItemChecked($DNS_LV, $i) = "true" Then $a = $i
        _GUICtrlListView_SetItemChecked($DNS_LV, $i, False)
    Next
    _GUICtrlListView_SetItemChecked($DNS_LV, $a, True)
    Sleep(50)
WEnd
 

Le seul souci : si je coche la 1, puis la 2, puis la 3(etc), ca fonctionne...
Le reste se décoche.

Mais si je coche la 2, je ne peux pas cocher la 1 : ça reste cocher sur la 2.


Une idée ?


Merci.

[walkson]

et par cette méthode ?

► Afficher le texte

Code : Tout sélectionner

    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    #include <GuiListView.au3>
    Local $aa[4]
    Global $Form1 = GUICreate("Form1", 466, 120, 192, 124)
    $DNS_LV = GUICtrlCreateListView("test1|test2|test3",10,10,400,100, -1, BitOR($LVS_EX_CHECKBOXES , $WS_EX_CLIENTEDGE , $LVS_EX_GRIDLINES))
    For $a = 0 To UBound($aa) - 1
    $aa [$a] = GUICtrlCreateListViewItem("1|2|3",$DNS_LV)
    Next

    GUISetState(@SW_SHOW)

    While 1
     $nMsg = GUIGetMsg()

     Switch $nMsg
      Case $GUI_EVENT_CLOSE
       Exit
        Case $aa[0] To $aa[UBound($aa) - 1]
            $y = 0
            For $i = $aa[0] To $aa[UBound($aa) - 1]
                If $i = $nMsg Then ExitLoop
                $y += 1
            Next
            _GUICtrlListView_SetItemChecked ( $DNS_LV, -1,False  )
            _GUICtrlListView_SetItemChecked ( $DNS_LV, $y,True  )

     EndSwitch
    WEnd
 

Il suffit de créer un array à la dimension de _FileCountLines($FileKeyInterfaces) selon votre code
Ce serait moins énergivore que d'écouter en permanence la listview (à mon humble avis)

[franco]

Resalut


Merci Walkson !!


Ton dernier script m'a donné la solution : un grand merci.
J'ai pu l'adapter à mon script de départ.

Et ça fonctionne.
Et oui.. Moins (beaucoup moins) énergivore.


Voici le script :

► Afficher le textecode

Code : Tout sélectionner

#include <file.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>

$FMDNS_Dir = @TempDir & "\FindMyDNS"
DirRemove($FMDNS_Dir, 1)
DirCreate($FMDNS_Dir)

Global $FileKeyInterfaces
Global $Form1 = GUICreate("Form1", 900, 400, 192, 124)

$DNS_LV = GUICtrlCreateListView("Clé|Interface (CLSID)|NameServer/DhcpNameServer", 10, 50, 400, 200, -1, $LVS_EX_CHECKBOXES + $WS_EX_CLIENTEDGE + $LVS_EX_GRIDLINES)
_ListDNS()
Local $aa[_FileCountLines($FileKeyInterfaces)]
For $a = 0 To UBound($aa) - 1
    $aa[$a] = GUICtrlCreateListViewItem(FileReadLine($FileKeyInterfaces, $a + 1), $DNS_LV)
Next

GUICtrlSendMsg($DNS_LV, $LVM_SETCOLUMNWIDTH, 0, $LVSCW_AUTOSIZE)
GUICtrlSendMsg($DNS_LV, $LVM_SETCOLUMNWIDTH, 1, $LVSCW_AUTOSIZE)
GUICtrlSendMsg($DNS_LV, $LVM_SETCOLUMNWIDTH, 2, $LVSCW_AUTOSIZE)
$width1 = _GUICtrlListView_GetColumnWidth($DNS_LV, 0)
$width2 = _GUICtrlListView_GetColumnWidth($DNS_LV, 1)
$width3 = _GUICtrlListView_GetColumnWidth($DNS_LV, 2)
_GUICtrlListView_SetColumnWidth($DNS_LV, 0, $width1 + 10)
_GUICtrlListView_SetColumnWidth($DNS_LV, 1, $width2 + 10)
_GUICtrlListView_SetColumnWidth($DNS_LV, 2, $width3 + 10)
$width = $width1 + $width2 + $width3 + 30
WinMove($Form1, "", 10, 10, $width + 30)
GUICtrlSetPos($DNS_LV, 10, 50, $width)

GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $aa[0] To $aa[UBound($aa) - 1]
            $y = 0
            For $i = $aa[0] To $aa[UBound($aa) - 1]
                If $i = $nMsg Then ExitLoop
                $y += 1
            Next
            _GUICtrlListView_SetItemChecked($DNS_LV, -1, False)
            _GUICtrlListView_SetItemChecked($DNS_LV, $y, True)


    EndSwitch
WEnd

Func _ListDNS()
    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($DNS_LV))
    $FileKeyInterfaces = $FMDNS_Dir & "\KeyInterfaces.txt"
    $FileKeyInterfaces2 = $FMDNS_Dir & "\KeyInterfaces2.txt"


    $kDNS1 = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters\Interfaces"
    $kDNS2 = "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\Tcpip\Parameters\Interfaces"
    $kDNS3 = "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet002\Services\Tcpip\Parameters\Interfaces"


    Global $a = 1
    $tFKI = FileOpen($FileKeyInterfaces, 2)
    While 1
        $KeyInterfaces = RegEnumKey($kDNS1, $a)
        If $KeyInterfaces = "" Then
            $a = 1
            ExitLoop
        EndIf
        FileWriteLine($tFKI, $kDNS1 & "\" & $KeyInterfaces)
        $a += 1
    WEnd
    While 1
        $KeyInterfaces = RegEnumKey($kDNS2, $a)
        If $KeyInterfaces = "" Then
            $a = 1
            ExitLoop
        EndIf
        FileWriteLine($tFKI, $kDNS2 & "\" & $KeyInterfaces)
        $a += 1
    WEnd
    While 1
        $KeyInterfaces = RegEnumKey($kDNS3, $a)
        If $KeyInterfaces = "" Then
            $a = 1
            ExitLoop
        EndIf
        FileWriteLine($tFKI, $kDNS3 & "\" & $KeyInterfaces)
        $a += 1
    WEnd
    FileClose($tFKI)


    $tFKI2 = FileOpen($FileKeyInterfaces2, 2)
    For $i = 1 To _FileCountLines($FileKeyInterfaces)
        If RegRead(FileReadLine($FileKeyInterfaces, $i), "NameServer") <> "" Then FileWriteLine($tFKI2, FileReadLine($FileKeyInterfaces, $i) & "|" & RegRead(FileReadLine($FileKeyInterfaces, $i), "NameServer"))
        If RegRead(FileReadLine($FileKeyInterfaces, $i), "DhcpNameServer") <> "" Then FileWriteLine($tFKI2, FileReadLine($FileKeyInterfaces, $i) & "|" & RegRead(FileReadLine($FileKeyInterfaces, $i), "DhcpNameServer"))
    Next


    FileWriteLine($tFKI2, "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters" & "|" & "FAI" & "|" & RegRead("HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters", "DhcpNameServer"))
    FileClose($tFKI2)
    _ReplaceStringInFile($FileKeyInterfaces2, $kDNS1 & "\", $kDNS1 & "|")
    _ReplaceStringInFile($FileKeyInterfaces2, $kDNS2 & "\", $kDNS2 & "|")
    _ReplaceStringInFile($FileKeyInterfaces2, $kDNS3 & "\", $kDNS3 & "|")
    FileMove($FileKeyInterfaces2, $FileKeyInterfaces, 1)
EndFunc   ;==>_ListDNS
 

Je passe en Résolu.

Merci à tous.