[R] Ecrire directement dans un tableau

[caropost]

Bonjour à tous,

Est-il possible d'afficher un tableau dont la première colonne est déjà remplie et de demander à l'utilisateur de remplir ce tableau directement, sans avoir à ouvrir une nouvelle fenêtre à chaque fois qu'on a un champ à remplir ?

Pour le moment, voilà ce que je fais :

► Afficher le texte

Code : Tout sélectionner

#include <Array.au3>

Local $tableau[10][2]

$nombre = InputBox("Nombre de fleurs", "Combien de fleurs à répertorier ?")

For $i = 1 to $nombre
    $tableau[$i-1][0] = "Fleur " & $i
    $saisie = InputBox("Nom de la fleur", "Entrer le nom de la fleur " & $i)
    $tableau[$i-1][1] = $saisie
Next

_ArrayDisplay($tableau, "Tableau récapitulatif ", "10|2", 2 + 64, 64, "Numéro | Nom de la fleur", Default, 0xDDFFDD)

Mais plutôt que d'ouvrir une boîte à chaque fois, je voudrais pouvoir afficher le tableau juste après avoir demandé un nombre, sélectionner une case et écrire dedans directement. Est-ce possible ? J'ai cherché dans la doc mais je n'ai pas trouvé ce que je cherchais (à moins qu'avec la fatigue, je sois passé à côté ^^)
Le tableau est juste un buffer, un peu plus loin je reprends ces informations petit à petit pour les enregistrer quelque part...

Merci par avance pour votre aide

[A2Energie]

Bonjour,

Désolé de ne pas répondre pour le moment à ta question mais voici une mise à jour de ton code avant la suite.

Code : Tout sélectionner

#include <Array.au3>

$nombre = InputBox("Nombre de fleurs", "Combien de fleurs à répertorier ?")

Local $tableau[$nombre][2]

For $i = 0 to $nombre - 1
    $tableau[$i][0] = "Fleur " & $i
    $saisie = InputBox("Nom de la fleur", "Entrer le nom de la fleur " & $i)
    $tableau[$i][1] = $saisie
Next

_ArrayDisplay($tableau, "Tableau récapitulatif ", "10|2", 2 + 64, 64, "Numéro | Nom de la fleur", Default, 0xDDFFDD)
 

[A2Energie]

Bonjour,

Je pense qu'il faut passer par des controls edits, mais je ne suis pas totalement sure de moi.

Voici un ptit exemple qui doit être amélioré :

Code : Tout sélectionner

#include <Array.au3>
#include <GUIConstantsEx.au3>
$nombre = InputBox("Nombre de fleurs", "Combien de fleurs à répertorier ?")

Local $tableau[$nombre][3]

$GUIList = GUICreate("Tableau récapitulatif", 220, 20*$nombre+20, 100, 200, -1, $WS_EX_ACCEPTFILES)
For $i = 0 to $nombre - 1
   $tableau[$i][2] = GUICtrlCreateEdit("", 10, 20*$i, 200, 18)
Next
$Button = GUICtrlCreateButton("Valider",10, 20*$nombre, 220, 18)
GUISetState(@SW_SHOW)

While 1
   $FTreeActionTemp = GUIGetMsg()
   If $FTreeActionTemp = $Button Then
      For $i = 0 to $nombre - 1
         $tableau[$i][0] = $i + 1
         $tableau[$i][1] = GUICtrlRead($tableau[$i][2])
      Next
      ExitLoop
   EndIf
WEnd

_ArrayDisplay($tableau, "Tableau récapitulatif ", "10|2", 2 + 64, 64, "Numéro | Nom de la fleur", Default, 0xDDFFDD)
 

[mikell]

Est-il possible d'afficher un tableau dont la première colonne est déjà remplie et de demander à l'utilisateur de remplir ce tableau directement, sans avoir à ouvrir une nouvelle fenêtre à chaque fois qu'on a un champ à remplir ?

Qui dit affichage dit gui, qui dit affichage de tableau dit listview, qui dit remplissage de tableau visuel et intuitif dit listview éditable
Dans ce code ça se fait par double-clic sur les subitems

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>

Opt("GuiCloseOnESC", 0)
Global $hEdit, $hDC, $hBrush, $Item = -1, $SubItem = 0
Global $Style = BitOR($WS_CHILD, $WS_VISIBLE, $ES_AUTOHSCROLL, $ES_LEFT)

$hGUI = GUICreate("ListView Subitems edit in place", 300, 200)

$hListView = _GUICtrlListView_Create($hGUI, "Items|SubItems", 2, 2, 296, 196, BitOR($LVS_EDITLABELS, $LVS_REPORT))
_GUICtrlListView_SetExtendedListViewStyle($hListView, $LVS_EX_GRIDLINES)

For $i = 1 To 10
    _GUICtrlListView_AddItem($hListView, "Item " & $i)
    _GUICtrlListView_AddSubItem($hListView, $i - 1, "SubItem " & $i, 1)
Next

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE


Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $tNMHDR, $hWndFrom, $iCode
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = DllStructGetData($tNMHDR, "hWndFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hListView
            Switch $iCode
                Case $NM_DBLCLK
                    Local $aHit = _GUICtrlListView_SubItemHitTest($hListView)
                    If ($aHit[0] <> -1) And ($aHit[1] > 0) Then
                        $Item = $aHit[0]
                        $SubItem = $aHit[1]
                        Local $aRect = _GUICtrlListView_GetSubItemRect($hListView, $Item, $SubItem)
                    Else
                        Return $GUI_RUNDEFMSG
                    EndIf
                    
                    Local $iItemText = _GUICtrlListView_GetItemText($hListView, $Item, $SubItem)
                    Local $iLen = _GUICtrlListView_GetStringWidth($hListView, $iItemText)
                    $hEdit = _GUICtrlEdit_Create($hGUI, $iItemText, $aRect[0] + 3, $aRect[1], $iLen + 10, 17, $Style)
                    
                    _GUICtrlEdit_SetSel($hEdit, 0, -1)
                    _WinAPI_SetFocus($hEdit)
                    $hDC = _WinAPI_GetWindowDC($hEdit)
                    $hBrush = _WinAPI_CreateSolidBrush(0x0000FF)
                    FrameRect($hDC, 0, 0, $iLen + 10 , 17, $hBrush)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func FrameRect($hDC, $nLeft, $nTop, $nRight, $nBottom, $hBrush)
    Local $stRect = DllStructCreate("int;int;int;int")
    DllStructSetData($stRect, 1, $nLeft)
    DllStructSetData($stRect, 2, $nTop)
    DllStructSetData($stRect, 3, $nRight)
    DllStructSetData($stRect, 4, $nBottom)
    DllCall("user32.dll", "int", "FrameRect", "hwnd", $hDC, "ptr", DllStructGetPtr($stRect), "hwnd", $hBrush)
EndFunc

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $iCode = BitShift($wParam, 16)
    Switch $lParam
        Case $hEdit
            Switch $iCode
                Case $EN_KILLFOCUS
                    Local $iText = _GUICtrlEdit_GetText($hEdit)
                    _GUICtrlListView_SetItemText($hListView, $Item, $iText, $SubItem)
                    _WinAPI_DeleteObject($hBrush)
                    _WinAPI_ReleaseDC($hEdit, $hDC)
                    _WinAPI_DestroyWindow($hEdit)
                    $Item = -1
                    $SubItem = 0
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

[caropost]

Je vous remercie

Ce que je cherche est un peu un mixte des 2 : pouvoir écrire directement dans un tableau comme dans le code de Mikell et pouvoir validé qu'on a fini de remplir les cases pour que le script continu comme dans le code de A2Energie Et après, pouvoir reprendre ses données pour en faire quelque chose.
J'ai essayé de reprendre le code de Mikell mais je n'arrivais à ajouter un bouton qui me permettrait de continuer (je ne pouvais plus remplir mes champs mais peut-être que je n'utilisais pas la bonne fonction). Du coup j'ai repris le code de A2Energie et je l'ai un peu adapté à mes besoins :

► Afficher le texte

Code : Tout sélectionner

#include <Array.au3>
#include <GUIConstants.au3>
$nombre = InputBox("Nombre de fleurs", "Combien de fleurs à répertorier ?")

Local $tableau[$nombre][3]

$GUIList = GUICreate("Entrez les valeurs", 320, 30*$nombre+20, 100, 100, -1, $WS_EX_ACCEPTFILES)
For $i = 0 to $nombre - 1
   $tableau[$i][0] = GUICtrlCreateLabel("Fleur " & $i+1, 10, 20*$i, 100, 18)
   $tableau[$i][1] = GUICtrlCreateInput("Nom", 110, 20*$i, 100, 18)
   $tableau[$i][2] = GUICtrlCreateInput("Couleur", 210, 20*$i, 100, 18)
Next
$Button = GUICtrlCreateButton("Valider",10, 20*$nombre, 100, 18)
GUISetState(@SW_SHOW)

While 1
   $FTreeActionTemp = GUIGetMsg()
   If $FTreeActionTemp = $Button Then
      For $i = 0 to $nombre - 1
         $tableau[$i][0] = "Fleur " & $i + 1
         $tableau[$i][1] = GUICtrlRead($tableau[$i][1])
         $tableau[$i][2] = GUICtrlRead($tableau[$i][2])
      Next
      ExitLoop
   EndIf
WEnd

_ArrayDisplay($tableau, "Tableau récapitulatif ", "10|3", 2 + 64, 64, "Numéro | Nom de la fleur | Couleur de la fleur", Default, 0xDDFFDD)

Run("notepad.exe")
WinWaitActive("Untitled - Notepad")
For $i = 0 to $nombre - 1
    Send($tableau[$i][0] & "  a pour nom " & $tableau[$i][1] & " et est de couleur " & $tableau[$i][2])
    Send("{ENTER}")
    Sleep(500)
Next

Le _ArrayDisplay est plus pour moi vérifier que ça fonctionne bien comme je le souhaitais mais dans la version finale,
Par contre, la première fenêtre où je rentre mes paramètres ne se ferme pas avant la fin du script, ce qui m'embête un peu...

[mikell]

Ah ok j'avais pas bien compris ce que tu voulais exactement
Effectivement le code de A2Energie est plus simple

► Afficher le texte

Code : Tout sélectionner

    #include <Array.au3>
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    Opt("WinTitleMatchMode", -2)

    $nombre = InputBox("Nombre de fleurs", "Combien de fleurs à répertorier ?")

    Local $tableau[$nombre][3]

    $GUIList = GUICreate("Entrez les valeurs", 320, 20*$nombre+25, 100, 100, -1, $WS_EX_ACCEPTFILES)
    For $i = 0 to $nombre - 1
       $tableau[$i][0] = GUICtrlCreateLabel("Fleur " & $i+1, 10, 20*$i, 100, 18)
       $tableau[$i][1] = GUICtrlCreateInput("Nom", 110, 20*$i, 100, 18)
       $tableau[$i][2] = GUICtrlCreateInput("Couleur", 210, 20*$i, 100, 18)
    Next
    $Button = GUICtrlCreateButton("Valider",10, 20*$nombre, 100, 18)
    GUISetState(@SW_SHOW)

    While 1
       $msg = GUIGetMsg()
       If $msg = $GUI_EVENT_CLOSE Then Exit
       If $msg = $Button Then
          For $i = 0 to $nombre - 1
             $tableau[$i][0] = "Fleur " & $i + 1
             $tableau[$i][1] = GUICtrlRead($tableau[$i][1])
             $tableau[$i][2] = GUICtrlRead($tableau[$i][2])
          Next
          ExitLoop
       EndIf
    WEnd

   GuiDelete($GUIList)
   ; _ArrayDisplay($tableau, "Tableau récapitulatif ", "10|3", 2 + 64, 64, "Numéro | Nom de la fleur | Couleur de la fleur", Default, 0xDDFFDD)
    _ArrayDisplay($tableau)

    Run("notepad.exe")
    WinWaitActive("bloc-notes")
    For $i = 0 to $nombre - 1
        Send($tableau[$i][0] & "  a pour nom " & $tableau[$i][1] & " et est de couleur " & $tableau[$i][2])
        Send("{ENTER}")
        Sleep(500)
    Next

[caropost]

Je te remercie

[jguinch]

@caropost : merci de passe le titre du premier message en [R] sil le problème est résolu.

[caropost]

@caropost : merci de passe le titre du premier message en [R] sil le problème est résolu.

Je comptais le faire, j'attendais juste de savoir si j'allais avoir des demandes de modifications qui me bloqueraient mais ça ne serait pas pour tout de suite donc je vais le faire