[..] Récupération de données de pages html -> Fichier .Ini

[Mirad0]

Bonjours,
J'ai un petit problème étant débutant dans la programmation avec autoit et surtout n'ayant jamais utiliser de Func lié au Html je suis perdu.
J'ai besoin d'un script qui va chercher des données de client d'un site internet ( AlloResto ) pour les sauvegarder dans un fichier .InI et les retrouver dans une Gui.
J'ai trouver l'infos que je veut dans le code source du site mais je ne sais pas comment la sauvegarder dans un fichier Ini.
J'ai déjà la Gui en prête.

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>

Global $iniFile = "Contact.ini"
#region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Carnet d'adresse Clients", 309, 154, 192, 124)
$Combo1 = GUICtrlCreateCombo("", 16, 14, 217, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
$Input1 = GUICtrlCreateInput("", 104, 46, 127, 21)
$Input2 = GUICtrlCreateInput("", 104, 78, 200, 21)
$Input3 = GUICtrlCreateInput("", 104, 108, 200, 42)
$Label1 = GUICtrlCreateLabel("telephone", 34, 48, 51, 17)
$Label2 = GUICtrlCreateLabel("adresse postale", 28, 82, 62, 17)
$Label3 = GUICtrlCreateLabel("Information", 12, 110, 78, 17)
$Button1 = GUICtrlCreateButton("+", 250, 16, 25, 21)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
$Button2 = GUICtrlCreateButton("-", 275, 16, 25, 21)
GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif")
GUISetState(@SW_SHOW)
#endregion ### END Koda GUI section ###

Local $aData = IniReadSectionNames($iniFile)
If IsArray($aData) Then
    For $i = 1 To $aData[0]
        _GUICtrlComboBox_AddString($Combo1, $aData[$i])
    Next
EndIf

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Combo1
            _Contact_Select(GUICtrlRead($Combo1))
        Case $Button1
            _Contact_Add()
        Case $Button2
            ; supprime toute trace du contact selectionner dans la combobox dans le fichier .ini

            If MsgBox(4 + 48 + 256, "Suppression", "Confirmer la suppression du contact") = 6 Then
                _Contact_Delete()
            EndIf
    EndSwitch
WEnd

Func _Contact_Delete()
    IniDelete($iniFile, GUICtrlRead($Combo1))
    Local $iIndex = _GUICtrlComboBox_GetCurSel($Combo1)
    _GUICtrlComboBox_DeleteString($Combo1, $iIndex)
    _GUICtrlComboBox_SetCurSel($Combo1)
    _Contact_Select("")
EndFunc

Func _Contact_Select($Name)
    GUICtrlSetData($Input1, IniRead($iniFile, $Name, "telephone", ""))
    GUICtrlSetData($Input2, IniRead($iniFile, $Name, "adresse_postale", ""))
    GUICtrlSetData($Input3, IniRead($iniFile, $Name, "Information", ""))
EndFunc

Func _Contact_Add()
    $Form2 = GUICreate("Carnet d'adresse Clients", 309, 154, 192, 124)
    $Inputsave1 = GUICtrlCreateInput("", 98, 26, 137, 21)
    $Inputsave2 = GUICtrlCreateInput("", 98, 52, 135, 21)
    $Inputsave3 = GUICtrlCreateInput("", 98, 78, 135, 21)
    $Inputsave4 = GUICtrlCreateInput("Aucune", 98, 106, 133, 21)
    $Labelsave1 = GUICtrlCreateLabel("nom du contact", 10, 30, 78, 17)
    $Labelsave2 = GUICtrlCreateLabel("telephone", 36, 54, 51, 17)
    $labelsave3 = GUICtrlCreateLabel("adresse postale", 26, 82, 62, 17)
    $Label1 = GUICtrlCreateLabel("Information", 10, 110, 78, 17)
    $Button3 = GUICtrlCreateButton("sauvegarder", 236, 122, 67, 25)
    GUISetState(@SW_SHOW)

    While 1
        $nMsg1 = GUIGetMsg()
        Switch $nMsg1
            Case $GUI_EVENT_CLOSE
                GUIDelete($Form2)
                ExitLoop
            Case $Button3
                ;enregistre dans le fichier.ini sous la forme :  exemple si dessous
                ;       [nom_du_contact]
                ;       telephone = 0612345678
                ;       mail = jean@mail.com
                ;       adresse_postale = 2 rue des aoutiens
                Dim $aData[3][2] = [ _
                        ["telephone", GUICtrlRead($Inputsave2)], _
                        ["adresse_postale", GUICtrlRead($Inputsave3)], _
                        ["Information", GUICtrlRead($Inputsave4)]]

                IniWriteSection($iniFile, GUICtrlRead($Inputsave1), $aData, 0)
                Local $iIndex = _GUICtrlComboBox_AddString($Combo1, GUICtrlRead($Inputsave1))
                _GUICtrlComboBox_SetCurSel($Combo1, $iIndex)
                 _Contact_Select(GUICtrlRead($Inputsave1))
                GUIDelete($Form2)
                ExitLoop
        EndSwitch
    WEnd

EndFunc   ;==>_add_contact

J'avais déjà commencé un coder un peut mais ce script marche seulement en entrant les infos manuellement, étant donner qu'ont a plus de 10 nouveaux client par jours c'est devenue très pénibles.

[mikell]

Faudrait fournir le lien de la page concernée, en précisant les infos que tu veux récupérer sur cette page
Si tu as déjà un code qui extrait ces données, fais voir

[Mirad0]

Je me suis mal exprimer j'ai pas de code qui permet d'extraire les données, c'est justement ceux que je cherche à faire.
Pour le lien c'est compliqué car c'est un espace privé du site ( chaque restaurant gère les commandes sur sa page dédier ) c'est sur ma page que je cherche à prendre les infos des clients. Je peut copier coller le code source de ce que je cherche à copier en floutant les infos sensible ( numéro de telephone, nom, adresse )

[Mirad0]

Alors voilà j'ai trouvé un exemple que je peut vous donnez pour que vous puissiez m'aidez je sais pas si sa suffira.

Code : Tout sélectionner

class="tab_commande_newcus newcust">[color=#FF0000]Jimena Garcia[/color]</span><br />[color=#FF0000]0333955243[/color]</td><td class="tab_commandes_td">[color=#FF0000]1 rue des magasins[/color]<br />STRASBOURG - Halles / 67000</td><td class="tab_commandes_td" align="center">d.q.p&nbsp;-&nbsp;22:30</td><td class="tab_commandes_td" align="right">[color=#FF0000]34,95&nbsp;&euro;[/color]</td><td

C'est les infos d'une cliente (fausse) j'ai mis en rouge les infos dont j'ai besoin.

[Sepular]

Pour récupérer la source de la page HTML

► Afficher le texte

Code : Tout sélectionner

HttpSetUserAgent("MyUserAgent")
$source = BinaryToString(InetRead("http://www.autoitscript.fr/forum/portal.php"))
ConsoleWrite($source)
 

Il ne te reste plus qu'a découper la source pour obtenir les infos que tu souhaite

[orax]

https://regex101.com/r/jN1tV9

Code : Tout sélectionner

#include <StringConstants.au3>
#include <Array.au3>
$source='class="tab_commande_newcus newcust">Sergent Garcia</span><br />0333955243</td><td class="tab_commandes_td">1 rue des magasins<br />STRASBOURG - Halles / 67000</td><td class="tab_commandes_td" align="center">d.q.p&nbsp;-&nbsp;22:30</td><td class="tab_commandes_td" align="right">34,95&nbsp;&euro;</td><td'
$r=StringRegExp($source, 'newcust">(.+)<\/span>.+?(\d+).+"tab_commandes_td">(.+)<br \/>.+>(\d.+)&nbsp;&euro;', $STR_REGEXPARRAYGLOBALMATCH)
_ArrayDisplay($r)

[mikell]

Si tu as les données de plusieurs clients sur la même page, je suggère de faire le tri en 2 temps :

► Afficher le texte

Code : Tout sélectionner

#include <Array.au3>

Global $iniFile = "Contact.ini"

$source = '<tralala><class="tab_commande_newcus newcust">Sergent Garcia</span><br />0333955243</td><td class="tab_commandes_td">1 rue des magasins<br />STRASBOURG - Halles / 67000</td><td class="tab_commandes_td" align="center">d.q.p&nbsp;-&nbsp;22:30</td><td class="tab_commandes_td" align="right">34,95&nbsp;&euro;</td><td>du texte</td><tsoin tsoin>' & @crlf & _
'<tralala><class="tab_commande_newcus newcust">Zorro</span><br />1333955243</td><td class="tab_commandes_td">2 rue des boutiques<br />HAMBOURG - Halles / 67009</td><td class="tab_commandes_td" align="center">d.q.p&nbsp;-&nbsp;22:30</td><td class="tab_commandes_td" align="right">54,90&nbsp;&euro;</td><td>et encore du texte</td><tsoin tsoin>'

[color=#FF0000];;; isole les parties de code concernant chaque client[/color]
$a = StringRegExp($source, '(?s)newcust"(.*?)&nbsp;&euro', 3)
_ArrayDisplay($a)  ;<< (juste pour vérifier)
If IsArray($a) Then
   For $i = 0 to UBound($a)-1
       [color=#FF0000];;; récupère les infos[/color]
       $a[$i] = StringReplace($a[$i], "&nbsp;", " ")
       $r = StringRegExp($a[$i], '>([^<]+)', 3)
       _ArrayDisplay($r)
       [color=#FF0000];;; exemple d'écriture dans le ini[/color]
       For $k = 1 to UBound($r)-1
          IniWrite($iniFile, $r[0], $k, $r[$k])
       Next
   Next
EndIf

[Mirad0]

Merci je vais décortiqué tous ça je vous tien au courant