[..] Ajouter Clés de registre avec AutoIt

[Lebalbo2013]

Bonjour,
J'ai exporté une clé de régistre de La base de registre de mon poste de référence;Je souhaiterais ajouter cette clé ainsi que toutes ses valeurs sur plusieurs postes.La clé se présente sous la forme :" HKLM\Software\Monapplication".Je souhaite que la clé de registre se trouve dans le même répertoire que le script à exécuter.
Mon soucis c'est ce que je ne sais pas comment le faire.
Merci d'avance pour votre aide.
Cdlt,
Steph.


*** Important ***
- Ajoutez [..] au début de votre titre.
- N'oubliez pas les balises de code.
- N'utilisez pas la coloration syntaxique dans ce forum

Plus de détails sur ce lien :
http://www.autoitscript.fr/forum/viewto ... f=35&t=595

[Y01]

Bonjour,

Exportation des fichiers du Registre

Pour exporter tout ou partie du Registre à distance, utilisez l'Éditeur du Registre. Une fois l'Éditeur du Registre ouvert, vous pouvez exporter le Registre sous forme de fichier texte ou de fichier ruche.

Utilisez un éditeur de texte tel que le Bloc-notes pour modifier les fichiers du Registre que vous avez créés lors de l'exportation.

Vous pouvez enregistrer les fichiers du Registre au format Windows, en tant que fichiers d'enregistrement, fichiers ruches binaires ou fichiers texte. Les fichiers du Registre sont enregistrés avec l'extension .reg et les fichiers texte avec l'extension .txt.
Exporter tout ou partie du Registre

Ouvrez l'Éditeur du Registre. Si vous voulez enregistrer uniquement une branche particulière, sélectionnez-la.

Dans le menu Fichier, cliquez sur Exporter….

Dans la zone Nom du fichier, entrez un nom pour le fichier du Registre.

Dans la zone Type, sélectionnez le type de fichier que vous voulez utiliser pour le fichier enregistré (fichier d'enregistrement, fichier ruche de Registre, fichier texte, fichier d'enregistrement Windows 98/NT4.0).

Dans la zone Étendue de l'exportation, utilisez les cases d'option pour préciser si vous voulez exporter l'intégralité du Registre ou uniquement la branche sélectionnée.

Cliquez sur Enregistrer.

Filecopy ("//cheminsurleréseau/MaRegistry.reg", @scriptdir, 1)

run(@scriptdir & "\MaRegistry.reg")


ça devrait à peu près répondre aux demandes.

[TommyDDR]

Pas Run mais ShellExecute.

[Y01]

J'étais pas loin sans avoir fait de test !

Merci de la correction

[Lebalbo2013]

Merci pour vos réponses.çà fonctionne bien mais je voudrais plus que s'affiche le message de Windows me demandant si je suis sûr de vouloir réécrire dans la base de registre.Je voudrais forcer l'ajout de cette clé sans avoir à cliquer sur ok.
Merci d'avance pour vos retours.
Biens Cordialement,
Steph.

[orax]

Avec la commande REG.

Code : Tout sélectionner

Run("reg import test.reg", @ScriptDir, @SW_HIDE)

[Lebalbo2013]

Malheuresuement çà semble ne pas fonctionner.Le script précédent (celui de Y01 et du modérateur) fonctionnait très bien sauf que le message d'avertissement de l'éditeur de registre s'affichait toujours.Ce que je ne souhaite pas.
Quelqu'un aurait-il une piste s'il vous plaît?
Merci.

[Y01]

Ceci peut être :

Code : Tout sélectionner

Run(@ComSpec & " /c " & 'Reg import test.reg', @scriptdir, @SW_HIDE)

[TommyDDR]

On peut aussi recoder le comportement de reg.exe ^^ :

► Afficher le textecode

Code : Tout sélectionner

ImportReg(CheminVersVotre.reg)

Func ImportReg($regFile)
    Local $regTemp = @TempDir & "\regTemp.reg"
    Local $contenu = StringReplace(FileRead($regFile), "\" & @CRLF & "  ", "")
    Local $file = FileOpen($regTemp, 2)
    FileWrite($file, $contenu)
    FileClose($file)
    If(Not(FileExists($regTemp))) Then Return SetError(1)
    Local $sections = IniReadSectionNames($regTemp)
    For $i = 1 To $sections[0]
        RegWrite($sections[$i])
        Local $keys = IniReadSection($regTemp, $sections[$i])
        If(Not(@error)) Then
            For $j = 1 To $keys[0][0]
                Local $typeAndValue = ValueGetTypeAndValue($keys[$j][1])
                RegWrite($sections[$i], StringTrimRight(StringTrimLeft($keys[$j][0], 1), 1), $typeAndValue[0], $typeAndValue[1])
            Next
        EndIf
    Next
    FileDelete($regTemp)
EndFunc

Func ValueGetTypeAndValue($value)
    Local $typeAndValue[2]
    If(StringLeft($value, 1) = '"') Then
        $typeAndValue[0] = "REG_SZ"
        $typeAndValue[1] = StringTrimRight(StringTrimLeft($value, 1), 1)
    ElseIf(StringLeft($value, 4) = "hex:") Then
        $typeAndValue[0] = "REG_BINARY"
        $typeAndValue[1] = HexToString(StringTrimLeft($value, 4))
    ElseIf(StringLeft($value, 6) = "dword:") Then
        $typeAndValue[0] = "REG_DWORD"
        $typeAndValue[1] = "0x" & StringTrimLeft($value, 6)
    ElseIf(StringLeft($value, 7) = "hex(b):") Then
        $typeAndValue[0] = "REG_QWORD"
        $typeAndValue[1] = HexToString(StringTrimLeft($value, 7), False, True)
    ElseIf(StringLeft($value, 7) = "hex(7):") Then
        $typeAndValue[0] = "REG_MULTI_SZ"
        $typeAndValue[1] = HexToString(StringTrimRight(StringTrimLeft($value, 7), 12), True)
    ElseIf(StringLeft($value, 7) = "hex(2):") Then
        $typeAndValue[0] = "REG_EXPAND_SZ"
        $typeAndValue[1] = HexToString(StringTrimRight(StringTrimLeft($value, 7), 6), True)
    EndIf
    Return $typeAndValue
EndFunc

Func HexToString($value, $toString = False, $revert = False)
    $value =        StringSplit($value, ",", 3)
    Local $retour = "0x"
    Local $start = 0
    Local $end = UBound($value)-1
    Local $step = 1
    If($toString) Then
        $retour =   ""
        $step = 2
    EndIf
    If($revert) Then
        $start = $end
        $end = 0
        $step *= -1
    EndIf
    For $i = $start To $end Step $step
        If($toString) Then
            If($value[$i] = 0) Then
                $retour &= @LF
            Else
                $retour &= Chr("0x" & $value[$i])
            EndIf
        Else
            $retour &= $value[$i]
        EndIf
    Next
    Return $retour
EndFunc

C'est codé vite fait mais cela devrait convenir à tous les types de clés.

[orax]

Malheuresuement çà semble ne pas fonctionner.

J'avais pourtant vérifié que ça fonctionne donc ça doit fonctionner.
Le code que j'avais donné ne peut pas afficher le message d'erreur s'il y en a un. Mais pour l'afficher on peut utiliser "cmd /k", ce qui laissera la fenêtre DOS ouverte :

Code : Tout sélectionner

Run(@ComSpec & " /k " & "reg import test.reg", @ScriptDir)

[jguinch]

Il faudra faire attention à l'architecture de l'OS, car si le .reg a été exporté depuis un poste 64 bits et qu'on utilise reg.exe / regedit.exe ou un script x86, on risque d'avoir des clés dans HKLM\Software\Wow6432Node au lieu de HKLM\Software... Il faudra alors exécuter le regedit / reg natif (accessible par @WindowsDir & "\Systative" sur un Windows x64 et script x86 )

Sympa ta fonction Tommy. Il y a aussi le cas de figure où on supprime des clés/valeurs avec le .reg

[TommyDDR]

Supprime ?
L'export d'une clé de registre contient toutes les clés actuellement dans celle-ci non ? comment peut-il y avoir une information de supression ?

[orax]

@jguinch
Sur Windows 8.1 x64, il y a /reg:32 ou /reg:64. Mais sur les Windows antérieurs je ne sais pas.

Code : Tout sélectionner

C:\>reg import /?
REG IMPORT Nom_fichier [/reg:32 | /reg:64]
  Nom_fichier  Le nom du fichier disque à importer (ordinateur local
               uniquement).
  /reg:32      Spécifie que l'accès à la clé doit s'effectuer via l'affichage
               du Registre 32 bits.
  /reg:64      Spécifie que l'accès à la clé doit s'effectuer via l'affichage
               du Registre 64 bits.

[jguinch]

A l'export non, pas de suppression je suis d'accord.
Mais on peut bien imaginer que certains (comme moi) préfèreront modifier le .reg exporté pour faire en sort qu'il supprime les clés avant de les écrire (ce qui permet de supprimer les éventuelles sous-clés/valeurs indésirables déjà présentes)... Mais c'est qu'une idée...

@orax : sous Windows 7, y'a pas ces options (que je ne connaissais pas d'ailleurs, merci donc ).

[TommyDDR]

Pour moi, la fonction à pour vocation d'importer les clé contenues dans le fichier en entrée, libre à l'utilisateur de le modifier avant.

[orax]

Supprime la clé "HKEY_CURRENT_USER\test"

Code : Tout sélectionner

Windows Registry Editor Version 5.00
[[color=#FF0000]-[/color]HKEY_CURRENT_USER\test]

Supprime la valeur "val"

Code : Tout sélectionner

Windows Registry Editor Version 5.00
[-HKEY_CURRENT_USER\test]
"val"=[color=#FF0000]-[/color]

Pour ceux que ça intéresse : Procédure d'ajout, de modification ou de suppression des sous-clés et des valeurs de Registre à l'aide d'un fichier .reg

[TommyDDR]

Ah, je ne connaissais pas le coup du "-", c'est maintenant implémenté !

► Afficher le textecode

Code : Tout sélectionner

ImportReg(@DesktopDir & "\a - Copy.reg")

Func ImportReg($regFile)
    Local $regTemp = @TempDir & "\regTemp.reg"
    Local $contenu = StringReplace(FileRead($regFile), "\" & @CRLF & "  ", "")
    Local $file = FileOpen($regTemp, 2)
    FileWrite($file, $contenu)
    FileClose($file)
    If(Not(FileExists($regTemp))) Then Return SetError(1)
    Local $sections = IniReadSectionNames($regTemp)
    For $i = 1 To $sections[0]
        If(StringLeft($sections[$i], 1) = "-") Then
            RegDelete(StringTrimLeft($sections[$i], 1))
        Else
            RegWrite($sections[$i])
            Local $keys = IniReadSection($regTemp, $sections[$i])
            If(Not(@error)) Then
                For $j = 1 To $keys[0][0]
                    Local $name = StringTrimRight(StringTrimLeft($keys[$j][0], 1), 1)
                    If($keys[$j][1] = "-") Then
                        RegDelete($sections[$i], $name)
                    Else
                        Local $typeAndValue = ValueGetTypeAndValue($keys[$j][1])
                        RegWrite($sections[$i], $name, $typeAndValue[0], $typeAndValue[1])
                    EndIf
                Next
            EndIf
        EndIf
    Next
    FileDelete($regTemp)
EndFunc

Func ValueGetTypeAndValue($value)
    Local $typeAndValue[2]
    If(StringLeft($value, 1) = '"') Then
        $typeAndValue[0] = "REG_SZ"
        $typeAndValue[1] = StringTrimRight(StringTrimLeft($value, 1), 1)
    ElseIf(StringLeft($value, 4) = "hex:") Then
        $typeAndValue[0] = "REG_BINARY"
        $typeAndValue[1] = HexToString(StringTrimLeft($value, 4))
    ElseIf(StringLeft($value, 6) = "dword:") Then
        $typeAndValue[0] = "REG_DWORD"
        $typeAndValue[1] = "0x" & StringTrimLeft($value, 6)
    ElseIf(StringLeft($value, 7) = "hex(b):") Then
        $typeAndValue[0] = "REG_QWORD"
        $typeAndValue[1] = HexToString(StringTrimLeft($value, 7), False, True)
    ElseIf(StringLeft($value, 7) = "hex(7):") Then
        $typeAndValue[0] = "REG_MULTI_SZ"
        $typeAndValue[1] = HexToString(StringTrimRight(StringTrimLeft($value, 7), 12), True)
    ElseIf(StringLeft($value, 7) = "hex(2):") Then
        $typeAndValue[0] = "REG_EXPAND_SZ"
        $typeAndValue[1] = HexToString(StringTrimRight(StringTrimLeft($value, 7), 6), True)
    EndIf
    Return $typeAndValue
EndFunc

Func HexToString($value, $toString = False, $revert = False)
    $value =        StringSplit($value, ",", 3)
    Local $retour = "0x"
    Local $start = 0
    Local $end = UBound($value)-1
    Local $step = 1
    If($toString) Then
        $retour =   ""
        $step = 2
    EndIf
    If($revert) Then
        $start = $end
        $end = 0
        $step *= -1
    EndIf
    For $i = $start To $end Step $step
        If($toString) Then
            If($value[$i] = 0) Then
                $retour &= @LF
            Else
                $retour &= Chr("0x" & $value[$i])
            EndIf
        Else
            $retour &= $value[$i]
        EndIf
    Next
    Return $retour
EndFunc

[Lebalbo2013]

Merci à tous .

[jguinch]

@Lebalbo2013 : merci de passer le sujet en [R] si c'est pas trop te demander... Et c'est valable pour tous les topics résolus.
Merci

[Lebalbo2013]

@jguinch Excuse moi pour l'oubli,
je le fais tout de suite.