[R] Trouver la valeur d'un pixel

[sozary]

Bonsoir!

Alors voilà: j'ai deux images de 16x16 pixels chacune.
Sur l'une d'elle, il y a une zone en blanc, destinée à être remplacé par les pixels de l'autre image au même endroit.
Malheureusement, après plusieurs échecs, je doit m'en remettre à vous, j'ai cherché du côté de BitmapGetPixel, mais malheureusement, tous les cas de figure via à l'aide n'ont pas marché..

Need help please!

[TommyDDR]

Tenez, ce n'est peut être pas optimisé (déconseillé sur des grosses images) mais c'est fonctionnel.
La fonction prend en entrée le chemin vers l'image contenant les pixels blancs, le chemin vers l'image remplaçant les pixels blanc et la couleurs des pixels à remplacer.

► Afficher le textecode

Code : Tout sélectionner

#include <GDIPlus.au3>

Global $imagePixBlanc = @ScriptDir & "\ImagePixBlanc.png"
Global $imageRemplace = @ScriptDir & "\ImageRemplace.png"

_GDIPlus_Startup()
Local $image = ImageColorReplace($imagePixBlanc, $imageRemplace, 0xFFFFFF)
_GDIPlus_ImageSaveToFile($image, @ScriptDir & "\test.png")
_GDIPlus_BitmapDispose($image)
_GDIPlus_Shutdown()

Func ImageColorReplace($img1, $img2, $color)
    Local $bitmap1 = _GDIPlus_BitmapCreateFromFile($img1)
    Local $bitmap2 = _GDIPlus_BitmapCreateFromFile($img2)
    Local $width1 = _GDIPlus_ImageGetWidth($bitmap1)
    Local $width2 = _GDIPlus_ImageGetWidth($bitmap2)
    Local $height1 = _GDIPlus_ImageGetHeight($bitmap1)
    Local $height2 = _GDIPlus_ImageGetHeight($bitmap2)
    Local $xMax = $width1 < $width2 ? $width1 : $width2
    Local $yMax = $height1 < $height2 ? $height1 : $height2
    For $y = 0 To $yMax
        For $x = 0 To $xMax
            If("0x" & Hex(_GDIPlus_BitmapGetPixel($bitmap1, $x, $y), 6) = $color) Then
                _GDIPlus_BitmapSetPixel($bitmap1, $x, $y, _GDIPlus_BitmapGetPixel($bitmap2, $x, $y))
            EndIf
        Next
    Next
    _GDIPlus_BitmapDispose($bitmap2)
    Return $bitmap1
EndFunc
 

Edit : bmp -> png

[sozary]

Nickel! Merci! J'ai quand même étudié le code afin de comprendre le fonctionnement !

Merci!

[walkson]

Global $imagePixBlanc = @ScriptDir & "\ImagePixBlanc.bmp"
Global $imageRemplace = @ScriptDir & "\ImageRemplace.bmp"

Petite erreur corrigée en .png

[sozary]

Oui effectivement sinon sa n'avais pas marché!

[TommyDDR]

Oups, j'avais bossé en bmp mais le forum n'accepte pas les pièces jointes bmp donc j'ai changer de format mais oublié de mettre à jour le code ^^ c'est corrigé.

[antonin298]

J'essaye d'utiliser les méthode de traitement d'image , mais impossible je me suis inspiré du code ci dessus mais ca ne marche toujours pas ..
tout ce que je veux faire c'est changer un pixel de mon image mais quand je lance le programme rien d'apparent ne se passe il ne crée aucune image en retour et la MsgBox indique une couleur de pixel=0
Qlq un serait m'aiguiller ?

Code : Tout sélectionner

[code]#include <GDIPlus.au3>



Global $bitmap = @ScriptDir & "\capt.png"

_GDIPlus_Startup()


$b2 = _GDIPlus_BitmapSetPixel( $bitmap, 10,10, 7653715)

MsgBox(0,"lol","lol "&_GDIPlus_BitmapGetPixel($b2, 10, 10))

_GDIPlus_ImageSaveToFile($b2 , @ScriptDir & "\pict.png")


_GDIPlus_Shutdown()

[/code]

[TommyDDR]

Code : Tout sélectionner

Global $bitmap = @ScriptDir & "\capt.png"
[...]
$b2 = _GDIPlus_BitmapSetPixel( $bitmap, 10,10, 7653715)

votre $bitmap contient une chaine de caractères et non pas un bitmap.

Regardez le code fourni un peu plus haut.