[R] Détecter l'état de la restauration système

[franco]

Bonjour à toutes et à tous.

J'utilise l'UDF SystemRestore.au3 pour :

1. Lister tous les points de restauration (dans une listview avec cases à cocher)
2. Créer un point de restauration
3. Supprimer les points de restaurations souhaités (en cochant les cases correspondantes).
4. Activer la restauration système
5. Désactiver la restauration système

La seule chose que je ne sais pas faire, que je n'ai pas trouvé comment faire : détecter / vérifier l'état de la restauration système, à savoir si elle est activée ou désactivée.


J'avais trouvé ce topic : http://www.autoitscript.com/forum/topic ... -disabled/
Cela détecte l'état de la restauration système en vérifiant la valeur d'une donnée (disableSR).

Mais vu que ce topic date de 2006, je comprends donc pourquoi je n'ai pas cette donnée/valeur.

J'ai quand même tenté ceci :

► Afficher le textecode n°1

Code : Tout sélectionner

#include "SystemRestore.au3"

_SR_Disable(@HomeDrive)

$SysRst = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore", "DisableSR")
If @error Then MsgBox(0, "System Restore Check", "Troubles reading the registry.")
If $SysRst == 1 Then MsgBox(0, "System Restore Check", "System Restore is disabled")
If $SysRst == 0 Then MsgBox(0, "System Restore Check", "System Restore is enabled")

La restauration système a bien été désactivée, mais cela m'affiche le message d'erreur cité ci-dessus.


J'ai testé cela aussi :

► Afficher le textecode n°2

Code : Tout sélectionner

#include "SystemRestore.au3"

_SR_Disable(@HomeDrive)
MsgBox(0,"","yo")

$var = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore", "DisableSR")
If $var = 1 Then
    MsgBox(4096, "System Restore Status:", "disabled")
Else
    MsgBox(4096, "System Restore Status:", "enabled")
EndIf

La restauration système a bien été désactivée, mais ça m'affiche enabled...
D'ailleurs, si la restauration est active, ça m'affiche aussi enabled...

J'ai même recherche dans le registre, des valeurs, etc...
Avec seaf (logiciel de recherche sur disque dur et/ou registre), j'ai tenté de faire une recherche avec systemrestore (uniquement sur le registre)
=> 4 Clés, aucune valeur qui donne l'état de la restauration système.


Donc, du coup, je sèche.

Y-a-t-il un moyen de vérifier l'état de la restauration système ?


PS : Pour les gens désirant voir ce que j'ai fait (pas fini ^^), voici le code :

► Afficher le texteCode

Code : Tout sélectionner

#RequireAdmin
#include <GUIConstantsEx.au3>
#include <GUIListView.au3>
#include <WindowsConstants.au3>
#include "SystemRestore.au3"

Global $Form1 = GUICreate("Form1", 860, 490, 10, 10)

$PtRstLV = GUICtrlCreateListView("SqN|Description|Date - Heure", 10, 60, 540, 200, $WS_BORDER, $LVS_EX_CHECKBOXES)
_EnumRestP()
$SelAllPt = GUICtrlCreateRadio("Tout sélectionner", 15, 265, 120, 20)
GUICtrlSetFont(-1, 9, 400, 0, "comic sans ms")
$SelNoPt = GUICtrlCreateRadio("Ne rien sélectionner", 145, 265, 150, 20)
GUICtrlSetFont(-1, 9, 400, 0, "comic sans ms")

GUICtrlCreateGroup("",560,60,290,200, $WS_SIZEBOX)
$ActivateSR = GUICtrlCreateButton("Activer", 580, 90, 120, 30)
$DeactivateSR = GUICtrlCreateButton("Désactiver", 710, 90, 120, 30)
$CreatePt = GUICtrlCreateButton("Créer un point", 580, 140, 120, 30)
$DelSelPt = GUICtrlCreateButton("Supprimer la sélection", 710,140, 120, 30)
$RazList = GUICtrlCreateButton("Actualiser", 580, 210, 120, 30)
$CreateReport = GUICtrlCreateButton("Rapport",710, 210, 120, 30)

GUICtrlCreateGroup("",380,290,350,80, $WS_SIZEBOX)



GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $RazList
            _EnumRestP()
        Case $SelAllPt
            For $i = 0 To _GUICtrlListView_GetItemCount($PtRstLV) - 1
                _GUICtrlListView_SetItemChecked($PtRstLV, $i, True)
            Next
            GUICtrlSetState($SelAllPt, $GUI_UNCHECKED)
        Case $SelNoPt
            For $i = 0 To _GUICtrlListView_GetItemCount($PtRstLV) - 1
                _GUICtrlListView_SetItemChecked($PtRstLV, $i, False)
            Next
            GUICtrlSetState($SelNoPt, $GUI_UNCHECKED)

        case $CreatePt
            GUICtrlSetState($CreatePt,$GUI_HIDE)
            Sleep(5000)
            GUICtrlSetState($CreatePt,$GUI_SHOW)
;~          _SR_CreateRestorePoint('My restore point')
;~          _EnumRestP()

    EndSwitch
WEnd

Func _EnumRestP()
    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($PtRstLV))
    $rPoints = _SR_EnumRestorePoints()
    For $i = $rPoints[0][0] To 1 Step -1
        $DateH = StringSplit(StringReplace($rPoints[$i][2], " ", "-"), "-")
        $Date = StringSplit($DateH[1], "/")
        $Date = $Date[2] & "/" & $Date[1] & "/" & $Date[3]
        $Hour = StringSplit($DateH[2], ":")
        $Hour = $Hour[1] + 1 & ":" & $Hour[2] & ":" & $Hour[3]
        $DateHour = $Date & " - " & $Hour
        GUICtrlCreateListViewItem($rPoints[$i][0] & "|" & $rPoints[$i][1] & "|" & $DateHour, $PtRstLV)
    Next
    GUICtrlSendMsg($PtRstLV, $LVM_SETCOLUMNWIDTH, 0, $LVSCW_AUTOSIZE)
    GUICtrlSendMsg($PtRstLV, $LVM_SETCOLUMNWIDTH, 1, $LVSCW_AUTOSIZE)
    GUICtrlSendMsg($PtRstLV, $LVM_SETCOLUMNWIDTH, 2, $LVSCW_AUTOSIZE)
EndFunc   ;==>_EnumRestP

Merci à vous.

[Y01]

Bonjour,

Sur quel système d'exploitation compte tu faire tourner ce bout de code ?

[franco]

Salut.

Sur XP jusqu'à windows 8.1.
=> sur XP, je pense que la méthode liée à la clé registre fonctionnera.

Je pense aussi que je dois donc faire des conditions.

SI XP, faire cette méthode.
Sinon, autre méthode.


Faut donc trouver une méthode qui fonctionne de windows vista à windows 8.1.


Dès que l'occasion me le permettra, je lancerais ma VM XP, afin de voir si la méthode fonctionne.
Je réinstallerais sous VM vista, par la même occasion.


@+ et merci de ta réponse.

[Y01]

C'est exactement ce que j'allais te dire de faire

Tiens nous au courant des résultats de tes tests.

[A2Energie]

Bonjour,

Je pense qu'il faut détecter le bouton (Check) activer ou desactiver dans les propriétés système.

Pour le moment je n'arrive pas à identifier correctement la fenêtre système : Protection système pour Disque local (C:)

Code : Tout sélectionner

$etat = ControlCommand("[CLASS:#32770]", "", "[CLASS:Button; INSTANCE:2]", "IsChecked", "")
MsgBox(1,"ETAT",$etat)

Je te tiens informé si je trouve.

[orax]

Sur Vista et +, c'est RPSessionInterval.

Code : Tout sélectionner

$SysRst = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore", "RPSessionInterval")

http://msdn.microsoft.com/en-us/library ... 85%29.aspx

RPSessionInterval
Windows Vista: Receives zero if System Restore is disabled.

[franco]

Salut et merci à vous tous

Sur mon windows 8.1, je n'ai pas ceci : "RPSessionInterval".
Donc, dès que je réinstalle vista, je pourrais voir.


Pour l'histoire du détection du bouton check (propriétés système), c'est différent sous windows 8.
Par contre, ça risque de fonctionner pour les autres.


J'ai de quoi tester : merci à tous



Je reviendrai si j'ai des news ^^
++

[A2Energie]

Bonjour,

Concernant Windows 8.1,
Afin d'afficher la fenêtre d'activation ou désactivation :
Clique droit sur menu démarré / Systeme / Protection du systeme / Configurer

Le problème étant qu'après différents essais et différentes méthodes la fenêtre : Protection système pour Disque local (C:) ne semble pas répondre aux control...

Je pense qu'il s'agissait d'une mauvaise piste.

[A2Energie]

Bonjour,

Je pense pas être util, mais voici une solution alternative pour détecter la coche ou décoche de la case restauration activé ou désactivée.

Code : Tout sélectionner

$EtatPos = WinGetPos("[CLASS:#32770; TITLE:Protection système pour Disque local (C:)]", "")
If PixelGetColor($EtatPos[0] + 50, $EtatPos[1] + 110) = 16777215 Then
   MsgBox(1, "Etat", "Désactivé")
Else
   MsgBox(1, "Etat", "Activé")
EndIf
 

[orax]

Sur mon windows 8.1, je n'ai pas ceci : "RPSessionInterval".

Moi je l'ai (sur Win 8.1).
De ce que j'ai compris, il peut y avoir RPSessionInterval et/ou RPGlobalInterval.

[franco]

Salut.

J'ai ni l'un... ni l'autre

Tu as la pro de windows 8.1 ? Car moi, non.

Sinon, encore un mystère des joies de l'informatique.


Bon, je vais lancer XP. ^^
On verra s'il détecte (ou non) l'état de la restauration système.


++

[franco]

Bonsoir / Rebonsoir

Pour XP, c'est résolu !

Voici le code "fonctionnel" (que je dois donc adapter, mais bon, pas de souci puisque c'est OK)

► Afficher le textecode

Code : Tout sélectionner

#include "SystemRestore.au3"
_SR_Disable(@HomeDrive&"\")
$SysRst = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore", "DisableSR")
If $SysRst = 1 Then
    MsgBox(0, "", "désactivé")
Else
    MsgBox(0, "", "activé")
EndIf

_SR_Enable(@HomeDrive&"\")
$SysRst = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore", "DisableSR")
If $SysRst = 1 Then
    MsgBox(0, "", "désactivé")
Else
    MsgBox(0, "", "activé")
EndIf

1. Cela m'affiche bien désactivé après la désactivation de la restauration système
2. Cela m'affiche bien activé après la réactivation de la restauration système

Il ne me reste plus que les tests sous windows vista,7 et 8.


EDIT :
Effectivement, pour vista, c'est une autre valeur que XP (RPSessionInterval)

Voici le code :

► Afficher le textecode

Code : Tout sélectionner

#include "SystemRestore.au3"
_SR_Disable(@HomeDrive & "\")
$SysRst = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore", "RPSessionInterval")
If $SysRst = 1 Then
    MsgBox(0, "", "activé")
Else
    MsgBox(0, "", "désactivé")
EndIf

_SR_Enable(@HomeDrive & "\")
$SysRst = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore", "RPSessionInterval")
If $SysRst = 1 Then
    MsgBox(0, "", "activé")
Else
    MsgBox(0, "", "désactivé")
EndIf

Donc maintenant, l'étau se resserre : windows 7 et 8 (et 8.1).


Merci pour vos bons conseils
++

[franco]

Recoucou

D'après test, c'est à partir de windows 7 que cela se complique.

• Plus de valeur de registre concernant la clé liée à systemrestore
• Quand on lance la protection système, plus de case à cocher et au3Info ne donne pas le texte désiré.

Or, quand on lance la protection système, il y a un bouton configurer. Image1
Si on clique dessus, on a 3 cases (la première et la troisième correspondant à "activé" et "désactivé"). Image2

On peut donc (d'après ce lien : http://autoitscript.fr/forum/viewtopic. ... 332#p91332 ou http://autoitscript.fr/forum/viewtopic. ... 345#p91345 ), faire comme ceci (ou adapter) afin d'avoir l'état.

ma question :
Est-possible de faire cela si la fenêtre en question est minimisée ?

Cela m'arrangerait bien, j'avoue.


++

[A2Energie]

Bonjour,

Concernant le controlcommand (si vous parvenez a le faire fonctionner) : Oui.
Concernant le Pixelcolor : Non, vous devez avoir la fenetre visible sur l écran

Cordialement..

[franco]

Recoucou.

Je pense qu'à partir de windows 7, je n'ouvrirais que la protection du système.
Ils verront par eux-même que l'outil a bien activé (ou désactivé) la restauration système.

Pour XP, vista, soit je fais commme dit plus haut, soit je fais de même.


En tout cas, merci à vous.
Je reposterai le code fini.


++

[jl56]

Bonjour à tous,

@franco

Merci pour ce partage, je cherchais justement a faire cette manip, ton script m'a fait gagné beaucoup de temps.
je te renvoie, pour l'exemple, ton code avec mes modifs

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

#include <WindowsConstants.au3>
#RequireAdmin
#include <GUIConstantsEx.au3>
#include <GUIListView.au3>
#include <WindowsConstants.au3>
#include "SystemRestore.au3"
#include <ListViewConstants.au3>
Global $Form_sr = GUICreate("Restauration Système", 860, 390, 10, 10)
GUISetBkColor(0xE0FFFF)
Global $rPoints
$PtRstLV = GUICtrlCreateListView("SqN|Description|Date - Heure", 10, 60, 540, 200, $WS_BORDER, $LVS_EX_CHECKBOXES)
_EnumRestP()
$SelAllPt = GUICtrlCreateRadio("Tout sélectionner", 15, 265, 120, 20)
GUICtrlSetFont(-1, 9, 400, 0, "comic sans ms")
$SelNoPt = GUICtrlCreateRadio("Ne rien sélectionner", 145, 265, 150, 20)
GUICtrlSetFont(-1, 9, 400, 0, "comic sans ms")

GUICtrlCreateGroup("", 560, 60, 290, 200, $WS_SIZEBOX)
$ActivateSR = GUICtrlCreateButton("Activer", 580, 90, 120, 30)
$DeactivateSR = GUICtrlCreateButton("Désactiver", 710, 90, 120, 30)
$CreatePt = GUICtrlCreateButton("Créer un point", 580, 140, 120, 30)
$DelSelPt = GUICtrlCreateButton("Supprimer la sélection", 710, 140, 120, 30)
$RazList = GUICtrlCreateButton("Actualiser", 580, 210, 120, 30)
$but_Restauration_system = GUICtrlCreateButton("Restauration system", 710, 210, 120, 30)
$quitter_sr = GUICtrlCreateButton("QUITTER", 380, 290, 120, 46)
GUICtrlSetFont(-1, 14, 800, 0, "MS Sans Serif")
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0xFF0000)


GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $quitter_sr
            Exit

        Case $RazList
            _EnumRestP()
        Case $SelAllPt
            For $i = 0 To _GUICtrlListView_GetItemCount($PtRstLV) - 1
                _GUICtrlListView_SetItemChecked($PtRstLV, $i, True)
            Next
            GUICtrlSetState($SelAllPt, $GUI_UNCHECKED)
        Case $SelNoPt
            For $i = 0 To _GUICtrlListView_GetItemCount($PtRstLV) - 1
                _GUICtrlListView_SetItemChecked($PtRstLV, $i, False)
            Next
            GUICtrlSetState($SelNoPt, $GUI_UNCHECKED)

        Case $CreatePt
            GUICtrlSetState($CreatePt, $GUI_HIDE)
            _SR_CreateRestorePoint('Point de restauration créé par xxx')
            Sleep(4000)
            GUICtrlSetState($CreatePt, $GUI_SHOW)
            _EnumRestP()

        Case $DeactivateSR
            If _SR_Disable() Then MsgBox(0, "Info", "la restauration system est bien désactivée", 30)

        Case $ActivateSR
            If _SR_enable() Then MsgBox(0, "Info", "La restauration system est bien activée", 30)

    Case $but_Restauration_system
        $DateHour =""
            For $i = $rPoints[0][0] To 0 Step -1
                If _GUICtrlListView_GetItemChecked($PtRstLV, $i) Then
;~                  MsgBox(0, "test i="&$i,_GUICtrlListView_GetItemChecked( $PtRstLV,$i))
                    $DateH = StringSplit(StringReplace($rPoints[$rPoints[0][0] - $i][2], " ", "-"), "-")
                    $Date = StringSplit($DateH[1], "/")
                    $Date = $Date[2] & "/" & $Date[1] & "/" & $Date[3]
                    $Hour = StringSplit($DateH[2], ":")
                    $Hour = $Hour[1] + 1 & ":" & $Hour[2] & ":" & $Hour[3]
                    $DateHour = $Date & " - " & $Hour

                    $answer = MsgBox(262148, "Attention", "Le point de restauration system que vous avez selectionné est" & @CRLF &@CRLF& $rPoints[$rPoints[0][0] - $i][1] _
                             & " le " & $DateHour & @CRLF & @CRLF & "Voulez vous restaurer ce point (un redemarrage sera éxécuté)", 30)

                    If $answer = 6 Then
                        If _SR_Restore($rPoints[$rPoints[0][0] - $i][0]) Then
                            MsgBox(262144, "Attention la restauration system à réussie", "Le system va redémarrer, quittez toutes vos applications", 60)
                            Shutdown(2)
                        EndIf
                    EndIf
                EndIf
            Next
            if $DateHour="" Then MsgBox(262144, "Attention","Vous n'avez pas selectionné un point de restauration dans la liste",10)

        Case $DelSelPt
            For $i = $rPoints[0][0] To 0 Step -1
                If _GUICtrlListView_GetItemChecked($PtRstLV, $i) Then
;~
                    _SR_RemoveRestorePoint($rPoints[$rPoints[0][0] - $i][0])
                EndIf
            Next
            _EnumRestP()

    EndSwitch
WEnd


Func _EnumRestP()
    _GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($PtRstLV))
    $rPoints = _SR_EnumRestorePoints()
    Dim $handle_liste[$rPoints[0][0] + 10]
    For $i = $rPoints[0][0] To 1 Step -1
        $DateH = StringSplit(StringReplace($rPoints[$i][2], " ", "-"), "-")
        $Date = StringSplit($DateH[1], "/")
        $Date = $Date[2] & "/" & $Date[1] & "/" & $Date[3]
        $Hour = StringSplit($DateH[2], ":")
        $Hour = $Hour[1] + 1 & ":" & $Hour[2] & ":" & $Hour[3]
        $DateHour = $Date & " - " & $Hour
        GUICtrlCreateListViewItem($rPoints[$i][0] & "|" & $rPoints[$i][1] & "|" & $DateHour, $PtRstLV)
    Next
    GUICtrlSendMsg($PtRstLV, $LVM_SETCOLUMNWIDTH, 0, $LVSCW_AUTOSIZE)
    GUICtrlSendMsg($PtRstLV, $LVM_SETCOLUMNWIDTH, 1, $LVSCW_AUTOSIZE)
    GUICtrlSendMsg($PtRstLV, $LVM_SETCOLUMNWIDTH, 2, $LVSCW_AUTOSIZE)
EndFunc   ;==>_EnumRestP
 

Merci encore

A+ JL56

[franco]

Salut

Content pour toi si mon bout de code t'a permis de finir le tien

J'aime le partage, et vu que je trouve tout ou presque sur le net, autant en faire profiter les autres.


Par contre, tu peux améliorer ton code, ou plutôt faire "propre" ^^

Regarde ceci

Code : Tout sélectionner

        Case $GUI_EVENT_CLOSE
            Exit
        Case $quitter_sr
            Exit
 

Remplace par ceci

Code : Tout sélectionner

        Case $GUI_EVENT_CLOSE, $quitter_sr
            Exit

Vu que c'est le même code, en mettant sous cette forme, cela équivaut à "scripter" les deux boutons avec le même code (ici Exit).




++

[franco]

Salut.

Si je devais résumer ma découverte en une phrase, la voici :
Comment passer pour un c*n en deux minutes

Orax a dit plus haut : « Sur Vista et +, c'est RPSessionInterval »
=> Je lui ai répondu que je n'avais pas cette valeur... Ni les autres données par ce dernier.

Pour que les autres ne perdent pas le fil conducteur :
Orax
Moi
Orax
Moi

Plusieurs tests effectués, même constat : aucune valeur identique.
Je me suis même dit : qu'est-ce que j'ai encore cassé


Par bonheur, je connais un outil bien pratique : RegShot

• Il permet de faire DEUX clichés du registre afin de comparer ces deux éléments.
• Un rapport s'ouvre en indiquant donc les modifications apportées.

Du coup, j'ai eu l'idée suivante (que j'ai réalisée sans problème) :
Premier cliché > Désactiver la restauration système > Deuxième cliché > Comparer.

Le rapport s'ouvre : plusieurs lignes s'offrent à moi.

Je décide donc de supprimer toutes les lignes ne correspondant pas à la restauration système...

Et c'est là qu'Orax va rire ^^

• Regardez la seule ligne exploitable : HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore\RPSessionInterval: 0x00000001
• Regardez ce que disait Orax : Sur Vista et +, c'est RPSessionInterval

Bref, Orax avait raison.

Mais pourquoi je ne voyais rien...


Car comme un véritable novice, j'ai oublié qu'à partir de windows 7, l'uac étant activé, je devais ouvrir le registre avec les droits admin pour que je vois toutes les valeurs...

Cela veut dire que deux choses :

1. Je dois mieux réflechir la prochaine fois. C'est pas gagné
2. Je n'ai plus de problème, puisque je peux détecter l'état de la restauration système à la fois sur XP, Vista, 7, 8 et 8.1

Bref, à cause de mes étourderies, j'ai fait bosser des membres pour rien... Désolé les gars.

J'aurais appris qu'à partir de vista, c'est un autre valeur à traiter.


Donc, je peux continuer mon code. Je le posterais une fois finie.
Et je peux donc faire ce que je voulais faire.



Vais donc passer en résolu.

Pour ceux qui sont intéressés par RegShot (car bigrement pratique, j'en ai fait les frais ) :

► Afficher le texteRegShot

Lien de téléchargement : http://sourceforge.net/projects/regshot/

Tutoriel (PCAstuces) : http://www.pcastuces.com/pratique/windo ... /page3.htm
Bien que je n'ai pas fait comme cela.

Voici comment j'ai procédé :

• Lancez RegShot et choisissez la langue Française ( tant qu'à faire ^^ )
• Cliquez sur le bouton 1er cliché et patientez (1 min environ) : les boutons deviennent grisés.
• Une fois le scan fini, les boutons sont à nouveau actifs : Cliquez sur le bouton 2ème cliché et patientez (1min environ)
• Une fois le scan fini, cliquez sur comparer et patientez (c'est assez rapide : 10/30 secondes).
• Et un rapport s'ouvre : miracle.

Il faudra ensuite virer les lignes non utiles et ne garder que les lignes correspondant à votre recherche.

Merci à tous.
Et Shame on Me. ^^

[jl56]

Bonjour à tous,

@franco

Je suis toujours intéressé si tu as besoin de tester sur des OS fait moi signe

A+

JL56

[orax]

D'après ce lien (pour Vista et +) : http://msdn.microsoft.com/en-us/library ... 85%29.aspx il y a les valeurs RPGlobalInterval ou RPSessionInterval à prendre en compte. Donc par sécurité, peut-être qu'il serait préférable de vérifier ces 2 valeurs.

Avec Regedit, l'actualisation n'est pas automatique. Je ne sais pas si tu l'avais fait mais il faut appuyer sur F5 pour voir les nouvelles données apparaître.