[R] Listview & Msgbox

[Y01]

Bonjour,

J'ai créé une petite liseuse de logs qui liste tous les fichiers .log et .bmp d'un dossier et qui les affichent dans une MSGBOX lorsqu'on clique dessus.

Mon problème est que je souhaiterais que ce soit une listview qui s'ouvre lorsque je clic sur un .log et une msgbox pour un .bmp.

Le code actuellement :

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <FileConstants.au3>


Global $chemin = "D:\Logs"          ; Chemin où se situe les fichiers
Global $files = _FileListToArrayRec($chemin, "*.log;*.bmp", 1)  ; Récupération des fichiers
Global $GUI = GUICreate("Liseuse", 220, 250, 100, 200)
Local $idListview = GUICtrlCreateListView("Liste", 10, 10, 200, 220) ;,$LVS_SORTDESCENDING)
_GUICtrlListView_SetColumnWidth($idListview, 0, 170)
GUISetState(@SW_SHOW, $GUI)
Opt("GUIResizeMode", $GUI_DOCKALL)
Local $boutons[$files[0]]
Local $placement = 10
Local $droite = 10
For $i = 1 to $files[0]
   $boutons[$i-1] = GUICtrlCreateListViewItem($files[$i], $idListview)
   $placement = $placement + 30
Next


While 1
   $nMsg = GUIGetMsg()
      Switch $nMsg
      Case $GUI_EVENT_CLOSE                                 ; Lorsqu'on clic sur la croix de fermeture, on ferme l'application.
         Exit
      EndSwitch
      For $i = 1 to $files[0]
If $nMsg = $boutons[$i-1] Then MsgBox(262144,$files[$i],FileRead($chemin & "\" & $files[$i]))
Next
WEnd

EDIT : Le code finalisé

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <FileConstants.au3>
#include <GDIPlus.au3>

Global $iShow = 0, $sSelectedFile
Global $chemin = @UserProfileDir & "\Desktop"         ; Chemin où se situe les fichiers
Global $files = _FileListToArrayRec($chemin, "*.Log;*.jpg", 1)  ; Récupération des fichiers
Global $GUI = GUICreate("Liseuse", 220, 250, 100, 200)
Local $idListview = GUICtrlCreateListView("Liste", 10, 10, 200, 230)
Global $idDummy = GUICtrlCreateDummy()
_GUICtrlListView_SetColumnWidth($idListview, 0, 196)
GUISetState(@SW_SHOW, $GUI)
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
Opt("GUIResizeMode", $GUI_DOCKALL)

Local $boutons[$files[0]]

For $i = 1 to $files[0]
   $boutons[$i - 1] = GUICtrlCreateListViewItem($files[$i], $idListview)
Next

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    If $iShow Then _Show()

WEnd

Func _Show()
    GUISetState(@SW_DISABLE, $GUI)

    Local $nMsgChild
    Local $iGuiWidth = 800, $iGuiHeight = 600

    $sType = "pic"
    If StringRegExp($sSelectedFile, "(?i)\.log$") Then $sType = "log"

    If $sType = "pic" Then
        _GDIPlus_Startup()
        $hBitmap = _GDIPlus_BitmapCreateFromFile ( $chemin & "\" & $sSelectedFile )
        $iW = _GDIPlus_ImageGetWidth($hBitmap)
        $iH = _GDIPlus_ImageGetHeight($hBitmap)
        _GDIPlus_BitmapDispose($hBitmap)
        ConsoleWrite($iGuiWidth & "x" & $iGuiHeight & @CRLF)
        _GDIPlus_Shutdown()

        If $iW > $iH Then
            $iGuiHeight = Ceiling($iH * $iGuiWidth / $iW)
        Else
            $iGuiWidth = Ceiling($iW * $iGuiHeight / $iH)
        EndIf
    EndIf

    $hViewer = GUICreate("Viewer", $iGuiWidth, $iGuiHeight, Default, Default, Default, $WS_EX_TOOLWINDOW, $GUI)

    Switch $sType
        Case "pic"
            GUICtrlCreatePic($chemin & "\" & $sSelectedFile, 0, 0, $iGuiWidth, $iGuiHeight)
         Case "log"
            Local $idMyedit = GUICtrlCreateEdit("", 10, 10, 780, 580, $ES_AUTOVSCROLL + $WS_VSCROLL)
            GUICtrlSetData($idMyedit, FileRead($chemin & "\" & $sSelectedFile), "")
    EndSwitch

    GUISetState()

    While 1
        $nMsgChild = GUIGetMsg()
        Switch $nMsgChild
            Case $GUI_EVENT_CLOSE
                GUISetState(@SW_ENABLE, $GUI)
                GUIDelete($hViewer)
                ExitLoop
        EndSwitch
    WEnd

    $iShow = 0
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $iIDFrom, $iCode, $tNMHDR, $tInfo, $iIndex

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $iIDFrom
        Case $idListview
            Switch $iCode
                Case $NM_CLICK
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    $iIndex = DllStructGetData($tInfo, "Index")

                    $iShow = 1
                    $sSelectedFile = _GUICtrlListView_GetItemText($idListview, $iIndex)

            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

[DimVar]

Bonjour,

Une msgbox ne peut pas afficher de BMP. (ou alors je n'ai pas compris votre requête)


Cdlt.

[Y01]

C'est l’inconvénient de ne pas tester tous les modifications que l'on effectuent.

Mea Culpa.

A la base, les fichiers étaient ouvert avec un shellexecute, ce qui marchait parfaitement.

Par contre, le problème initial était que je souhaitais que les fichiers restent en premier plan, ce qui explique la msgbox(262144...) et ça fonctionne très bien (pour les logs en tout cas).

Mon autre problème est que j'ai des logs de plusieurs pages et que c'est impossible d'avoir le contenu complet dans un msgbox.

Concernant les BMP, je pense qu'on fera avec si on ne peut les ouvrir qu'avec un shellexecute.

[jguinch]

Le mieux serait une GUI qui affiche les logs avec GUICtrlCreateEdit et les images avec GUICtrlCreatePic.
- tu mets la GUI en premier plan
- tu auras un ascenseur pour les logs
- tu pourras dimensionner l'image comme tu veux (tu peux d'ailleurs récupérer la taille de l'image avec _GDIPlus_ImageGetWidth et _GDIPlus_ImageGetHeight :

Code : Tout sélectionner

 _GDIPlus_Startup()
$hBitmap = _GDIPlus_BitmapCreateFromFile ( "C:\Users\j1guinchard\Documents\GDIPlus_Image.bmp" )
$iWidth = _GDIPlus_ImageGetWidth($hBitmap)
$iHeight = _GDIPlus_ImageGetHeight($hBitmap)
_GDIPlus_BitmapDispose($hBitmap)
ConsoleWrite($iWidth & "x" & $iHeight)
 

[Y01]

Merci jguinch, j'ai réussi à faire une GUI qui me récupère le contenu de mes logs par contre je n'arrive pas à lui faire comprendre la diffèrence entre un bmp et un log.

J'ai essayé ça mais sans succès :

► Afficher le texte

Code : Tout sélectionner

      GUICreate("My GUI edit")
      Local $idMyedit = GUICtrlCreateEdit("", 10, 10, 375, 375, $ES_AUTOVSCROLL + $WS_VSCROLL)
      GUISetState(@SW_SHOW)

While 1
   $nMsg = GUIGetMsg()
      Switch $nMsg
      Case $GUI_EVENT_CLOSE                                 ; Lorsqu'on clic sur la croix de fermeture, on ferme l'application.
         Exit
      EndSwitch
      For $i = 1 to $files[0]
         If $nMsg = $boutons[$i-1] Then
            if $files[$i] = "*.txt" then GUICtrlSetData($idMyedit, FileRead($chemin & "\" & $files[$i]), "")
            Else MsgBox(0,"","action pour un bmp")
            EndIf

Next
WEnd

[jguinch]

J'avais un peu de temps ce soir, je t'ai fais un petit truc qui devrait ressembler à ce que tu veux.
J'ai utilisé GUIRegisterMsg au lieu de ta boucle For $i = 1 to $files[0] et créé une GUI pour afficher soit une image soit du texte.
La GUI et l'image sont redimensionnées à l'affichage (en me basant sur mon idée précédente).

Pour différencier un .log d'un .bmp, j'ai simplement testé si le nom du fichier se termine par .log ou non :
If StringRegExp($sSelectedFile, "(?i)\.log$") Then $sType = "log"

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstants.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <FileConstants.au3>
#include <GDIPlus.au3>

Global $iShow = 0, $sSelectedFile

Global $chemin = "D:\Mes Documents"          ; Chemin où se situe les fichiers
Global $files = _FileListToArrayRec($chemin, "*.log;*.jpg", 1)  ; Récupération des fichiers
Global $GUI = GUICreate("Liseuse", 220, 250, 100, 200)
Local $idListview = GUICtrlCreateListView("Liste", 10, 10, 200, 220) ;,$LVS_SORTDESCENDING)
Global $idDummy = GUICtrlCreateDummy()

_GUICtrlListView_SetColumnWidth($idListview, 0, 170)
GUISetState(@SW_SHOW, $GUI)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")


Opt("GUIResizeMode", $GUI_DOCKALL)


Local $boutons[$files[0]]

For $i = 1 to $files[0]
   $boutons[$i - 1] = GUICtrlCreateListViewItem($files[$i], $idListview)
Next





While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
    
    If $iShow Then _Show()
    
WEnd




Func _Show()
    GUISetState(@SW_DISABLE, $GUI)
    
    Local $nMsgChild
    Local $iGuiWidth = 1024, $iGuiHeight = 768
    
    $sType = "pic"
    If StringRegExp($sSelectedFile, "(?i)\.log$") Then $sType = "log"
    
    If $sType = "pic" Then
        _GDIPlus_Startup()
        $hBitmap = _GDIPlus_BitmapCreateFromFile ( $chemin & "\" & $sSelectedFile )
        $iW = _GDIPlus_ImageGetWidth($hBitmap)
        $iH = _GDIPlus_ImageGetHeight($hBitmap)
        _GDIPlus_BitmapDispose($hBitmap)
        ConsoleWrite($iGuiWidth & "x" & $iGuiHeight & @CRLF)
        _GDIPlus_Shutdown()
        
        If $iW > $iH Then
            $iGuiHeight = Ceiling($iH * $iGuiWidth / $iW)
        Else
            $iGuiWidth = Ceiling($iW * $iGuiHeight / $iH)
        EndIf
        
    EndIf
    
    $hViewer = GUICreate("Viewer", $iGuiWidth, $iGuiHeight, Default, Default, Default, $WS_EX_TOOLWINDOW, $GUI)
    
    Switch $sType
        Case "pic"
            GUICtrlCreatePic($chemin & "\" & $sSelectedFile, 0, 0, $iGuiWidth, $iGuiHeight)
        Case "log"
            $sContent = FileRead( $chemin & "\" & $sSelectedFile)
            $edit = GUICtrlCreateEdit($sContent, 0, 0, $iGuiWidth, $iGuiHeight, 0x0800)
    EndSwitch
    
    GUISetState()
    
    While 1
        $nMsgChild = GUIGetMsg()
        Switch $nMsgChild
            Case $GUI_EVENT_CLOSE
                GUISetState(@SW_ENABLE, $GUI)
                GUIDelete($hViewer)
                ExitLoop
        EndSwitch
    WEnd
    
    $iShow = 0
EndFunc






Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $iIDFrom, $iCode, $tNMHDR, $tInfo, $iIndex

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    
    Switch $iIDFrom
        Case $idListview
            Switch $iCode
                Case $NM_CLICK
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    $iIndex = DllStructGetData($tInfo, "Index")
                    
                    $iShow = 1
                    $sSelectedFile = _GUICtrlListView_GetItemText($idListview, $iIndex) 
                    
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

 

[Y01]

Génial jguinch !!!

ça marche nickel.

PS : Désolé de la latence de réponse, je n'avais pas d'ordinateur à dispo.