[R] GDIPlus redimensionner une image (sans fichier)

[ZDS]

Bonjour,

Je me heurte à un souci, j'aimerai trouver le problème du script suivant (la ligne 15 en commentaire pose problème) :

► Afficher le texteGDIPlus/Resize

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <Constants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

; create variables and objects

_GDIPlus_Startup()

$gpsind0 = _GDIPlus_ImageLoadFromFile("search.png")
$hHBMP0 = _GDIPlus_BitmapCreateHBITMAPFromBitmap($gpsind0)
$context0 = _GDIPlus_ImageGetGraphicsContext($gpsind0)
$gpsind1 = _GDIPlus_BitmapCreateFromGraphics(90,60, $context0)
$context1 = _GDIPlus_ImageGetGraphicsContext($gpsind1)
;~ _GDIPlus_GraphicsDrawImageRectRect($context1, $hHBMP, 0, 0, 450, 431, 0, 0, 90, 30)
$hHBMP1 = _GDIPlus_BitmapCreateHBITMAPFromBitmap($gpsind1)
$Form1 = GUICreate("A problem to solve", 150, 150)
$btn0 = GUICtrlCreateButton('Button', 10, 10, 90, 60, 0x0080) ; $BS_BITMAP = 0x0080
$btn1 = GUICtrlCreateButton('Button', 10, 80, 90, 60, 0x0080) ; $BS_BITMAP = 0x0080
GUISetState(@SW_SHOW)
_WinAPI_DeleteObject(GUICtrlSendMsg($btn0, 0xF7, 0x00, $hHBMP0)) ; $BM_SETIMAGE = 0xF7 ; $IMAGE_BITMAP = 0x00
_WinAPI_DeleteObject(GUICtrlSendMsg($btn1, 0xF7, 0x00, $hHBMP1)) ; $BM_SETIMAGE = 0xF7 ; $IMAGE_BITMAP = 0x00

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _WinAPI_DeleteObject($hHBMP1)
            _GDIPlus_ImageDispose($gpsind1)
            _GDIPlus_GraphicsDispose($context0)
            _WinAPI_DeleteObject($hHBMP0)
            _GDIPlus_ImageDispose($gpsind0)
            _GDIPlus_Shutdown()
            GUIDelete()
            Exit
        Case $btn0
            MsgBox(64, '', 'you clicked a button 0')
        Case $btn1
            MsgBox(64, '', 'you clicked a button 1')

    EndSwitch
WEnd

Je me suis basé sur un exemple similaire, pour pouvoir retailler (en redimensionnant, pas en rognant) une image issue d'une capture d'écran avec _ScreenCapture_Capture("") qui retourne un handle. En gros, dans ce script là, c'est comme si je ne pouvais pas toucher à la variable $hHBMP0. Mon but est de trouver comment faire en sorte qu'une version "écrasée" de $hHBMP0 (450px par 431px) se retrouve dans $hHBMP1 (90px par 50px). Le bouton $btn0 affiche bien l'image (non redimensionnée), mais $btn1 n'affiche pour le moment qu'un rectangle noir...

Ci joint l'image utilisée pour mon test.

► Afficher le texteImage

Merci d'avance pour votre aide, et à très bientôt !

[mikell]

J'ai récupéré ça au fond d'un tiroir... c'est vieux, c'est moche mais ça marche
Charge à toi d'en faire quelque chose de mignon

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <Constants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

_GDIPlus_Startup()

$gpsind0 = _GDIPlus_ImageLoadFromFile("file.png")
$hHBMP0 = _GDIPlus_BitmapCreateHBITMAPFromBitmap($gpsind0)
$hHBMP1 = _hBitmap_Resize($hHBMP0, 90, 60)

$Form1 = GUICreate("A problem to solve", 150, 150)
$btn0 = GUICtrlCreateButton('Button', 10, 10, 90, 60, 0x0080) ; $BS_BITMAP = 0x0080
$btn1 = GUICtrlCreateButton('Button', 10, 80, 90, 60, 0x0080) ; $BS_BITMAP = 0x0080
GUISetState(@SW_SHOW)

_WinAPI_DeleteObject(GUICtrlSendMsg($btn0, 0xF7, 0x00, $hHBMP0)) ; $BM_SETIMAGE = 0xF7 ; $IMAGE_BITMAP = 0x00
_WinAPI_DeleteObject(GUICtrlSendMsg($btn1, 0xF7, 0x00, $hHBMP1)) ; $BM_SETIMAGE = 0xF7 ; $IMAGE_BITMAP = 0x00



While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _WinAPI_DeleteObject($hHBMP1)
            _WinAPI_DeleteObject($hHBMP0)
            _GDIPlus_ImageDispose($gpsind0)
            _GDIPlus_Shutdown()
            GUIDelete()
            Exit
        Case $btn0
            MsgBox(64, '', 'you clicked a button 0')
        Case $btn1
            MsgBox(64, '', 'you clicked a button 1')

    EndSwitch
WEnd



Func _hBitmap_GetSize($hBitmap)
    Local $tObj = DllStructCreate('long Type;long Width;long Height;long WidthBytes;ushort Planes;ushort BitsPixel;ptr Bits')
    Local $Ret = DllCall('gdi32.dll', 'int', 'GetObject', 'int', $hBitmap, 'int', DllStructGetSize($tObj), 'ptr', DllStructGetPtr($tObj))

    If (@error) Or ($Ret[0] = 0) Then
        Return 0
    EndIf
    Local $Size[2] = [DllStructGetData($tObj, 'Width'), DllStructGetData($tObj, 'Height')]
    If ($Size[0] = 0) Or ($Size[1] = 0) Then
        Return 0
    EndIf
    Return $Size
EndFunc   ;==>_Icons_Bitmap_GetSize


Func _hBitmap_Resize($hBitmap, $iWidth, $iHeight)
    Local $Size = _hBitmap_GetSize($hBitmap)
    If $Size = 0 Then
        Return 0
    EndIf
    Local $Ret, $hDC, $hDestDC, $SrcDC, $hBmp

    $hDC = _WinAPI_GetDC(0)
    $hDestDC = _WinAPI_CreateCompatibleDC($hDC)
    $hBmp = _WinAPI_CreateCompatibleBitmap($hDC, $iWidth, $iHeight)
    _WinAPI_SelectObject($hDestDC, $hBmp)
    $hSrcDC = _WinAPI_CreateCompatibleDC($hDC)
    _WinAPI_SelectObject($hSrcDC, $hBitmap)
    _WinAPI_ReleaseDC(0, $hDC)
    DllCall('gdi32.dll', 'int', 'SetStretchBltMode', 'hwnd', $hDestDC, 'int', 4)
    $Ret = DllCall('gdi32.dll', 'int', 'StretchBlt', 'hwnd', $hDestDC, 'int', 0, 'int', 0, 'int', $iWidth, 'int', $iHeight, 'hwnd', $hSrcDC, 'int', 0, 'int', 0, 'int', $Size[0], 'int', $Size[1], 'dword', $SRCCOPY)
    If (@error) Or ($Ret[0] = 0) Then
        _WinAPI_DeleteObject($hBmp)
        $hBmp = 0
    EndIf

    _WinAPI_DeleteDC($hDestDC)
    _WinAPI_DeleteDC($hSrcDC)
    Return $hBmp
EndFunc   ;==>_Icons_Bitmap_Resize
 

[ZDS]

Merci beaucoup, je vais essayer d'en tirer qqchose En tout cas, l'effet voulu est bon.

[mikell]

Pour les dllcalls les fonctions équivalentes sont dans WinAPIGdi.au3
_WinAPI_GetBitmapDimension
_WinAPI_SetStretchBltMode
_WinAPI_StretchBlt

[ZDS]

Problème [R]ésolu !

J'ai remis à jour les DllCall avec des fonctions existantes (les grands esprits se rencontrent, Mikell ^^) et modifié le StretchMode (le 4 "HALFTONE" est plus propre, même si on perd la transparence ce n'est pas un souci dans mon cas), et une fois adapté à mon code d'origine, ça fonctionne du feu de dieu.

Merci beaucoup !

► Afficher le texteCode corrigé

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <Constants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <WinAPIGdi.au3>

test()

Func test()
    _GDIPlus_Startup()
    Local $gpsind0 = _GDIPlus_ImageLoadFromFile("search.png")
    Local $hHBMP0 = _GDIPlus_BitmapCreateHBITMAPFromBitmap($gpsind0)
    Local $hHBMP1 = _hBitmap_Resize($hHBMP0, 90, 60)

    Local $Form1 = GUICreate("A problem to solve", 150, 150)
    Local $btn0 = GUICtrlCreateButton('Button', 10, 10, 90, 60, 0x0080) ; $BS_BITMAP = 0x0080
    Local $btn1 = GUICtrlCreateButton('Button', 10, 80, 90, 60, 0x0080) ; $BS_BITMAP = 0x0080
    GUISetState(@SW_SHOW)

    _WinAPI_DeleteObject(GUICtrlSendMsg($btn0, 0xF7, 0x00, $hHBMP0)) ; $BM_SETIMAGE = 0xF7 ; $IMAGE_BITMAP = 0x00
    _WinAPI_DeleteObject(GUICtrlSendMsg($btn1, 0xF7, 0x00, $hHBMP1)) ; $BM_SETIMAGE = 0xF7 ; $IMAGE_BITMAP = 0x00

    While 1
        Local $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                _WinAPI_DeleteObject($hHBMP1)
                _WinAPI_DeleteObject($hHBMP0)
                _GDIPlus_ImageDispose($gpsind0)
                _GDIPlus_Shutdown()
                GUIDelete()
                ExitLoop
            Case $btn0
                MsgBox(64, '', 'you clicked a button 0')
            Case $btn1
                MsgBox(64, '', 'you clicked a button 1')
        EndSwitch
    WEnd
EndFunc

Func _hBitmap_Resize($hBitmap, $iWidth, $iHeight)
    Local $Size = _WinAPI_GetBitmapDimension($hBitmap)
    If $Size = 0 Then Return 0
    Local $hDC = _WinAPI_GetDC(0)
    Local $hDestDC = _WinAPI_CreateCompatibleDC($hDC)
    Local $hBmp = _WinAPI_CreateCompatibleBitmap($hDC, $iWidth, $iHeight)
    _WinAPI_SelectObject($hDestDC, $hBmp)
    Local $hSrcDC = _WinAPI_CreateCompatibleDC($hDC)
    _WinAPI_SelectObject($hSrcDC, $hBitmap)
    _WinAPI_ReleaseDC(0, $hDC)
    _WinAPI_SetStretchBltMode($hDestDC, 4)
    Local $result = _WinAPI_StretchBlt($hDestDC, 0, 0, $iWidth, $iHeight, $hSrcDC, 0, 0, DllStructGetData($Size,'X'), DllStructGetData($Size,'Y'), 0x00CC0020) ; $SRCCOPY = 0x00CC0020
    If @error Or Not $result Then
        _WinAPI_DeleteObject($hBmp)
        $hBmp = 0
    EndIf
    _WinAPI_DeleteDC($hDestDC)
    _WinAPI_DeleteDC($hSrcDC)
    Return $hBmp
EndFunc   ;==>_hBitmap_Resize