[R] Image dans ListView

[Ks10]

Bonsoir à tous !

J'ai besoin de quelques renseignements concernant les listviews.
Le but principale est de listé des données et avoir un contrôle sur chacune de ces lignes.

1er besoin :

- Avoir une ligne avec des données et une dernière colonne avec des icônes.

2ième besoin :

- Pouvoir cliqué sur ces icônes quelques soit le nombre de ligne présente dans la listview.

Voici un début de code et je suis déjà bloqué :

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Form1", 615, 437, 192, 124)
Global $List1 = GUICtrlCreateListView("Colonne 1|Colonne 2|Colonne 3|Icone", 0, 0, 609, 422)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

For $i = 0 To 10
           GuiCtrlCreateListViewItem($list1, "" & "|Test|Test|Test|")
       GUICtrlSetImage($List3, "shell32.dll", 23, 0)
Next


While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit

 EndSwitch
WEnd


 

Donc voila plusieurs question :


- Si je fait comme sa, j'ai une icone sur la première colonne mais comment la placer n'importe ou ?
- Sur la dernière colonne par exemple ?
- Comment rajouter une autre icône à coté de l'autre ?
- Je peut cliquer sur ces icones ? indépendemment de l'autre ? et des lignes ?

Merci d'avance pour vos réponses.

[Hugues]

Bonjour,

Un truc comme cà?:

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $idListview, $hImage
    Local $iStylesEx = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)

    $hGui = GUICreate("ImageList AddIcon", 400, 300)
    $idListview = _GUICtrlListView_Create($hGui, "", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($idListview, $iStylesEx)
    GUISetState(@SW_SHOW)

    ; Load images
    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Column 1", 120)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Add items
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1, 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2, 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 1", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 2: Col 2", 1, 2)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 1", 2)
    _GUICtrlListView_AddItem($idListview, "Row 4: Col 1", 3)
    _GUICtrlListView_AddItem($idListview, "Row 5: Col 1", 4)
    _GUICtrlListView_AddSubItem($idListview, 4, "Row 5: Col 2", 1, 3)
    _GUICtrlListView_AddItem($idListview, "Row 6: Col 1", 5)
    _GUICtrlListView_AddSubItem($idListview, 5, "Row 6: Col 2", 1, 4)
    _GUICtrlListView_AddSubItem($idListview, 5, "Row 6: Col 3", 2, 3)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example
 

[Ks10]

Au niveau des icônes cela correspond, j'avait déjà tester cette solution.
Mais au niveau du listing, cela ne correspond pas. C'est beaucoup trop "manuel" et moins "automatique".

Dès le moment où je met sa :

Code : Tout sélectionner

For $î = 0 To 10

    _GUICtrlListView_AddItem($idListview, "Row 1: Col 1", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 2", 1, 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 1: Col 3", 2, 2)

Next

La premiere colonne est listé mais les autres non. Si je fait dans une boucle différente chaque colonne cela revien pareil.

Une autre solution ?

[Hugues]

Je peux te proposer ça dans un premier temps:

Code : Tout sélectionner

[spoiler=]

#include <GuiListView.au3>
#include <GuiImageList.au3>
    #include <GUIConstantsEx.au3>
    #include <GUIListBox.au3>
    #include <WindowsConstants.au3>
    #Region ### START Koda GUI section ### Form=
    Global $Form1 = GUICreate("Form1", 615, 437, 192, 124)
    Global $hListView = GUICtrlCreateListView("Colonne 1|Colonne 2|Colonne 3|Icone", 0, 0, 609, 422)
    Global $NumberOfRows = 20, $hImage
    GUISetState(@SW_SHOW)
    $hImage = _GUIImageList_Create(16, 16, 5, 3)


    For $i = 0 To $NumberOfRows
        _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
        _GUICtrlListView_AddSubItem($hListView, $i, "Row 1: Col 2", 1, 1)
        _GUICtrlListView_AddSubItem($hListView, $i, "Row 1: Col 3", 2, 1)
        GUICtrlSetImage($hListView,"shell32.dll", $i + 1)
    Next


    While 1
        $nMsg = GUIGetMsg()
            Switch $nMsg
                Case $GUI_EVENT_CLOSE
                Exit

            EndSwitch
    WEnd



[/spoiler]

ensuite il y a un sujet qui est pas mal ^^: http://www.autoitscript.fr/forum/viewto ... 20&t=10120

[Ks10]

Ta solution, fonctionne mais pas avec la commande GuiCtrlCreateListViewItem ^^ je dois faire fonctionné avec sa. Mais bon c'est pas grave j'ai enlever l'idée des icônes, c'est un peu plus chiant à gêrer avec les icônes.

Par contre j'ai un autre petit soucis :

- Est-il possible de détecté un double clique dans la listview ?
J'ai trouver des sujets qui parle de $WM_notify mais cela ne semble pas fonctionné avec "GuiCtrlCreateListView".

J'ai tenter d'élaborer une fonction avec _IsPressed("01") avec une sorte d'évènement de porte 0 et 1 mais cela ne fonctionne pas non plus.

Si quelqu'un a la solution je suis preneur.

Merci d'avance

[mikell]

Le WM_NOTIFY fonctionne
On peut tout à fait (à 99%) faire un mix des fonctions listview intégrées avec celles de l'UDF

► Afficher le texte

Code : Tout sélectionner

#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <Array.au3>

Dim $array[3][3]
$array[0][1] = @Autoitexe
$array[0][2] = FileGetVersion(@Autoitexe)
$array[1][1] = "ligne 2, colonne 1"
$array[1][2] = "ligne 2, colonne 2"
$array[2][1] = "ligne 3, colonne 1"
$array[2][2] = "ligne 3, colonne 2"

$gui = GUICreate("listview items", 420, 180, 100, 200, -1)
$listview = GUICtrlCreateListView("icone|colonne 1|colonne 2 ", 10, 10, 400, 130, -1, $LVS_EX_SUBITEMIMAGES+$LVS_EX_FULLROWSELECT)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 60)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 200)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 2, 130)

$hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @Autoitexe, 0)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 132)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 138)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
_GUICtrlListView_SetImageList($listview, $hImage, 1)

Dim $ligne[3]
$ligne[0] = GUICtrlCreateListViewItem("|" &$array[0][1] & "| ", $listview)
$ligne[1] = GUICtrlCreateListViewItem("|" &$array[1][1] & "|" , $listview)
$ligne[2] = GUICtrlCreateListViewItem("|" &$array[2][1] & "|" , $listview)

_GUICtrlListView_AddSubItem($listview, 0, "(1)", 0, 0)
_GUICtrlListView_AddSubItem($listview, 1, "(2)", 0, 1)
_GUICtrlListView_AddSubItem($listview, 2, "(3)", 0, 2)
_GUICtrlListView_AddSubItem($listview, 0, $array[0][2], 2, 3)
_GUICtrlListView_AddSubItem($listview, 1, $array[1][2], 2, 4)
_GUICtrlListView_AddSubItem($listview, 2, $array[2][2], 2, 5)
GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
   

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = GUICtrlGetHandle($listView)
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_DBLCLK
                         $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                         $index = DllStructGetData($tInfo, "Index")
                         For $i = 0 to 2
                               GuiCtrlSetColor($ligne[$i], 0x000000)
                         Next
                         GuiCtrlSetColor($ligne[$index], 0xff0000)
                         ControlListView($gui, "", $listview, "DeSelect", -1)
           EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

[Ks10]

Ah oui effectivement, avec ta fonction ça fonctionne, c'est surement les fonctions que j'ai récupérer qui n'était pas bonne.

En tous cas, merci encore pour vos réponses. Sujet resolved

[Ks10]

Je ré-ouvre ce sujet car il est en rapport avec le poste précédent.
En utilisant la fonction WM_Notify , j'essaye d'ouvrir une autre interface lorsque je clique sur un item de ma listview.
Cependant je ne sait pour quel raison mon programme plante dès que cette fenêtre apparaît.

Voici le code de l'interface et la fonction :

► Afficher le texte

Code : Tout sélectionner

Func _Read_Email()

        Local $Form3 = GUICreate("Form1", 382, 486, -1, -1, $WS_POPUP)
        Local $bck_mail = GUICtrlCreatePic(@ScriptDir & "\Ressources\background_mail.jpg", 0, 0, 380, 484)
        GUICtrlSetState(-1, $GUI_DISABLE)
        Local $ext_mail = GUICtrlCreatePic(@ScriptDir & "\Ressources\unclick_exit_mail.jpg", 344, 0, 36, 36)
        Local $mail_date = GUICtrlCreateLabel("DATE : ", 8, 56, 42, 17)
        GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
        Local $Input_date = GUICtrlCreateInput("Input1", 56, 56, 321, 21)
        Local $mail_emetteur = GUICtrlCreateLabel("Emetteur : ", 8, 120, 55, 17)
        GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
        Local $Input_emetteur = GUICtrlCreateInput("Input2", 64, 120, 313, 21)
        Local $mail_objet = GUICtrlCreateLabel("Objet : ", 8, 184, 38, 17)
        GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
        Local $Input_objet = GUICtrlCreateInput("Input3", 48, 184, 329, 21)
        Local $mail_message = GUICtrlCreateLabel("Message : ", 8, 232, 56, 17)
        GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
        Local $input_message = GUICtrlCreateEdit("", 8, 256, 369, 177)
        Local $btn_repond = GUICtrlCreatePic("", 8, 432, 180, 44)
        Local $btn_del = GUICtrlCreatePic("", 192, 432, 180, 44)
        GUISetState(@SW_SHOW)

        While 1
            $nMsg = GUIGetMsg(1)
        Select

                Case $nMsg[0] = $GUI_EVENT_CLOSE And $nMsg[1] =$Form3
                    GUIDelete($Form3)
                    ExitLoop

        EndSelect
        WEnd


EndFunc
 

La fonction :

► Afficher le texte

Code : Tout sélectionner

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = GUICtrlGetHandle($List3)
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_DBLCLK
                         $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                         $index = DllStructGetData($tInfo, "Index")
                                $iIndex = _GUICtrlListView_GetSelectedIndices($List3)
                                If ($iIndex) <> "" Then
                                    $sel  = _GUICtrlListView_GetItemText($List3,Int($iIndex))
                                    _Read_Email()
                                EndIf
                         ;ControlListView($gui, "", $List3, "DeSelect", -1)
           EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Je pense que le plantage est du à la boucle qui s'imbrique dans la fonction mais je ne comprend pas comment faire autrement.

Merci d'avance.

[mikell]

Pourtant tu devrais puisque tu sais utiliser GUIGetMsg(1)
Perso, je créerais la gui $form3 en début de script et cachée, juste un 'show' dans le wm_notify et la gestion dans la boucle principale du script

[Ks10]

OK je vais faire ça alors, pourtant dans le reste de mon code c'est ce que jai fait jai créé toute les autres gui avant et je les est caché pour celui la jai voulu utiliser cette méthode mais cela ne semble pas être la plus adéquate.
Merci encore.