[..] Fichier texte dans une Listbox

[Andranik]

Bonjour,

J'ai vraiment du mal avec les tableaux et les fichiers ... Je n’arrive pas a comprendre leur fonctionnement.
J'ai un fichier texte "ID.txt" et une Listbox qui doit dépendre du fichier id.txt
Dans le fichier id il y a X Ligne et Y colonne.
Je souhaiterait afficher dans la listbox La 1er colonne de mon fichier id.txt
Si je choisis une ligne dans ma listbox et que je veux faire appel a une fonction qui doit afficher la valeur de la colonne 2 de la ligne sélectionner

Code : Tout sélectionner

    $Countfile= _FileCountLines("C:\temp\ids.txt")   ;Je compte le nombre de ligne dans le fichier

    $file = "C:\temp\ids.txt"

For $i = 1 To $CountFile                                     
      ;Local $var1[1]                                      ;$var1 est une colonne 
      $var1 = FileReadLine($file, $i)                       ;Lecture de la ligne 
      $res = StringSplit($var1,":")                     ; Je sépare par un ":" 

 _GUICtrlListBox_AddString($List1, $res)               ;Et je affiche tout cela ici
Next


 

Merci

[jguinch]

StringSplit renvoie un tableau :

Code : Tout sélectionner

_GUICtrlListBox_AddString($List1, $res[1])

[mikell]

Tiens un exemple sympa d'application de StringRegExp avec flag 4
Sur un txt comme ça

Code : Tout sélectionner

abc:123
def:456
ghi:789

Essaye ça

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>

GUICreate("My GUI list") 
$btn = GUICtrlCreateButton("clic", 64, 32, 75, 25)
$mylist = GUICtrlCreateList("", 176, 32, 121, 97)
GUISetState(@SW_SHOW)

$file = FileRead("ids.txt")
$lines = StringRegExp($file, '(?m)^(\N+?):(\N+)\R?', 4)
Local $nblines = UBound($lines), $list = ""
For $i = 0 to $nblines-1
      $list &= ($lines[$i])[1] & "|"
Next
GuiCtrlSetData($mylist, $list)

While 1
        $msg = GUIGetMsg()
        Switch $msg
            Case $btn
                $item = GUICtrlRead($mylist)
                For $i = 0 to $nblines-1
                   If $item = ($lines[$i])[1] Then Msgbox(0,"", ($lines[$i])[2] )
                Next
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
WEnd
 

[Andranik]

StringSplit renvoie un tableau :

Code : Tout sélectionner

_GUICtrlListBox_AddString($List1, $res[1])

Merci... cela a fonctionné

[mikell]

1/ FileReadLine($file, $i) est à éviter :
"From a performance standpoint it is a bad idea to read line by line specifying "line" parameter whose value is incrementing by one. This forces AutoIt to reread the file from the beginning until it reach the specified line."
2/ Il faut te mettre aux tableaux, sinon tu auras du mal à progresser en AutoIt
3/ Il faut aller au plus simple. Le petit script ci-dessous (qui fait absolument TOUT ce que tu demandes) utilise la fonction _FileReadToArray (de la dernière version stable 3.3.12.0) qui retourne un tableau à 2 dimensions

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <File.au3>
#Include <Array.au3>

GUICreate("My GUI list") 
$btn = GUICtrlCreateButton("clic", 64, 32, 75, 25)
$mylist = GUICtrlCreateList("", 176, 32, 121, 97)
GUISetState(@SW_SHOW)

Local $lines
_FileReadToArray("ids.txt", $lines, 0, ":")
_ArrayDisplay($lines)

Local $nblines = UBound($lines), $list = ""
For $i = 0 to $nblines-1
      $list &= $lines[$i][0] & "|"
Next
GuiCtrlSetData($mylist, $list)

While 1
        $msg = GUIGetMsg()
        Switch $msg
            Case $btn
                $item = GUICtrlRead($mylist)
                For $i = 0 to $nblines-1
                   If $item = $lines[$i][0] Then Msgbox(0,"", $lines[$i][1] )
                Next
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
WEnd