[R] Interrogation sur un code du tuto Autoit

[Chrnos023]

Bonjour,

De nouveau dans l'aide générale.

J'étudie en ce moment le mode événementiel sur le site du zero.
Je me pose une question sur le code suivant:

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1) ; Activation du mode événementiel

; ########## Début de la création de la GUI 1 ##########
$GUI1 = GUICreate("GUI1", 250, 150, -1, -1) ; Création de la GUI1
GUISetOnEvent($GUI_EVENT_CLOSE, "FermeGUI") ; Attribution de la fonction FermeGUI pour l'événement $GUI_EVENT_CLOSE
$Lb1 = GUICtrlCreateLabel("Fenêtre 1", 85, 10, 120, 24) ; Création du label1
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif") ; Mise en gras du texte du contrôle précédent (Label1)
$Chb1 = GUICtrlCreateCheckbox("Checkbox1", 90, 60, 100, 20) ; Création d'une CheckBox
GUICtrlSetOnEvent($Chb1, "CheckBox1") ; Attribution de la fonction CheckBox1 pour un clic sur $Chb1
$Btn1 = GUICtrlCreateButton("Masque la GUI1 et Affiche la GUI2", 35, 110, 180, 25) ; Création d'un bouton simple
GUICtrlSetOnEvent($Btn1, "Bouton1") ; Attribution de la fonction Bouton1 pour un clic sur $Btn1
; ########## Fin de la création de la GUI 1 ##########

; ########## Début de la création de la GUI 2 ##########
$GUI2 = GUICreate("GUI2", 250, 150, -1, -1) ; Création de la GUI2
GUISetOnEvent($GUI_EVENT_CLOSE, "FermeGUI") ; Attribution de la fonction FermeGUI pour l'événement $GUI_EVENT_CLOSE
$Lbl2 = GUICtrlCreateLabel("Fenêtre 2", 85, 10, 120, 24) ; Création du label2
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif") ; Mise en gras du texte du contrôle précédent (Label2)
$Rd1 = GUICtrlCreateRadio("Radio1", 100, 60, 100, 20) ; Création d'un bouton radio
GUICtrlSetOnEvent($Rd1, "Radio1") ; Attribution de la fonction Radio1 pour un clic sur $Rd1
$Btn2 = GUICtrlCreateButton("Masque GUI 1 et Affiche GUI 2", 35, 110, 180, 25) ; Création d'un bouton simple
GUICtrlSetOnEvent($Btn2, "Bouton2") ; Attribution de la fonction Bouton2 pour un clic sur $Btn2
; ########## Fin de la création de la GUI 2 ##########

GUISetState(@SW_SHOW, $GUI1) ; On affiche la GUI1 (la GUI2 reste masquée)

While 1 ; Début de la boucle infinie
        Sleep(1000) ; Pause du script
WEnd ; Fin de la boucle infinie

Func FermeGUI() ; Début de la fonction
        If @GUI_WINHANDLE = $GUI1 Then ; Contrôle de la valeur de @GUI_WINHANDLE
                MsgBox(64, 'Info', 'Vous avez choisi de fermer la fenêtre 1 ayant pour handle : ' & @GUI_WINHANDLE) ; Message
        Else ; Sinon
                MsgBox(64, 'Info', 'Vous avez choisi de fermer la fenêtre 2 ayant pour handle : ' & @GUI_WINHANDLE) ; Message
        EndIf ; Fin de la condition If
        Exit ; Sortie du script
EndFunc ; Fin de la fonction

Func CheckBox1() ; Début de la fonction
        MsgBox(64, 'Info', 'Vous avez cliqué sur la CheckBox') ; Message
EndFunc ; Fin de la fonction

Func Bouton1() ; Début de la fonction
        GUISetState(@SW_HIDE, $GUI1) ; On masque la GUI 1
        GUISetState(@SW_SHOW, $GUI2) ; On affiche la GUI 2
EndFunc ; Fin de la fonction

Func Radio1() ; Début de la fonction
        MsgBox(64, 'Info', 'Vous avez cliqué sur la RadioBox') ; Message
EndFunc ; Fin de la fonction

Func Bouton2() ; Début de la fonction
        GUISetState(@SW_HIDE, $GUI2) ; On masque la GUI 2
        GUISetState(@SW_SHOW, $GUI1) ; On affiche la GUI 1
EndFunc ; Fin de la fonction

Pourquoi mettre une boucle avec juste un sleep à l'intérieur????
Voir ce bout de code:

► Afficher le texte

Code : Tout sélectionner

While 1 ; Début de la boucle infinie
        Sleep(1000) ; Pause du script
WEnd ; Fin de la boucle infinie

D'avance merci de votre aide.

[Ks10]

D'après ce que j'ai pu voir et constater cela réduit la consommation du CPU.
Mais inutile de mettre un Sleep(1000)
Un sleep(100) suffit.

Fait une expérimentation :

Crée un script avec une boucle sans un sleep et regarde ta consommation CPU.
Met un sleep et regarde à nouveau.

[jguinch]

Effectivement, même un Sleep(10) permet de réduire la consommation CPU.
Par contre, s'il n'y a rien d'autre dans la boucle, on peut même mettre une valeur plus importante, ce qui réduira encore plus la consommation : Sleep(0xFFFFFF) par ex.

[Chrnos023]

J'ai remarqué en mettant en commentaire la boucle infini que la fenêtre apparait et disparait.
Je pensais que la boucle infini qu'on utilise en programmation séquentielle était inutile en programmation événementielle.

[TommyDDR]

La boucle infinie est la boucle qui fait tourner votre programme, sans celle-ci on arrive au bout du fichier et donc le programme se quitte.

Nous avons donc besoin de cette boucle infinie, reste plus qu'à savoir ce qu'on met dedans, si on ne met rien, alors la condition du while ici -> "1" va être exécuté en boucle et très rapidement, vérifier un "1" (sans jeu de mot) n'est pas gourmand en soit, mais le faire en boucle sans attente reviendrait à pédaler sur un vélo sans chaîne (on donne tout ce qu'on à pour pas grand chose), c'est pour cela qu'on ajoute un sleep, pour diminuer le nombre de fois où l'on va regarder la condition du while.

PS : à vérifier mais je pense qu'il est préférable de mettre while(true) à while(1), en effet, l'intérieur d'un while est une condition et sera forcément transformer en booléen, en mettant true, je pense qu'on économise une transformation.

[Chrnos023]

Après test, oui la boucle sans pause fait monter le pc de mon bureau (pas très puissant) à 50% de son UC, une pause de 1 seconde le fait pas dépasser le 10% d'utilisation (pour un pc ou l'UC tourne a 3 4%).

Merci d'avoir éclaircit ce point. Je retourne à mes événements.

[mikell]

@Tommy

IsBool ( variable ) Checks if a variable's base type is boolean.
Return Value
Success: 1.
Failure: 0 if expression is not boolean type.

Pourquoi pas
Success: true
Failure: false
?

Edit
Cela dit une boucle comme ça marche aussi très bien

► Afficher le texte

Code : Tout sélectionner

Opt("GUIOnEventMode", 1) 

$GUI1 = GUICreate("GUI1", 250, 150, -1, -1)
GUISetOnEvent(-3, "FermeGUI")  ; $GUI_EVENT_CLOSE
$Btn1 = GUICtrlCreateButton("bouton", 35, 110, 180, 25) 
GUICtrlSetOnEvent($Btn1, "Bouton1")
GUISetState() 

While 184573.75 
     Sleep(10000000)
WEnd 

Func FermeGUI() 
         Exit 
EndFunc 

Func Bouton1() 
        Msgbox(0,"", "bouton")
EndFunc 
 

[jguinch]

@Tommy : sur le principe, je suis d'accord pour dire que While True devrait être plus rapide que While 1 puisqu'il n'y a pas besoin d'exécuter le code...

J'ai fait un petit test, j'ai été surpris de voir que c'est While 1 qui est plus rapide à chaque fois (même si j'inverse les 2 tests) :

► Afficher le texte

Code : Tout sélectionner

$hTimer = TimerInit()
$x = 0
While True
    $x += 1
    If $x = 10000000 Then ExitLoop
WEnd
$diff1 = TimerDiff($hTimer)
ConsoleWrite( "Avec True : " & $diff1 & @CRLF)


$hTimer = TimerInit()
$x = 0
While 1
    $x += 1
    If $x = 10000000 Then ExitLoop
WEnd
$diff2 = TimerDiff($hTimer)
ConsoleWrite( "Avec 1 : " & $diff2 & @CRLF)

ConsoleWrite( "While " & ( ( $diff1 < $diff2) ? "True" : 1 ) & " a gagné")
 

Vous pouvez tester de votre côté ?

[TommyDDR]

Je n'ai pas le bon PC pour tester ça (vive les entreprises qui fournissent des bêtes de courses à leurs employers...).

Les whiles varient de 600ms à 3400ms (et encore, j'ai du diviser par 10 le x max) donc pas représentatifs, je resterai chez moi ce soir.

[Chrnos023]

voici le résultat du pc du boulot:
Avec True : 13477.1723235628
Avec 1 : 12927.0091275803
While 1 a gagné+>15:40:50 AutoIt3.exe ended.rc:0

[TT22]

Avec True : 9813.02088826585
Avec 1 : 9594.33869525905
While 1 a gagné

[TommyDDR]

Avec True : 3656.09928527831
Avec 1 : 3517.62097063391
While 1 a gagné

En effet le while 1 gagne toujours.

(Par contre il va falloir songer à vous acheter des vrais PC les gars )

[jguinch]

Avec True : 7589.71065886528
Avec 1 : 7526.57334437988
While 1 a gagné

Donc au final, je crois qu'on peut conclure que While 1 est à préférer à While True, même si on ne sait pas trop pourquoi...
Ca nous a bien fait avancer le Schmilblick !

Edit : et Mikell, tu as toujours ton PC sous XP ? Ca donne quoi ?

[ZDS]

Avec True : 3156.02175045564
Avec 1 : 3034.71175977151
Avec $true : 3374.95722152416
While 1 a gagné

+1 avec les dires de TommyDDR ^^

(Je pense que True est interprété presque comme le sont les variables, peut-être est-ce à cause de ça vu que ça reste un mot clef et non une véritable valeur)

► Afficher le texte

Code : Tout sélectionner

Local $hTimer, $x, $diff1, $diff2, $diff3, $true = True

$hTimer = TimerInit()
$x = 0
While True
    $x += 1
    If $x = 10000000 Then ExitLoop
WEnd
$diff1 = TimerDiff($hTimer)
ConsoleWrite( "Avec True : " & $diff1 & @CRLF)

$hTimer = TimerInit()
$x = 0
While 1
    $x += 1
    If $x = 10000000 Then ExitLoop
WEnd
$diff2 = TimerDiff($hTimer)
ConsoleWrite( "Avec 1 : " & $diff2 & @CRLF)

$hTimer = TimerInit()
$x = 0
While $true
    $x += 1
    If $x = 10000000 Then ExitLoop
WEnd
$diff3 = TimerDiff($hTimer)
ConsoleWrite( "Avec $true : " & $diff3 & @CRLF)

ConsoleWrite( "While " & ( ($diff1 < $diff2 And $diff1 < $diff3) ? "True" : ($diff2 < $diff3 ? "1" : "$true") ) & " a gagné")

[mikell]

Avec True : 6084.80830375447
Avec 1 : 6035.86535150891
While 1 a gagné>Exit code: 0 Time: 12.397

Mon vieux PC sous XP gavé de machins n'est pas si lent ma foi
La différence tient peut-être (?) au temps qu'AutoIt va mettre à lire les 4 caractères de 'true' et à les traduire en booléen
Avec 25 : 6043.89742547215
Avec 1 : 6040.9263602908
While 1 a gagné>Exit code: 0 Time: 12.398

[jchd]

Parser le token, en déterminer la nature (constante, variable, mot-clé, fonction) puis la valeur et traiter cet argument à chaque tour de boucle. Il me semble évident que c'est un poil plus long pour True que pour 1.

[TommyDDR]

Voilà comment clore un sujet, merci jchd.

[Chrnos023]

Je test sur mon pc gamer.

[Chrnos023]

true: 4507.9740313695
1: 4419.15756135952