[R] Redimensionner GUI par programmation

[laloute]

Je vous explique mon soucis.

J'ai créé un GUI qui ressemble a ceci :


J'aimerais que au démarrage du script, elle soit de cette taille là :


Et pouvoir modifier sa taille grâce au checkbox, je clique elle reprend sa taille originale lors de la création.
J'ai fouillé sur ce forum et via google mais je n'ai eu le droit qu'a des redimensionnement de la gui et des composant avec l'action de la souris.

Merci d'avance.

[mikell]

à intégrer dans le script avec les valeurs voulues

Code : Tout sélectionner

While 1
; ....
    Case $checkbox
        If _IsChecked($checkbox) Then 
            WinMove($gui, "", Default, Default, $largeur1, $hauteur1)
        Else
            WinMove($gui, "", Default, Default, $largeur1, $hauteur2)
        EndIf
Wend

Func _IsChecked($control)
    Return BitAnd(GUICtrlRead($control), $GUI_CHECKED) = $GUI_CHECKED
EndFunc

[laloute]

Merci pour la réponse si rapide.

Mais cela ne va pas. Cette méthode modifie tous mes contrôles. Le TabItem passe en dessous la listview, la checkbox dessus.

Je pense à un méthode qui ne faisait que remonter la fenêtre en laissant les contrôles intact, Je sais qu'en c#, windev c'est possible.

Edit : Sinon j'ai pensé à la limite ne créer mon TabItem qu’après un WinMove pour agrandir la fenêtre et le supprimer à la réduction.

[TommyDDR]

regardez du coté de GUICtrlSetResizing

[mikell]

et/ou GUIResizeMode

[walkson]

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
Opt("GUIResizeMode", 1024)
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Form1", 182, 269, 198, 125,BitOR($GUI_SS_DEFAULT_GUI,$WS_SIZEBOX,$WS_THICKFRAME) )
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
Global $Button1 = GUICtrlCreateButton("--|>", 16, 144, 33, 33, $WS_GROUP)
GUICtrlSetTip(-1,"Je ne bouge pas")
GUICtrlSetOnEvent(-1, "Button1Click")
GUICtrlSetResizing(-1,  $GUI_DOCKALL)
Global $Button2 = GUICtrlCreateButton("Button2", 70, 144, 97, 33)
GUICtrlSetResizing($Button2, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)
Global $Button3 = GUICtrlCreateButton("Button3", 70, 180, 97, 33)
GUICtrlSetResizing($Button3, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
WinSetOnTop($Form1,"",0)
$i = 1
While 1
Sleep(100)
WEnd
Func Form1Close()
Exit
EndFunc
Func Button1Click()

    If $i = 1 Then
    WinMove($Form1,"",Default, Default, 542,269)
    $i = 2
    ElseIf $i = 2 Then
    WinMove($Form1,"",Default, Default, 182,269)
    $i = 1
    EndIf

EndFunc

[laloute]

Merci pour vos réponses. J avais commencé différemment mais la méthode de wali son est sympa. Je te test en rentrant.

Envoyé de mon GT-I9505 en utilisant Tapatalk

[mikell]

Remarque que watson ne fait qu'appliquer ce que TommyDDR a évoqué avant ^^

[walkson]

Tout à fait Mikell, J'avais un exemple sous la main, j'ai pensé qu'il serait utile.
Autrement, c'est pas la Saint WALKSON aujourd'hui

[laloute]

Oui mais un novice comme moi un exemple est bien plus parlant.
J'utilisais un boucle 'while 1' avec 'Switch $nMsg' mais je vais peut être utiliser le mode événementiel qui me parait apporter plus de souplesse.

Je rencontre un problème quand même. Ma fenêtre est rogner en bas et à droite lorsque je remet la taille originale. J'ai essayer avec le code de walkson et c est pareil.

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)
Opt("GUIResizeMode", 1024)

#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("Form1", 182, 260, -1, -1,BitOR($GUI_SS_DEFAULT_GUI,$WS_SIZEBOX,$WS_THICKFRAME) )
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
Global $Button1 = GUICtrlCreateButton("--|>", 16, 144, 33, 33, $WS_GROUP)
GUICtrlSetTip(-1,"Je ne bouge pas")
GUICtrlSetOnEvent(-1, "Button1Click")
GUICtrlSetResizing(-1,  $GUI_DOCKALL)
Global $Button2 = GUICtrlCreateButton("Button2", 70, 144, 97, 33)
GUICtrlSetResizing($Button2, $GUI_DOCKALL)
Global $Button3 = GUICtrlCreateButton("Button3", 70, 180, 97, 33)
GUICtrlSetResizing($Button3, $GUI_DOCKALL)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

WinSetOnTop($Form1,"",0)
$i = 1

While 1
    Sleep(100)
WEnd

Func Form1Close()
    Exit
EndFunc

Func Button1Click()

    If $i = 1 Then
         WinMove($Form1,"",Default, Default, 542,269)
         $i = 2
    ElseIf $i = 2 Then
         WinMove($Form1,"",Default, Default, 182,269)
         $i = 1
    EndIf

EndFunc

J'ai juste mis '$GUI_DOCKALL' pour les bouttons.

[walkson]

Bonsoir,
Vous pouvez redimensionné la GUI

Code : Tout sélectionner

    Func Button1Click()

        If $i = 1 Then
             WinMove($Form1,"",Default, Default, 542,269)
             $i = 2
        ElseIf $i = 2 Then
             WinMove($Form1,"",Default, Default, 195,269);modifiez les dimensions L H
             $i = 1
        EndIf

    EndFunc

Sauf erreur de ma part, WinMove redimensionne la fenêtre complète et donc les dimensions sont différentes de GUICreate(), les marges et l'entête de la fenêtre à rajouter (à confirmer...?)

[laloute]

Ah ok. Marche nikel comme ça.

Je cherche plus comment on supprime un contrôle par programmation.

Je créé un TabItem et je me sers de ce code pour le masquer quand je reviens sur la taille originale.

Code : Tout sélectionner

GUICtrlSetState($tab, $GUI_HIDE)

Est ce la meilleur méthode ?

[mikell]

Sauf erreur de ma part, WinMove redimensionne la fenêtre complète et donc les dimensions sont différentes de GUICreate()

Absolument mon cher wilson
C'est pour ça qu'il est plus prudent d'utiliser WinGetPos dans ce genre de circonstance

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)
Opt("GUIResizeMode", 1024)

Global $Form1 = GUICreate("Form1", 182, 260, -1, -1,BitOR($GUI_SS_DEFAULT_GUI,$WS_SIZEBOX,$WS_THICKFRAME) )
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
Global $Button1 = GUICtrlCreateButton("--|>", 16, 144, 33, 33, $WS_GROUP)
GUICtrlSetTip(-1,"Je ne bouge pas")
GUICtrlSetOnEvent(-1, "Button1Click")
GUICtrlSetResizing(-1,  $GUI_DOCKALL)
Global $Button2 = GUICtrlCreateButton("Button2", 70, 144, 97, 33)
GUICtrlSetResizing($Button2, $GUI_DOCKALL)
Global $Button3 = GUICtrlCreateButton("Button3", 70, 180, 97, 33)
GUICtrlSetResizing($Button3, $GUI_DOCKALL)
GUISetState(@SW_SHOW)

$pos = WinGetPos($Form1)
;Msgbox(0,"", $pos[2] & " x " & $pos[3])

WinSetOnTop($Form1,"",0)
$i = 1

While 1
    Sleep(100)
WEnd

Func Form1Close()
    Exit
EndFunc

Func Button1Click()

    If $i = 1 Then
         WinMove($Form1,"",Default, Default, 542,$pos[3])
         $i = 2
    ElseIf $i = 2 Then
         WinMove($Form1,"",Default, Default, $pos[2],$pos[3])
         $i = 1
    EndIf

EndFunc

[walkson]

Je crois que je vais finir en Walkiri
Sinon, je n'avais pas pensé à WinGetPos, Là c'est net, clair et précis
@ Laloute GUICtrlSetState($tab, $GUI_HIDE) masque le contrôle mais ne le décharge pas, l’inverse: $GUI_SHOW Pour supprimer un contrôle: GuiCtrlDelete()

[laloute]

Le soucis ou et non en fait, c'est que je vais avoir des checkbox, textbox avec des infos qui sont chargés au lancement de l'appli.
Si je supprime le contrôle je serais obliger de le recharger à chaque fois que je veux récupérer l’état d'un contrôle.

Merci mikell c est extrêmement clair maintenant.