[R] Listview à plusieurs colonnes : séparer les parties

[franco]

Bonjour.

C'est encore moi.

Je ne voulais pas écrire sur l'autre sujet, car ma question est différente

Je vous explique :
Je sais créer des listviews, à plusieurs colonnes.

En batch, dans un fichier texte, je liste toutes les mises à jour windows update installées sur mon PC.


Voici en gros ce que contient ce fichier :

Update KB2830477 Thomas-HP\Thomas 11/13/2013
Update KB2592687 AUTORITE NT\Système 10/25/2012
Update KB971033 Thomas-HP\Thomas 4/4/2012
Security Update KB2393802 AUTORITE NT\Système 2/10/2012
Security Update KB2425227 AUTORITE NT\Système 2/10/2012

Chaque ligne est écrit de la même façon, en 4 parties.

Comment faire pour les insérer dans la listview ?


Exemple d'un script que j'ai concocté pour un autre besoin, où j'ai créé une listview à plusieurs colonnes :

► Afficher le textecode

Code : Tout sélectionner

#include <file.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>


$RFIDir=@TempDir & "\RFI\"
DirRemove($RFIDir,1)
DirCreate($RFIDir)


Global $Form1 = GUICreate("Form1", 480, 115, 100, 100, -1, $WS_EX_ACCEPTFILES)

GUICtrlCreateLabel("Glissez / déposez le fichier afin d'y récupérer les informations", 10, 10, 370, 20)
GUICtrlSetFont(-1, 9, 400, 0, "comic sans ms")
$IoFile = GUICtrlCreateInput("", 10, 40, 460, 20)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)

$RecupBT = GUICtrlCreateButton("récupérer les infos", 10, 75, 140, 30)
_GUICTRLBUTTON_SETIMAGELIST(-1,_GETIMAGELISTHANDLE(@ScriptDir&"\Images\recuperer.ico",0,TRUE ))
$iErase = GUICtrlCreateButton("effacer la zone", 170, 75, 140, 30)
_GUICTRLBUTTON_SETIMAGELIST(-1,_GETIMAGELISTHANDLE(@ScriptDir&"\Images\effacer.ico",0,TRUE ))
$Exit = GUICtrlCreateButton("fermer le programme", 330, 75, 140, 30)
_GUICTRLBUTTON_SETIMAGELIST(-1,_GETIMAGELISTHANDLE(@ScriptDir&"\Images\quitter.ico",0,TRUE ))


;~ _GetInfo(@DesktopDir & "\64.exe")

GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Exit
            Exit
        Case $iErase
            GUICtrlSetData($IoFile, "")

        Case $RecupBT
            If GUICtrlRead($IoFile) = "" Then
                MsgBox(0, "Erreur !", "Attention, vous avez oublié d'indiquer le fichier à traiter." & @CRLF & @CRLF & "Appuyer sur OK pour réitérer l'opération.")
            Else
                If Not FileExists(GUICtrlRead($IoFile)) Then
                    MsgBox(0, "Erreur !", "Attention, le fichier que vous avez indiqué n'existe pas." & @CRLF & @CRLF & "Plusieurs causes possible :" & @CRLF & "1. Le chemin indiqué et erroné." & @CRLF & "2. Le fichier n'existe pas." & @CRLF & @CRLF & "Glissez et déposez le fichier, vous évitera ce genre de souci." & @CRLF & "Appuyez sur OK pour continier.")
                Else
                    _GetInfo(GUICtrlRead($IoFile))
                EndIf
            EndIf



    EndSwitch
WEnd


Func _GetInfo($IoFichier)
    Local $szDrive, $szDir, $szFName, $szExt
    _PathSplit($IoFichier, $szDrive, $szDir, $szFName, $szExt)

    $WorkingDir = $szDrive & $szDir
    $FileInDir = $szFName & $szExt


    Global $Form2 = GUICreate("Form1", 480, 280, 100, 260)

    GUICtrlCreateLabel("Informations concernant le fichier", 20, 10, 420, 20)
    GUICtrlSetFont(-1, 9, 400, 0, "comic sans ms")
    GUICtrlCreateLabel($FileInDir, 20, 30, 420, 20)
    GUICtrlSetFont(-1, 9, 600, 0, "comic sans ms")
    GUICtrlSetColor(-1,0x416590)


$InfosList = GUICtrlCreateListView("",10,70,250,200)
_GUICtrlListView_AddColumn($InfosList, "propriétés", 80)
_GUICtrlListView_AddColumn($InfosList, "", 80)
_GUICtrlListView_AddColumn($InfosList, "Résultat", 90)

;~  $RFI_Resultat = $RFIDir & "RFI_Resultat.txt"
;~  $RFI_Result = FileOpen($RFI_Resultat,2)


local $FGV_StringName[13]
$FGV_StringName[1] = "Comments"
$FGV_StringName[2] = "InternalName"
$FGV_StringName[3] = "ProductName"
$FGV_StringName[4] = "CompanyName"
$FGV_StringName[5] = "LegalCopyright"
$FGV_StringName[6] = "ProductVersion"
$FGV_StringName[7] = "FileDescription"
$FGV_StringName[8] = "LegalTrademarks"
$FGV_StringName[9] = "PrivateBuild"
$FGV_StringName[10] = "FileVersion"
$FGV_StringName[11] = "OriginalFilename"
$FGV_StringName[12] = "SpecialBuild"

local $FGV_StringName_FR[13]
$FGV_StringName_FR[1] = "Commentaires"
$FGV_StringName_FR[2] = "Nom interne"
$FGV_StringName_FR[3] = "Nom du produit"
$FGV_StringName_FR[4] = "Propriétaire"
$FGV_StringName_FR[5] = "LegalCopyright"
$FGV_StringName_FR[6] = "Version du produit"
$FGV_StringName_FR[7] = "Description du fichier"
$FGV_StringName_FR[8] = "LegalTrademarks"
$FGV_StringName_FR[9] = "PrivateBuild"
$FGV_StringName_FR[10] = "Version du fichier"
$FGV_StringName_FR[11] = "OriginalFilename"
$FGV_StringName_FR[12] = "SpecialBuild"

$RFI_Rapport = $RFIDir & "\"  & "RFI[" & $szFName & "].txt"
$RFI_Result = FileOpen($RFI_Rapport,2)

        FileWriteLine($RFI_Result,"­­­­­­­­­­­­­­-")
        FileWriteLine($RFI_Result," RecupFileInfo ")
        FileWriteLine($RFI_Result,"---------------"&@crlf&@crlf)
        FileWriteLine($RFI_Result,"Fichier traité : " & $FileInDir)
        FileWriteLine($RFI_Result,"chemin : " & $IoFichier&@crlf&@crlf)
        FileWriteLine($RFI_Result,"-------")
        FileWriteLine($RFI_Result,"-------"&@crlf&@crlf)

    For $i = 1 To 12
        FileWriteLine($RFI_Result,$FGV_StringName[$i] &  " (" & $FGV_StringName_FR[$i] & ") : " & FileGetVersion($iofichier,$FGV_StringName[$i]))
        GUICtrlCreateListViewItem($FGV_StringName[$i] & "|" & $FGV_StringName_FR[$i] & "|" & FileGetVersion($iofichier,$FGV_StringName[$i]),$InfosList)
    Next
FileClose($RFI_Result)
ShellExecute($RFI_Rapport)
;~ for $i=1 to 12
;~  FileWriteLine($RFI_Result,$FGV_StringName[$i] &  $separation[$i] & FileGetVersion($iofichier,$FGV_StringName[$i]))
;~ Next
;~ FileClose($RFI_Result)
;~ GUICtrlSetData($InfosEdit,FileRead($RFI_Resultat))
;~ MsgBox(0,"",$var)
;~ GUICtrlSetData($InfosEdit,$FGV_StringName[1] & "" & FileGetVersion($iofichier,$FGV_StringName[1]))

$copycontent = GUICtrlCreateButton("copier le contenu",300,70,140,30)
_GUICTRLBUTTON_SETIMAGELIST(-1,_GETIMAGELISTHANDLE(@ScriptDir&"\Images\copiercontenu.ico",0,TRUE ))
$createreport = GUICtrlCreateButton("créer un rapport",300,120,140,30)
_GUICTRLBUTTON_SETIMAGELIST(-1,_GETIMAGELISTHANDLE(@ScriptDir&"\Images\rapport.ico",0,TRUE ))
$ExitTool = GUICtrlCreateButton("fermer la fenêtre",300,240,140,30)
_GUICTRLBUTTON_SETIMAGELIST(-1,_GETIMAGELISTHANDLE(@ScriptDir&"\Images\retour12.ico",0,TRUE ))


    GUISetState(@SW_SHOW)


    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                GUIDelete($Form2)
                ExitLoop

        EndSwitch
    WEnd


;~  MsgBox(0, "", $IoFichier)



;~ $ZHPHEP_DIR = @ProgramFilesDir & "\ZebHelpProcess\"
;~ $ZHPHEP_EXE = @ProgramFilesDir & "\ZebHelpProcess\ZHPHep.exe"

;~ $FGV_StringName[1] = "Comments"
;~ $FGV_StringName[2] = "InternalName"
;~ $FGV_StringName[3] = "ProductName"
;~ $FGV_StringName[4] = "CompanyName"
;~ $FGV_StringName[5] = "LegalCopyright"
;~ $FGV_StringName[6] = "ProductVersion"
;~ $FGV_StringName[7] = "FileDescription"
;~ $FGV_StringName[8] = "LegalTrademarks"
;~ $FGV_StringName[9] = "PrivateBuild"
;~ $FGV_StringName[10] = "FileVersion"
;~ $FGV_StringName[11] = "OriginalFilename"
;~ $FGV_StringName[112] = "SpecialBuild"
EndFunc   ;==>_GetInfo

Func _GetImageListHandle($sFile, $nIconID = 0, $fLarge = False)
    Local $iSize = 16
    If $fLarge Then $iSize = 22

    Local $hImage = _GUIImageList_Create($iSize, $iSize, 5, 3)
    If StringUpper(StringMid($sFile, StringLen($sFile) - 2)) = "BMP" Then
        _GUIImageList_AddBitmap($hImage, $sFile)
    Else
        _GUIImageList_AddIcon($hImage, $sFile, $nIconID, $fLarge)
    EndIf
    Return $hImage
EndFunc   ;==>_GetImageListHandle


 

Il faut donc que j'arrive à mettre chaque partie dans une variable...

Mais là, je coince.


Pouvez-vous m'aider svp ?
Merci à vous



@+

[jguinch]

Comment sont formatées les lignes de ton fichier texte ? Tu dis qu'il y 4 parties, il y a bien un séparateur entre les différentes parties ?
Si tu n'as pas de séparateur autre qu'un espace, il va falloir revoir ton batch, ou tout simplement le remplacer par un script AutoIt (ce qui sera plus simple).

[mikell]

Le problème n'est pas tant d'écrire dans la listview que de parser correctement les lignes

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <ListviewConstants.au3>

GUICreate("listview items", 600, 250, 100, 200)
$listview = GUICtrlCreateListView("col1  |col2|col3 |col4 ", 10, 10, 580, 150)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 150)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 1, 80)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 2, 150)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 3, 80)
$file = FileRead("1.txt")
$lines = StringRegExp($file, '(?m)(^.*)\R?', 3)
For $i = 0 to UBound($lines)-1  ; lignes
    $line = StringReplace($lines[$i], "\", "\\")
    $line = StringRegExpReplace($lines[$i], '([^K]+)\s(KB\d+)\s(.+?)\s(\d{1,2}/\d{1,2}/\d+)', '$1|$2|$3|$4') 
    GUICtrlCreateListViewItem($line, $listview)
Next
GUISetState()

While 1
  Switch GUIGetMsg()
     Case $GUI_EVENT_CLOSE
         ExitLoop
  EndSwitch
WEnd
 

C'est clair qu'un séparateur autre qu'un espace simplifierait énormément le code
L'idéal serait un "|" comme ça le boulot est déjà fait et ya plus qu'à balancer la ligne dans la listview ^^

[franco]

Salut

@ jguinch
Non, il n'y a pas de séparateur (juste des espaces).
Pour le batch, j'avais trouvé cela : http://www.techsupportalert.com/content ... system.htm
Tiens, je viens des capter qu'on pouvait le faire en un fichier HTML.

Peut-être peut-on afficher l'appercu du html en autoit ? Je vais voir.

Et sur le fait de le faire en autoit, j'aurais aimé, mais je n'ai pas trouvé comment faire
Je vais voir si je ne trouve pas... Espérons que google m'aide ^^
Je vais même sur les sites US ^^

@mikell : Tout à fait
J'ai même tenter de prendre les espaces par | Je ne te dis pas ma surprise

Ah, il me vient une idée : peut-on remplacer les epsaces (le nombre varie ><) par | ?

Je vais regarder de plus près le code.


Merci à vous

@+

[franco]

Re

Le code de mikell fonctionne à merveille !!!

Décidément : merci à vous !

[jguinch]

En fait, si tu reprends le batch qui te génère la liste, tu verras qu'il utilise la commande wmic = requête WMI.
Les requêtes WMI sont utilisables avec AutoIt, il y a des tas d'exemples sur le(s) forum(s).

Je t'ai préparé un script qui fait l'équivalent du batch, mais je ne le poste pas pour l'instant, je pense que ça ne t'aidera pas à apprendre si c'est du tout cuit.

Documente-toi sur WMI et cherche des exemples simples (WMI Query)
Télécharge aussi AutoIt Scriptomatic, ça t'aidera à faire des test et ça te génèrera du code, et pourquoi pas un explorateur WMI (perso j'aime bien WMI Explorer, il est très simple et ne nécessite pas d'installation)

Pour info, la commande wmic qfe list brief utilisée dans le batch interroge la classe WMI Win32_QuickFixEngineering.

[franco]

Salut

« Télécharge aussi AutoIt Scriptomatic, ça t'aidera à faire des test et ça te génèrera du code, et pourquoi pas un explorateur WMI (perso j'aime bien WMI Explorer, il est très simple et ne nécessite pas d'installation) »

Je viens d'installer les 2.

Via WMI Explorer (et le WMI lié à la commande batch), j'ai pu généré un code qui m'affiche dans un msgbox les différents éléments...

Je n'ai plus qu'à "prendre" se qui m'intéresse, et les mettre dans une boucle FOR pour l'insérer dans une listview.


Merci chef ! J'ai de la lecture


Et tant mieux que tu ne donnes pas le script, je préfère trouver par moi-même.
Et avec ce que tu m'as donné, je peux ne pas trouver.



@++

[franco]

Bonjour.

J'ai utilisé scriptomatic.

En effet, c'est super ce script !

Voilà ce que j'ai obtenu :

► Afficher le textecode

Code : Tout sélectionner

; Generated by AutoIt Scriptomatic

$wbemFlagReturnImmediately = 0x10
$wbemFlagForwardOnly = 0x20
$colItems = ""
$strComputer = "localhost"

$Output=""
$Output = $Output & "Computer: " & $strComputer  & @CRLF
$Output = $Output & "==========================================" & @CRLF
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\")
$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_QuickFixEngineering", "WQL", _
                                          $wbemFlagReturnImmediately + $wbemFlagForwardOnly)

If IsObj($colItems) then
   For $objItem In $colItems
      $Output = $Output & "Caption: " & $objItem.Caption & @CRLF
      $Output = $Output & "CSName: " & $objItem.CSName & @CRLF
      $Output = $Output & "Description: " & $objItem.Description & @CRLF
      $Output = $Output & "FixComments: " & $objItem.FixComments & @CRLF
      $Output = $Output & "HotFixID: " & $objItem.HotFixID & @CRLF
      $Output = $Output & "InstallDate: " & WMIDateStringToDate($objItem.InstallDate) & @CRLF
      $Output = $Output & "InstalledBy: " & $objItem.InstalledBy & @CRLF
      $Output = $Output & "InstalledOn: " & $objItem.InstalledOn & @CRLF
      $Output = $Output & "Name: " & $objItem.Name & @CRLF
      $Output = $Output & "ServicePackInEffect: " & $objItem.ServicePackInEffect & @CRLF
      $Output = $Output & "Status: " & $objItem.Status & @CRLF
      if Msgbox(1,"WMI Output",$Output) = 2 then ExitLoop
      $Output=""
   Next
Else
   Msgbox(0,"WMI Output","No WMI Objects Found for class: " & "Win32_QuickFixEngineering" )
Endif


Func WMIDateStringToDate($dtmDate)

    Return (StringMid($dtmDate, 5, 2) & "/" & _
    StringMid($dtmDate, 7, 2) & "/" & StringLeft($dtmDate, 4) _
    & " " & StringMid($dtmDate, 9, 2) & ":" & StringMid($dtmDate, 11, 2) & ":" & StringMid($dtmDate,13, 2))
EndFunc

Voici ce que j'en ai fait :

► Afficher le textecode

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <ProgressConstants.au3>
#include <WindowsConstants.au3>

Global $colItems, $Form1, $Output

$myWU = GUICreate("Les mises à jour Windows", 430, 430, 100, 100)

Global $WULIST = GUICtrlCreateListView("Description|KB|Installé par|Date", 00, 00, 430, 430)
GUICtrlSendMsg($WULIST, $LVM_SETCOLUMNWIDTH, 0, 100)
GUICtrlSendMsg($WULIST, $LVM_SETCOLUMNWIDTH, 1, 85)
GUICtrlSendMsg($WULIST, $LVM_SETCOLUMNWIDTH, 2, 85)
GUICtrlSendMsg($WULIST, $LVM_SETCOLUMNWIDTH, 3, 170)

$Progress = GUICtrlCreateProgress(00, 390, 430, 20, $PBS_MARQUEE)
GUICtrlSendMsg($Progress, 0x0400 + 10, 1, Number(30)) ; on envoie la ProgressBar
GUISetState(@SW_SHOW)

$wbemFlagReturnImmediately = 0x10
$wbemFlagForwardOnly = 0x20
$strComputer = "localhost"
$Output = $Output & "Computer: " & $strComputer & @CRLF
$Output = $Output & "==========================================" & @CRLF
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\")
$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_QuickFixEngineering", "WQL", _
        $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
For $objItem In $colItems
    $Output = $objItem.Description & "|" & $objItem.HotFixID & "|" & $objItem.InstalledBy & "|" & $objItem.InstalledOn
    GUICtrlCreateListViewItem($Output, $WULIST)
Next

GUICtrlDelete($Progress)

GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd
 

Cela fonctionne ! Et bien plus rapide que le batch

merci 1000 fois !