[R] Input formaté : Capitale + minuscules

[aulus]

Bonjour,

Il existe une fonction pour mettre automatiquement l'entrée dans un input en majuscules et en minuscules. Je ne trouve pas de fonction plaçant automatiquement une Capitale en tête de nom propre, le reste de l'entrée étant en minuscules. J'ai créé ce petit code qui fait très bien son travail :

Code : Tout sélectionner

$_Long = Stringlen($_Entree)
$_Long = $_Long - 1
$_Entree = StringUpper(StringLeft($_Entree, 1)) & StringLower(StringRight($_Entree, $_Long))
 

Mais pour que ce formatage se fasse, je n'ai su qu'accompagner l'input d'un bouton envoyant une fonction contenant ce code. Est-ce possible de formater le texte au fur et à mesure de la frappe du texte entré dans l'input (première lettre en majuscule et suivantes en minuscules) ?

Je vous remercie de votre éclairage.

[mikell]

Voilà, faut recourir au bon vieux GUIRegisterMsg($WM_COMMAND, ...)

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <String.au3>

Opt("GUIOnEventMode", 1)

$hGUI = GUICreate("test", 500, 200)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
$hInput = GUICtrlCreateInput("", 10, 30, 280, 20)
GUISetState(@SW_SHOW, $hGUI)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")


While 1
   Sleep(10)
WEnd


Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $IdFrom = BitAnd($wParam, 0x0000FFFF)
    Local $iCode = BitShift($wParam, 16)
    Switch $IdFrom
    Case $hInput
        Switch $iCode
            Case $EN_UPDATE
               GuiCtrlSetData($IdFrom, _StringTitleCase(GuiCtrlRead($IdFrom)))   ;<<<<<<
         EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Func _Exit()
  Exit
EndFunc
 

Marrant, ça s'intégre très bien à un certain code que tu connais

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <ListBoxConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <String.au3>

Opt("GUIOnEventMode", 1)

Global $aPrenoms[8] = ["Alain", "André", "Albert", "Bernard", "Beatrice", "Antoine", "Charles", "Caroline"]
Global $aNoms[8] = ["Dupont", "David", "Martin", "Morin", "Dubois", "Lagrange", "Laborie", "Legrand"]


$hGUI = GUICreate("AutoComplete Input Text", 500, 200)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUICtrlCreateLabel('majuscule auto à la 1ère lettre de chaque mot ', 10, 10, 280, 20)
$hInput = GUICtrlCreateInput("", 10, 30, 280, 20)

GUICtrlCreateLabel('test avec les lettres "a, b, c" ', 10, 70, 280, 20)
$hInput2 = GUICtrlCreateInput("", 10, 90, 280, 20)
_Associate($hInput2, $aPrenoms)

GUICtrlCreateLabel('test avec les lettres "d, l, m" ', 10, 130, 280, 20)
$hInput3 = GUICtrlCreateInput("", 10, 150, 280, 20)
_Associate($hInput3, $aNoms)

$edit = GuiCtrlCreateEdit("", 310, 20, 180, 120)
$ok = GuiCtrlCreateButton("OK", 380, 150, 40, 25)
GUICtrlSetOnEvent(-1, "_ok")
GUISetState(@SW_SHOW, $hGUI)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")


While 1
   Sleep(10)
WEnd



Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
  ; #forceref $hWnd, $Msg, $lParam
    Local $IdFrom = BitAnd($wParam, 0x0000FFFF)
    Local $iCode = BitShift($wParam, 16)
    Switch $iCode
        Case $EN_UPDATE
             Switch $IdFrom
                 Case $hInput
                     GuiCtrlSetData($IdFrom, _StringTitleCase(GuiCtrlRead($IdFrom)))
                 Case $hInput2, $hInput3
                     GUISetAccelerators($AccelKeys)
                     $iCurrIndex = -1
                     $idCurInput = $IdFrom
                   _Update($idCurInput)
         EndSwitch
    EndSwitch
   Return $GUI_RUNDEFMSG
EndFunc


Func _ok()
  Local $txt
  If GuiCtrlRead($hInput)<>"" Then $txt &= GuiCtrlRead($hInput) &" "
  If GuiCtrlRead($hInput2)<>"" Then $txt &= GuiCtrlRead($hInput2) &" "
  If GuiCtrlRead($hInput3)<>"" Then $txt &= GuiCtrlRead($hInput3)
  GuiCtrlSetData($edit, $txt)
EndFunc


;============== fonctions internes ===================================

Func _Associate($_input, $_array)
   Local Static $ub = 0
   If $ub = 0 Then 
       Global $hListGUI = -1, $hList = -1, $idCurInput = "", $iCurrIndex = -1
       Global $assoc[1][2] = [["0", "0"]]
       _SetAccelerators()
   EndIf
   $ub += 1
   Redim $assoc[$ub+1][2]
   $assoc[$ub][0] = $_input
   $assoc[$ub][1] = $_array
   $assoc[0][0] = $ub
EndFunc 


Func _SetAccelerators()
   Global $hTAB, $hENTER, $AccelKeys
   $hTAB = GUICtrlCreateDummy()
   GUICtrlSetOnEvent(-1, "_Accelerators")
   $hENTER = GUICtrlCreateDummy()
   GUICtrlSetOnEvent(-1, "_Accelerators")
   Dim $AccelKeys[2][2] = [["{TAB}", $hTAB], ["{ENTER}", $hENTER]]
EndFunc 


Func _Accelerators()
  Switch @GUI_CtrlId
     Case $hTAB
         If $hListGUI <> -1 Then   
             Local $count = GUICtrlSendMsg($hList, $LB_GETCOUNT, 0, 0)
             If $count = 1 Then 
                 GUICtrlSendMsg($hList, $LB_SETCURSEL, 0, 0)
                 _SetInput()
             Else
                 $iCurrIndex =  ($iCurrIndex > $count-2) ? 0 : ($iCurrIndex+1)
                 GUICtrlSendMsg($hList, $LB_SETCURSEL, $iCurrIndex, 0)
             EndIf
         Else
             GUISetAccelerators("", $hGUI)
         EndIf
     Case $hENTER
         If $hListGUI <> -1 Then 
             If $iCurrIndex = -1 Then GUICtrlSendMsg($hList, $LB_SETCURSEL, 0, 0)
             _SetInput()
         EndIf
  EndSwitch
EndFunc


Func _Update($_input)
    Local Static $sCurrInput = ""
    If GUICtrlRead($_Input) <> $sCurrInput Then
        $sCurrInput = GUICtrlRead($_Input)
        If $hListGUI <> -1 Then ; List is visible.
             GUIDelete($hListGUI)
             $hListGUI = -1
        EndIf

        Local $_array
        For $i = 1 to $assoc[0][0]
             If $assoc[$i][0] = $_input Then $_array = $assoc[$i][1]
        Next
        $hList = _PopupSelector($hGUI, $hListGUI, $_Input, _CheckInputText($_Input, $_array))
        If $hList <> -1 Then GUICtrlSetOnEvent($hList, "_SetInput")
    EndIf

    Local $sChosen
    If $hList <> -1 Then 
       $sChosen = GUICtrlRead($hList)
       If $sChosen <> "" Then
          GuiCtrlSetData($_Input, $sChosen)
          $sCurrInput = GUICtrlRead($_Input)
          GUIDelete($hListGUI)
          $hListGUI = -1
       EndIf
   EndIf
EndFunc  ;==>_Update


Func _SetInput()
    GuiCtrlSetData($idCurInput, GUICtrlRead($hList))
    GUIDelete($hListGUI)
    $hListGUI = -1
    GUISetAccelerators("", $hGUI)
EndFunc


Func _PopupSelector($hMainGUI, ByRef $hListGUI, $_Input, $sCurr_List)
    Local $hList = -1
    If $sCurr_List = "" Then Return $hList

    Local $pos = ControlGetPos($hMainGUI, "", $_Input)
    $hListGUI = GUICreate("", 280, 160, $pos[0], $pos[1]+$pos[3], $WS_POPUP, _
        BitOR($WS_EX_TOOLWINDOW, $WS_EX_TOPMOST, $WS_EX_MDICHILD), $hMainGUI)
    $hList = GUICtrlCreateList("", 0, 0, 280, 150, BitOR($LBS_STANDARD, $WS_HSCROLL))
    GUICtrlSetData($hList, $sCurr_List)

    Local $count = GUICtrlSendMsg($hList, $LB_GETCOUNT, 0, 0)
    Local $iCurrHeight = $count * GUICtrlSendMsg($hList, $LB_GETITEMHEIGHT, 0, 0) + 10
    WinMove($hListGUI, "", Default, Default, Default, $iCurrHeight)
    GUICtrlSetPos($hList, 0, 0, 150, $iCurrHeight)

    GUISetControlsVisible($hListGUI) ; To Make Control Visible And Window Invisible.
    GUISetState(@SW_SHOWNOACTIVATE, $hListGUI)
    Return $hList
EndFunc   ;==>_PopupSelector


Func _CheckInputText($_Input, $array)
   Local $sPartialData = ""
   Local $aSelected = _GetSelectionPointers($_Input)
    If (IsArray($aSelected)) And ($aSelected[0] <= $aSelected[1]) Then
        Local $s_CurrInput = GUICtrlRead($_Input)
        Local $aSplit = StringSplit(StringLeft($s_CurrInput, $aSelected[0]), " ")
        $aSelected[0] -= StringLen($aSplit[$aSplit[0]])
        If $aSplit[$aSplit[0]] <> "" Then
            For $A = 0 To UBound($array)-1
                If StringLeft($array[$A], StringLen($aSplit[$aSplit[0]])) = $aSplit[$aSplit[0]] _
                And $array[$A] <> $aSplit[$aSplit[0]] Then
                    $sPartialData &= $array[$A] & "|"
                EndIf
            Next
        EndIf
    EndIf
    Return $sPartialData
EndFunc   ;==>_CheckInputText


Func _GetSelectionPointers($hEdit)
    Local $aReturn[2] = [0, 0]
    Local $aSelected = GUICtrlRecvMsg($hEdit, 0x00B0) ; $EM_GETSEL.
    If IsArray($aSelected) Then
        $aReturn[0] = $aSelected[0]
        $aReturn[1] = $aSelected[1]
    EndIf
    Return $aReturn
EndFunc   ;==>_GetSelectionPointers


Func GUISetControlsVisible($hWnd) ; By Melba23.
    Local $aControlGetPos = 0, $hCreateRect = 0, $hRectRgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
    Local $iLastControlID = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle(-1))
    For $i = 3 To $iLastControlID
        $aControlGetPos = ControlGetPos($hWnd, '', $i)
        If IsArray($aControlGetPos) = 0 Then ContinueLoop
        $hCreateRect = _WinAPI_CreateRectRgn($aControlGetPos[0], $aControlGetPos[1], _
            $aControlGetPos[0] + $aControlGetPos[2], $aControlGetPos[1] + $aControlGetPos[3])
        _WinAPI_CombineRgn($hRectRgn, $hCreateRect, $hRectRgn, 2)
        _WinAPI_DeleteObject($hCreateRect)
    Next
    _WinAPI_SetWindowRgn($hWnd, $hRectRgn, True)
    _WinAPI_DeleteObject($hRectRgn)
EndFunc   ;==>GUISetControlsVisible


Func _Exit()
  Exit
EndFunc
 

[jguinch]

@mikell : pourquoi est-ce que tu utilises $EN_UPDATE plutôt que $EN_CHANGE ? C'est juste pour comprendre, parce que je ne sais jamais lequel choisir (je prends toujours $EN_CHANGE, du coup)

[mikell]

En théorie ça permet de prendre des décisions avant l'affichage du contenu de l'input à l'écran (bien que je t'avoue ne pas trouver en pratique la différence flagrante)
Voilà les considérations MSDNesques

EN_UPDATE notification code
Sent when an edit control is about to redraw itself. This notification code is sent after the control has formatted the text, but before it displays the text. This makes it possible to resize the edit control window, if necessary.

EN_CHANGE notification code
Sent when the user has taken an action that may have altered text in an edit control. Unlike the EN_UPDATE notification code, this notification code is sent after the system updates the screen.

[aulus]

Merci Mikell pour ce code qui me simplifie bien le travail.

Quant à l'inclusion dans le code que vous rappelez, je suis parvenu à la réussir par tâtonnements... Je ne suis pas peu fier de voir que ce que j'ai fait ressemble à votre code. Je me demande si, avec le temps, je n'ai pas progressé un peu !

A force de modifier mon programme pour l'améliorer jour après jour, je me retrouve avec des variables Global pour lesquelles je me pose la question de savoir si elles sont toujours utiles. Existe-t-il un moyen de le vérifier qui me permettrait d'éviter les fastidieuses recherches avec l'outil ad-hoc ?

Encore (et toujours) merci !

[mikell]

Quand on a des codes très longs et qu'on a modifiés plusieurs fois, se pose souvent le problème des variables orphelines
Dans ce cas le temps passé à se bricoler un petit outil sera généralement infiniment moindre que le temps passé à se taper les recherches fastidieuses

► Afficher le texte

Code : Tout sélectionner

$_word = "$log"                 ; mot/variable à rechercher
$_file = @ScriptFullPath        ; adresse du fichier où chercher
$_keyword = ""  ;"&="           ; mot-clé pouvant (ou pas) figurer sur la même ligne que $_word

$result = _Search($_file, $_word, $_keyword)
Msgbox(0,"résultats pour  " & $_word, $result)

;================================================
Func _Search($_file, $word, $keyword = "")
   Local $log, $file, $lines
   $file = FileRead($_file)
   $lines = StringRegExp($file, '(?m)(^.*)\R?', 3)
   For $j = 0 to UBound($lines)-1  ; lignes
       If StringInStr($lines[$j], $word) AND _ 
        ($keyword="" OR ($keyword<>"" and StringInStr($lines[$j], $keyword)) ) Then
             $log &= "ligne " & $j+1 & " :   " & StringStripWS($lines[$j], 3) & @crlf
       EndIf
   Next
   $log &= @crlf 
   Return $log
EndFunc
 

NB : pour les majuscules il peut y avoir des exigences particulières, ex. le code suivant si on tape le nom "Jean d'Arbois d'Auteuil"

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Opt("GUIOnEventMode", 1)

$hGUI = GUICreate("test", 500, 200)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
$hInput = GUICtrlCreateInput("", 10, 30, 280, 20)
GUISetState(@SW_SHOW, $hGUI)

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")


While 1
   Sleep(10)
WEnd


Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $IdFrom = BitAnd($wParam, 0x0000FFFF)
    Local $iCode = BitShift($wParam, 16)
    Switch $IdFrom
    Case $hInput
        Switch $iCode
            Case $EN_UPDATE
               GuiCtrlSetData($IdFrom, _StringTitleCase2(GuiCtrlRead($IdFrom)))  
         EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc


Func _StringTitleCase2($sString)
    Local $fCapNext = True, $sChr = "", $sReturn = ""
    For $i = 1 To StringLen($sString)
        $sChr = StringMid($sString, $i, 1)
        Select
            Case $sChr = "'"
                $let = StringMid($sReturn, StringLen($sReturn)-1)
                $sReturn = StringReplace($sReturn, $let, StringLower($let), -1) 
                $fCapNext = True
            Case $fCapNext = True
            ;   If StringRegExp($sChr, "[a-zA-Z\xC0-\xFF0-9]") Then
                If StringRegExp($sChr, "[a-zA-Z]") Then
                    $sChr = StringUpper($sChr)
                    $fCapNext = False
                EndIf
            Case not StringRegExp($sChr, "[a-zA-Z\xC0-\xFF0-9]")
                $fCapNext = True
            Case Else
                $sChr = StringLower($sChr)
        EndSelect
        $sReturn &= $sChr
    Next
    Return $sReturn
EndFunc   ;==>_StringTitleCase

Func _Exit()
  Exit
EndFunc
 

[aulus]

Le premier code va m'être bien utile. Je vais mettre toutes mes variables globales dans un tableau, et par une boucle je vais attendre patiemment que le programme m'affiche les résultats.

Quant au deuxième code, les expressions régulières m'épateront toujours, tout comme ceux qui les maîtrisent !

Merci Mikell.

[jguinch]

Pour les variables, on peut faire autrement, en ajoutant #AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 en entête de fichier et en utilisant SyntaxCheck Prod.

[mikell]

Heu c'est une détection d'erreurs à la compilation ça non ?
De toute façon une variable déclarée mais inutilisée ce n'est pas une erreur au sens SyntaxCheckProd du terme ?

[jguinch]

Détection d'erreurs oui, mais pas que ça...
Ca vérifie que les variables sont bien déclarées avant utilisation, et aussi que les variables déclarées sont bien utilisées (variables locales uniquement).
Ca vient de la page User Defined Functions Standards (Ricky m'avait conseillé ça pour un des mes UDF)
Par contre, pas trouvé pour les variables globales...