[R] Erreur avec "Illegal char in "

[Bling]

Salut les gens =D je suis nouveau ici et + généralement en autoit. J'apprends avec le site du zéros et j'ai un petit soucis pour lancer un script présent dans un des tutos..

► Afficher le texte

Code : Tout sélectionner

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1) ; Activation du mode événementiel

; ########## Début de la création de la GUI 1 ##########
$GUI1 = GUICreate("GUI1", 250, 150, -1, -1) ; Création de la GUI1
GUISetOnEvent($GUI_EVENT_CLOSE, "FermeGUI") ; Attribution de la fonction FermeGUI pour l'événement $GUI_EVENT_CLOSE
$Lb1 = GUICtrlCreateLabel("Fenêtre 1", 85, 10, 120, 24) ; Création du label1
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif") ; Mise en gras du texte du contrôle précédent (Label1)
$Chb1 = GUICtrlCreateCheckbox("Checkbox1", 90, 60, 100, 20) ; Création d'une CheckBox
GUICtrlSetOnEvent($Chb1, "CheckBox1") ; Attribution de la fonction CheckBox1 pour un clic sur $Chb1
$Btn1 = GUICtrlCreateButton("Masque la GUI1 et Affiche la GUI2", 35, 110, 180, 25) ; Création d'un bouton simple
GUICtrlSetOnEvent($Btn1, "Bouton1") ; Attribution de la fonction Bouton1 pour un clic sur $Btn1
; ########## Fin de la création de la GUI 1 ##########

; ########## Début de la création de la GUI 2 ##########
$GUI2 = GUICreate("GUI2", 250, 150, -1, -1) ; Création de la GUI2
GUISetOnEvent($GUI_EVENT_CLOSE, "FermeGUI") ; Attribution de la fonction FermeGUI pour l'événement $GUI_EVENT_CLOSE
$Lbl2 = GUICtrlCreateLabel("Fenêtre 2", 85, 10, 120, 24) ; Création du label2
GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif") ; Mise en gras du texte du contrôle précédent (Label2)
$Rd1 = GUICtrlCreateRadio("Radio1", 100, 60, 100, 20) ; Création d'un bouton radio
GUICtrlSetOnEvent($Rd1, "Radio1") ; Attribution de la fonction Radio1 pour un clic sur $Rd1
$Btn2 = GUICtrlCreateButton("Masque GUI 1 et Affiche GUI 2", 35, 110, 180, 25) ; Création d'un bouton simple
GUICtrlSetOnEvent($Btn2, "Bouton2") ; Attribution de la fonction Bouton2 pour un clic sur $Btn2
; ########## Fin de la création de la GUI 2 ##########

GUISetState(@SW_SHOW, $GUI1) ; On affiche la GUI1 (la GUI2 reste masquée)

While 1 ; Début de la boucle infinie
        Sleep(1000) ; Pause du script
WEnd ; Fin de la boucle infinie

Func FermeGUI() ; Début de la fonction
        If @GUI_WINHANDLE = $GUI1 Then ; Contrôle de la valeur de @GUI_WINHANDLE
                MsgBox(64, 'Info', 'Vous avez choisi de fermer la fenêtre 1 ayant pour handle : ' & @GUI_WINHANDLE) ; Message
        Else ; Sinon
                MsgBox(64, 'Info', 'Vous avez choisi de fermer la fenêtre 2 ayant pour handle : ' & @GUI_WINHANDLE) ; Message
        EndIf ; Fin de la condition If
        Exit ; Sortie du script
EndFunc ; Fin de la fonction

Func CheckBox1() ; Début de la fonction
        MsgBox(64, 'Info', 'Vous avez cliqué sur la CheckBox') ; Message
EndFunc ; Fin de la fonction

Func Bouton1() ; Début de la fonction
        GUISetState(@SW_HIDE, $GUI1) ; On masque la GUI 1
        GUISetState(@SW_SHOW, $GUI2) ; On affiche la GUI 2
EndFunc ; Fin de la fonction

Func Radio1() ; Début de la fonction
        MsgBox(64, 'Info', 'Vous avez cliqué sur la RadioBox') ; Message
EndFunc ; Fin de la fonction

Func Bouton2() ; Début de la fonction
        GUISetState(@SW_HIDE, $GUI2) ; On masque la GUI 2
        GUISetState(@SW_SHOW, $GUI1) ; On affiche la GUI 1
EndFunc ; Fin de la fonction

Je me prends 3 illegal character in include directive et 1 syntax error sur la ligne du dessous. Ce que je pige pas c'est que si je fais un nouveau fichier avec les include et une msgbox ça roule mais pas là.. Enfin ça vient peut être uniquement de la ligne du dessous?

Merci

[sylvanie]

Bonjour,
En tout cas en faisant un copier/coller du code présenter, ça fonctionne.
Donc idée d'investigation:

-Le fichier d'où est extrait ce code contient un caractère caché dû à un copier/coller => créé un nouveu fichier est copier/coller le code mis sur le forum (car dépourvu de caractères de ce type)

- Un des includes pose problème, mais le tes du msgbox est insuffisant car il ne stimule pas toutes les fonctions comme le fait le script => tenter une réinstall d'Autoit ...

Bonne investigation.

[TommyDDR]

Lorsque vous avez l'erreur, normalement vous avez 2 choix : "Stop" "Continue", essayez continue, j'ai aussi eu des problèmes lors du check de syntaxe que je n'ai pu résoudre QUE en copiant collant le code dans un nouveau script et en supprimant l'ancien...

[Bling]

Je ne comprends vraiment pas. Si j'éfface les lignes qui posent problème et que je les réecris ça passe mais l'erreur se met en dessous et ainsi de suite... Je pense que si j'écrivais tout le script manuellement ça compilerait, mais si je dois faire ça chaque fois ça va être dur... C'est pas le premier script avec lequel je rencontre ce problème. Ca peut me le faire sur des scripts beaucoup + court et simple aussi, dans ce cas je recopie tout et ça passe...
Et je n'ai pas d'option pour continuer, tout ce que j'ai c'est f4 pour jump à la prochaine erreur :/
Edit: j'ai supprimé tout les fichiers et j'en ai recrée un à partir du code collé sur le forum et ça marche comme ça... Si quelqu'un a une explication ça m'intéresse

[sylvanie]

Si vous avez encore un fichier posant problème, essayez de le joindre en PJ de ce poste, histoire de voire si il n'y a pas un caractère hexa qui traîne ...

[EDIT]
si ça peut aider, voici un script qui élimine les caractères qui ne sont pas compris entre [0x20 - 0x7F] en gardant également les retours chariots et tab :

► Afficher le texte

Code : Tout sélectionner

;script d'épuration de caractère non compris entre 0x20 à 0x7F sauf \r \n \t
$Nb_arg=$CmdLine[0]

If $Nb_arg <> 1 Then Exit MsgBox(16,"Erreur","Usage : "&@ScriptName&" Nom_de_fichier")

$fichier_a_traiter=$CmdLine[1]
If Not FileExists($fichier_a_traiter) Then Exit MsgBox(16,"Erreur",$fichier_a_traiter&" n'existe pas")
If Not FileCopy($fichier_a_traiter,$fichier_a_traiter&".old",1) Then Exit MsgBox(16,"Erreur","Impossible de faire un backup de "&$fichier_a_traiter&" Abandon !")
$contenu=FileRead($fichier_a_traiter)
$contenu=StringRegExpReplace($contenu,"[\x00-\x08\x0c\x0E-\x1F\x80-\xFF]","")
$hndout=FileOpen($fichier_a_traiter,2)
If $hndout = -1 Then Exit MsgBox(16,"Erreur","Impossible d'ouvrir "&$fichier_a_traiter&" en écriture")
FileWrite($hndout,$contenu)
FileClose($hndout)
Exit 0

 

ça permet de nettoyer. A personnaliser au cas à cas (par exple il efface "€" ), donc faut ajouter des exceptions

[blacksoul305]

Bien le bonsoir,

j'ajoute ma petite touche. Alors, le problème est que, moi aussi ça me l'avait fait et quand je copiais le code de par le site du zero, j'avais aussi des caractères invisibles qui se plaçaient. Donc une solution, recopier le code ! De toute façon on apprend mieux comme ça !

[sylvanie]

Banco !
En éditant votre fichier défectueux avec un éditeur hexa, on voit par exemple dès la première ligne que les espaces (0x20 normalement) n'en sont pas, ceux sont des 0xA0 (espaces insécables utilisés en html)
[EDIT]

du coups, inspirez vous du script que j'ai fourni, mais changer la regexp par simplement

StringRegExpReplace($contenu,"\xa0"," ")

ça devrait suffir

[Bling]

Merci pour les explications (:

[timmalos]

Ce n'est pas la première personne à qui cela arrive j'ai eu plusieurs fois la demande sur le sdz, et les espaces en sont bien la cause on avait verifié la dernière fois. Mais ca ne le fait pas pour tout le monde, et impossible de deviner la cause, même si je pencherais pour le navigateur.

[sylvanie]

si vous pensez que ce sujet est "résolu", merci de penser à le passer en [R] sur le premier message.