[R] Envoi de fax avec autoit ?

[Utilisateur 3309 supprimé]

Bonjour,
je souhaiterais envoyer des documents (PDF) par fax avec autoit. est-ce qu'autoit sait piloter le service d'envoi de FAX de windows ?
J'ai vu que certains y arrivent avec excel en VBA, mais j'ai rien trouvé avec autoit

Merci de votre aide !

[timmalos]

Si t'as un code en VBA on pourra te le traduire , rien trouvé d’intéressant sur le forum anglais.

[jguinch]

Salut
Petite question bête : disposes-tu d'un modem ou d'un serveur de fax ?

[Utilisateur 3309 supprimé]

Alors on a un serveur avec microsoft shared fax (le service de fax de microsoft, l'imprimante virtuelle FAX) c'est ce qu'on utilise pour envoyer des fax depuis les pc.
Mais j'ai acces au serveur sur lequel se trouve le modem, c'est un classique 56K. et le script pourrait tourner dessus mais vraiment en dernier recours...

Et pour envoyer des fax en VBA j'avais trouvé ca :
http://www.devhut.net/2010/09/03/vba-sending-faxes-vba/

et ca:
http://www.excelforum.com/excel-program ... m-vba.html

Code : Tout sélectionner

Here is my function:

Public Sub FaxeFeuille(FeuilleAFaxer As String, destinataire As String,
numero As String)
Dim keys As String
Worksheets(FeuilleAFaxer).Select
keys = "^p%nfax~~~" & destinataire & "{TAB}{TAB}" & numero
SendKeys keys
End Sub

You must have a fax printer called 'Fax'.
Works on Excel 2K / Windows Xp german.

 

et puis ca :
http://groupes.codes-sources.com/articl ... 84245.aspx

[jguinch]

Est-ce que tu peux essayer avec le code VBS suivant ?
Il faudra créer le fchier test.rtf, l'adapter à ton environnement (numéro de fax, mail....) puis exécuter le script VBS :

► Afficher le texte

On Error Resume Next
Set FaxServer = WScript.CreateObject("FAXCOMEX.FaxServer")
CheckError("WScript.CreateObject(FAXCOMEX.FaxServer)")
WScript.Echo "FaxServer created"
' Connect to the fax server. Specify computer name if the server is remote. See How to connect to a remote Fax Service for details.
FaxServer.Connect ""
CheckError("FaxServer.Connect")

Set FaxDoc = WScript.CreateObject("FAXCOMEX.FaxDocument")
CheckError("WScript.CreateObject(FAXCOMEX.FaxDocument)")

' Set file name of any printable document.
FaxDoc.Body = "test.rtf"
CheckError("FaxDoc.Body")
FaxDoc.DocumentName = "My First Fax"
' Add recipient's fax number. If this string contains a canonical fax number
' (starting with plus + followed by a country code, an area code in round brackets
' surrounded by spaces and a fax number), the Fax Service will translate
' that number into dialable format in accordance with your current location.
' Otherwise, make sure the international prefix or long distance prefix is specified when needed,
' as the fax number will be passed on to a fax driver (Fax Service Provider) unchanged.
' For example, sending a fax from San Francisco to Sydney's fax number 123456, the canonical address
' +61 (2) 123456 will be translated into dialable address 011612123456.
' If you are using T37FSP in conjunction with Internet Fax Service, specify absolute address
' 612123456 (without leading plus, to avoid translation into dialable format),
' as most Internet Fax Services expect the number in the absolute format.
' To take advantage of Windows Fax Service outbound routing available on Windows Server
' fax address must be specified in canonical format.

FaxDoc.Recipients.Add ("612123456")

' Optionally, set the sender properties.
' T37FSP uses only FaxDoc.Sender.Email in Windows Server 2003 for delivery status notifications.
' In Windows Server 2008, T37FSP derives email address from FaxDoc.Sender.Name via facsBridge.xml file.

FaxDoc.Sender.Email = "bob@xyz.com"
FaxDoc.Sender.Name = "Bob"
FaxDoc.Sender.FaxNumber = "7777777"

' Optionally, Use FaxDoc.CoverPage and FaxDoc.CoverPageType to specify a cover page
' FaxDoc.CoverPage = generic
' FaxDoc.CoverPageType = 2

' Optionally, you can control banner in outbound faxes
FaxServer.Folders.OutgoingQueue.Branding = True ' True to set banner on, False to set banner off
FaxServer.Folders.OutgoingQueue.Save ' Make the change persistent
' Optionally, use FaxServer.Folders.OutgoingQueue.Retries and
' FaxServer.Folders.OutgoingQueue.RetryDelay to control retries

' Submit the document to the connected fax server and get back the job ID.
JobID = FaxDoc.ConnectedSubmit(FaxServer)
CheckError("FaxDoc.ConnectedSubmit")
WScript.Echo "FaxDoc.ConnectedSubmit success"


Sub CheckError(strDetails)
Dim strErr
If Err.Number <> 0 then
strErr = strDetails & " : Exception " & Err.Description & " err.Number=0x" & Hex(Err.Number)
WScript.Echo strErr
WScript.Quit(Err.Number)
End If
End Sub

Si ça fonctionne, on verra pour le convertir vers AutoIt....

[Utilisateur 3309 supprimé]

OK merci je vois ca demain matin

[Utilisateur 3309 supprimé]

Génial ! ca marche en VBS...tu penses pouvoir nous faire une version Autoit ?

[jguinch]

Bon, alors j'ai bricolé un truc... Par contre, je n'ai moyen de tester, donc à toi de dire si ça marche...

► Afficher le texte

Code : Tout sélectionner

Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")

$FaxServer = ObjCreate("FAXCOMEX.FaxServer")
$FaxDoc = ObjCreate("FAXCOMEX.FaxDocument")

If $FaxServer == 0 OR $FaxDoc == 0 Then _ErrFunc()

$FaxServer.Connect("")

$FaxDoc.Body = "Document.rtf"
$FaxDoc.DocumentName = "Mon fax"
$FaxDoc.Recipients.Add ("0123456789")
$FaxDoc.Sender.Email = "bob@xyz.com"
$FaxDoc.Sender.Name = "bob"
$FaxDoc.Sender.FaxNumber = "7777777"

$FaxServer.Folders.OutgoingQueue.Branding = True 
$FaxServer.Folders.OutgoingQueue.Save

$JobID = $FaxDoc.ConnectedSubmit($FaxServer)



Func _ErrFunc($oError)
    MsgBox(16, "Error", "Impossible de charger le service de Fax" )
    Exit
EndFunc   ;==>_ErrFunc
 

[blacksoul305]

Code : Tout sélectionner

If $FaxServer [color=#FF0000]==[/color] 0 OR $FaxDoc [color=#FF0000]==[/color] 0 Then _ErrFunc()

N'est-ce pas une mauvaise habitude avec les langages de plus bas niveau où == est le test de l'égalité et = l'assignation d'une valeur ?

[Utilisateur 3309 supprimé]

Aie , j'ai un message d'erreur qui me dit "Impossible de charger le service de FAX".
J'ai retesté le VBS au cas ou et lui il fonctionne bien...

[blacksoul305]

Et si tu modifies la ligne que j'ai citée dans mon message précédent en remplaçant les "==" par "=", tu as l'erreur ou pas ?

[Utilisateur 3309 supprimé]

c'est pareil, j'avais essayé dès que j'ai vu le message...

[jguinch]

Désolé, j'avais généré une erreur pour tester la fonction _ErrFunc

Il faut modifier le code (j'ai mis à jour mon post précédent) :

Code : Tout sélectionner

$FaxDoc = ObjCreate("FAXCOMEX.FaxDocument")

Ca prouve que tu n'as pas cherché à comprendre...


@blacksoul305 : oui, je fais aussi du PHP, c'est une habitude d'utiliser le ==
(je trouve que c'est plus propre, mais c'est peut être une mauvaise habitude... )

[blacksoul305]

@blacksoul305 : oui, je fais aussi du PHP, c'est une habitude d'utiliser le ==
(je trouve que c'est plus propre, mais c'est peut être une mauvaise habitude... )

Ah autant pour moi, je pensais que cela générait l'erreur. Apparemment c'est autorisé, donc chacun ses habitudes

[Utilisateur 3309 supprimé]

Ca Marche !!!
Bravo !

J'avais cherché a comprendre, mais un petit s glissé en cachette...je ne m'en été pas rendu compte, t'aurais pu choisir plus GROS comme erreur volontaire !

Et ben merci encore, je peux te dire que ce code est une exclu car j'ai bien remué internet dans tous les sens et il n'y a rien (concernant Autoit) de capable de faire ca.

Bonne journée.

[TommyDDR]

Informations sur = et == en Autoit :

Code : Tout sélectionner

If($Var1 = $Var2)

revient à faire si "Number($Var1) est égal à Number($Var2)"
Alors que

Code : Tout sélectionner

If($Var1 == $Var2)

revient à faire si "StringCompare($Var1, $Var2, 1) est égal à 0 (identique case sensitive)".

En règle général, le == répondra toujours à vos attentes (sauf si vous voulez comparer des chaines sans faire attentions aux majuscules).

En effet, if(0 = "abc") retournera vrai car Number("abc") = 0, cela peut être source de bug.

Voici quelques exemples :

► Afficher le textecode

Code : Tout sélectionner

Global $Var1 = 123
Global $Var2 = "123"
CheckVars($Var1, $Var2)

$Var1 = 123
$Var2 = "123a"
CheckVars($Var1, $Var2)

$Var1 = 0
$Var2 = "a"
CheckVars($Var1, $Var2)

$Var1 = "a"
$Var2 = "A"
CheckVars($Var1, $Var2)

Func CheckVars($Var1, $Var2)
    ConsoleWrite($Var1 & " = " & $Var2 & " : ")
    ConsoleWrite($Var1 = $Var2)
    ConsoleWrite(@CRLF & $Var1 & " == " & $Var2 & " : ")
    ConsoleWrite($Var1 == $Var2)
    ConsoleWrite(@CRLF & @CRLF)
EndFunc
 

[Utilisateur 3309 supprimé]

petite question,
l'envoi de FAX a plusieurs personnes, ca marche comme ca ?

Code : Tout sélectionner

$FaxDoc.Sender.FaxNumber = "0466000000;0466000001;0466000002"

Edit:
je me répond a moi même apres essai : NON.

Du coup je suis confronté a un petit problème:
Lorsque j'envoi un fax manuellement avec microsoft shared Fax, j'ai la possibilité d'envoyer le fax a plusieurs destinataires. Notre serveur a 2 cartes FAX, lorsque j'envoi le fax a 2 destinataires chacun des fax est attribué a un modem et du coup les FAX ne se trouvent pas en file d'attente derriere le meme modem. Pour 2 fax c'est pas trop grave, mais lorsqu'on en envoi 1000 c'est pas rien...

J'ai donc fait une boucle dans laquelle je récupère les numéros de fax dans un excel et je FAX. le probleme c'est que dans ce cas là tous les fax attendent que le 1er fax soit terminer, ils sont tous dans la meme file d'attente, est-ce qu'il n'y aurait pas un parametre qui gere le canal (modem1 ou modem2) ??

Voici mon code:

► Afficher le texte

Code : Tout sélectionner

#include <Excel.au3>

Local $mailing = "c:\temp\mailing.xlsx" ; Chemin du fichier contenant les n° de FAX
Local $num_fax = ""

_ExcelBookOpen($mailing) ; On ouvre le fichier Excel
$oExcel = ObjGet("","Excel.Application")
_ExcelSheetActivate($oExcel, "mailing") ; on se positionne sur la feuille Excel qui s'appelle: mailing
$oExcel.Visible = 0

Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")

for $i = 1 to 10000 step 1

$FaxServer = ObjCreate("FAXCOMEX.FaxServer")
$FaxDoc = ObjCreate("FAXCOMEX.FaxDocument")
If $FaxServer == 0 OR $FaxDoc == 0 Then _ErrFunc()

    $num_fax = $oExcel.Activesheet.Cells(1+$i,1).Value
        if $num_fax =="" then ExitLoop ; Si la cellule est vide on sort de la boucle

$client = $oExcel.Activesheet.Cells(1+$i,2).Value
$divers = $oExcel.Activesheet.Cells(1+$i,3).Value

$FaxServer.Connect("mon_serveur") ; Connexion au serveur de Fax
$FaxDoc.Body = "c:\temp\test.rtf"               ; Fichier à FAXER
$FaxDoc.DocumentName = $client                  ; Nom du document
$FaxDoc.Recipients.Add ($num_fax)           ; FAX DU DESTINATAIRE
$FaxDoc.Sender.Email = "monmail@domaine.com" ;Mail de l'expéditeur
$FaxDoc.Sender.Name = "MOI"                 ; Nom de l'expéditeur FAX
$FaxDoc.Sender.FaxNumber = "0000000000"         ;Numero de FAX de l'appellant

$FaxServer.Folders.OutgoingQueue.Branding = False  ;True to set banner on, False to set banner off
$FaxServer.Folders.OutgoingQueue.Save

$JobID = $FaxDoc.ConnectedSubmit($FaxServer)    ; Envoi du FAX

Next

_ExcelBookClose($oExcel) ; On ferme Excel

Func _ErrFunc($oError)
    _ExcelBookClose($oExcel)
    MsgBox(16, "Erreur", "Impossible de charger le service de Fax" )
    Exit
EndFunc   ;==>_ErrFunc

Merci pour l'aide

[Utilisateur 3309 supprimé]

est-ce que ca pourrait aider ?

Broadcasting a Fax
http://msdn.microsoft.com/en-us/library ... s.85).aspx

ou bien faut il indiquer sur lequel des 2 modems on FAX le (1) ou le (2)?
http://msdn.microsoft.com/en-us/library ... s.85).aspx
'Get the device
objFaxDevice = objFaxServer.GetDevices.Item(1)

Merci pour l'aide

[Utilisateur 3309 supprimé]

J'ai trouvé
il suffit de mettre autant de...
$FaxDoc.Recipients.Add ("numero_de_fax1")
$FaxDoc.Recipients.Add ("numero_de_fax2")
$FaxDoc.Recipients.Add ("numero_de_fax3")

...qu'il y a de fax a envoyer, on peut donc faire une boucle avec une variable pour le numero de fax.

Edit:
j'ai crié victoire trop vite.
Ca marche normalement quand j'envoie un fax a 2 destinataire depuis la console de telecopie microsoft FAX:
voir image: http://upix.in/images/22646161622844204071.png

Mais j'ai systematiquement un message d'erreur sur 1 modem avec la méthode que je viens de trouver: Erreur irrecupérable
voir image: http://upix.in/images/25453954176792026907.png

[Utilisateur 3309 supprimé]

Bonjour,
me revoila de retour de vacances.

Mais je viens de passer plusieurs heures la dessus et j'ai enfin réussi a convertir le code VB ci-dessous en Autoit
Broadcasting a Fax
http://msdn.microsoft.com/en-us/library ... s.85).aspx

Voici le code est ca marche, les 2 fax sont bien envoyés sur les 2 modems/FAX (en parallele donc):

► Afficher le texte

Code : Tout sélectionner

$objFaxDocument = ObjCreate("FAXCOMEX.FaxDocument")
$collFaxRecipients = ObjCreate("FAXCOMEX.FaxRecipients")


$objFaxDocument.Body = "c:\temp\test.rtf"               ; Fichier à FAXER
$objFaxDocument.DocumentName = "Mon fax"                ; Nom du document

$collFaxRecipients = $objFaxDocument.Recipients

with $collFaxRecipients
    .Add ("0466800001", "destinataire1") 
    .Add ("0466800002", "destinataire2") 
EndWith

$objFaxDocument.Sender.LoadDefaultSender()
$objFaxDocument.GroupBroadcastReceipts = True

$JobID = $objFaxDocument.Submit("monserveur")

$lCount = $collFaxRecipients.Count
For $i = 1 To $lCount
    $collFaxRecipients.Remove(1)
Next

Par contre je ne sais pas pourquoi mais 1x sur 2, j'ai encore le message d'erreur: Erreur Irrécupérable sur le meme modem. Donc c'est pas fiable.
Du coup je me demande si le modem pour lequel j'ai l'erreur n'aurait pas un probleme...Si quelqu'un pouvait essayer ??
Il suffit de mettre 2 modems sur un server Win 2003 et d'installer le service fax.
Voici le tuto, c'est pas compliquer et c'est tres bien expliqué: http://www.autourdupc.com/index.php?sIm ... il2003.htm

Merci a celui qui voudra bien me confirmer que ca marche pour lui, ou pas...