[..] Température CPU

[Strofe]

Bonjour

Je me permets de vous solliciter car je n'arrive pas à obtenir la température du CPU ??

J'ai cherché en AutoIt et en VBS.

► Afficher le texte

Code : Tout sélectionner

strServer = "."

Set objWMI = GetObject("winmgmts://" & strServer & "/root\cimv2")
Set objInstances = objWMI.InstancesOf("Win32_TemperatureProbe",48)

On Error Resume Next
For Each objInstance in objInstances
    With objInstance
        WScript.Echo .Accuracy
        WScript.Echo .Availability
        WScript.Echo .Caption
        WScript.Echo .ConfigManagerErrorCode
        WScript.Echo .ConfigManagerUserConfig
        WScript.Echo .CreationClassName
        WScript.Echo .CurrentReading
        WScript.Echo .Description
        WScript.Echo .DeviceID
        WScript.Echo .ErrorCleared
        WScript.Echo .ErrorDescription
        WScript.Echo .InstallDate
        WScript.Echo .IsLinear
        WScript.Echo .LastErrorCode
        WScript.Echo .LowerThresholdCritical
        WScript.Echo .LowerThresholdFatal
        WScript.Echo .LowerThresholdNonCritical
        WScript.Echo .MaxReadable
        WScript.Echo .MinReadable
        WScript.Echo .Name
        WScript.Echo .NominalReading
        WScript.Echo .NormalMax
        WScript.Echo .NormalMin
        WScript.Echo .PNPDeviceID
        WScript.Echo Join(.PowerManagementCapabilities, ", ")
        WScript.Echo .PowerManagementSupported
        WScript.Echo .Resolution
        WScript.Echo .Status
        WScript.Echo .StatusInfo
        WScript.Echo .SystemCreationClassName
        WScript.Echo .SystemName
        WScript.Echo .Tolerance
        WScript.Echo .UpperThresholdCritical
        WScript.Echo .UpperThresholdFatal
        WScript.Echo .UpperThresholdNonCritical
    End With
On Error Goto 0
Next

La valeur "CurrentReading" ne renvoie rien.

Une piste SVP ?

Bonne journée

[blacksoul305]

Salut,

quand j'ai vu ton sujet je me suis dis : "c'est impossible ce qu'il veut faire", bah il se trouve que si. Par contre ça va dépendre de ta carte mère. Apparemment, si ta carte mère est plutôt récente, d'après ce post sur le forum US, tu peux récupérer la température. Dans un post plus loin, il est bien confirmé que ça va dépendre de ta carte mère ici.

► Afficher le texte

Code : Tout sélectionner

Msgbox(0,"",_ACPI_Temp() & "c")

Func _ACPI_Temp()

    $wbemFlagReturnImmediately = 0x10
    $wbemFlagForwardOnly = 0x20
    $CurrTemp = -1
    $strComputer  = "."
    $objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\wmi")
    $colItems = $objWMIService.ExecQuery( "SELECT * FROM MSAcpi_ThermalZoneTemperature", "WQL",$wbemFlagReturnImmediately + $wbemFlagForwardOnly)

    For $objItem in $colItems

        $CurrTemp =($objItem.CurrentTemperature - 2732) / 10
;~ $Critical = ($objItem.CriticalTripPoint - 2732) / 10

    Next

    Return $CurrTemp

EndFunc

[Strofe]

Bonsoir

Merci pour ta réponse

Mais j'ai -1c en retour. Donc lecture impossible.

Mon PC --> Portable DELL Precision M4660 --> Seven 64 Btis --> 8 Go de Ram

Je cherche encore sniffff

A+

[blacksoul305]

Erf, pourtant ce PC a l'air bien récent. Je vais me renseigner de mon côté !

EDIT : Voilà où j'en suis dans mes recherches. Après avoir attiré ici, on nous redirige là bas. Ils parlent de WMI et je sais pas du tout ce que c'est, va falloir voir ça de plus près. Sinon j'ai eu ce script :

► Afficher le texte

Code : Tout sélectionner

#NoTrayIcon
#include <iWMILib.au3>
#include <GUIConstantsEx.au3>

_iWMI_Initialize()

GUICreate("WMI addon for EVEREST", 620, 314, -1, -1, -1, 0x2000000)
        $contID = GUICtrlCreateLabel("Value", 575, 138)

Global $aData[101]
Global $gGraph = _Graph_Create(50, 18, 513, 254)
_Graph_SetRange_X($gGraph, 1, 100, 0)
_Graph_SetRange_Y($gGraph, 0, 100, 10)
_Redraw()

GUISetState()
Do
    _Randomise()
    _Redraw()
Until GUIGetMsg() = -3

Func _Randomise()   
    $cObjects = _iWMI_ExecQueryRaw( _iWMI_Connect("localhost",0,"","", "Root\WMI" ), "SELECT * FROM EVEREST_SensorValues", False )
    For $oObject In $cObjects
    Next
        GUICtrlSetData($contID, $oObject.Value)
    If $aData[100] <> $oObject.Value Then
    For $i = 1 To 99
        $aData[$i] = $aData[$i + 1]
    Next
    $aData[100] = $oObject.Value
    EndIf
EndFunc   ;==>_Randomise

Func _Redraw()
    GUISetState(@SW_LOCK)
    _Graph_Clear($gGraph)
    _Graph_SetGrid_X($gGraph, 5, 0x468c2f)
    _Graph_SetGrid_Y($gGraph, 10, 0x468c2f)
    _Graph_Set_Color($gGraph, 0xF9F32B)
    _Graph_Plot_Start($gGraph, 1, $gGraph[1])
    For $i = 1 To 100
        _Graph_Plot_Line($gGraph, $i, $aData[$i])
    Next
    _Graph_Refresh($gGraph)
    GUISetState(@SW_UNLOCK)
EndFunc   ;==>_Redraw

Func _Graph_Create($iLeft, $iTop, $iWidth, $iHeight, $hColourBorder = 0x000000, $hColorFill = 0xFFFFFF)
    $hWnd = GUICtrlCreateGraphic($iLeft, $iTop, $iWidth + 1, $iHeight + 1)
    GUICtrlSetColor(-1, $hColourBorder)
    GUICtrlSetBkColor(-1, $hColorFill)
    Local $ahTicksLabelsX[1]
    Local $ahTicksLabelsY[1]
    Local $ahTicksX[1]
    Local $ahTicksY[1]
    Dim $aGraphArray[16] = ["", $hWnd, $iLeft, $iTop, $iWidth, $iHeight, 0, 1, 0, 1, _
            $ahTicksX, $ahTicksLabelsX, $ahTicksY, $ahTicksLabelsY, $hColourBorder, $hColorFill]
    Return $aGraphArray
EndFunc   ;==>_Graph_Create

Func _Graph_Clear(ByRef $aGraphArray)
    GUICtrlDelete($aGraphArray[1])
    $aGraphArray[1] = GUICtrlCreateGraphic($aGraphArray[2], $aGraphArray[3], _
            $aGraphArray[4] + 1, $aGraphArray[5] + 1)
    GUICtrlSetBkColor(-1, 0x000000)
    GUICtrlSetColor(-1, 0x000000)
EndFunc   ;==>_Graph_Clear

Func _Graph_SetRange_X(ByRef $aGraphArray, $iLow, $iHigh, $iXTicks = 1, $bLabels = 1, $iRound = 0)
    ;----- load user vars to array -----
    $aGraphArray[6] = $iLow
    $aGraphArray[7] = $iHigh
    ;----- prepare nested array -----
    $ahTicksX = $aGraphArray[10]
    $ahTicksLabelsX = $aGraphArray[11]
    ;----- delete any existing ticks -----
    For $i = 1 to (UBound($ahTicksX) - 1)
        GUICtrlDelete($ahTicksX[$i])
    Next
    Dim $ahTicksX[1]
    ;----- create new ticks -----
    For $i = 1 To $iXTicks + 1
        ReDim $ahTicksX[$i + 1]
        $ahTicksX[$i] = GUICtrlCreateLabel("", (($i - 1) * ($aGraphArray[4] / $iXTicks)) + $aGraphArray[2], _
                $aGraphArray[3] + $aGraphArray[5], 1, 5)
        GUICtrlSetBkColor(-1, 0x000000)
        GUICtrlSetState(-1, $GUI_DISABLE)
    Next
    ;----- delete any existing labels -----
    For $i = 1 to (UBound($ahTicksLabelsX) - 1)
        GUICtrlDelete($ahTicksLabelsX[$i])
    Next
    Dim $ahTicksLabelsX[1]
    ;----- create new labels -----
    For $i = 1 To $iXTicks + 1
        ReDim $ahTicksLabelsX[$i + 1]
        $ahTicksLabelsX[$i] = GUICtrlCreateLabel("", _
                ($aGraphArray[2] + (($aGraphArray[4] / $iXTicks) * ($i - 1))) - (($aGraphArray[4] / $iXTicks) / 2), _
                $aGraphArray[3] + $aGraphArray[5] + 10, $aGraphArray[4] / $iXTicks, 13, 1)
        GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
    Next
    ;----- if labels are required, then fill -----
    If $bLabels = 1 Then
        For $i = 1 To (UBound($ahTicksLabelsX) - 1)
            GUICtrlSetData($ahTicksLabelsX[$i], _
                    StringFormat("%." & $iRound & "f", _Graph_Reference_Pixel("p", (($i - 1) * ($aGraphArray[4] / $iXTicks)), _
                    $aGraphArray[6], $aGraphArray[7], $aGraphArray[4])))
        Next
    EndIf
    ;----- load created arrays back into array -----
    $aGraphArray[10] = $ahTicksX
    $aGraphArray[11] = $ahTicksLabelsX
EndFunc   ;==>_Graph_SetRange_X

Func _Graph_SetRange_Y(ByRef $aGraphArray, $iLow, $iHigh, $iYTicks = 1, $bLabels = 1, $iRound = 0)
    ;----- load user vars to array -----
    $aGraphArray[8] = $iLow
    $aGraphArray[9] = $iHigh
    ;----- prepare nested array -----
    $ahTicksY = $aGraphArray[12]
    $ahTicksLabelsY = $aGraphArray[13]
    ;----- delete any existing ticks -----
    For $i = 1 to (UBound($ahTicksY) - 1)
        GUICtrlDelete($ahTicksY[$i])
    Next
    Dim $ahTicksY[1]
    ;----- create new ticks -----
    For $i = 1 To $iYTicks + 1
        ReDim $ahTicksY[$i + 1]
        $ahTicksY[$i] = GUICtrlCreateLabel("", $aGraphArray[2] - 5, _
                ($aGraphArray[3] + $aGraphArray[5]) - (($aGraphArray[5] / $iYTicks) * ($i - 1)), 5, 1)
        GUICtrlSetBkColor(-1, 0x000000)
        GUICtrlSetState(-1, $GUI_DISABLE)
    Next
    ;----- delete any existing labels -----
    For $i = 1 to (UBound($ahTicksLabelsY) - 1)
        GUICtrlDelete($ahTicksLabelsY[$i])
    Next
    Dim $ahTicksLabelsY[1]
    ;----- create new labels -----
    For $i = 1 To $iYTicks + 1
        ReDim $ahTicksLabelsY[$i + 1]
        $ahTicksLabelsY[$i] = GUICtrlCreateLabel("", $aGraphArray[2] - 40, _
                ($aGraphArray[3] + $aGraphArray[5]) - (($aGraphArray[5] / $iYTicks) * ($i - 1)) - 6, 30, 13, 2)
        GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
    Next
    ;----- if labels are required, then fill -----
    If $bLabels = 1 Then
        For $i = 1 To (UBound($ahTicksLabelsY) - 1)
            GUICtrlSetData($ahTicksLabelsY[$i], StringFormat("%." & $iRound & "f", _Graph_Reference_Pixel("p", _
                    (($i - 1) * ($aGraphArray[5] / $iYTicks)), $aGraphArray[8], $aGraphArray[9], $aGraphArray[5])))
        Next
    EndIf
    ;----- load created arrays back into array -----
    $aGraphArray[12] = $ahTicksY
    $aGraphArray[13] = $ahTicksLabelsY
EndFunc   ;==>_Graph_SetRange_Y

Func _Graph_Plot_Start(ByRef $aGraphArray, $iX, $iY)
    ;----- MOVE pen to start point -----
    GUICtrlSetGraphic($aGraphArray[1], $GUI_GR_MOVE, _
            _Graph_Reference_Pixel("x", $iX, $aGraphArray[6], $aGraphArray[7], $aGraphArray[4]), _
            _Graph_Reference_Pixel("y", $iY, $aGraphArray[8], $aGraphArray[9], $aGraphArray[5]))
EndFunc   ;==>_Graph_Plot_Start

Func _Graph_Plot_Line(ByRef $aGraphArray, $iX, $iY)
    ;----- Draw line from previous point to new point -----
    GUICtrlSetGraphic($aGraphArray[1], $GUI_GR_LINE, _
            _Graph_Reference_Pixel("x", $iX, $aGraphArray[6], $aGraphArray[7], $aGraphArray[4]), _
            _Graph_Reference_Pixel("y", $iY, $aGraphArray[8], $aGraphArray[9], $aGraphArray[5]))
EndFunc   ;==>_Graph_Plot_Line

Func _Graph_Set_Color(ByRef $aGraphArray, $hColor, $hBkGrdColor = $GUI_GR_NOBKCOLOR)
    GUICtrlSetGraphic($aGraphArray[1], $GUI_GR_COLOR, $hColor, $hBkGrdColor)
EndFunc   ;==>_Graph_Set_Color

Func _Graph_SetGrid_X(ByRef $aGraphArray, $Ticks = 1, $hColor = 0xf0f0f0)
    _Graph_Set_Color($aGraphArray, $hColor, $GUI_GR_NOBKCOLOR)
    Select
        Case $Ticks > 0
            For $i = $aGraphArray[6] To $aGraphArray[7] Step $Ticks
                If $i = Number($aGraphArray[6]) Or $i = Number($aGraphArray[7]) Then ContinueLoop
                GUICtrlSetGraphic($aGraphArray[1], $GUI_GR_RECT, _ ;rectangle
                        _Graph_Reference_Pixel("x", $i, $aGraphArray[6], $aGraphArray[7], $aGraphArray[4]), _ ;x
                        1, _ ;y
                        1, _ ;width
                        $aGraphArray[5] - 1) ;height
            Next
    EndSelect
    _Graph_Set_Color($aGraphArray, 0x000000)
EndFunc   ;==>_Graph_SetGrid_X

Func _Graph_SetGrid_Y(ByRef $aGraphArray, $Ticks = 1, $hColor = 0xf0f0f0)
    _Graph_Set_Color($aGraphArray, $hColor, $GUI_GR_NOBKCOLOR)
    Select
        Case $Ticks > 0
            For $i = $aGraphArray[8] To $aGraphArray[9] Step $Ticks
                If $i = Number($aGraphArray[8]) Or $i = Number($aGraphArray[9]) Then ContinueLoop
                GUICtrlSetGraphic($aGraphArray[1], $GUI_GR_RECT, _ ;rectangle
                        1, _ ;x
                        _Graph_Reference_Pixel("y", $i, $aGraphArray[8], $aGraphArray[9], $aGraphArray[5]), _ ;y
                        $aGraphArray[4] - 1, _ ;width
                        1) ;height
            Next
    EndSelect
    _Graph_Set_Color($aGraphArray, 0x000000)
EndFunc   ;==>_Graph_SetGrid_Y

Func _Graph_Refresh(ByRef $aGraphArray)
    GUICtrlSetGraphic($aGraphArray[1], $GUI_GR_REFRESH)
EndFunc   ;==>_Graph_Refresh

Func _Graph_Reference_Pixel($iType, $iValue, $iLow, $iHigh, $iTotalPixels)
    ;----- perform pixel reference calculations -----
    Switch $iType
        Case "x"
            Return (($iTotalPixels / ($iHigh - $iLow)) * (($iHigh - $iLow) * (($iValue - $iLow) / ($iHigh - $iLow))))
        Case "y"
            Return ($iTotalPixels - (($iTotalPixels / ($iHigh - $iLow)) * (($iHigh - $iLow) * (($iValue - $iLow) / ($iHigh - $iLow)))))
        Case "p"
            Return ($iValue / ($iTotalPixels / ($iHigh - $iLow))) + $iLow
    EndSwitch
EndFunc   ;==>_Graph_Reference_Pixel

► Afficher le texteiWMILib.au3

Code : Tout sélectionner

; #INDEX# =======================================================================================================================
; Title .........: igzters WMI Library (iWMILib)
;
; Version .......: 1.2.0
;
; AutoIt Version : 3.3.6.1
;
; Language ......: English
;
; Description ...: A collection of functions for interacting with WMI to local and remote computers.
;
; Author(s) .....: Thomas Uhrfelt
;
; Dll ...........: None.
;
; Functions .....: _iWMI_Initialize
;                  _iWMI_Connect
;                  _iWMI_Disconnect
;                  _iWMI_Dispose
;                  _iWMI_ExecQueryClassSelect
;                  _iWMI_SetPingDelay
;                  _iWMI_QueryCorrection (internal)
;                  _iWMI_ErrorHandler (internal)
;
; Remarks .......: http://msdn.microsoft.com/en-us/library/aa394606(VS.85).aspx (WQL - SQL for WMI).
;                  http://www.autoitscript.com/autoit3/files/beta/autoit/COM/ErrorEventTest-WMI.AU3 (AutoIT and COM error handling).
;                  http://msdn.microsoft.com/en-us/library/aa394585%28v=VS.85%29.aspx (WMI Tasks for Scripts and Applications) - Good resource for ideas on how to use WMI.
;
;                  If you have problems and getting "RPC Server unavailible on remote computers you might want to try
;                  issuing the following commands on the computers:
;                  >netsh firewall set service RemoteAdmin enable
;                  >netsh firewall add portopening protocol=tcp port=135 name=DCOM_TCP135
;
;                  This include is now multiple callers resistant - so even if you have a couple of scripts within the same project
;                  including and calling it - it'll cope with that.
;
; Also check out :  http://www.autoitscript.com/forum/index.php?showtopic=106163 (Active Directory UDF that is extremely useful for me).
;                   http://www.autoitscript.com/forum/index.php?showtopic=74325 (Event driven TCP UDF that rocks by boat - simple and very useful).
;
; ToDo: .........:  None planned.
;
; History........:
;                   0000-00-00  * Been sitting on my harddrive for over a year without use.
;                   2010-06-12  * Added a COM error handler event for queries that fails (output to console).
;                               * Renamed _iWMI_ExecQueryClass to _iWMI_ExecQueryClassSelect.
;                               * Removed _iWMI_ExecQueryClassAssociators (use the raw query for this).
;                               * Improved commenting and cleanup of code.
;                               * Implemented ping test on remote computers, including adjustable ping delay.
;                               * Corrected bugs using SetError on successful actions.
;                               * Renamed _iWMI_EnableCorrectionEnable to _iWMI_QueryCorrectionEnable().
;                               * Fixed bug with checking $_iWMI_oWbemLocator object creation not working as intended.
;
;                   2010-06-13  * Lot's of smaller issues fixed (mainly costmetical).
;                               * Removed the enable and disable correction functions (handled via parameters instead).
;                               * Rewrote the logic to allow for multiple callers with their own connections. This will allow this library to
;                               be included and used from multiple sources at the same time within the same project.
;                               * Added namespace support to _iWMI_Connect (defaults to root/cimv2).
;                               * Bumped version to 1.2.0
;
; ===============================================================================================================================
#include <array.au3>

Global  $_iWMI_oWMIService, _
        $_iWMI_oWbemLocator, _
        $_iWMI_oWMIError, _                                             ; Error handler for COM objects.
        $_iWMI_iPingDelay           = 1000, _                           ; Default ping delay is 1000ms.
        $_iWMI_aConnections [1], _                                      ; Array of our WMI connections currently handled (not used yet).
        $_iWMI_aConnectionsIds [1], _                                   ; Array of our WMI connection ids currently handled (not used yet).
        $_iWMI_iConnectionIdCounter = 0, _                              ; Incremental counter for our connection ids (not used yet).
        $_iWMI_bInitialized         = false                             ; Are we initialized and ready to go?

Global Enum _                                                           ; Global error codes.
        $_iWMI_StatusSuccess                = 0 , _                     ; Operation succeeded.
        $_iWMI_StatusGeneralFailure             , _                     ; Operation failed.
        $_iWMI_StatusWMIIsInitialized           , _                     ; Attempt to initialize library failed because it was already initialized.
        $_iWMI_StatusWMINotInitialized          , _                     ; Attempt to dispose/use library failed because it was not initalized.
        $_iWMI_StatusNotValidHost           = 20, _                     ; The hostname supplied was not a valid one.
        $_iWMI_StatusNotValidHostType           , _                     ; The host type supplied was not a valid one.
        $_iWMI_StatusWMIObjectNotCreated    = 40, _                     ; WMI object creation failed.
        $_iWMI_StatusWbemObjectNotCreated       , _                     ; Wbem object creation failed.
        $_iWMI_StatusHostNotAvailible       = 60, _                     ; The host could not be reached (failed ping test).
        $_iWMI_StatusConnectionIdNotFound   = 80, _                     ; The connection id was not found (non existant).
        $_iWMI_StatusArrayFailure,                _                     ; Failed to add to connection or id array.
        $_iWMI_StatusNoQueryResults         = 100                       ; Query returned no results.

Global Const _
        $_iWMI_HOSTLOCAL                = 0, _                          ; Host is local.
        $_iWMI_HOSTREMOTE               = 1, _                          ; Host is remote.
        $_iWMI_QUERYCLASSEQUALS         = 0, _                          ; Class query is using equal.
        $_iWMI_QUERYCLASSLIKE           = 1                             ; Class query is using like. (% is added automatically)

;#FUNCTION# ====================================================================================================================
; Name...........:  _iWMI_Initialize
;
; Description ...:  Intialize the library.
;
; Parameters ....:  None.
;
; Return values .:  On Success      - Returns $_iWMI_StatusSuccess
;                   On Failure      - Returns errorcode and sets @Error
;
; Author(s) .....: Thomas Uhrfelt
; ===============================================================================================================================
Func _iWMI_Initialize()
    if ( $_iWMI_bInitialized ) Then                                                                         ; Are we already initialized?
        Return SetError($_iWMI_StatusWMIIsInitialized, 0, $_iWMI_StatusWMIIsInitialized)                    ; Return error if we are (need to check this error in calling function - this is not a major error).
    EndIf

    $_iWMI_oWMIError = ObjEvent("AutoIt.Error","_iWMI_ErrorHandler")                                        ; Install custom COM error handler.

    If IsObj($_iWMI_oWMIError) = False Then                                                                 ; Check if the creation or error handler worked.
        $_iWMI_bInitialized = False                                                                         ; If we fail then we are not really initialized (make sure we need another initialization ) - probably should reset everything here?!
        Return SetError($_iWMI_StatusWMINotInitialized, 0, $_iWMI_StatusWMINotInitialized)                  ; and return error!
    EndIf
    $_iWMI_iConnectionIdCounter = 0                                                                         ; Reset the connection id counter (can be reset whenever connections are null)
    $_iWMI_bInitialized = True                                                                              ; Yes now we are initialized.
    Return $_iWMI_StatusSuccess                                                                             ; Return success if everything went OK.
EndFunc ;==>_iWMI_Initialize

;#FUNCTION# ====================================================================================================================
; Name...........:  _iWMI_iWMI_Connect
;
; Description ...:  Intialize the library.
;
; Parameters ....:  $sHost          - Host to connect to (use localhost for local computer).
;                   $iHostType      - Optional - Type of host (local/remote).
;                                       0 = (Default) Connect to local computer. ($_iWMI_HOSTLOCAL)
;                                       1 = Connect to remote computer. ($_iWMI_HOSTREMOTE)
;                   $sUsername      - Optional - Username to connect to remote computers
;                                       "" = (Default) Connect with current credentials.
;                   $sPassword      - Optional - Password to connect to remote computer.
;                                       "" = (Default) Connect with current credentials.
;                   $sNamespace     - Optional - namespace to connection to (default: root\cimv2).
;
; Return values .:  On Success      - Returns $_iWMI_StatusSuccess
;                   On Failure      - Returns errorcode and sets @Error
;
; Author(s) .....: Thomas Uhrfelt
; ===============================================================================================================================
Func _iWMI_Connect( $sHost, $iHostType = $_iWMI_HOSTLOCAL, $sUsername="", $sPassword="", $sNamespace = "root\cimv2" )
    If $_iWMI_bInitialized = False Then                                                                     ; Check if we are initialized.
        Return SetError($_iWMI_StatusWMINotInitialized, 0, $_iWMI_StatusWMINotInitialized)                  ; Return error if we are not.
    EndIf

    If $sHost = "" Then                                                                                     ; Check for valid host if not return error.
        Return SetError($_iWMI_StatusNotValidHost,0,$_iWMI_StatusNotValidHost)
    EndIf

    If Not($iHostType = $_iWMI_HOSTLOCAL Or $iHostType = $_iWMI_HOSTREMOTE ) Then                           ; Check for valid host type (not needed since we default to localhost is omitted.
        Return SetError($_iWMI_StatusNotValidHostType,0,$_iWMI_StatusNotValidHostType)
    EndIf

    ; We are connecting to our local computer.
    If($iHostType = $_iWMI_HOSTLOCAL) Then                                                                  ; Initialize local host.
        $_iWMI_oWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\.\" & $sNamespace )                ; Impersonate
        If Not IsObj($_iWMI_oWMIService) Then                                                               ; We failed to create the object.
            Return SetError($_iWMI_StatusWMIObjectNotCreated, 0, $_iWMI_StatusWMIObjectNotCreated )
        EndIf
    ; We are connecting to a remote computer.
    ElseIf($iHostType = $_iWMI_HOSTREMOTE) Then                                                             ; Initialize remote host.
        If Not(Ping($sHost, $_iWMI_iPingDelay )) Then                                                       ; Check if host is availible.
            Return SetError($_iWMI_StatusHostNotAvailible, 0, $_iWMI_StatusHostNotAvailible)
        EndIf
        $_iWMI_oWbemLocator=ObjCreate("WbemScripting.SWbemLocator")
        If Not IsObj($_iWMI_oWbemLocator) Then
            Return SetError($_iWMI_StatusWbemObjectNotCreated, 0, $_iWMI_StatusWbemObjectNotCreated)
        EndIf
        $_iWMI_oWMIService = $_iWMI_oWbemLocator.ConnectServer ( _
            $sHost, _
            "root\cimv2", _
            $sUsername, _
            $sPassword )
        If Not IsObj($_iWMI_oWMIService) Then
            $_iWMI_oWbemLocator = ""                                                                        ; Dispose Wbem object due to the failure.
            Return SetError($_iWMI_StatusWMIObjectNotCreated, 0, $_iWMI_StatusWMIObjectNotCreated )
        EndIf
        $_iWMI_oWMIService.Security_.authenticationLevel = 6                                                ; We are using PktPrivacy.
    EndIf
    $_iWMI_iConnectionIdCounter += 1                                                                        ; Increase the connection id counter.
    _ArrayAdd( $_iWMI_aConnections, $_iWMI_oWMIService )                                                    ; Put the WMI Service object in the array.
    If @Error = True Then                                                                                   ; We have a problem.
        $_iWMI_iConnectionIdCounter -= 1
        Return SetError($_iWMI_StatusArrayFailure, 0, $_iWMI_StatusArrayFailure )
    EndIf
    _ArrayAdd( $_iWMI_aConnectionsIds, $_iWMI_iConnectionIdCounter )
    If @Error = True Then                                                                                   ; We had a problem - need to revert the connection as well.
        _ArrayPop( $_iWMI_aConnections )
        $_iWMI_iConnectionIdCounter -= 1
        Return SetError($_iWMI_StatusArrayFailure, 0, $_iWMI_StatusArrayFailure )
    EndIf
    Return $_iWMI_iConnectionIdCounter                                                                      ; Return the id of our connection.
EndFunc ; ==>_iWMI_Connect

;#FUNCTION# ====================================================================================================================
; Name...........:  _iWMI_Disconnect
;
; Description ...:  Disconnects a connection.
;
; Parameters ....:  $iId            - Connection id to disconnect.
;
; Return values .:  On Success      - Returns $_iWMI_StatusSuccess
;                   On Failure      - Returns errorcode and sets @Error
;
; Author(s) .....: Thomas Uhrfelt
; ===============================================================================================================================
Func _iWMI_Disconnect( $iId )
    If $_iWMI_bInitialized = False Then                                                                     ; Check if we are initialized.
        Return SetError($_iWMI_StatusWMINotInitialized, 0, $_iWMI_StatusWMINotInitialized)                  ; Return error if we are not.
    EndIf

    $iIndex = _ArraySearch( $_iWMI_aConnectionsIds, $iId )                                                  ; Search for our Id.
    If @Error = True Then                                                                                   ; We did not find the id - ooops!
        Return SetError($_iWMI_StatusConnectionIdNotFound, 0, $_iWMI_StatusConnectionIdNotFound)
    EndIf
    ; if these fails we should abort - something is very wrong - only reason would be AutoIT bugs - revisited later.
    _ArrayDelete( $_iWMI_aConnections   , $iIndex )
    _ArrayDelete( $_iWMI_aConnectionsIds, $iIndex )

    If ( Ubound($_iWMI_aConnections ) = 1 ) Then                                                            ; We are not back to where we came from.
        $_iWMI_iConnectionIdCounter = 0
    EndIf
    Return $_iWMI_StatusSuccess
EndFunc ; ==>_iWMI_Disconnect

;#FUNCTION# ====================================================================================================================
; Name...........:  _iWMI_Dispose
;
; Description ...:  Dispose the library.
;
; Return values .:  On Success      - Returns $_iWMI_StatusSuccess
;                   On Failure      - Returns errorcode and sets @Error
;
; Author(s) .....: Thomas Uhrfelt
; ===============================================================================================================================
Func _iWMI_Dispose()
    If $_iWMI_bInitialized = True Then                                                                      ; We are initialized so we can dispose
        ReDim $_iWMI_aConnections [1]                                                                       ; Reset the arrays just in case to re-claim memory.
        ReDim $_iWMI_aConnectionsIds [1]
        $_iWMI_iConnectionIdCounter = 0                                                                     ; Reset the connection counter.
        Return $_iWMI_StatusSuccess
    Else
        Return SetError($_iWMI_StatusWMINotInitialized, 0, $_iWMI_StatusWMINotInitialized)
    EndIf
    Return SetError($_iWMI_StatusGeneralFailure, 0, $_iWMI_StatusGeneralFailure)
EndFunc ;==>_iWMI_Dispose

;#FUNCTION# ====================================================================================================================
; Name...........:  _iWMI_QueryCorrection
;
; Description ...:  Performs the actual query correction by replacing \ with \\.
;
; Parameters ....:  $sQuery         - Query to perfom the correction on.
;
; Return values .:  $sQuery         - The corrected query.
;
; Author(s) .....:  Thomas Uhrfelt
; ===============================================================================================================================
Func _iWMI_QueryCorrection($sQuery)
    return StringReplace($sQuery,"\","\\")
EndFunc ;==>_iWMI_QueryCorrection

;#FUNCTION# ====================================================================================================================
; Name...........:  _iWMI_SetPingDelay
;
; Description ...:  Sets the ping timeout for remote connections.
;
; Parameters ....:  $iDelay         - Optional - Number of miliseconds for ping timeout (default: 1000 ). Min value is 1000ms.
;
; Return values .:  On Success      - Returns $_iWMI_StatusSuccess.
;                   On Failure      - Returns errorcode and sets @Error.
;
; Author(s) .....:  Thomas Uhrfelt
; ===============================================================================================================================
Func _iWMI_SetPingDelay( $iDelay = 1000 )
    If $iDelay < 1000 Then
        Return SetError($_iWMI_StatusGeneralFailure, 0, $_iWMI_StatusGeneralFailure)
    EndIf
    $_iWMI_iPingDelay = $iDelay
    Return $_iWMI_StatusSuccess
EndFunc ;==> _iWMI_SetPingDelay

;#FUNCTION# ====================================================================================================================
; Name...........:  _iWMI_ErrorHandler
;
; Description ...:  COM event error handler. Handles COM errors frequently thrown by erroneous WQL statements (or some statements
;                   with NULL returns).
;
; Parameters ....:  None.
;
; Return values .:  None.
;
; Remarks .......:  In the future I probably need to improve the error handling with return values.
;
; Author(s)......:  Thomas Uhrfelt
; ===============================================================================================================================
Func _iWMI_ErrorHandler()
        ConsoleWrite("Error.number: "           & Hex( $_iWMI_oWMIError,8) & @CRLF )
        ConsoleWrite("Error.windescription: "   & $_iWMI_oWMIError.windescription & @CRLF )
        ConsoleWrite("Error.source: "           & $_iWMI_oWMIError.source & @CRLF )
        ConsoleWrite("Error.helpfile: "         & $_iWMI_oWMIError.helpfile & @CRLF )
        ConsoleWrite("Error.helpcontext: "      & $_iWMI_oWMIError.helpcontext & @CRLF )
        ConsoleWrite("Error.lastdllerror: "     & $_iWMI_oWMIError.lastdllerror & @CRLF )
        ConsoleWrite("Error.scriptline: "       & $_iWMI_oWMIError.scriptline & @CRLF )
Endfunc ;==>_iWMI_ErrorHandler

;#FUNCTION# ====================================================================================================================
; Name...........:  _iWMI_ExecQueryClassSelect
;
; Description ...:  Executes a WMI class query on the connected computer.
;
; Parameters ....:  $iId            - Id of the connection.
;                   $sClass         - Class to query.
;                   $bCorrection    - Optional - Use query correction.
;                                       0 = (Default) Do not use query correction.
;                                       1 = Use query correction.
;                   $sQueryType     - Optional - Equals or Like query.
;                                       0 = (Default) Use an equal query ($_iWMI_QUERYCLASSEQUALS)
;                                       1 = Use a like query ($_iWMI_QUERYCLASSLIKE)
;                   $sProperty      - Optional - Which property to select on (default: "").
;                   $sPropertyValue - Optional - Which property value to select on (default: "").
;                   $sProperties    - Optional - Which properties to query (default: "*" ).
;                   $iFlag          - Optional - Flag to execute the query (default: 0x00).
;
; Return values .:  On Success      - Returns collection of results from the query.
;                   On Failure      - Returns errorcode and sets @Error
;
; Remarks .......:  When querying for files/folders with spaces in them please be careful how you use ' & ", example:
;                   _iWMI_ExecQueryClass( "Win32_LogicalFileSecuritySetting", "Path", '"C:\\Autoexec.bat"' ) unless
;                    you have query correction enabled.
;
; Author(s) .....:  Thomas Uhrfelt
; ===============================================================================================================================
Func _iWMI_ExecQueryClassSelect( $iID, $sClass, $bCorrection = False, $sQueryType = $_iWMI_QUERYCLASSEQUALS, $sProperty = "", $sPropertyValue = "", $sProperties = "*", $iFlag = 0x00 )

    If $_iWMI_bInitialized = False Then                                                                     ; Check if we are initialized.
        Return SetError($_iWMI_StatusWMINotInitialized, 0, $_iWMI_StatusWMINotInitialized)                  ; Return error if we are not.
    EndIf

    $iIndex = _ArraySearch( $_iWMI_aConnectionsIds, $iId )                                                  ; Search for our Id.
    If @Error = True Then                                                                                   ; We did not find the id - ooops!
        Return SetError($_iWMI_StatusConnectionIdNotFound, 0, $_iWMI_StatusConnectionIdNotFound)
    EndIf

    If $sProperties = "" Then $sProperties = "*"

    ; Create the query
    Local $sQuery = "SELECT "       & _
                    $sProperties    & _
                    " FROM "        & _
                    $sClass
    If $sProperty <> "" And $sPropertyValue <> "" And $sQueryType = $_iWMI_QUERYCLASSEQUALS Then            ; Equals query.
        $sQuery = $sQuery & _
                    " WHERE "       & _
                    $sProperty      & _
                    '="'            & _
                    $sPropertyValue & '"'
    ElseIf $sProperty <> "" And $sPropertyValue <> "" And $sQueryType = $_iWMI_QUERYCLASSLIKE Then          ; Like query.
        $sQuery = $sQuery & _
                    " WHERE "       & _
                    $sProperty      & _
                    ' LIKE %"'      & _
                    $sPropertyValue & '%"'
    EndIf

    If $bCorrection = True Then                                                                             ; Should we correct the query
        $sQuery =  _iWMI_QueryCorrection( $sQuery )
    EndIf

    $iIndex = _ArraySearch( $_iWMI_aConnectionsIds, $iId )                                                  ; Search for our Id.
    If @Error = True Then                                                                                   ; We did not find the id - ooops!
        Return SetError($_iWMI_StatusConnectionIdNotFound, 0, $_iWMI_StatusConnectionIdNotFound)
    EndIf

    Local $cResults = $_iWMI_aConnections[$iIndex].ExecQuery( $sQuery, "WQL", $iFlag )                      ; Execute the query if we found the connection.


    If ($cResults.Count = 0) Then                                                                           ; Did we get any results?
        Return SetError($_iWMI_StatusNoQueryResults, 0, $_iWMI_StatusNoQueryResults)                        ; No - return an error.
    EndIf

    Return $cResults

EndFunc ;==>_iWMI_ExecQueryClassSelect

;#FUNCTION# ====================================================================================================================
; Name...........:  _iWMI_ExecQueryRaw
;
; Description ...:  Executes a raw WMI class query on the connected computer.
;
; Parameters ....:  $iId            - Id of the connection.
; Parameters ....:  $sQuery         - Query string.
;                   $bCorrection    - Optional - Use query correction.
;                                       0 = (Default) Do not use query correction.
;                                       1 = Use query correction.
;                   $iFlag          - Optional - Flag to execute the query (default: 0x00).
;
; Return values .:  On Success      - Returns collection of results from the query.
;                   On Failure      - Returns errorcode and sets @Error
;
; Author(s) .....:  Thomas Uhrfelt
; ===============================================================================================================================
Func _iWMI_ExecQueryRaw( $iId,$sQuery,$bCorrection = False,$iFlag = 0x00 )

    If $_iWMI_bInitialized = False Then                                                                     ; Check if we are initialized.
        Return SetError($_iWMI_StatusWMINotInitialized, 0, $_iWMI_StatusWMINotInitialized)                  ; Return error if we are not.
    EndIf

    $iIndex = _ArraySearch( $_iWMI_aConnectionsIds, $iId )                                                  ; Search for our Id.
    If @Error = True Then                                                                                   ; We did not find the id - ooops!
        Return SetError($_iWMI_StatusConnectionIdNotFound, 0, $_iWMI_StatusConnectionIdNotFound)
    EndIf

    If $bCorrection = True Then                                                                             ; Should we correct the query
        $sQuery =  _iWMI_QueryCorrection( $sQuery )
    EndIf

    Local $cResults = $_iWMI_aConnections[$iIndex].ExecQuery( $sQuery, "WQL", $iFlag )                      ; Execute the query if we found the connection.

    If ($cResults.Count = 0) Then                                                                           ; Did we get any results?
        Return SetError($_iWMI_StatusNoQueryResults, 0, $_iWMI_StatusNoQueryResults)                        ; No - return an error.
    EndIf

    Return $cResults

EndFunc ;==>_iWMI_ExecQueryRaw

Voilà tout...

EDIT 2 : Voici un autre code qui a l'air intéressant qui se voit être sorti du programme Scriptomatic, qui est dans un des liens que j'ai cité. Désolé pour les nombreux codes, on verra celui qui marche et je supprimerai les autres pour éviter de polluer quand même :

► Afficher le texte

Code : Tout sélectionner

; Generated by AutoIt Scriptomatic

$wbemFlagReturnImmediately = 0x10
$wbemFlagForwardOnly = 0x20
$colItems = ""
$strComputer = "" ; le nom de ton PC

$Output=""
$Output = $Output & "Computer: " & $strComputer  & @CRLF
$Output = $Output & "==========================================" & @CRLF
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\CIMV2")
$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_TemperatureProbe", "WQL", _
                                          $wbemFlagReturnImmediately + $wbemFlagForwardOnly)

If IsObj($colItems) then
   For $objItem In $colItems
      $Output = $Output & "Accuracy: " & $objItem.Accuracy & @CRLF
      $Output = $Output & "Availability: " & $objItem.Availability & @CRLF
      $Output = $Output & "Caption: " & $objItem.Caption & @CRLF
      $Output = $Output & "ConfigManagerErrorCode: " & $objItem.ConfigManagerErrorCode & @CRLF
      $Output = $Output & "ConfigManagerUserConfig: " & $objItem.ConfigManagerUserConfig & @CRLF
      $Output = $Output & "CreationClassName: " & $objItem.CreationClassName & @CRLF
      $Output = $Output & "CurrentReading: " & $objItem.CurrentReading & @CRLF
      $Output = $Output & "Description: " & $objItem.Description & @CRLF
      $Output = $Output & "DeviceID: " & $objItem.DeviceID & @CRLF
      $Output = $Output & "ErrorCleared: " & $objItem.ErrorCleared & @CRLF
      $Output = $Output & "ErrorDescription: " & $objItem.ErrorDescription & @CRLF
      $Output = $Output & "InstallDate: " & WMIDateStringToDate($objItem.InstallDate) & @CRLF
      $Output = $Output & "IsLinear: " & $objItem.IsLinear & @CRLF
      $Output = $Output & "LastErrorCode: " & $objItem.LastErrorCode & @CRLF
      $Output = $Output & "LowerThresholdCritical: " & $objItem.LowerThresholdCritical & @CRLF
      $Output = $Output & "LowerThresholdFatal: " & $objItem.LowerThresholdFatal & @CRLF
      $Output = $Output & "LowerThresholdNonCritical: " & $objItem.LowerThresholdNonCritical & @CRLF
      $Output = $Output & "MaxReadable: " & $objItem.MaxReadable & @CRLF
      $Output = $Output & "MinReadable: " & $objItem.MinReadable & @CRLF
      $Output = $Output & "Name: " & $objItem.Name & @CRLF
      $Output = $Output & "NominalReading: " & $objItem.NominalReading & @CRLF
      $Output = $Output & "NormalMax: " & $objItem.NormalMax & @CRLF
      $Output = $Output & "NormalMin: " & $objItem.NormalMin & @CRLF
      $Output = $Output & "PNPDeviceID: " & $objItem.PNPDeviceID & @CRLF
      $strPowerManagementCapabilities = $objItem.PowerManagementCapabilities(0)
      $Output = $Output & "PowerManagementCapabilities: " & $strPowerManagementCapabilities & @CRLF
      $Output = $Output & "PowerManagementSupported: " & $objItem.PowerManagementSupported & @CRLF
      $Output = $Output & "Resolution: " & $objItem.Resolution & @CRLF
      $Output = $Output & "Status: " & $objItem.Status & @CRLF
      $Output = $Output & "StatusInfo: " & $objItem.StatusInfo & @CRLF
      $Output = $Output & "SystemCreationClassName: " & $objItem.SystemCreationClassName & @CRLF
      $Output = $Output & "SystemName: " & $objItem.SystemName & @CRLF
      $Output = $Output & "Tolerance: " & $objItem.Tolerance & @CRLF
      $Output = $Output & "UpperThresholdCritical: " & $objItem.UpperThresholdCritical & @CRLF
      $Output = $Output & "UpperThresholdFatal: " & $objItem.UpperThresholdFatal & @CRLF
      $Output = $Output & "UpperThresholdNonCritical: " & $objItem.UpperThresholdNonCritical & @CRLF
      if Msgbox(1,"WMI Output",$Output) = 2 then ExitLoop
      $Output=""
   Next
Else
   Msgbox(0,"WMI Output","No WMI Objects Found for class: " & "Win32_TemperatureProbe" )
Endif


Func WMIDateStringToDate($dtmDate)

 Return (StringMid($dtmDate, 5, 2) & "/" & _
 StringMid($dtmDate, 7, 2) & "/" & StringLeft($dtmDate, 4) _
 & " " & StringMid($dtmDate, 9, 2) & ":" & StringMid($dtmDate, 11, 2) & ":" & StringMid($dtmDate,13, 2))
EndFunc

Re voilà tout !

[Tlem]

Juste comme ça, est-ce que SpeedFan affiche la température ?

[blacksoul305]

Bah disons qu'il cherche la température du processeur. Il semblerait que ce logiciel donne la température (mais pas que) des ventilos...

EDIT : J'ai rien dis...

[Strofe]

Bonsoir

Le soft indique tout... et moi je ne veux que la température

► Afficher le texte

Win9x:NO 64Bit:YES GiveIO:NO SpeedFan:YES
I/O properly initialized
Linked ISA BUS at $0290
Linked Intel 6 Series SMBUS at $8000
Found nVidia Quadro 1000M
Linked nVidiaI2C0 SMBUS at $3D403E3F
Linked nVidiaI2C1 SMBUS at $3D403637
Linked nVidiaI2C2 SMBUS at $3D405051
Scanning ISA BUS at $0290...
Scanning Intel SMBus at $8000...
LIS331DL found on SMBus at $1D
Scanning I2CNVidia SMBus at $3D403E3F...
Scanning I2CNVidia SMBus at $3D403637...
Scanning I2CNVidia SMBus at $3D405051...
Found TOSHIBA MK5061GSY on AdvSMART
Found ACPI temperature
Found Intel(R) Core(TM) i7-2720QM CPU @ 2.20GHz
End of detection

Mais cela veut dire que c'est POSSIBLE..

A+

[Tlem]

Mais cela veut dire que c'est POSSIBLE..

Tout à fait. Il ne reste plus qu'à trouver le bon code.

Il me semble que sur le forum US, il y a un outil écrit en AutoIt qui est capable de retourner tout un tas d'informations sur votre PC. Trouvez cet outil, testez le et voyez si il retourne bien la température. Il vous suffira d'analyser le code pour trouver votre bonheur. ^^