[R] AutoIt - Avoir infos propriétés .mp3

[Fan2Rock]

Salut à tous ,

J'ai récemment récupéré toutes les musiques de mon iPod (que je n'avais pas sur mon PC car je les avais accidentellement supprimés) sauf que leurs titres sont bidons (genre AZER, QUSO, etc.). Cependant, les propriétés du fichier .mp3 sont restées intactes. J'aimerais donc savoir si il existe une commande AutoIt qui permetterais de récupérer les propriétés d'un fichier et de les mettre dans une variable (ici il s'agirais surtout de récupérer le nom de l'artiste et le titre de la piste comme ça je pourrais renommer le fichier dont on a lu les propriétés dans le style: $NOMARTISTE&" - "&$TITREMSQ&".mp3") grâce a une fonction qui ferais celà automatiquement pour toutes les musiques.

Les nom de fichiers ont l'air d'avoir toujours quatre lettres majuscules et aucun chiffres je ne sais pas si ça peut aider ^^.

Par avance merci,
Bye,
Ludoo

[mikell]

http://www.autoitscript.com/forum/topic ... e-property
Sinon fais une recherche sur le forum avec les mots "mp3 tag"

[Tlem]

Bonsoir.
Merci de mettre un titre plus explicite avant que je ne

[Fan2Rock]

désolé c'était une erreur de ma part ^^"

j'ai regardé plusieurs script proposé sur des sites différents mais je ne comprend pas comment ils fonctionnent et comment je pourrais les integrer dans un script et l'utiliser avec mes fichiers.

Voilà les quatres codes que j'ai trouvé. Pouvez vous me dire si ils sont bien et surtout comment on les utilise?

► Afficher le texte

Code : Tout sélectionner

Func _ShowFileProperties($sFile, $sVerb = "properties", $hWnd = 0)
    If Not FileExists($sFile) Then Return SetError(1, 0, 0)

    Local Const $SEE_MASK_INVOKEIDLIST = 0xC
    Local Const $SEE_MASK_NOCLOSEPROCESS = 0x40
    Local Const $SEE_MASK_FLAG_NO_UI = 0x400

    Local $PropBuff, $FileBuff, $SHELLEXECUTEINFO

    $PropBuff = DllStructCreate("char[256]")
    DllStructSetData($PropBuff, 1, $sVerb)

    $FileBuff = DllStructCreate("char[256]")
    DllStructSetData($FileBuff, 1, $sFile)

    $SHELLEXECUTEINFO = DllStructCreate("int cbSize;long fMask;hwnd hWnd;ptr lpVerb;ptr lpFile;ptr lpParameters;ptr lpDirectory;" & _
                                        "int nShow;int hInstApp;ptr lpIDList;ptr lpClass;hwnd hkeyClass;int dwHotKey;hwnd hIcon;" & _
                                        "hwnd hProcess")

    DllStructSetData($SHELLEXECUTEINFO, "cbSize", DllStructGetSize($SHELLEXECUTEINFO))
    DllStructSetData($SHELLEXECUTEINFO, "fMask", BitOR($SEE_MASK_NOCLOSEPROCESS, $SEE_MASK_INVOKEIDLIST, $SEE_MASK_FLAG_NO_UI))
    DllStructSetData($SHELLEXECUTEINFO, "hwnd", $hWnd)
    DllStructSetData($SHELLEXECUTEINFO, "lpVerb", DllStructGetPtr($PropBuff, 1))
    DllStructSetData($SHELLEXECUTEINFO, "lpFile", DllStructGetPtr($FileBuff, 1))

    $aRet = DllCall("shell32.dll", "int", "ShellExecuteEx", "ptr", DllStructGetPtr($SHELLEXECUTEINFO))
    If $aRet[0] = 0 Then Return SetError(2, 0, 0)

    Local $iPrevMode = Opt("WinTitleMatchMode", 2)
    Local $iTitle = StringRegExpReplace($sFile, "^.*\\(.*)\..*", "\1")

    WinWait($iTitle)

    Do
        Sleep(10)
    Until WinExists($iTitle) = 0

    Opt("WinTitleMatchMode", $iPrevMode)

    Return $aRet[0]
EndFunc

► Afficher le texte

Code : Tout sélectionner

; Début du script - Ajouter votre code ci-dessous.
;===============================================================================
;
; Function Name:   _FileDisplayProperties
; Description::    Uses a DLL to call the properties window of a file
; Parameter(s):    $a_CallFile = The file to display the properties of
;               $a_Wait = 1, wait until the user closes the dialog
;                      0, automatically return when it opens
; Requirement(s):  Shell32.dll
; Return Value(s): Returns the DLL call value, 1 if it was a success
; Author(s):       Alienware (Swift) and LarryDalooza
; Examples(s):
;               #Include <File.au3>
;               $FilePropReturnValue = _FileDisplayProperties(@ScriptFullPath)
;               MsgBox(0, "_FileDisplayProperties return value", "The return value of _FileDisplayProperties is: " & $FilePropReturnValue)
;
;===============================================================================

Func _FileDisplayProperties($sCallFile, $iWait = 1)
    If Not FileExists($sCallFile) Then Return SetError(1, 0, 0)
    Local $iReturn = DllCall("shell32.dll", "int", _
            "SHObjectProperties", "hwnd", 0, "dword", 0x00000002, _
            "wstr", $sCallFile, "wstr", 0)
    If $iWait = 1 Then
        $bOriginalOpt = Opt("WinTitleMatchMode", -2)
        WinWaitActive("Properties", "Cancel")
        WinWaitClose("Properties", "Cancel")
        Opt("WinTitleMatchMode", $bOriginalOpt)
    EndIf
    Return $iReturn[0]
EndFunc   ;==>_FileDisplayProperties

► Afficher le texte

Code : Tout sélectionner

; Début du script - Ajouter votre code ci-dessous.
HotKeySet("{Esc}", "OnExit")
_ShellExecuteEx(@ScriptName, "", @ScriptDir, "properties")

While 1
    Sleep(500)
WEnd

Func _ShellExecuteEx($sCmd, $Args = "", $sFolder = "", $Verb = "", $rState = @SW_SHOWNORMAL, $hWnd = 0)
    ;Crétion des structures
    Local $struINFO = DllStructCreate("long;long;long;ptr;ptr;ptr;ptr;long;long;long;ptr;long;long;long;long")
    Local $struVerb = DllStructCreate("char[15];char")
    Local $struPath = DllStructCreate("char[255];char")
    Local $struArgs = DllStructCreate("char[255];char")
    Local $struWDir = DllStructCreate("char[255];char")
    ; On remplit les structure précedement crée avec les paramétre
    DllStructSetData($struVerb, 1, $Verb)
    ;Si l'extension de fichier est un lien (lnk) alors
    ; on récupere les info grace a figetshorcut (voir aide)
    ; on remplit la stucture avec les valeurs trouvé
    If StringRight($sCmd, 3) = "lnk" Then
        Local $aShortcutInfo = FileGetShortcut($sCmd)
        If IsArray($aShortcutInfo) Then
            DllStructSetData($struPath, 1, $aShortcutInfo[0])
            DllStructSetData($struWDir, 1, $aShortcutInfo[1])
            DllStructSetData($struArgs, 1, $aShortcutInfo[2])
            $rState = $aShortcutInfo[6]
        Else
            Return 0
        EndIf
    Else
        DllStructSetData($struPath, 1, $sCmd)
        DllStructSetData($struWDir, 1, $sFolder)
        DllStructSetData($struArgs, 1, $Args)
    EndIf
    ; On remplit la stucture SHELLEXECUTEINFO
    DllStructSetData($struINFO, 1, DllStructGetSize($struINFO))
    DllStructSetData($struINFO, 2, BitOR(0xC, 0x40, 0x400))
    DllStructSetData($struINFO, 3, $hWnd)
    DllStructSetData($struINFO, 4, DllStructGetPtr($struVerb))
    DllStructSetData($struINFO, 5, DllStructGetPtr($struPath))
    DllStructSetData($struINFO, 6, DllStructGetPtr($struArgs))
    DllStructSetData($struINFO, 7, DllStructGetPtr($struWDir))
    DllStructSetData($struINFO, 8, $rState)
    ;On appel la procedure
    Local $ret = DllCall("shell32.dll", "int", "ShellExecuteEx", "ptr", DllStructGetPtr($struINFO))
    Return $ret[0]
EndFunc   ;==>_ShellExecuteEx

Func OnExit()
    Exit
EndFunc

► Afficher le texte

Code : Tout sélectionner

Global $MAX_PROPERTIES = 64 ; Maximum par test = 40

; Fonction de récupération des informations d'un fichier
; Entrée :
; - $chemin [string]  : chemin COMPLET du fichier
; Sortie :
; - $resultat [array] : Matrice de taille [ $n+1 x 3 ]
;                       - $resultat[0][0]     : représente le nombre de propriétés trouvées (apparemment indépendant du type du fichier $chemin), aka $n
;                       - $resultat[i][0] i>0 : représente le nom de la propriété
;                       - $resultat[i][1] i>0 : représente l'indexe système de la propriété
;                       - $resultat[i][2] i>0 : représente la valeur de la propriété pour le fichier $chemin
; - @extended         : [Aucune information]
; - @error            : [Aucune information]
Func getFichierListeProprietes($chemin)
    Local $resultat[1][3] = [[0,"",""]
    $resultat[0][0] = 0
    If FileExists($chemin) Then
        Local $shell = ObjCreate("shell.application"), $lastSlash = StringInStr($chemin, "\", 0, -1)
        Local $repertoire = $shell.NameSpace(StringLeft($chemin, $lastSlash))
        Local $fichier = $repertoire.Parsename(StringTrimLeft($chemin, $lastSlash))
        For $i = 0 to $MAX_PROPERTIES
            If $repertoire.GetDetailsOf($repertoire.Items, $i) <> "" Then
                ReDim $resultat[UBound($resultat)+1][3]
                $resultat[0][0] = UBound($resultat)-1
                $resultat[$resultat[0][0]][0] = $repertoire.GetDetailsOf($repertoire.Items, $i)
                $resultat[$resultat[0][0]][1] = $i
                $resultat[$resultat[0][0]][2] = $repertoire.GetDetailsOf($fichier, $i)
            EndIf
        Next
    EndIf
    Return $resultat
EndFunc

; Fonction de récupération d'une information d'un fichier
; Entrée :
; - $chemin [string]    : chemin COMPLET du fichier
; - $propriete [string] : nom de la propriété à rechercher
;              [int]    : index système de la propriété à rechercher
; Sortie :
; - $resultat [string]  : Valeur de la propriété pour le fichier $chemin de taille
; - @extended           : Index système de la propriété
; - @error              : [Cas d'erreur]
;                         - @error = 1 : le fichier $chemin est introuvable
;                         - @error = 2 : l'index sytème $propriete est invalide
;                         - @error = 2 : la propriété $propriete est introuvable
Func getFichierPropriete($chemin, $propriete)
    If Not FileExists($chemin) Then
        SetError(1)
    ElseIf IsInt($propriete) And Int($propriete) <= $MAX_PROPERTIES Then
        SetError(2)
    Else
        Local $shell = ObjCreate("shell.application"), $lastSlash = StringInStr($chemin, "\", 0, -1)
        Local $repertoire = $shell.NameSpace(StringLeft($chemin, $lastSlash))
        Local $fichier = $repertoire.Parsename(StringTrimLeft($chemin, $lastSlash))
        If IsInt($propriete) Then
            SetExtended($propriete)
            Return $repertoire.GetDetailsOf($fichier, $propriete)
        Else
            For $i = 0 to $MAX_PROPERTIES
                If $propriete <> "" And $repertoire.GetDetailsOf($repertoire.Items, $i) = $propriete Then
                    SetExtended($i)
                    Return $repertoire.GetDetailsOf($fichier, $i)
                EndIf
            Next
            SetError(3)
        EndIf
    EndIf
    Return ""
EndFunc

#Region Fonctions pour un accès rapide
Func getFichierAuteur($chemin)
    Return getFichierPropriete($chemin, 9)
EndFunc
Func getFichierTitre($chemin)
    Return getFichierPropriete($chemin, 10)
EndFunc
Func getFichierCommentaires($chemin)
    Return getFichierPropriete($chemin, 14)
EndFunc
#EndRegion

[mikell]

T'es quand même incroyab' ...
Tu mets 4 codes SAUF celui dont je t'ai donné le lien

► Afficher le texte

Code : Tout sélectionner

$mp3 = "G:\Compil\The Foggy Dew (sinead o'connor & the_chieftains).mp3"
$titre = _GetExtProperty($mp3, 10)
$artiste = _GetExtProperty($mp3, 16)

msgbox(0,"", $titre &@crlf& $artiste)

;===============================================================================
; Function Name:    GetExtProperty($sPath,$iProp)
; Description:      Returns an extended property of a given file.
; Parameter(s):     $sPath - The path to the file you are attempting to retrieve an extended property from.
;                   $iProp - The numerical value for the property you want returned. If $iProp is is set
;                             to -1 then all properties will be returned in a 1 dimensional array in their corresponding order.
;                           The properties are as follows:
;                           Name = 0
;                           Size = 1
;                           Type = 2
;                           DateModified = 3
;                           DateCreated = 4
;                           DateAccessed = 5
;                           Attributes = 6
;                           Status = 7
;                           Owner = 8
;                           Author = 9
;                           Title = 10
;                           Subject = 11
;                           Category = 12
;                           Pages = 13
;                           Comments = 14
;                           Copyright = 15
;                           Artist = 16
;                           AlbumTitle = 17
;                           Year = 18
;                           TrackNumber = 19
;                           Genre = 20
;                           Duration = 21
;                           BitRate = 22
;                           Protected = 23
;                           CameraModel = 24
;                           DatePictureTaken = 25
;                           Dimensions = 26
;                           Width = 27
;                           Height = 28
;                           Company = 30
;                           Description = 31
;                           FileVersion = 32
;                           ProductName = 33
;                           ProductVersion = 34
; Requirement(s):   File specified in $spath must exist.
; Return Value(s):  On Success - The extended file property, or if $iProp = -1 then an array with all properties
;                   On Failure - 0, @Error - 1 (If file does not exist)
; Author(s):        Simucal (Simucal@gmail.com)
; Note(s):
;
;===============================================================================
Func _GetExtProperty($sPath, $iProp)
    Local $iExist, $sFile, $sDir, $oShellApp, $oDir, $oFile, $aProperty, $sProperty
    $iExist = FileExists($sPath)
    If $iExist = 0 Then
        SetError(1)
        Return 0
    Else
        $sFile = StringTrimLeft($sPath, StringInStr($sPath, "\", 0, -1))
        $sDir = StringTrimRight($sPath, (StringLen($sPath) - StringInStr($sPath, "\", 0, -1)))
        $oShellApp = ObjCreate ("shell.application")
        $oDir = $oShellApp.NameSpace ($sDir)
        $oFile = $oDir.Parsename ($sFile)
        If $iProp = -1 Then
            Local $aProperty[35]
            For $i = 0 To 34
                $aProperty[$i] = $oDir.GetDetailsOf ($oFile, $i)
            Next
            Return $aProperty
        Else
            $sProperty = $oDir.GetDetailsOf ($oFile, $iProp)
            If $sProperty = "" Then
                Return 0
            Else
                Return $sProperty
            EndIf
        EndIf
    EndIf
EndFunc   ;==>_GetExtProperty

qui est en fait sensiblement le même que ton code n°4

► Afficher le texte

Code : Tout sélectionner

#Include <Array.au3>
Global $MAX_PROPERTIES = 64 ; Maximum par test = 40

$mp3 = "G:\Compil\The Foggy Dew (sinead o'connor & the_chieftains).mp3"
$my_props = getFichierListeProprietes($mp3)
_ArrayDisplay($my_props)

;===================================================

; Fonction de récupération des informations d'un fichier
; Entrée :
; - $chemin [string]  : chemin COMPLET du fichier
; Sortie :
; - $resultat [array] : Matrice de taille [ $n+1 x 3 ]
;                       - $resultat[0][0]     : représente le nombre de propriétés trouvées (apparemment indépendant du type du fichier $chemin), aka $n
;                       - $resultat[i][0] i>0 : représente le nom de la propriété
;                       - $resultat[i][1] i>0 : représente l'indexe système de la propriété
;                       - $resultat[i][2] i>0 : représente la valeur de la propriété pour le fichier $chemin
; - @extended         : [Aucune information]
; - @error            : [Aucune information]
Func getFichierListeProprietes($chemin)
    Local $resultat[1][3] 
    $resultat[0][0] = 0
    If FileExists($chemin) Then
        Local $shell = ObjCreate("shell.application"), $lastSlash = StringInStr($chemin, "\", 0, -1)
        Local $repertoire = $shell.NameSpace(StringLeft($chemin, $lastSlash))
        Local $fichier = $repertoire.Parsename(StringTrimLeft($chemin, $lastSlash))
        For $i = 0 to $MAX_PROPERTIES
            If $repertoire.GetDetailsOf($repertoire.Items, $i) <> "" Then
                ReDim $resultat[UBound($resultat)+1][3]
                $resultat[0][0] = UBound($resultat)-1
                $resultat[$resultat[0][0]][0] = $repertoire.GetDetailsOf($repertoire.Items, $i)
                $resultat[$resultat[0][0]][1] = $i
                $resultat[$resultat[0][0]][2] = $repertoire.GetDetailsOf($fichier, $i)
            EndIf
        Next
    EndIf
    Return $resultat
EndFunc

; Fonction de récupération d'une information d'un fichier
; Entrée :
; - $chemin [string]    : chemin COMPLET du fichier
; - $propriete [string] : nom de la propriété à rechercher
;              [int]    : index système de la propriété à rechercher
; Sortie :
; - $resultat [string]  : Valeur de la propriété pour le fichier $chemin de taille
; - @extended           : Index système de la propriété
; - @error              : [Cas d'erreur]
;                         - @error = 1 : le fichier $chemin est introuvable
;                         - @error = 2 : l'index sytème $propriete est invalide
;                         - @error = 2 : la propriété $propriete est introuvable
Func getFichierPropriete($chemin, $propriete)
    If Not FileExists($chemin) Then
        SetError(1)
    ElseIf IsInt($propriete) And Int($propriete) <= $MAX_PROPERTIES Then
        SetError(2)
    Else
        Local $shell = ObjCreate("shell.application"), $lastSlash = StringInStr($chemin, "\", 0, -1)
        Local $repertoire = $shell.NameSpace(StringLeft($chemin, $lastSlash))
        Local $fichier = $repertoire.Parsename(StringTrimLeft($chemin, $lastSlash))
        If IsInt($propriete) Then
            SetExtended($propriete)
            Return $repertoire.GetDetailsOf($fichier, $propriete)
        Else
            For $i = 0 to $MAX_PROPERTIES
                If $propriete <> "" And $repertoire.GetDetailsOf($repertoire.Items, $i) = $propriete Then
                    SetExtended($i)
                    Return $repertoire.GetDetailsOf($fichier, $i)
                EndIf
            Next
            SetError(3)
        EndIf
    EndIf
    Return ""
EndFunc

#Region Fonctions pour un accès rapide
Func getFichierAuteur($chemin)
    Return getFichierPropriete($chemin, 9)
EndFunc
Func getFichierTitre($chemin)
    Return getFichierPropriete($chemin, 10)
EndFunc
Func getFichierCommentaires($chemin)
    Return getFichierPropriete($chemin, 14)
EndFunc
#EndRegion

[Uranium]

Si tu veux avoir les 'propriétés' d'un fichier audio .mp3 comme : l'Artiste , l'Album ,la Pochette ( si j'ai bien compris)
Il y a un UDF tout fait sur le forum anglais > là

[Fan2Rock]

(Désole de répondre aussi tard)

En tt cas merci beaucoup le code que tu ma passé fonctionne à merveille =)

Juste pour les futurs visiteurs de cette page je sais pas pourquoi mais chez moi le titre c'est 21 et l'artiste c'est 20 (au lieu de 10) ^^

Bye,
Merci,
Ludoo

[blacksoul305]

Hum, si ton problème est résolu, n'oublie pas la balise [R]