[R] Problème dechiffrement TP SdZ

[4sp4rt4m3]

Bonjour à tous,


Bien que le chiffrement ne m'intéresse pas j'ai fini quand même par attaquer le TP Cryptographie de Timmalos sur SdZ.
Tout marche correctement sauf le déchiffrement du texte... Malgré tout les exemples (ainsi que la correction du TP) je ne vois pas mon erreur. Je suis sur que c'est truc tout con, mais je ne la vois pas . Si quelqu'un peut mettre le doigt dessus ^^ sans me donner la réponse... Ca m'aiderais

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <Crypt.au3>

$Form1 = GUICreate("Encrypt-Decrypt", 351, 287, -1, -1)
Global $Tab1 = GUICtrlCreateTab(8, 7, 337, 273)
Global $TabSheet1 = GUICtrlCreateTabItem("Texte")
GUICtrlSetState(-1,$GUI_SHOW)
Global $Chif1 = GUICtrlCreateButton("Chiffrer", 181, 252, 75, 20)
Global $Dech1 = GUICtrlCreateButton("Déchiffrer", 262, 252, 75, 20)
Global $Edit1 = GUICtrlCreateEdit("Collez votre texte ici...", 19, 40, 313, 121)
Global $Input1 = GUICtrlCreateInput("", 104, 176, 121, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))
Global $Label1 = GUICtrlCreateLabel("Mot de passe :", 24, 178, 74, 17)
Global $Label2 = GUICtrlCreateLabel("Algorithme :", 36, 210, 62, 17)
Global $Combo1 = GUICtrlCreateCombo("", 104, 208, 81, 25, BitOR($CBS_DROPDOWNLIST,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "--------|RC2|RC4|DES|3DES|AES 128|AES 192|AES 256|", "--------")
GUICtrlSetTip(-1, "Sélectionnez l'algorithme de chiffrement")
$Aide1 = GUICtrlCreateButton("?", 14, 252, 19, 20)
GUICtrlSetTip(-1, "Aide")
$Button9 = GUICtrlCreateButton("Reset", 38, 252, 35, 20)
GUICtrlSetTip(-1, "Remise à Zer0")
Global $TabSheet2 = GUICtrlCreateTabItem("Fichier")
Global $Chif2 = GUICtrlCreateButton("Chiffrer", 181, 252, 75, 20)
Global $Dech2 = GUICtrlCreateButton("Déchiffrer", 262, 252, 75, 20)
Global $Input2 = GUICtrlCreateInput("", 104, 118, 121, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))
Global $Combo2 = GUICtrlCreateCombo("", 104, 152, 81, 25, BitOR($CBS_DROPDOWNLIST,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "--------|RC2|RC4|DES|3DES|AES 128|AES 192|AES 256", "--------")
GUICtrlSetTip(-1, "Sélectionnez l'algorithme de chiffrement")
Global $Label3 = GUICtrlCreateLabel("Mot de passe :", 24, 120, 74, 17)
Global $Label4 = GUICtrlCreateLabel("Algorithme :", 36, 154, 62, 17)
Global $Button5 = GUICtrlCreateButton("...", 290, 73, 35, 22)
GUICtrlSetTip(-1, "Parcourir")
Global $Input3 = GUICtrlCreateInput("", 20, 74, 265, 21)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Input4 = GUICtrlCreateInput("", 20, 214, 265, 21)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Button6 = GUICtrlCreateButton("...", 290, 213, 35, 22)
GUICtrlSetTip(-1, "Parcourir")
$Aide2 = GUICtrlCreateButton("?", 14, 252, 19, 20)
GUICtrlSetTip(-1, "Aide")
$Label5 = GUICtrlCreateLabel("Sélectionnez un fichier :", 20, 52, 117, 17)
$Label6 = GUICtrlCreateLabel("Destination du fichier :", 20, 192, 109, 17)
$Button10 = GUICtrlCreateButton("Reset", 38, 252, 35, 20)
GUICtrlSetTip(-1, "Remise à Zer0")
GUICtrlCreateTabItem("")
GUISetState(@SW_SHOW)
Global $algo
Global $algo2



While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Combo1
            Switch GUICtrlRead($Combo1) ;listing de ce propose le contenu de la combobox
                Case "RC2"
                    $algo = $CALG_RC2 ; si l'item du combobox est sur "RC2" alors la valeur de la variable $algo est : $CALG_RC2

                Case "RC4"
                    $algo = $CALG_RC4 ; ainsi de suite

                Case "DES"
                    $algo = $CALG_DES

                Case "3DES"
                    $algo = $CALG_3DES

                Case "AES 128"
                    $algo = $CALG_AES_128

                Case "AES 192"
                    $algo = $CALG_AES_192

                Case "AES 256"
                    $algo = $CALG_AES_256
            EndSwitch

            Case $Combo2
            Switch GUICtrlRead($Combo2)
                Case "RC2"
                    $algo2 = $CALG_RC2

                Case "RC4"
                    $algo2 = $CALG_RC4

                Case "DES"
                    $algo2 = $CALG_DES

                Case "3DES"
                    $algo2 = $CALG_3DES

                Case "AES 128"
                    $algo2 = $CALG_AES_128

                Case "AES 192"
                    $algo2 = $CALG_AES_192

                Case "AES 256"
                    $algo2 = $CALG_AES_256
            EndSwitch

        Case $Chif1
            $LireEdit = GUICtrlRead($Edit1)  ; recupere le contenu de l'Edit
            $LireCombo = GUICtrlRead($Combo1) ; recupere le contenu l'Item du combobox
            If $LireEdit = ""  Then  ; si l'Edit est vide alors...
                MsgBox(16, "Information manquante!", "Veuillez insérer un texte dans le champ prévu à cet effet!")
            ElseIf $LireCombo = "--------" Then   ; sinon si la combo affiche "--------" alors...
                MsgBox(16, "Information manquante!", "Aucun algorithme n'a été spécifié dans la liste déroulante!")
            Else  ; si tout est en règle alors on chiffre le texte donné...
            $Crypt = _Crypt_EncryptData(GUICtrlRead($Edit1), GUICtrlRead($Input1), $algo)
            $affiche = GUICtrlSetData($Edit1, $Crypt)
            EndIf

        Case $Dech1
            $Decrypt = _Crypt_DecryptData(GUICtrlRead($Edit1), GUICtrlRead($Input1), $algo) ; Idem mais à l'envers
            $affiche2 = GUICtrlSetData($Edit1, $Decrypt)

        Case $Button5
            Global $FilePath = FileOpenDialog("Choisissez un fichier", @DesktopDir, "Tout les fichiers (*.*)", 1) ; ouvre une fenetre pour selectionner un fichier
            GUICtrlSetData($Input3, $FilePath) ; met le chemin du fichier dans l'Input3

        Case $Button6
            Global $SavePath = FileSaveDialog("Destination du fichier", @DesktopDir, "Tout les fichier (*.*)", 16, "")
            GUICtrlSetData($Input4, $SavePath)

        Case $Chif2
            $LireInput3 = GUICtrlRead($Input3)
            $LireInput4 = GUICtrlRead($Input4)
            $LireCombo2 = GUICtrlRead($Combo2)
            If $LireInput3 Or $LireInput4 = ""  Then
                MsgBox(16, "Manque(s) d'information(s)", "Vous devez sélectionner un fichier et sa destination...")
            ElseIf $LireCombo2 = "--------"  Then
                MsgBox(16, "Manque d'information", "Aucun algorithme n'a été spécifié dans la liste déroulante!")
            Else
            $CryptFile = _Crypt_EncryptFile($FilePath, $FilePath & ".crypt", GUICtrlRead($Input2), $algo2)
            EndIf

        Case $Dech2
            $DecryptFile = _Crypt_DecryptFile($FilePath, $FilePath & ".decrypt", GUICtrlRead($Input2), $algo2)

        Case $Button9
            GUICtrlSetData($Edit1, "")
            GUICtrlSetData($Input1, "")
            GUICtrlSetData($Combo1, "--------")

        Case $Button10
            GUICtrlSetData($Input2, "")
            GUICtrlSetData($Input3, "")
            GUICtrlSetData($Input4, "")
            GUICtrlSetData($Combo2, "--------")

    EndSwitch
WEnd
 

Merci de vos éventuelles aides.

[tioxine]

Bonjour,

Si si ça marche, mais le retour est en hexa
Si on utilise le décodage hexa => ascii, on obtient le bon texte

Code : Tout sélectionner

        Case $Dech1
            $Decrypt = _Crypt_DecryptData(GUICtrlRead($Edit1), GUICtrlRead($Input1), $algo) ; Idem mais à l'envers;
            $affiche2 = GUICtrlSetData($Edit1, _HexToString(StringRight($Decrypt,StringLen($Decrypt) - 2)))
 

A+

[4sp4rt4m3]

C'était effectivement la fonction "_HexToString" qui me manquais, merci à toi pour l'aide

[ricky]

Hello,

j'ai regardé le code que tu as posté et il m'a intéressé, donc je me suis amusé à le modifier/améliorer pour mon usage, voici ce que ça donne :

► Afficher le texte

Code : Tout sélectionner

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <String.au3>
#include <Crypt.au3>

Global $arrayEncryptFile[6] = [5,"Failed to create key","Failed to open source file","Failed to open destination file","Failed to encrypt final piece","Failed to encrypt piece"]
Global $arrayEncryptDate[3] = [2,"Cannot create key","Failed to decrypt data"]
Global $algo, $temp, $nMsg
Global $choixCryptage = "RC2|RC4|DES|3DES|AES 128|AES 192|AES 256"

Global $softName = "Crypteur"

Global $Form1 = GUICreate($softName, 351, 287, -1, -1)
Global $Tab1 = GUICtrlCreateTab(8, 7, 337, 273)
Global $TabSheet1 = GUICtrlCreateTabItem("Texte")
GUICtrlSetState(-1,$GUI_SHOW)
Global $Chif1 = GUICtrlCreateButton("Chiffrer", 181, 252, 75, 20)
Global $Dech1 = GUICtrlCreateButton("Déchiffrer", 262, 252, 75, 20)
Global $Edit1 = GUICtrlCreateEdit("Collez votre texte ici...", 19, 40, 313, 121)
Global $Input1 = GUICtrlCreateInput("", 104, 176, 121, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))
GUICtrlCreateLabel("Mot de passe :", 24, 178, 74, 17)
GUICtrlCreateLabel("Algorithme :", 36, 210, 62, 17)
Global $Combo1 = GUICtrlCreateCombo("", 104, 208, 81, 25, BitOR($CBS_DROPDOWNLIST,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, $choixCryptage, "")
GUICtrlSetTip(-1, "Sélectionnez l'algorithme de chiffrement")
Global $Aide1 = GUICtrlCreateButton("?", 14, 252, 19, 20)
GUICtrlSetTip(-1, "Aide")
Global $Button9 = GUICtrlCreateButton("Reset", 38, 252, 35, 20)
GUICtrlSetTip(-1, "Remise à Zer0")
Global $TabSheet2 = GUICtrlCreateTabItem("Fichier")
Global $Chif2 = GUICtrlCreateButton("Chiffrer", 181, 252, 75, 20)
Global $Dech2 = GUICtrlCreateButton("Déchiffrer", 262, 252, 75, 20)
Global $Input2 = GUICtrlCreateInput("", 104, 118, 121, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))
Global $Combo2 = GUICtrlCreateCombo("", 104, 152, 81, 25, BitOR($CBS_DROPDOWNLIST,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, $choixCryptage, "")
GUICtrlSetTip(-1, "Sélectionnez l'algorithme de chiffrement")
GUICtrlCreateLabel("Mot de passe :", 24, 120, 74, 17)
GUICtrlCreateLabel("Algorithme :", 36, 154, 62, 17)
Global $Button5 = GUICtrlCreateButton("...", 290, 73, 35, 22)
GUICtrlSetTip(-1, "Parcourir")
Global $Input3 = GUICtrlCreateInput("", 20, 74, 265, 21)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Input4 = GUICtrlCreateInput("", 20, 214, 265, 21)
GUICtrlSetState(-1, $GUI_DISABLE)
Global $Button6 = GUICtrlCreateButton("...", 290, 213, 35, 22)
GUICtrlSetTip(-1, "Parcourir")
Global $Aide2 = GUICtrlCreateButton("?", 14, 252, 19, 20)
GUICtrlSetTip(-1, "Aide")
GUICtrlCreateLabel("Sélectionnez un fichier :", 20, 52, 117, 17)
GUICtrlCreateLabel("Destination du fichier :", 20, 192, 109, 17)
Global $Button10 = GUICtrlCreateButton("Reset", 38, 252, 35, 20)
GUICtrlSetTip(-1, "Remise à Zer0")
GUICtrlCreateTabItem("")
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Combo1

            $algo = ChoixAlgo(GUICtrlRead($Combo1))

        Case $Combo2

            $algo = ChoixAlgo(GUICtrlRead($Combo2))

        Case $Chif1
            If GUICtrlRead($Edit1) = ""  Then  ; si l'Edit est vide alors...
                MsgBox(16, "Information manquante!", "Veuillez insérer un texte dans le champ prévu à cet effet!")
            ElseIf GUICtrlRead($Combo1) = "" Then   ; sinon si la combo affiche "" alors...
                MsgBox(16, "Information manquante!", "Aucun algorithme n'a été spécifié dans la liste déroulante!")
            Else  ; si tout est en règle alors on chiffre le texte donné...
                $temp = _Crypt_EncryptData(GUICtrlRead($Edit1), GUICtrlRead($Input1), $algo)

                if @error = 0 then
                    GUICtrlSetData($Edit1, $temp)
                Else
                    MsgBox(16,$softName,"Erreur lors du cryptage : " & $arrayEncryptDate[@error])
                endif

            EndIf

        Case $Dech1
            If GUICtrlRead($Edit1) = ""  Then  ; si l'Edit est vide alors...
                MsgBox(16, "Information manquante!", "Veuillez insérer un texte dans le champ prévu à cet effet!")
            ElseIf GUICtrlRead($Combo1) = "" Then   ; sinon si la combo affiche "" alors...
                MsgBox(16, "Information manquante!", "Aucun algorithme n'a été spécifié dans la liste déroulante!")
            Else  ; si tout est en règle alors on chiffre le texte donné...
                $temp = _Crypt_DecryptData(GUICtrlRead($Edit1), GUICtrlRead($Input1), $algo) ; Idem mais à l'envers;

                if @error = 0 then
                    GUICtrlSetData($Edit1, _HexToString(StringRight($temp,StringLen($temp) - 2)))
                Else
                    MsgBox(16,$softName,"Erreur lors du décryptage : " & $arrayEncryptDate[@error])
                endif

            EndIf

        Case $Button5
            $temp = FileOpenDialog("Choisissez un fichier", @DesktopDir, "Tout les fichiers (*.*)", 1) ; ouvre une fenetre pour selectionner un fichier
            GUICtrlSetData($Input3, $temp) ; met le chemin du fichier dans l'Input3

        Case $Button6
            $temp = FileSaveDialog("Destination du fichier", @DesktopDir, "Tout les fichier (*.*)", 16, "")
            GUICtrlSetData($Input4, $temp)

        Case $Chif2

            If GUICtrlRead($Input3) = "" Or GUICtrlRead($Input4) = ""  Then
                MsgBox(16, "Manque(s) d'information(s)", "Vous devez sélectionner un fichier et sa destination...")
            ElseIf GUICtrlRead($Combo2) = ""  Then
                MsgBox(16, "Manque d'information", "Aucun algorithme n'a été spécifié dans la liste déroulante!")
            Else
                _Crypt_EncryptFile(GUICtrlRead($Input3), GUICtrlRead($Input4) & ".crypt", GUICtrlRead($Input2), $algo)

                if @error = 0 then
                    CleanFichier ()
                Else
                    MsgBox(16,$softName,"Erreur lors du cryptage : " & $arrayEncryptFile[@error])
                endif
            EndIf

        Case $Dech2
            If GUICtrlRead($Input3) = "" Or GUICtrlRead($Input4) = ""  Then
                MsgBox(16, "Manque(s) d'information(s)", "Vous devez sélectionner un fichier et sa destination...")
            ElseIf GUICtrlRead($Combo2) = ""  Then
                MsgBox(16, "Manque d'information", "Aucun algorithme n'a été spécifié dans la liste déroulante!")
            Else
                _Crypt_DecryptFile(GUICtrlRead($Input3), GUICtrlRead($Input4) & ".decrypt", GUICtrlRead($Input2), $algo)

                if @error = 0 then
                    CleanFichier ()
                Else
                    MsgBox(16,$softName,"Erreur lors du décryptage : " & $arrayEncryptFile[@error])
                endif
            EndIf

        Case $Button9
            CleanTexte ()

        Case $Button10
            CleanFichier ()

    EndSwitch
WEnd

Func ChoixAlgo ($value)

    Switch $value
        Case "RC2"
            Return $CALG_RC2

        Case "RC4"
            Return $CALG_RC4

        Case "DES"
            Return $CALG_DES

        Case "3DES"
            Return $CALG_3DES

        Case "AES 128"
            Return $CALG_AES_128

        Case "AES 192"
            Return $CALG_AES_192

        Case "AES 256"
            Return $CALG_AES_256
    EndSwitch
EndFunc

Func CleanFichier ()
    $algo = ""
    GUICtrlSetData($Input2, "")
    GUICtrlSetData($Input3, "")
    GUICtrlSetData($Input4, "")
    GUICtrlSetData($Combo2, "|" & $choixCryptage,$algo)
EndFunc

Func CleanTexte ()
    $algo = ""
    GUICtrlSetData($Edit1, "Collez votre texte ici...")
    GUICtrlSetData($Input1, "")
    GUICtrlSetData($Combo1, "|" & $choixCryptage,$algo)
EndFunc

A toi de voir si ça t'intéresse...

[4sp4rt4m3]

Merci du partage Ricky, je pourrai m'en inspirer pour un prochain petit projet...