[R] Mise à jour d'une Edit ?

[blacksoul305]

EDIT : ###ATTENTION, l'idée de la mise à jour de l'Edit a été arrêté car bien trop compliquée et encombrante, solution finale : ListView###

Salut salut,

voilà le soucis. Donc, au premier abord, vous pensez sûrement que ma demande sort d'un abruti qui semble ne pas avoir lu les règles du forum et encore moins les commandes de la touche F1 après avoir vu le titre, cependant c'pas aussi simple que ça.

Dans mon programme, on peut choisir plusieurs choses qui sont répertoriés dans un .ini. Pour donner un peu plus de style, j'ai décidé de mettre une Edit dans une autre GUI et qu'au fur et à mesure que l'utilisateur choisi, l'Edit se mette à jour. J'ai d'abord essayé ça :

Ajouter qqch :

Code : Tout sélectionner

<condition>
$qqch = lolipop
$save = GuiCtrlRead($Edit1)
GuiCtrlSetData($Edit1,$save& @CRLF& "- "&$qqch)

supprimer qqch :

Code : Tout sélectionner

<condition>
GuictrlSetData($Edit,$save)

Donc oui là ça marchait, mais pour 2 qqch, puisque si j'en mes trois, je supprime une fois j'ai $save de l'autre fois, mais je re-supprime, bah là ça marche pas.
J'ai donc essayé ça :

Ajouter qqch :

Code : Tout sélectionner

<condition>
$var = IniReadSectionNames($ini) ; les noms de sections représentent les qqch
For $i = 1 To $var[0]
GuiCtrlSetData($Edit1,"- "&$var[$i]&@CRLF)

Tout cela ne s'est pas montré efficace. Je veux qu'en fait (et oui je complique), que les "qqch" c'est à dire les noms de sections soient comme cela dans mon Edit :

- plop
- flop
- clac
- boum

Je vous remercie d'avance !

[Tlem]

Sujet du message: [..] Mise à jour d'une Edit ?
Message non luPosté: Ven 23 Mar 2012 à 21:21

Salut salut,

voilà le soucis. Donc, au premier abord, vous pensez sûrement que ma demande sort d'un abruti qui semble ne pas avoir lu les règles du forum et encore moins les commandes de la touche F1 après avoir vu le titre, cependant c'pas aussi simple que ça.

Ha !!!

Le titre me semble correct.
La politesse au début et à la fin y est !
Le problème à l'air d’être décrit correctement.

Pourquoi être aussi négatif ?
Doit-je lire le reste de votre sujet afin de voir le problème ou doit-je m'arrêter à "ma demande sort d'un abruti" ?

[lesolutionneur]

@Tlem : ton message est useless

[blacksoul305]

Héhé, il est vrai que j'ai peut être été trop négatif sur ce coup là. C'est juste que mon sujet a l'air d'être naze car on apprend ça dans les premiers chapitre du tutoriel, mais là c'est que c'est un peu plus compliqué. J'arrive pas à voir comment arriver à ce que je veux, vous avez quelque chose à me proposer ? Un code ou une piste ?

Merci !

[Tlem]

C'est un mélange de divers solutions, mais cela devrait (je l'espère) vous donner un guide :

► Afficher le texte

Code : Tout sélectionner

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

Global $TextDeMonEdit
Global $TableauIni[5] = [4, "plop", "flop", "clac", "boum"] ; Tableau créé par IniReadSectionNames

; La GUI
Global $GUI1 = GUICreate("Form1", 282, 179, 192, 124)
Global $Edit1 = GUICtrlCreateEdit("", 8, 8, 153, 161)
Global $Button1 = GUICtrlCreateButton("Ajout 1 Ligne", 184, 16, 75, 25)
Global $Button2 = GUICtrlCreateButton("Ajout 3 lignes", 184, 56, 75, 25)
Global $Button3 = GUICtrlCreateButton("Lecture", 184, 96, 75, 25)
Global $Button4 = GUICtrlCreateButton("Efface", 184, 136, 75, 25)

_RempliEdit($TableauIni) ; On rempli l'édit avec les données du tableau.

GUISetState(@SW_SHOW) ; On affiche la GUI

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE ; Pour quitter
            Exit

        Case $Button1
            $TextDeMonEdit = GUICtrlRead($Edit1) ; Je lit le contenu de l'édit dans $TextDeMonEdit
            GUICtrlSetData($Edit1, $TextDeMonEdit & @CRLF & "- Ligne ajoutée") ; Je rajoute une ligne à $TextDeMonEdit et je met à jour l'edit.

        Case $Button2
            Local $Mes3lignes = "Ligne 01" & @CRLF & "Ligne 02" & @CRLF & "Ligne 03" ; Je crée une chaine de trois lignes.
            Local $aMes3Lignes = StringSplit($Mes3lignes, @CRLF, 1) ; Je transforme la chaine en tableau
            _RempliEdit($aMes3Lignes) ; Je rajoute les lignes à l'edit.

        Case $Button3
            $TextDeMonEdit = GUICtrlRead($Edit1) ; Je lit le contenu de l'édit dans $TextDeMonEdit
            MsgBox(0, "", $TextDeMonEdit) ; J'affiche le résultat dans un boite de dialogue.

        Case $Button4
            GUICtrlSetData($Edit1, "") ; J'efface l'edit.

    EndSwitch
WEnd

Func _RempliEdit($aTableau)
    If Not IsArray($aTableau) Then Return ; Si $aTableau n'est pas un tableau, on sort de la fonction

    Local $sToAdd
    Local $sEdit = GUICtrlRead($Edit1) ; Je lit le contenu de l'édit dans $sEdit

    ; Je transforme le tableau en chaine (avec le - et l'espace devant le mot)
    For $i = 1 To UBound($aTableau) - 1
        $sToAdd &= "- " & $aTableau[$i] & @CRLF
    Next

    $sToAdd = StringTrimRight($sToAdd, 2) ; Je vire le dernier @CRLF qui ne sert à rien

    If $sEdit = "" Then ; Je contrôle si l'edit est vide (cela évite une ligne vierge au début)
        GUICtrlSetData($Edit1, $sToAdd)
    Else ; Sinon j'ajoute au contenu de $Edit1
        GUICtrlSetData($Edit1, GUICtrlRead($Edit1) & @CRLF & $sToAdd)
    EndIf
EndFunc   ;==>_RempliEdit

[mikell]

On peut aussi vachement se simplifier la vie en utilisant, au lieu d'une edit, une listview sans header et à une seule colonne
Le look est identique mais c'est plus facile à gérer

[Tlem]

+1, mais je fait avec ce qui à été proposé.

[parazitenew]

Coucou, je passais par là

ça m'interresserai de savoir comment enlever le header d'une listview,

[mikell]

Code : Tout sélectionner

$oIE=ObjCreate("Shell.Explorer.2")
$gui = GUICreate("", 700, 450, -1, -1, -1, 0x80) 
$gX = GUICtrlCreateObj($oIE, 0, 0, 700, 450)
GUISetState()
$oIE.Navigate("mk:@MSITStore:" & StringRegExpReplace(@Autoitexe, '(.+)\\[^\\]+', "$1") _  
    & "\AutoIt3.chm::/html/appendix/GUIStyles.htm#ListView")
$oIE.Refresh
While GuiGetMsg()<>-3
Wend

[matwachich]

@parazitenew: regardez les style de GuiCtrlCreateListView (plus précisément $LVS_NOCOLUMNHEADER)

Pour le problème principal, je dis qu'il faudrait séparer les données de l'affichage:
- Les données sont stockées dans un Array (qu'on peut facilement gérer - ajouter/enlever)
- L'affichage se fait à partir du Array: à chaque fois, on efface tout le contenu, et on en construit un autre (String) qu'on insert dans le Edit

C'est une méthode parmi d'autres...

PS: @mikell, mmm j'adore cette fonction des fichiers d'aide...

[blacksoul305]

Déjà merci pour votre code Tlem commenté (mois pas savoir parler très bien le français) code commenté Tlem, je vais l'étudier car les arrays sont vraiment pas ma tasse de thé, mais il est vrai qu'avec mon fonctionnement (qqch = section d'un ini), je suis obligé de me battre avec, pas très bons copains hein ?

Bref, l'idée de la Treeview me branche pas mal, mais l'truc c'est que ça me fait peur le nombre de topics créés à cause de cette commande maléfique . Aussi jusqu'à maintenant F1 ajouter qqch en l'écrivant en tant que nom de section, et F2 supprimer un qqch en le supprimant de l'ini et lors du lancement du code principal, on lit une dernière fois le Ini, on refait la liste de tout ce qui est là et on traite le tout en boucle. Voilà, j'espère vous avoir un peu plus renseigné sur le protocole du prog. Maintenant, est-ce que l'idée de Treeview va pas être un peu difficile à mettre en place, je sais pas du tout. Vous allez me dire, le but de la programmation c'est de passer toujours à quelque chose de plus dur et de plus intéressant. J'ai cependant peur d'en avoir marre à ne pas y arriver au bout d'un moment .

Bon, je vais regarder le code de Tlem et aussi regarder la doc sur la Treeview, conseils et idées sont les bienvenus. Merci !

EDIT : Après avoir regardé votre code Tlem, je pense avoir trouvé la solution (qui n'est pas écrite) en fait, votre code m'y a fait fortement penser (et à mon avis ça doit être celle proposée par matwachich). En effet, votre code ajoute très bien les lignes avec un tiret comme je le voulais, mais c'est pas ça qui me bloquait. Le problème chez moi était lors de la suppression d'un qqch qui ne marchait pas au delà de 2 qqch. Inutile quoi. Pourquoi ne pas tout simplement supprimer une ligne du tableau et par la même occasion du ini, on relit une fois le ini, on remet à jour l'Edit ? Bien sûr, je dis "tout simplement" mais j'en suis incapable mais vous pouvez peut être
Lazy mode: ON
me fournir un truc tout prêt ?
Lazy mode: OFF
Bon, j'vais voir si j'peux faire quelques test en charcutant le code de Tlem et en créant un ini. Merci en tout cas !

EDIT2 : J'ai essayé ce code sans succès avec cet ini là, j'ai eu ce résultat-ci.
Je pense qu'en fait il ne reviens pas à la ligne de mon Edit, il supprime juste ce qu'il viens de mettre à jour. Et je pense avoir trouver le problème aussi.
EDIT3 : BINGO!

► Afficher le texte

"ce code"

Code : Tout sélectionner

            $var = IniReadSectionNames($ini)
            For $i = 1 To $var[0]
                [strike]GUICtrlSetData($Edit1,"- " &$var[$i]& @CRLF)[/strike]
                GUICtrlSetData($Edit1,[color=#FF0000]GUICtrlRead($Edit1)[/color]&"- " &$var[$i]& @CRLF)
            Next

"cet ini là"

Code : Tout sélectionner

[plop]
[clac]
[plap]
[Flop]

"ce résultat-ci"

Code : Tout sélectionner

- Flop

EDIT4 : Oh crotte j'en ai marre là !!

J'ai deux problèmes maintenant :
En ajoutant un qqch, la liste se met à jour correctement. En ajoutant le second, la liste remet le premier et mes ensuite le second qqch, ce qui me donne :

Code : Tout sélectionner

- qqch1 ; lors du premier ajout
- qqch1 ; lors du second ajout
- qqch2 ; lors du second ajout

En supprimant, j'utilise IniDelete() mais ça supprime seulement la valeur et non le nom de la section. Maintenant je pourrai peut être faire en sorte que si la valeur de la clef de la section qqch = 1 on l'ajoute dans le traitement si ça vaut 0 on s'en occupe pas. Mais là je dois modifier pas mal de lignes et je suis même pas sur d'y arriver ... Ou alors il faudrait que je me démerde à mettre les qqch en tant que valeur et non de nom de section. Y a vraiment aucune autre solution ?

EDIT5 : Yes, je crois que j'ai trouvé pour supprimer le ini :

The Default keyword may also be used which will cause the section to be deleted.

Cela m'enlève une grosse épine du pied, il me manque plus que l'ajout qui m'embête !

Je vous remercie encore pour votre aide si précieuse !!

EDIT6 : Mise à jour du problème donc. Comment mettre à jour une EditBox avec un array de façon à faire :

Code : Tout sélectionner

- chose1
- chose2
-chose3

Ça a l'air dur puisque au forum US on ne me répond pas non plus... Désolé pour le fil à retordre.

[mikell]

Tu persistes dans l'erreur donc tu te fais chier, normal
Le boss et moi on t'a déjà conseillé une listview (PAS une treeview)

[blacksoul305]

Ah... Bah j'suis désolé. Mais si jamais vous avez la réponse à ma dernière question, mettez là. Moi je vais bosser sur la ListView que vous me conseillez. Encore merci à vous pour vos idées !

[mikell]

Pour le mix listview + array + ini voilà un petit script exagérément détaillé qui donne quelques bases

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <ListviewConstants.au3>
#include <Array.au3>

Global $array, $ini = @scriptdir & "\test.ini"
If FileExists($ini) Then
   $array = _ReadZeIni()
   _ArrayDisplay($array)
EndIf

Dim $array[3]
$array[0] = @Autoitexe
$array[1] = @SystemDir & "\cmd.exe"      
$array[2] = @SystemDir & "\notepad.exe"   

$gui = GUICreate("listview items", 300, 180, 100, 200, -1)
$listview = GUICtrlCreateListView("soft", 10, 10, 280, 130, $LVS_NOCOLUMNHEADER)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 270)

Dim $ligne[3]
$ligne[0] = GUICtrlCreateListViewItem($array[0], $listview)
GUICtrlSetImage(-1, @Autoitexe, -1)  
$ligne[1] = GUICtrlCreateListViewItem($array[1], $listview)
GUICtrlSetImage(-1, @SystemDir & "\cmd.exe", -1)
$ligne[2] = GUICtrlCreateListViewItem($array[2], $listview)
GUICtrlSetImage(-1, @SystemDir & "\notepad.exe", -1)
$degage = GuiCtrlCreateButton("supprime", 100, 145, 80, 25)
GUISetState()

While 1
$msg = GUIGetMsg()
Switch $msg
    Case  -3
    _WriteInZeIni()
       Exit
    Case $degage
        $index = ControlListView($gui, "", $listview, "GetSelected")
        GUICtrlDelete($ligne[$index])
        _ArrayDelete($ligne, $index)
EndSwitch
Wend

Func _WriteInZeIni()
FileDelete($ini)
$count = ControlListView($gui, "", $listview, "GetItemCount")
For $i = 0 To $count-1
    IniWrite($ini, $i, ControlListView($gui, "", $listview, "GetText", $i), "" )
Next
EndFunc

Func _ReadZeIni()
If FileExists($ini) Then
   $var = IniReadSectionNames($ini)
   Dim $array[$var[0]]
   For $i = 1 To $var[0]
    $readsection = IniReadSection($ini, $var[$i]) 
    $array[$i-1] = $readsection[1][0]  
   Next
EndIf
Return $array
EndFunc
 

[blacksoul305]

Merci pour le mal que tu t'es donné, c'est super gentil ! Je ne peux malheureusement travailler dessus ce soir car cours obligent, mais je vais essayer demain si j'ai du temps.

Merci encore !

[mikell]

Si je me permets de te chambrer, alors c'est la moindre des choses
Le même un peu remanié (peut-être plus parlant) :

► Afficher le texte

Code : Tout sélectionner

#include <GuiConstantsEx.au3>
#include <ListviewConstants.au3>
#include <Array.au3>

Global $ini = @scriptdir & "\test.ini"
Global $array = _ReadZeIni($ini)        ; 1ère array pour stocker les infos
If @error Then                  ; si le ini est absent, corrompu ou vide
   FileCopy($ini, @scriptdir & "\test.bak")    ; sauvegarde
   FileDelete($ini)
   Dim $array[3]      ; array par défaut
   $array[0] = @Autoitexe
   $array[1] = @SystemDir & "\cmd.exe"      
   $array[2] = @SystemDir & "\notepad.exe"   
EndIf
; _ArrayDisplay($array)

$gui = GUICreate("listview programmes", 340, 180, 500, 20, -1)
$listview = GUICtrlCreateListView("soft", 10, 10, 320, 130, $LVS_NOCOLUMNHEADER)
GUICtrlSendMsg($listview, $LVM_SETCOLUMNWIDTH, 0, 310)

Dim $ligne[UBound($array)]            ; 2ème array pour stocker les handles des items
For $i = 0 To UBound($array)-1
   $ligne[$i] = GUICtrlCreateListViewItem($array[$i], $listview)
   GUICtrlSetImage(-1, $array[$i], -1)  
Next
$ajoute = GuiCtrlCreateButton("ajoute", 50, 145, 80, 25)
$degage = GuiCtrlCreateButton("supprime", 150, 145, 80, 25)
GUISetState()

While 1
$msg = GUIGetMsg()
Switch $msg
    Case  -3
    _WriteInZeIni($ini)
       Exit
    Case $degage
        $index = ControlListView($gui, "", $listview, "GetSelected")
        GUICtrlDelete($ligne[$index])
        _ArrayDelete($ligne, $index)
        _ArrayDelete($array, $index)
    Case $ajoute
    $var = FileOpenDialog("choisir...", @DesktopDir & "\", "softs (*.exe)")
    If not @error Then
        $prevnb = UBound($array)
        ReDim $array[$prevnb+1]
        $array[$prevnb] = $var
        ReDim $ligne[$prevnb+1]
        $ligne[$prevnb] = GUICtrlCreateListViewItem($array[$prevnb], $listview)
        GUICtrlSetImage(-1, $array[$prevnb], -1)
    EndIf   
EndSwitch
Wend

Func _WriteInZeIni($file)
   FileDelete($file)
   For $i = 0 To UBound($array)-1
    IniWrite($file, $i, "path", $array[$i])
   Next
; on peut aussi écrire le ini en lisant la listview :
; $count = ControlListView($gui, "", $listview, "GetItemCount")
; For $i = 0 To $count-1
;   IniWrite($file, $i, ControlListView($gui, "", $listview, "GetText", $i), "" )
; Next
EndFunc

Func _ReadZeIni($file)
   $var = IniReadSectionNames($file)
   If @error Then 
    SetError(1)
    Return
   EndIf
   Dim $array[$var[0]]
   For $i = 1 To $var[0]
    $readsection = IniReadSection($ini, $var[$i]) 
    $array[$i-1] = $readsection[1][1]  
   Next
Return $array
EndFunc
 

[blacksoul305]

J'étudie en ce moment même ton programme, et je vais paraître chiant, mais la commande UBound, je sais pas trop à quoi elle sert. J'ai déjà regardé à la doc, mais je comprend pas son utilité. Or, pas mal de gens l'utilise. Aujourd'hui j'ai parlé de mon problème de mise à jour d'Edit à mon ami, et il m'a retourné ce code, mais qui lui aussi ne marche pas. Il me renvoie même lors de l'exécution (et non la compilation) une erreur :

Code : Tout sélectionner

                $var = IniReadSectionNames($ini)
                For $JaimeLeCacaQuandIlEstMoisi = 1 To UBound($var)
                    GUICtrlSetData($Edit1,"- "&GUICtrlRead($Edit1)&$var[$JaimeLeCacaQuandIlEstMoisi]&@CRLF)
                Next

==> Array variable has incorrect number of subscripts or subscript dimension range exceeded.:

Bon, je vais voir si j'peux me débrouiller avec ton code, encore merci !

[mikell]

Si tu dois utiliser des arrays, UBound est incontournable
ça renvoie le nombre d'éléments dans l'array
exemple :
$array[5] = [0, 1, 2, 3, 4] => 5 éléments donc UBound($array) = 5

La finesse c'est l'index des éléments (qu'on utilise dans une boucle For par exemple) qui commence à 0 (le 1er élément a l'index 0, le 5ème l'index 4 )
Donc pour cette array il faudra écrire :
For $i = 0 To 4
ou alors
For $i = 0 To UBound($array)-1
sinon tu auras la très habituelle erreur "Array variable has incorrect number of subscripts or subscript dimension range exceeded"

Donc l'erreur de ton pote avec IniReadSectionNames c'est :
- ou bien on utilise $var[0] (nombre de sections)
- ou bien UBound($var)-1 (l'array $var a comme éléments $var[0] + un élément par section)
héhé

[blacksoul305]

Oui mais là je connais pas la dimension (je sais pas si on dit comme ça) de l'array, car tu l'as défini à 5, mais dans mon cas il peut être aléatoire...

EDIT : J'ai vu ta dernière commande, je teste dès à présent

EDIT2 : J'arrête avec l'Edit, ça commence à m'embêter cette histoire. Faut que j'essaie de placer une ListView dans mon code principal, ça va être long j'ai l'impression ! Merci pour l'aide en tout cas, c'est sympa.

EDIT3 : J'arrive à la fatale conclusion que dans mon Edit j'ai des doubles de la première section lors du second ajout, comme au problème initial...

[mikell]

Purée mais laisse tomber cette foutue Edit !!!
http://www.autoitscript.fr/forum/viewto ... 020#p65020

Faut que j'essaie de placer une ListView dans mon code principal, ça va être long j'ai l'impression

Faut pas réagir comme ça. Abandonne tes préjugés et tes a-priori, la listview est ton amie